lib/Target/PowerPC/PPCInstrAltivec.td

   1 //===- PPCInstrAltivec.td - The PowerPC Altivec Extension --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Altivec extension to the PowerPC instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Altivec transformation functions and pattern fragments.
  16 //
  17
  18 /// VPKUHUM_shuffle_mask/VPKUWUM_shuffle_mask - Return true if this is a valid
  19 /// shuffle mask for the VPKUHUM or VPKUWUM instructions.
  20 def VPKUHUM_shuffle_mask : PatLeaf<(build_vector), [{
  21   return PPC::isVPKUHUMShuffleMask(N, false);
  22 }]>;
  23 def VPKUWUM_shuffle_mask : PatLeaf<(build_vector), [{
  24   return PPC::isVPKUWUMShuffleMask(N, false);
  25 }]>;
  26
  27 def VPKUHUM_unary_shuffle_mask : PatLeaf<(build_vector), [{
  28   return PPC::isVPKUHUMShuffleMask(N, true);
  29 }]>;
  30 def VPKUWUM_unary_shuffle_mask : PatLeaf<(build_vector), [{
  31   return PPC::isVPKUWUMShuffleMask(N, true);
  32 }]>;
  33
  34
  35 def VMRGLB_shuffle_mask : PatLeaf<(build_vector), [{
  36   return PPC::isVMRGLShuffleMask(N, 1, false);
  37 }]>;
  38 def VMRGLH_shuffle_mask : PatLeaf<(build_vector), [{
  39   return PPC::isVMRGLShuffleMask(N, 2, false);
  40 }]>;
  41 def VMRGLW_shuffle_mask : PatLeaf<(build_vector), [{
  42   return PPC::isVMRGLShuffleMask(N, 4, false);
  43 }]>;
  44 def VMRGHB_shuffle_mask : PatLeaf<(build_vector), [{
  45   return PPC::isVMRGHShuffleMask(N, 1, false);
  46 }]>;
  47 def VMRGHH_shuffle_mask : PatLeaf<(build_vector), [{
  48   return PPC::isVMRGHShuffleMask(N, 2, false);
  49 }]>;
  50 def VMRGHW_shuffle_mask : PatLeaf<(build_vector), [{
  51   return PPC::isVMRGHShuffleMask(N, 4, false);
  52 }]>;
  53
  54 def VMRGLB_unary_shuffle_mask : PatLeaf<(build_vector), [{
  55   return PPC::isVMRGLShuffleMask(N, 1, true);
  56 }]>;
  57 def VMRGLH_unary_shuffle_mask : PatLeaf<(build_vector), [{
  58   return PPC::isVMRGLShuffleMask(N, 2, true);
  59 }]>;
  60 def VMRGLW_unary_shuffle_mask : PatLeaf<(build_vector), [{
  61   return PPC::isVMRGLShuffleMask(N, 4, true);
  62 }]>;
  63 def VMRGHB_unary_shuffle_mask : PatLeaf<(build_vector), [{
  64   return PPC::isVMRGHShuffleMask(N, 1, true);
  65 }]>;
  66 def VMRGHH_unary_shuffle_mask : PatLeaf<(build_vector), [{
  67   return PPC::isVMRGHShuffleMask(N, 2, true);
  68 }]>;
  69 def VMRGHW_unary_shuffle_mask : PatLeaf<(build_vector), [{
  70   return PPC::isVMRGHShuffleMask(N, 4, true);
  71 }]>;
  72
  73 def VSLDOI_get_imm : SDNodeXForm<build_vector, [{
  74   return getI32Imm(PPC::isVSLDOIShuffleMask(N, false));
  75 }]>;
  76 def VSLDOI_shuffle_mask :  PatLeaf<(build_vector), [{
  77   return PPC::isVSLDOIShuffleMask(N, false) != -1;
  78 }], VSLDOI_get_imm>;
  79
  80 /// VSLDOI_unary* - These are used to match vsldoi(X,X), which is turned into
  81 /// vector_shuffle(X,undef,mask) by the dag combiner.
  82 def VSLDOI_unary_get_imm : SDNodeXForm<build_vector, [{
  83   return getI32Imm(PPC::isVSLDOIShuffleMask(N, true));
  84 }]>;
  85 def VSLDOI_unary_shuffle_mask :  PatLeaf<(build_vector), [{
  86   return PPC::isVSLDOIShuffleMask(N, true) != -1;
  87 }], VSLDOI_unary_get_imm>;
  88
  89
  90 // VSPLT*_get_imm xform function: convert vector_shuffle mask to VSPLT* imm.
  91 def VSPLTB_get_imm : SDNodeXForm<build_vector, [{
  92   return getI32Imm(PPC::getVSPLTImmediate(N, 1));
  93 }]>;
  94 def VSPLTB_shuffle_mask : PatLeaf<(build_vector), [{
  95   return PPC::isSplatShuffleMask(N, 1);
  96 }], VSPLTB_get_imm>;
  97 def VSPLTH_get_imm : SDNodeXForm<build_vector, [{
  98   return getI32Imm(PPC::getVSPLTImmediate(N, 2));
  99 }]>;
 100 def VSPLTH_shuffle_mask : PatLeaf<(build_vector), [{
 101   return PPC::isSplatShuffleMask(N, 2);
 102 }], VSPLTH_get_imm>;
 103 def VSPLTW_get_imm : SDNodeXForm<build_vector, [{
 104   return getI32Imm(PPC::getVSPLTImmediate(N, 4));
 105 }]>;
 106 def VSPLTW_shuffle_mask : PatLeaf<(build_vector), [{
 107   return PPC::isSplatShuffleMask(N, 4);
 108 }], VSPLTW_get_imm>;
 109
 110
 111 // VSPLTISB_get_imm xform function: convert build_vector to VSPLTISB imm.
 112 def VSPLTISB_get_imm : SDNodeXForm<build_vector, [{
 113   return PPC::get_VSPLTI_elt(N, 1, *CurDAG);
 114 }]>;
 115 def vecspltisb : PatLeaf<(build_vector), [{
 116   return PPC::get_VSPLTI_elt(N, 1, *CurDAG).Val != 0;
 117 }], VSPLTISB_get_imm>;
 118
 119 // VSPLTISH_get_imm xform function: convert build_vector to VSPLTISH imm.
 120 def VSPLTISH_get_imm : SDNodeXForm<build_vector, [{
 121   return PPC::get_VSPLTI_elt(N, 2, *CurDAG);
 122 }]>;
 123 def vecspltish : PatLeaf<(build_vector), [{
 124   return PPC::get_VSPLTI_elt(N, 2, *CurDAG).Val != 0;
 125 }], VSPLTISH_get_imm>;
 126
 127 // VSPLTISW_get_imm xform function: convert build_vector to VSPLTISW imm.
 128 def VSPLTISW_get_imm : SDNodeXForm<build_vector, [{
 129   return PPC::get_VSPLTI_elt(N, 4, *CurDAG);
 130 }]>;
 131 def vecspltisw : PatLeaf<(build_vector), [{
 132   return PPC::get_VSPLTI_elt(N, 4, *CurDAG).Val != 0;
 133 }], VSPLTISW_get_imm>;
 134
 135 def V_immneg0 : PatLeaf<(build_vector), [{
 136   return PPC::isAllNegativeZeroVector(N);
 137 }]>;
 138
 139 //===----------------------------------------------------------------------===//
 140 // Helpers for defining instructions that directly correspond to intrinsics.
 141
 142 // VA1a_Int - A VAForm_1a intrinsic definition.
 143 class VA1a_Int<bits<6> xo, string opc, Intrinsic IntID>
 144   : VAForm_1a<xo, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB, VRRC:$vC),
 145               !strconcat(opc, " $vD, $vA, $vB, $vC"), VecFP,
 146                        [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB, VRRC:$vC))]>;
 147
 148 // VX1_Int - A VXForm_1 intrinsic definition.
 149 class VX1_Int<bits<11> xo, string opc, Intrinsic IntID>
 150   : VXForm_1<xo, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 151              !strconcat(opc, " $vD, $vA, $vB"), VecFP,
 152              [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB))]>;
 153
 154 // VX2_Int - A VXForm_2 intrinsic definition.
 155 class VX2_Int<bits<11> xo, string opc, Intrinsic IntID>
 156   : VXForm_2<xo, (outs VRRC:$vD), (ins VRRC:$vB),
 157              !strconcat(opc, " $vD, $vB"), VecFP,
 158              [(set VRRC:$vD, (IntID VRRC:$vB))]>;
 159
 160 //===----------------------------------------------------------------------===//
 161 // Instruction Definitions.
 162
 163 def IMPLICIT_DEF_VRRC : Pseudo<(outs VRRC:$rD), (ins),"; IMPLICIT_DEF_VRRC $rD",
 164                                [(set VRRC:$rD, (v4i32 (undef)))]>;
 165
 166 def DSS      : DSS_Form<822, (outs),
 167                         (ins u5imm:$ZERO0, u5imm:$STRM,u5imm:$ZERO1,u5imm:$ZERO2),
 168                         "dss $STRM", LdStGeneral /*FIXME*/, []>;
 169 def DSSALL   : DSS_Form<822, (outs),
 170                         (ins u5imm:$ONE, u5imm:$ZERO0,u5imm:$ZERO1,u5imm:$ZERO2),
 171                         "dssall", LdStGeneral /*FIXME*/, []>;
 172 def DST      : DSS_Form<342, (outs),
 173                         (ins u5imm:$ZERO, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 174                         "dst $rA, $rB, $STRM", LdStGeneral /*FIXME*/, []>;
 175 def DSTT     : DSS_Form<342, (outs),
 176                         (ins u5imm:$ONE, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 177                         "dstt $rA, $rB, $STRM", LdStGeneral /*FIXME*/, []>;
 178 def DSTST    : DSS_Form<374, (outs),
 179                         (ins u5imm:$ZERO, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 180                         "dstst $rA, $rB, $STRM", LdStGeneral /*FIXME*/, []>;
 181 def DSTSTT   : DSS_Form<374, (outs),
 182                         (ins u5imm:$ONE, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 183                         "dststt $rA, $rB, $STRM", LdStGeneral /*FIXME*/, []>;
 184
 185 def DST64    : DSS_Form<342, (outs),
 186                         (ins u5imm:$ZERO, u5imm:$STRM, G8RC:$rA, GPRC:$rB),
 187                         "dst $rA, $rB, $STRM", LdStGeneral /*FIXME*/, []>;
 188 def DSTT64   : DSS_Form<342, (outs),
 189                         (ins u5imm:$ONE, u5imm:$STRM, G8RC:$rA, GPRC:$rB),
 190                         "dstt $rA, $rB, $STRM", LdStGeneral /*FIXME*/, []>;
 191 def DSTST64  : DSS_Form<374, (outs),
 192                         (ins u5imm:$ZERO, u5imm:$STRM, G8RC:$rA, GPRC:$rB),
 193                         "dstst $rA, $rB, $STRM", LdStGeneral /*FIXME*/, []>;
 194 def DSTSTT64 : DSS_Form<374, (outs),
 195                         (ins u5imm:$ONE, u5imm:$STRM, G8RC:$rA, GPRC:$rB),
 196                         "dststt $rA, $rB, $STRM", LdStGeneral /*FIXME*/, []>;
 197
 198 def MFVSCR : VXForm_4<1540, (outs VRRC:$vD), (ins),
 199                       "mfvscr $vD", LdStGeneral,
 200                       [(set VRRC:$vD, (int_ppc_altivec_mfvscr))]>;
 201 def MTVSCR : VXForm_5<1604, (outs), (ins VRRC:$vB),
 202                       "mtvscr $vB", LdStGeneral,
 203                       [(int_ppc_altivec_mtvscr VRRC:$vB)]>;
 204
 205 let isLoad = 1, PPC970_Unit = 2 in {  // Loads.
 206 def LVEBX: XForm_1<31,   7, (outs VRRC:$vD), (ins memrr:$src),
 207                    "lvebx $vD, $src", LdStGeneral,
 208                    [(set VRRC:$vD, (int_ppc_altivec_lvebx xoaddr:$src))]>;
 209 def LVEHX: XForm_1<31,  39, (outs VRRC:$vD), (ins memrr:$src),
 210                    "lvehx $vD, $src", LdStGeneral,
 211                    [(set VRRC:$vD, (int_ppc_altivec_lvehx xoaddr:$src))]>;
 212 def LVEWX: XForm_1<31,  71, (outs VRRC:$vD), (ins memrr:$src),
 213                    "lvewx $vD, $src", LdStGeneral,
 214                    [(set VRRC:$vD, (int_ppc_altivec_lvewx xoaddr:$src))]>;
 215 def LVX  : XForm_1<31, 103, (outs VRRC:$vD), (ins memrr:$src),
 216                    "lvx $vD, $src", LdStGeneral,
 217                    [(set VRRC:$vD, (int_ppc_altivec_lvx xoaddr:$src))]>;
 218 def LVXL : XForm_1<31, 359, (outs VRRC:$vD), (ins memrr:$src),
 219                    "lvxl $vD, $src", LdStGeneral,
 220                    [(set VRRC:$vD, (int_ppc_altivec_lvxl xoaddr:$src))]>;
 221 }
 222
 223 def LVSL : XForm_1<31,   6, (outs VRRC:$vD), (ins memrr:$src),
 224                    "lvsl $vD, $src", LdStGeneral,
 225                    [(set VRRC:$vD, (int_ppc_altivec_lvsl xoaddr:$src))]>,
 226                    PPC970_Unit_LSU;
 227 def LVSR : XForm_1<31,  38, (outs VRRC:$vD), (ins memrr:$src),
 228                    "lvsr $vD, $src", LdStGeneral,
 229                    [(set VRRC:$vD, (int_ppc_altivec_lvsr xoaddr:$src))]>,
 230                    PPC970_Unit_LSU;
 231
 232 let isStore = 1, PPC970_Unit = 2 in {   // Stores.
 233 def STVEBX: XForm_8<31, 135, (outs), (ins VRRC:$rS, memrr:$dst),
 234                    "stvebx $rS, $dst", LdStGeneral,
 235                    [(int_ppc_altivec_stvebx VRRC:$rS, xoaddr:$dst)]>;
 236 def STVEHX: XForm_8<31, 167, (outs), (ins VRRC:$rS, memrr:$dst),
 237                    "stvehx $rS, $dst", LdStGeneral,
 238                    [(int_ppc_altivec_stvehx VRRC:$rS, xoaddr:$dst)]>;
 239 def STVEWX: XForm_8<31, 199, (outs), (ins VRRC:$rS, memrr:$dst),
 240                    "stvewx $rS, $dst", LdStGeneral,
 241                    [(int_ppc_altivec_stvewx VRRC:$rS, xoaddr:$dst)]>;
 242 def STVX  : XForm_8<31, 231, (outs), (ins VRRC:$rS, memrr:$dst),
 243                    "stvx $rS, $dst", LdStGeneral,
 244                    [(int_ppc_altivec_stvx VRRC:$rS, xoaddr:$dst)]>;
 245 def STVXL : XForm_8<31, 487, (outs), (ins VRRC:$rS, memrr:$dst),
 246                    "stvxl $rS, $dst", LdStGeneral,
 247                    [(int_ppc_altivec_stvxl VRRC:$rS, xoaddr:$dst)]>;
 248 }
 249
 250 let PPC970_Unit = 5 in {  // VALU Operations.
 251 // VA-Form instructions.  3-input AltiVec ops.
 252 def VMADDFP : VAForm_1<46, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vC, VRRC:$vB),
 253                        "vmaddfp $vD, $vA, $vC, $vB", VecFP,
 254                        [(set VRRC:$vD, (fadd (fmul VRRC:$vA, VRRC:$vC),
 255                                              VRRC:$vB))]>,
 256                        Requires<[FPContractions]>;
 257 def VNMSUBFP: VAForm_1<47, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vC, VRRC:$vB),
 258                        "vnmsubfp $vD, $vA, $vC, $vB", VecFP,
 259                        [(set VRRC:$vD, (fsub V_immneg0,
 260                                              (fsub (fmul VRRC:$vA, VRRC:$vC),
 261                                                    VRRC:$vB)))]>,
 262                        Requires<[FPContractions]>;
 263
 264 def VMHADDSHS  : VA1a_Int<32, "vmhaddshs",  int_ppc_altivec_vmhaddshs>;
 265 def VMHRADDSHS : VA1a_Int<33, "vmhraddshs", int_ppc_altivec_vmhraddshs>;
 266 def VMLADDUHM  : VA1a_Int<34, "vmladduhm",  int_ppc_altivec_vmladduhm>;
 267 def VPERM      : VA1a_Int<43, "vperm",      int_ppc_altivec_vperm>;
 268 def VSEL       : VA1a_Int<42, "vsel",       int_ppc_altivec_vsel>;
 269
 270 // Shuffles.
 271 def VSLDOI  : VAForm_2<44, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB, u5imm:$SH),
 272                        "vsldoi $vD, $vA, $vB, $SH", VecFP,
 273                        [(set VRRC:$vD,
 274                              (vector_shuffle (v16i8 VRRC:$vA), VRRC:$vB,
 275                                              VSLDOI_shuffle_mask:$SH))]>;
 276
 277 // VX-Form instructions.  AltiVec arithmetic ops.
 278 def VADDFP : VXForm_1<10, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 279                       "vaddfp $vD, $vA, $vB", VecFP,
 280                       [(set VRRC:$vD, (fadd VRRC:$vA, VRRC:$vB))]>;
 281
 282 def VADDUBM : VXForm_1<0, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 283                       "vaddubm $vD, $vA, $vB", VecGeneral,
 284                       [(set VRRC:$vD, (add (v16i8 VRRC:$vA), VRRC:$vB))]>;
 285 def VADDUHM : VXForm_1<64, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 286                       "vadduhm $vD, $vA, $vB", VecGeneral,
 287                       [(set VRRC:$vD, (add (v8i16 VRRC:$vA), VRRC:$vB))]>;
 288 def VADDUWM : VXForm_1<128, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 289                       "vadduwm $vD, $vA, $vB", VecGeneral,
 290                       [(set VRRC:$vD, (add (v4i32 VRRC:$vA), VRRC:$vB))]>;
 291
 292 def VADDCUW : VX1_Int<384, "vaddcuw", int_ppc_altivec_vaddcuw>;
 293 def VADDSBS : VX1_Int<768, "vaddsbs", int_ppc_altivec_vaddsbs>;
 294 def VADDSHS : VX1_Int<832, "vaddshs", int_ppc_altivec_vaddshs>;
 295 def VADDSWS : VX1_Int<896, "vaddsws", int_ppc_altivec_vaddsws>;
 296 def VADDUBS : VX1_Int<512, "vaddubs", int_ppc_altivec_vaddubs>;
 297 def VADDUHS : VX1_Int<576, "vadduhs", int_ppc_altivec_vadduhs>;
 298 def VADDUWS : VX1_Int<640, "vadduws", int_ppc_altivec_vadduws>;
 299
 300
 301 def VAND : VXForm_1<1028, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 302                     "vand $vD, $vA, $vB", VecFP,
 303                     [(set VRRC:$vD, (and (v4i32 VRRC:$vA), VRRC:$vB))]>;
 304 def VANDC : VXForm_1<1092, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 305                      "vandc $vD, $vA, $vB", VecFP,
 306                      [(set VRRC:$vD, (and (v4i32 VRRC:$vA), (vnot VRRC:$vB)))]>;
 307
 308 def VCFSX  : VXForm_1<842, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 309                       "vcfsx $vD, $vB, $UIMM", VecFP,
 310                       [(set VRRC:$vD,
 311                              (int_ppc_altivec_vcfsx VRRC:$vB, imm:$UIMM))]>;
 312 def VCFUX  : VXForm_1<778, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 313                       "vcfux $vD, $vB, $UIMM", VecFP,
 314                       [(set VRRC:$vD,
 315                              (int_ppc_altivec_vcfux VRRC:$vB, imm:$UIMM))]>;
 316 def VCTSXS : VXForm_1<970, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 317                       "vctsxs $vD, $vB, $UIMM", VecFP,
 318                       [(set VRRC:$vD,
 319                              (int_ppc_altivec_vctsxs VRRC:$vB, imm:$UIMM))]>;
 320 def VCTUXS : VXForm_1<906, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 321                       "vctuxs $vD, $vB, $UIMM", VecFP,
 322                       [(set VRRC:$vD,
 323                              (int_ppc_altivec_vctuxs VRRC:$vB, imm:$UIMM))]>;
 324 def VEXPTEFP : VX2_Int<394, "vexptefp", int_ppc_altivec_vexptefp>;
 325 def VLOGEFP  : VX2_Int<458, "vlogefp",  int_ppc_altivec_vlogefp>;
 326
 327 def VAVGSB : VX1_Int<1282, "vavgsb", int_ppc_altivec_vavgsb>;
 328 def VAVGSH : VX1_Int<1346, "vavgsh", int_ppc_altivec_vavgsh>;
 329 def VAVGSW : VX1_Int<1410, "vavgsw", int_ppc_altivec_vavgsw>;
 330 def VAVGUB : VX1_Int<1026, "vavgub", int_ppc_altivec_vavgub>;
 331 def VAVGUH : VX1_Int<1090, "vavguh", int_ppc_altivec_vavguh>;
 332 def VAVGUW : VX1_Int<1154, "vavguw", int_ppc_altivec_vavguw>;
 333
 334 def VMAXFP : VX1_Int<1034, "vmaxfp", int_ppc_altivec_vmaxfp>;
 335 def VMAXSB : VX1_Int< 258, "vmaxsb", int_ppc_altivec_vmaxsb>;
 336 def VMAXSH : VX1_Int< 322, "vmaxsh", int_ppc_altivec_vmaxsh>;
 337 def VMAXSW : VX1_Int< 386, "vmaxsw", int_ppc_altivec_vmaxsw>;
 338 def VMAXUB : VX1_Int<   2, "vmaxub", int_ppc_altivec_vmaxub>;
 339 def VMAXUH : VX1_Int<  66, "vmaxuh", int_ppc_altivec_vmaxuh>;
 340 def VMAXUW : VX1_Int< 130, "vmaxuw", int_ppc_altivec_vmaxuw>;
 341 def VMINFP : VX1_Int<1098, "vminfp", int_ppc_altivec_vminfp>;
 342 def VMINSB : VX1_Int< 770, "vminsb", int_ppc_altivec_vminsb>;
 343 def VMINSH : VX1_Int< 834, "vminsh", int_ppc_altivec_vminsh>;
 344 def VMINSW : VX1_Int< 898, "vminsw", int_ppc_altivec_vminsw>;
 345 def VMINUB : VX1_Int< 514, "vminub", int_ppc_altivec_vminub>;
 346 def VMINUH : VX1_Int< 578, "vminuh", int_ppc_altivec_vminuh>;
 347 def VMINUW : VX1_Int< 642, "vminuw", int_ppc_altivec_vminuw>;
 348
 349 def VMRGHB : VXForm_1< 12, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 350                       "vmrghb $vD, $vA, $vB", VecFP,
 351                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 352                                              VRRC:$vB, VMRGHB_shuffle_mask))]>;
 353 def VMRGHH : VXForm_1< 76, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 354                       "vmrghh $vD, $vA, $vB", VecFP,
 355                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 356                                              VRRC:$vB, VMRGHH_shuffle_mask))]>;
 357 def VMRGHW : VXForm_1<140, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 358                       "vmrghw $vD, $vA, $vB", VecFP,
 359                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 360                                              VRRC:$vB, VMRGHW_shuffle_mask))]>;
 361 def VMRGLB : VXForm_1<268, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 362                       "vmrglb $vD, $vA, $vB", VecFP,
 363                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 364                                              VRRC:$vB, VMRGLB_shuffle_mask))]>;
 365 def VMRGLH : VXForm_1<332, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 366                       "vmrglh $vD, $vA, $vB", VecFP,
 367                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 368                                              VRRC:$vB, VMRGLH_shuffle_mask))]>;
 369 def VMRGLW : VXForm_1<396, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 370                       "vmrglw $vD, $vA, $vB", VecFP,
 371                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 372                                              VRRC:$vB, VMRGLW_shuffle_mask))]>;
 373
 374 def VMSUMMBM : VA1a_Int<37, "vmsummbm", int_ppc_altivec_vmsummbm>;
 375 def VMSUMSHM : VA1a_Int<40, "vmsumshm", int_ppc_altivec_vmsumshm>;
 376 def VMSUMSHS : VA1a_Int<41, "vmsumshs", int_ppc_altivec_vmsumshs>;
 377 def VMSUMUBM : VA1a_Int<36, "vmsumubm", int_ppc_altivec_vmsumubm>;
 378 def VMSUMUHM : VA1a_Int<38, "vmsumuhm", int_ppc_altivec_vmsumuhm>;
 379 def VMSUMUHS : VA1a_Int<39, "vmsumuhs", int_ppc_altivec_vmsumuhs>;
 380
 381 def VMULESB : VX1_Int<776, "vmulesb", int_ppc_altivec_vmulesb>;
 382 def VMULESH : VX1_Int<840, "vmulesh", int_ppc_altivec_vmulesh>;
 383 def VMULEUB : VX1_Int<520, "vmuleub", int_ppc_altivec_vmuleub>;
 384 def VMULEUH : VX1_Int<584, "vmuleuh", int_ppc_altivec_vmuleuh>;
 385 def VMULOSB : VX1_Int<264, "vmulosb", int_ppc_altivec_vmulosb>;
 386 def VMULOSH : VX1_Int<328, "vmulosh", int_ppc_altivec_vmulosh>;
 387 def VMULOUB : VX1_Int<  8, "vmuloub", int_ppc_altivec_vmuloub>;
 388 def VMULOUH : VX1_Int< 72, "vmulouh", int_ppc_altivec_vmulouh>;
 389
 390 def VREFP     : VX2_Int<266, "vrefp",     int_ppc_altivec_vrefp>;
 391 def VRFIM     : VX2_Int<714, "vrfim",     int_ppc_altivec_vrfim>;
 392 def VRFIN     : VX2_Int<522, "vrfin",     int_ppc_altivec_vrfin>;
 393 def VRFIP     : VX2_Int<650, "vrfip",     int_ppc_altivec_vrfip>;
 394 def VRFIZ     : VX2_Int<586, "vrfiz",     int_ppc_altivec_vrfiz>;
 395 def VRSQRTEFP : VX2_Int<330, "vrsqrtefp", int_ppc_altivec_vrsqrtefp>;
 396
 397 def VSUBCUW : VX1_Int<74, "vsubcuw", int_ppc_altivec_vsubcuw>;
 398
 399 def VSUBFP  : VXForm_1<74, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 400                       "vsubfp $vD, $vA, $vB", VecGeneral,
 401                       [(set VRRC:$vD, (fsub VRRC:$vA, VRRC:$vB))]>;
 402 def VSUBUBM : VXForm_1<1024, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 403                       "vsububm $vD, $vA, $vB", VecGeneral,
 404                       [(set VRRC:$vD, (sub (v16i8 VRRC:$vA), VRRC:$vB))]>;
 405 def VSUBUHM : VXForm_1<1088, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 406                       "vsubuhm $vD, $vA, $vB", VecGeneral,
 407                       [(set VRRC:$vD, (sub (v8i16 VRRC:$vA), VRRC:$vB))]>;
 408 def VSUBUWM : VXForm_1<1152, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 409                       "vsubuwm $vD, $vA, $vB", VecGeneral,
 410                       [(set VRRC:$vD, (sub (v4i32 VRRC:$vA), VRRC:$vB))]>;
 411
 412 def VSUBSBS : VX1_Int<1792, "vsubsbs" , int_ppc_altivec_vsubsbs>;
 413 def VSUBSHS : VX1_Int<1856, "vsubshs" , int_ppc_altivec_vsubshs>;
 414 def VSUBSWS : VX1_Int<1920, "vsubsws" , int_ppc_altivec_vsubsws>;
 415 def VSUBUBS : VX1_Int<1536, "vsububs" , int_ppc_altivec_vsububs>;
 416 def VSUBUHS : VX1_Int<1600, "vsubuhs" , int_ppc_altivec_vsubuhs>;
 417 def VSUBUWS : VX1_Int<1664, "vsubuws" , int_ppc_altivec_vsubuws>;
 418 def VSUMSWS : VX1_Int<1928, "vsumsws" , int_ppc_altivec_vsumsws>;
 419 def VSUM2SWS: VX1_Int<1672, "vsum2sws", int_ppc_altivec_vsum2sws>;
 420 def VSUM4SBS: VX1_Int<1672, "vsum4sbs", int_ppc_altivec_vsum4sbs>;
 421 def VSUM4SHS: VX1_Int<1608, "vsum4shs", int_ppc_altivec_vsum4shs>;
 422 def VSUM4UBS: VX1_Int<1544, "vsum4ubs", int_ppc_altivec_vsum4ubs>;
 423
 424 def VNOR : VXForm_1<1284, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 425                     "vnor $vD, $vA, $vB", VecFP,
 426                     [(set VRRC:$vD, (vnot (or (v4i32 VRRC:$vA), VRRC:$vB)))]>;
 427 def VOR : VXForm_1<1156, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 428                       "vor $vD, $vA, $vB", VecFP,
 429                       [(set VRRC:$vD, (or (v4i32 VRRC:$vA), VRRC:$vB))]>;
 430 def VXOR : VXForm_1<1220, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 431                       "vxor $vD, $vA, $vB", VecFP,
 432                       [(set VRRC:$vD, (xor (v4i32 VRRC:$vA), VRRC:$vB))]>;
 433
 434 def VRLB   : VX1_Int<   4, "vrlb", int_ppc_altivec_vrlb>;
 435 def VRLH   : VX1_Int<  68, "vrlh", int_ppc_altivec_vrlh>;
 436 def VRLW   : VX1_Int< 132, "vrlw", int_ppc_altivec_vrlw>;
 437
 438 def VSL    : VX1_Int< 452, "vsl" , int_ppc_altivec_vsl >;
 439 def VSLO   : VX1_Int<1036, "vslo", int_ppc_altivec_vslo>;
 440 def VSLB   : VX1_Int< 260, "vslb", int_ppc_altivec_vslb>;
 441 def VSLH   : VX1_Int< 324, "vslh", int_ppc_altivec_vslh>;
 442 def VSLW   : VX1_Int< 388, "vslw", int_ppc_altivec_vslw>;
 443
 444 def VSPLTB : VXForm_1<524, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 445                       "vspltb $vD, $vB, $UIMM", VecPerm,
 446                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vB), (undef),
 447                                       VSPLTB_shuffle_mask:$UIMM))]>;
 448 def VSPLTH : VXForm_1<588, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 449                       "vsplth $vD, $vB, $UIMM", VecPerm,
 450                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vB), (undef),
 451                                       VSPLTH_shuffle_mask:$UIMM))]>;
 452 def VSPLTW : VXForm_1<652, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 453                       "vspltw $vD, $vB, $UIMM", VecPerm,
 454                       [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vB), (undef),
 455                                       VSPLTW_shuffle_mask:$UIMM))]>;
 456
 457 def VSR    : VX1_Int< 708, "vsr"  , int_ppc_altivec_vsr>;
 458 def VSRO   : VX1_Int<1100, "vsro" , int_ppc_altivec_vsro>;
 459 def VSRAB  : VX1_Int< 772, "vsrab", int_ppc_altivec_vsrab>;
 460 def VSRAH  : VX1_Int< 836, "vsrah", int_ppc_altivec_vsrah>;
 461 def VSRAW  : VX1_Int< 900, "vsraw", int_ppc_altivec_vsraw>;
 462 def VSRB   : VX1_Int< 516, "vsrb" , int_ppc_altivec_vsrb>;
 463 def VSRH   : VX1_Int< 580, "vsrh" , int_ppc_altivec_vsrh>;
 464 def VSRW   : VX1_Int< 644, "vsrw" , int_ppc_altivec_vsrw>;
 465
 466
 467 def VSPLTISB : VXForm_3<780, (outs VRRC:$vD), (ins s5imm:$SIMM),
 468                        "vspltisb $vD, $SIMM", VecPerm,
 469                        [(set VRRC:$vD, (v16i8 vecspltisb:$SIMM))]>;
 470 def VSPLTISH : VXForm_3<844, (outs VRRC:$vD), (ins s5imm:$SIMM),
 471                        "vspltish $vD, $SIMM", VecPerm,
 472                        [(set VRRC:$vD, (v8i16 vecspltish:$SIMM))]>;
 473 def VSPLTISW : VXForm_3<908, (outs VRRC:$vD), (ins s5imm:$SIMM),
 474                        "vspltisw $vD, $SIMM", VecPerm,
 475                        [(set VRRC:$vD, (v4i32 vecspltisw:$SIMM))]>;
 476
 477 // Vector Pack.
 478 def VPKPX   : VX1_Int<782, "vpkpx", int_ppc_altivec_vpkpx>;
 479 def VPKSHSS : VX1_Int<398, "vpkshss", int_ppc_altivec_vpkshss>;
 480 def VPKSHUS : VX1_Int<270, "vpkshus", int_ppc_altivec_vpkshus>;
 481 def VPKSWSS : VX1_Int<462, "vpkswss", int_ppc_altivec_vpkswss>;
 482 def VPKSWUS : VX1_Int<334, "vpkswus", int_ppc_altivec_vpkswus>;
 483 def VPKUHUM : VXForm_1<14, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 484                        "vpkuhum $vD, $vA, $vB", VecFP,
 485                        [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 486                                              VRRC:$vB, VPKUHUM_shuffle_mask))]>;
 487 def VPKUHUS : VX1_Int<142, "vpkuhus", int_ppc_altivec_vpkuhus>;
 488 def VPKUWUM : VXForm_1<78, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 489                        "vpkuwum $vD, $vA, $vB", VecFP,
 490                        [(set VRRC:$vD, (vector_shuffle (v16i8 VRRC:$vA),
 491                                              VRRC:$vB, VPKUWUM_shuffle_mask))]>;
 492 def VPKUWUS : VX1_Int<206, "vpkuwus", int_ppc_altivec_vpkuwus>;
 493
 494 // Vector Unpack.
 495 def VUPKHPX : VX2_Int<846, "vupkhpx", int_ppc_altivec_vupkhpx>;
 496 def VUPKHSB : VX2_Int<526, "vupkhsb", int_ppc_altivec_vupkhsb>;
 497 def VUPKHSH : VX2_Int<590, "vupkhsh", int_ppc_altivec_vupkhsh>;
 498 def VUPKLPX : VX2_Int<974, "vupklpx", int_ppc_altivec_vupklpx>;
 499 def VUPKLSB : VX2_Int<654, "vupklsb", int_ppc_altivec_vupklsb>;
 500 def VUPKLSH : VX2_Int<718, "vupklsh", int_ppc_altivec_vupklsh>;
 501
 502
 503 // Altivec Comparisons.
 504
 505 class VCMP<bits<10> xo, string asmstr, ValueType Ty>
 506   : VXRForm_1<xo, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),asmstr,VecFPCompare,
 507               [(set VRRC:$vD, (Ty (PPCvcmp VRRC:$vA, VRRC:$vB, xo)))]>;
 508 class VCMPo<bits<10> xo, string asmstr, ValueType Ty>
 509   : VXRForm_1<xo, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),asmstr,VecFPCompare,
 510               [(set VRRC:$vD, (Ty (PPCvcmp_o VRRC:$vA, VRRC:$vB, xo)))]> {
 511   let Defs = [CR6];
 512   let RC = 1;
 513 }
 514
 515 // f32 element comparisons.0
 516 def VCMPBFP   : VCMP <966, "vcmpbfp $vD, $vA, $vB"  , v4f32>;
 517 def VCMPBFPo  : VCMPo<966, "vcmpbfp. $vD, $vA, $vB" , v4f32>;
 518 def VCMPEQFP  : VCMP <198, "vcmpeqfp $vD, $vA, $vB" , v4f32>;
 519 def VCMPEQFPo : VCMPo<198, "vcmpeqfp. $vD, $vA, $vB", v4f32>;
 520 def VCMPGEFP  : VCMP <454, "vcmpgefp $vD, $vA, $vB" , v4f32>;
 521 def VCMPGEFPo : VCMPo<454, "vcmpgefp. $vD, $vA, $vB", v4f32>;
 522 def VCMPGTFP  : VCMP <710, "vcmpgtfp $vD, $vA, $vB" , v4f32>;
 523 def VCMPGTFPo : VCMPo<710, "vcmpgtfp. $vD, $vA, $vB", v4f32>;
 524
 525 // i8 element comparisons.
 526 def VCMPEQUB  : VCMP <  6, "vcmpequb $vD, $vA, $vB" , v16i8>;
 527 def VCMPEQUBo : VCMPo<  6, "vcmpequb. $vD, $vA, $vB", v16i8>;
 528 def VCMPGTSB  : VCMP <774, "vcmpgtsb $vD, $vA, $vB" , v16i8>;
 529 def VCMPGTSBo : VCMPo<774, "vcmpgtsb. $vD, $vA, $vB", v16i8>;
 530 def VCMPGTUB  : VCMP <518, "vcmpgtub $vD, $vA, $vB" , v16i8>;
 531 def VCMPGTUBo : VCMPo<518, "vcmpgtub. $vD, $vA, $vB", v16i8>;
 532
 533 // i16 element comparisons.
 534 def VCMPEQUH  : VCMP < 70, "vcmpequh $vD, $vA, $vB" , v8i16>;
 535 def VCMPEQUHo : VCMPo< 70, "vcmpequh. $vD, $vA, $vB", v8i16>;
 536 def VCMPGTSH  : VCMP <838, "vcmpgtsh $vD, $vA, $vB" , v8i16>;
 537 def VCMPGTSHo : VCMPo<838, "vcmpgtsh. $vD, $vA, $vB", v8i16>;
 538 def VCMPGTUH  : VCMP <582, "vcmpgtuh $vD, $vA, $vB" , v8i16>;
 539 def VCMPGTUHo : VCMPo<582, "vcmpgtuh. $vD, $vA, $vB", v8i16>;
 540
 541 // i32 element comparisons.
 542 def VCMPEQUW  : VCMP <134, "vcmpequw $vD, $vA, $vB" , v4i32>;
 543 def VCMPEQUWo : VCMPo<134, "vcmpequw. $vD, $vA, $vB", v4i32>;
 544 def VCMPGTSW  : VCMP <902, "vcmpgtsw $vD, $vA, $vB" , v4i32>;
 545 def VCMPGTSWo : VCMPo<902, "vcmpgtsw. $vD, $vA, $vB", v4i32>;
 546 def VCMPGTUW  : VCMP <646, "vcmpgtuw $vD, $vA, $vB" , v4i32>;
 547 def VCMPGTUWo : VCMPo<646, "vcmpgtuw. $vD, $vA, $vB", v4i32>;
 548
 549 def V_SET0 : VXForm_setzero<1220, (outs VRRC:$vD), (ins),
 550                       "vxor $vD, $vD, $vD", VecFP,
 551                       [(set VRRC:$vD, (v4i32 immAllZerosV))]>;
 552 }
 553
 554 //===----------------------------------------------------------------------===//
 555 // Additional Altivec Patterns
 556 //
 557
 558 // DS* intrinsics
 559 def : Pat<(int_ppc_altivec_dssall), (DSSALL 1, 0, 0, 0)>;
 560 def : Pat<(int_ppc_altivec_dss imm:$STRM), (DSS 0, imm:$STRM, 0, 0)>;
 561
 562 //  * 32-bit
 563 def : Pat<(int_ppc_altivec_dst GPRC:$rA, GPRC:$rB, imm:$STRM),
 564           (DST 0, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 565 def : Pat<(int_ppc_altivec_dstt GPRC:$rA, GPRC:$rB, imm:$STRM),
 566           (DSTT 1, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 567 def : Pat<(int_ppc_altivec_dstst GPRC:$rA, GPRC:$rB, imm:$STRM),
 568           (DSTST 0, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 569 def : Pat<(int_ppc_altivec_dststt GPRC:$rA, GPRC:$rB, imm:$STRM),
 570           (DSTSTT 1, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 571
 572 //  * 64-bit
 573 def : Pat<(int_ppc_altivec_dst G8RC:$rA, GPRC:$rB, imm:$STRM),
 574           (DST64 0, imm:$STRM, (i64 G8RC:$rA), GPRC:$rB)>;
 575 def : Pat<(int_ppc_altivec_dstt G8RC:$rA, GPRC:$rB, imm:$STRM),
 576           (DSTT64 1, imm:$STRM, (i64 G8RC:$rA), GPRC:$rB)>;
 577 def : Pat<(int_ppc_altivec_dstst G8RC:$rA, GPRC:$rB, imm:$STRM),
 578           (DSTST64 0, imm:$STRM, (i64 G8RC:$rA), GPRC:$rB)>;
 579 def : Pat<(int_ppc_altivec_dststt G8RC:$rA, GPRC:$rB, imm:$STRM),
 580           (DSTSTT64 1, imm:$STRM, (i64 G8RC:$rA), GPRC:$rB)>;
 581
 582 // Undef.
 583 def : Pat<(v16i8 (undef)), (IMPLICIT_DEF_VRRC)>;
 584 def : Pat<(v8i16 (undef)), (IMPLICIT_DEF_VRRC)>;
 585 def : Pat<(v4f32 (undef)), (IMPLICIT_DEF_VRRC)>;
 586
 587 // Loads.
 588 def : Pat<(v4i32 (load xoaddr:$src)), (LVX xoaddr:$src)>;
 589
 590 // Stores.
 591 def : Pat<(store (v4i32 VRRC:$rS), xoaddr:$dst),
 592           (STVX (v4i32 VRRC:$rS), xoaddr:$dst)>;
 593
 594 // Bit conversions.
 595 def : Pat<(v16i8 (bitconvert (v8i16 VRRC:$src))), (v16i8 VRRC:$src)>;
 596 def : Pat<(v16i8 (bitconvert (v4i32 VRRC:$src))), (v16i8 VRRC:$src)>;
 597 def : Pat<(v16i8 (bitconvert (v4f32 VRRC:$src))), (v16i8 VRRC:$src)>;
 598
 599 def : Pat<(v8i16 (bitconvert (v16i8 VRRC:$src))), (v8i16 VRRC:$src)>;
 600 def : Pat<(v8i16 (bitconvert (v4i32 VRRC:$src))), (v8i16 VRRC:$src)>;
 601 def : Pat<(v8i16 (bitconvert (v4f32 VRRC:$src))), (v8i16 VRRC:$src)>;
 602
 603 def : Pat<(v4i32 (bitconvert (v16i8 VRRC:$src))), (v4i32 VRRC:$src)>;
 604 def : Pat<(v4i32 (bitconvert (v8i16 VRRC:$src))), (v4i32 VRRC:$src)>;
 605 def : Pat<(v4i32 (bitconvert (v4f32 VRRC:$src))), (v4i32 VRRC:$src)>;
 606
 607 def : Pat<(v4f32 (bitconvert (v16i8 VRRC:$src))), (v4f32 VRRC:$src)>;
 608 def : Pat<(v4f32 (bitconvert (v8i16 VRRC:$src))), (v4f32 VRRC:$src)>;
 609 def : Pat<(v4f32 (bitconvert (v4i32 VRRC:$src))), (v4f32 VRRC:$src)>;
 610
 611 // Shuffles.
 612
 613 // Match vsldoi(x,x), vpkuwum(x,x), vpkuhum(x,x)
 614 def:Pat<(vector_shuffle (v16i8 VRRC:$vA), undef, VSLDOI_unary_shuffle_mask:$in),
 615         (VSLDOI VRRC:$vA, VRRC:$vA, VSLDOI_unary_shuffle_mask:$in)>;
 616 def:Pat<(vector_shuffle (v16i8 VRRC:$vA), undef,VPKUWUM_unary_shuffle_mask:$in),
 617         (VPKUWUM VRRC:$vA, VRRC:$vA)>;
 618 def:Pat<(vector_shuffle (v16i8 VRRC:$vA), undef,VPKUHUM_unary_shuffle_mask:$in),
 619         (VPKUHUM VRRC:$vA, VRRC:$vA)>;
 620
 621 // Match vmrg*(x,x)
 622 def:Pat<(vector_shuffle (v16i8 VRRC:$vA), undef, VMRGLB_unary_shuffle_mask:$in),
 623         (VMRGLB VRRC:$vA, VRRC:$vA)>;
 624 def:Pat<(vector_shuffle (v16i8 VRRC:$vA), undef, VMRGLH_unary_shuffle_mask:$in),
 625         (VMRGLH VRRC:$vA, VRRC:$vA)>;
 626 def:Pat<(vector_shuffle (v16i8 VRRC:$vA), undef, VMRGLW_unary_shuffle_mask:$in),
 627         (VMRGLW VRRC:$vA, VRRC:$vA)>;
 628 def:Pat<(vector_shuffle (v16i8 VRRC:$vA), undef, VMRGHB_unary_shuffle_mask:$in),
 629         (VMRGHB VRRC:$vA, VRRC:$vA)>;
 630 def:Pat<(vector_shuffle (v16i8 VRRC:$vA), undef, VMRGHH_unary_shuffle_mask:$in),
 631         (VMRGHH VRRC:$vA, VRRC:$vA)>;
 632 def:Pat<(vector_shuffle (v16i8 VRRC:$vA), undef, VMRGHW_unary_shuffle_mask:$in),
 633         (VMRGHW VRRC:$vA, VRRC:$vA)>;
 634
 635 // Logical Operations
 636 def : Pat<(v4i32 (vnot VRRC:$vA)),      (VNOR VRRC:$vA, VRRC:$vA)>;
 637 def : Pat<(v4i32 (vnot_conv VRRC:$vA)), (VNOR VRRC:$vA, VRRC:$vA)>;
 638
 639 def : Pat<(v4i32 (vnot_conv (or VRRC:$A, VRRC:$B))),
 640           (VNOR VRRC:$A, VRRC:$B)>;
 641 def : Pat<(v4i32 (and VRRC:$A, (vnot_conv VRRC:$B))),
 642           (VANDC VRRC:$A, VRRC:$B)>;
 643
 644 def : Pat<(fmul VRRC:$vA, VRRC:$vB),
 645           (VMADDFP VRRC:$vA, VRRC:$vB, (v4i32 (V_SET0)))>;
 646
 647 // Fused multiply add and multiply sub for packed float.  These are represented
 648 // separately from the real instructions above, for operations that must have
 649 // the additional precision, such as Newton-Rhapson (used by divide, sqrt)
 650 def : Pat<(PPCvmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 651           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 652 def : Pat<(PPCvnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 653           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 654
 655 def : Pat<(int_ppc_altivec_vmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 656           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 657 def : Pat<(int_ppc_altivec_vnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 658           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 659
 660 def : Pat<(PPCvperm (v16i8 VRRC:$vA), VRRC:$vB, VRRC:$vC),
 661           (VPERM VRRC:$vA, VRRC:$vB, VRRC:$vC)>;