lib/Target/Mips/MipsCondMov.td

   1 //===-- MipsCondMov.td - Describe Mips Conditional Moves --*- tablegen -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This is the Conditional Moves implementation.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 // Conditional moves:
  15 // These instructions are expanded in
  16 // MipsISelLowering::EmitInstrWithCustomInserter if target does not have
  17 // conditional move instructions.
  18 // cond:int, data:int
  19 class CondMovIntInt<RegisterClass CRC, RegisterClass DRC, bits<6> funct,
  20                     string instr_asm> :
  21   FR<0, funct, (outs DRC:$rd), (ins DRC:$rs, CRC:$rt, DRC:$F),
  22      !strconcat(instr_asm, "\t$rd, $rs, $rt"), [], NoItinerary> {
  23   let shamt = 0;
  24   let Constraints = "$F = $rd";
  25 }
  26
  27 // cond:int, data:float
  28 class CMov_I_F_FT<string opstr, RegisterClass CRC, RegisterClass DRC,
  29                   InstrItinClass Itin> :
  30   InstSE<(outs DRC:$fd), (ins DRC:$fs, CRC:$rt, DRC:$F),
  31          !strconcat(opstr, "\t$fd, $fs, $rt"), [], Itin, FrmFR> {
  32   let Constraints = "$F = $fd";
  33 }
  34
  35 // cond:float, data:int
  36 class CMov_F_I_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
  37                   SDPatternOperator OpNode = null_frag> :
  38   InstSE<(outs RC:$rd), (ins RC:$rs, RC:$F),
  39          !strconcat(opstr, "\t$rd, $rs, $$fcc0"),
  40          [(set RC:$rd, (OpNode RC:$rs, RC:$F))], Itin, FrmFR> {
  41   let Uses = [FCR31];
  42   let Constraints = "$F = $rd";
  43 }
  44
  45 // cond:float, data:float
  46 class CMov_F_F_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
  47                   SDPatternOperator OpNode = null_frag> :
  48   InstSE<(outs RC:$fd), (ins RC:$fs, RC:$F),
  49          !strconcat(opstr, "\t$fd, $fs, $$fcc0"),
  50          [(set RC:$fd, (OpNode RC:$fs, RC:$F))], Itin, FrmFR> {
  51   let Uses = [FCR31];
  52   let Constraints = "$F = $fd";
  53 }
  54
  55 // select patterns
  56 multiclass MovzPats0<RegisterClass CRC, RegisterClass DRC,
  57                      Instruction MOVZInst, Instruction SLTOp,
  58                      Instruction SLTuOp, Instruction SLTiOp,
  59                      Instruction SLTiuOp> {
  60   def : MipsPat<(select (i32 (setge CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  61                 (MOVZInst DRC:$T, (SLTOp CRC:$lhs, CRC:$rhs), DRC:$F)>;
  62   def : MipsPat<
  63           (select (i32 (setuge CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  64           (MOVZInst DRC:$T, (SLTuOp CRC:$lhs, CRC:$rhs), DRC:$F)>;
  65   def : MipsPat<
  66           (select (i32 (setge CRC:$lhs, immSExt16:$rhs)), DRC:$T, DRC:$F),
  67           (MOVZInst DRC:$T, (SLTiOp CRC:$lhs, immSExt16:$rhs), DRC:$F)>;
  68   def : MipsPat<
  69           (select (i32 (setuge CRC:$lh, immSExt16:$rh)), DRC:$T, DRC:$F),
  70           (MOVZInst DRC:$T, (SLTiuOp CRC:$lh, immSExt16:$rh), DRC:$F)>;
  71   def : MipsPat<
  72           (select (i32 (setle CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  73           (MOVZInst DRC:$T, (SLTOp CRC:$rhs, CRC:$lhs), DRC:$F)>;
  74   def : MipsPat<
  75           (select (i32 (setule CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  76           (MOVZInst DRC:$T, (SLTuOp CRC:$rhs, CRC:$lhs), DRC:$F)>;
  77 }
  78
  79 multiclass MovzPats1<RegisterClass CRC, RegisterClass DRC,
  80                      Instruction MOVZInst, Instruction XOROp> {
  81   def : MipsPat<(select (i32 (seteq CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  82                 (MOVZInst DRC:$T, (XOROp CRC:$lhs, CRC:$rhs), DRC:$F)>;
  83   def : MipsPat<(select (i32 (seteq CRC:$lhs, 0)), DRC:$T, DRC:$F),
  84                 (MOVZInst DRC:$T, CRC:$lhs, DRC:$F)>;
  85 }
  86
  87 multiclass MovzPats2<RegisterClass CRC, RegisterClass DRC,
  88                      Instruction MOVZInst, Instruction XORiOp> {
  89   def : MipsPat<
  90             (select (i32 (seteq CRC:$lhs, immZExt16:$uimm16)), DRC:$T, DRC:$F),
  91             (MOVZInst DRC:$T, (XORiOp CRC:$lhs, immZExt16:$uimm16), DRC:$F)>;
  92 }
  93
  94 multiclass MovnPats<RegisterClass CRC, RegisterClass DRC, Instruction MOVNInst,
  95                     Instruction XOROp> {
  96   def : MipsPat<(select (i32 (setne CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  97                 (MOVNInst DRC:$T, (XOROp CRC:$lhs, CRC:$rhs), DRC:$F)>;
  98   def : MipsPat<(select CRC:$cond, DRC:$T, DRC:$F),
  99                 (MOVNInst DRC:$T, CRC:$cond, DRC:$F)>;
 100   def : MipsPat<(select (i32 (setne CRC:$lhs, 0)),DRC:$T, DRC:$F),
 101                 (MOVNInst DRC:$T, CRC:$lhs, DRC:$F)>;
 102 }
 103
 104 // Instantiation of instructions.
 105 def MOVZ_I_I     : CondMovIntInt<CPURegs, CPURegs, 0x0a, "movz">;
 106 let Predicates = [HasStdEnc],
 107                   DecoderNamespace = "Mips64" in {
 108   def MOVZ_I_I64   : CondMovIntInt<CPURegs, CPU64Regs, 0x0a, "movz">;
 109   def MOVZ_I64_I   : CondMovIntInt<CPU64Regs, CPURegs, 0x0a, "movz"> {
 110     let isCodeGenOnly = 1;
 111   }
 112   def MOVZ_I64_I64 : CondMovIntInt<CPU64Regs, CPU64Regs, 0x0a, "movz"> {
 113     let isCodeGenOnly = 1;
 114   }
 115 }
 116
 117 def MOVN_I_I     : CondMovIntInt<CPURegs, CPURegs, 0x0b, "movn">;
 118 let Predicates = [HasStdEnc],
 119                   DecoderNamespace = "Mips64" in {
 120   def MOVN_I_I64   : CondMovIntInt<CPURegs, CPU64Regs, 0x0b, "movn">;
 121   def MOVN_I64_I   : CondMovIntInt<CPU64Regs, CPURegs, 0x0b, "movn"> {
 122     let isCodeGenOnly = 1;
 123   }
 124   def MOVN_I64_I64 : CondMovIntInt<CPU64Regs, CPU64Regs, 0x0b, "movn"> {
 125     let isCodeGenOnly = 1;
 126   }
 127 }
 128
 129 def MOVZ_I_S : CMov_I_F_FT<"movz.s", CPURegs, FGR32, IIFmove>,
 130                CMov_I_F_FM<18, 16>;
 131 def MOVZ_I64_S : CMov_I_F_FT<"movz.s", CPU64Regs, FGR32, IIFmove>,
 132                  CMov_I_F_FM<18, 16>, Requires<[HasMips64, HasStdEnc]> {
 133   let DecoderNamespace = "Mips64";
 134 }
 135
 136 def MOVN_I_S : CMov_I_F_FT<"movn.s", CPURegs, FGR32, IIFmove>,
 137                CMov_I_F_FM<19, 16>;
 138 def MOVN_I64_S : CMov_I_F_FT<"movn.s", CPU64Regs, FGR32, IIFmove>,
 139                  CMov_I_F_FM<19, 16>, Requires<[HasMips64, HasStdEnc]> {
 140   let DecoderNamespace = "Mips64";
 141 }
 142
 143 let Predicates = [NotFP64bit, HasStdEnc] in {
 144   def MOVZ_I_D32 : CMov_I_F_FT<"movz.d", CPURegs, AFGR64, IIFmove>,
 145                    CMov_I_F_FM<18, 17>;
 146   def MOVN_I_D32 : CMov_I_F_FT<"movn.d", CPURegs, AFGR64, IIFmove>,
 147                    CMov_I_F_FM<19, 17>;
 148 }
 149 let Predicates = [IsFP64bit, HasStdEnc],
 150                   DecoderNamespace = "Mips64" in {
 151   def MOVZ_I_D64 : CMov_I_F_FT<"movz.d", CPURegs, FGR64, IIFmove>,
 152                    CMov_I_F_FM<18, 17>;
 153   def MOVZ_I64_D64 : CMov_I_F_FT<"movz.d", CPU64Regs, FGR64, IIFmove>,
 154                      CMov_I_F_FM<18, 17> {
 155     let isCodeGenOnly = 1;
 156   }
 157   def MOVN_I_D64 : CMov_I_F_FT<"movn.d", CPURegs, FGR64, IIFmove>,
 158                    CMov_I_F_FM<19, 17>;
 159   def MOVN_I64_D64 : CMov_I_F_FT<"movn.d", CPU64Regs, FGR64, IIFmove>,
 160                      CMov_I_F_FM<19, 17> {
 161     let isCodeGenOnly = 1;
 162   }
 163 }
 164
 165 def MOVT_I : CMov_F_I_FT<"movt", CPURegs, IIAlu, MipsCMovFP_T>, CMov_F_I_FM<1>;
 166 def MOVT_I64 : CMov_F_I_FT<"movt", CPU64Regs, IIAlu, MipsCMovFP_T>,
 167                CMov_F_I_FM<1>, Requires<[HasMips64, HasStdEnc]> {
 168   let DecoderNamespace = "Mips64";
 169 }
 170
 171 def MOVF_I : CMov_F_I_FT<"movf", CPURegs, IIAlu, MipsCMovFP_F>, CMov_F_I_FM<0>;
 172 def MOVF_I64 : CMov_F_I_FT<"movf", CPU64Regs, IIAlu, MipsCMovFP_F>,
 173                CMov_F_I_FM<0>, Requires<[HasMips64, HasStdEnc]> {
 174   let DecoderNamespace = "Mips64";
 175 }
 176
 177 def MOVT_S : CMov_F_F_FT<"movt.s", FGR32, IIFmove, MipsCMovFP_T>,
 178              CMov_F_F_FM<16, 1>;
 179 def MOVF_S : CMov_F_F_FT<"movf.s", FGR32, IIFmove, MipsCMovFP_F>,
 180              CMov_F_F_FM<16, 0>;
 181
 182 let Predicates = [NotFP64bit, HasStdEnc] in {
 183   def MOVT_D32 : CMov_F_F_FT<"movt.d", AFGR64, IIFmove, MipsCMovFP_T>,
 184                  CMov_F_F_FM<17, 1>;
 185   def MOVF_D32 : CMov_F_F_FT<"movf.d", AFGR64, IIFmove, MipsCMovFP_F>,
 186                  CMov_F_F_FM<17, 0>;
 187 }
 188 let Predicates = [IsFP64bit, HasStdEnc],
 189     DecoderNamespace = "Mips64" in {
 190   def MOVT_D64 : CMov_F_F_FT<"movt.d", FGR64, IIFmove, MipsCMovFP_T>,
 191                  CMov_F_F_FM<17, 1>;
 192   def MOVF_D64 : CMov_F_F_FT<"movf.d", FGR64, IIFmove, MipsCMovFP_F>,
 193                  CMov_F_F_FM<17, 0>;
 194 }
 195
 196 // Instantiation of conditional move patterns.
 197 defm : MovzPats0<CPURegs, CPURegs, MOVZ_I_I, SLT, SLTu, SLTi, SLTiu>;
 198 defm : MovzPats1<CPURegs, CPURegs, MOVZ_I_I, XOR>;
 199 defm : MovzPats2<CPURegs, CPURegs, MOVZ_I_I, XORi>;
 200 let Predicates = [HasMips64, HasStdEnc] in {
 201   defm : MovzPats0<CPURegs, CPU64Regs, MOVZ_I_I64, SLT, SLTu, SLTi, SLTiu>;
 202   defm : MovzPats0<CPU64Regs, CPURegs, MOVZ_I_I, SLT64, SLTu64, SLTi64,
 203                    SLTiu64>;
 204   defm : MovzPats0<CPU64Regs, CPU64Regs, MOVZ_I_I64, SLT64, SLTu64, SLTi64,
 205                    SLTiu64>;
 206   defm : MovzPats1<CPURegs, CPU64Regs, MOVZ_I_I64, XOR>;
 207   defm : MovzPats1<CPU64Regs, CPURegs, MOVZ_I64_I, XOR64>;
 208   defm : MovzPats1<CPU64Regs, CPU64Regs, MOVZ_I64_I64, XOR64>;
 209   defm : MovzPats2<CPURegs, CPU64Regs, MOVZ_I_I64, XORi>;
 210   defm : MovzPats2<CPU64Regs, CPURegs, MOVZ_I64_I, XORi64>;
 211   defm : MovzPats2<CPU64Regs, CPU64Regs, MOVZ_I64_I64, XORi64>;
 212 }
 213
 214 defm : MovnPats<CPURegs, CPURegs, MOVN_I_I, XOR>;
 215 let Predicates = [HasMips64, HasStdEnc] in {
 216   defm : MovnPats<CPURegs, CPU64Regs, MOVN_I_I64, XOR>;
 217   defm : MovnPats<CPU64Regs, CPURegs, MOVN_I64_I, XOR64>;
 218   defm : MovnPats<CPU64Regs, CPU64Regs, MOVN_I64_I64, XOR64>;
 219 }
 220
 221 defm : MovzPats0<CPURegs, FGR32, MOVZ_I_S, SLT, SLTu, SLTi, SLTiu>;
 222 defm : MovzPats1<CPURegs, FGR32, MOVZ_I_S, XOR>;
 223 defm : MovnPats<CPURegs, FGR32, MOVN_I_S, XOR>;
 224 let Predicates = [HasMips64, HasStdEnc] in {
 225   defm : MovzPats0<CPU64Regs, FGR32, MOVZ_I_S, SLT64, SLTu64, SLTi64,
 226                    SLTiu64>;
 227   defm : MovzPats1<CPU64Regs, FGR32, MOVZ_I64_S, XOR64>;
 228   defm : MovnPats<CPU64Regs, FGR32, MOVN_I64_S, XOR64>;
 229 }
 230
 231 let Predicates = [NotFP64bit, HasStdEnc] in {
 232   defm : MovzPats0<CPURegs, AFGR64, MOVZ_I_D32, SLT, SLTu, SLTi, SLTiu>;
 233   defm : MovzPats1<CPURegs, AFGR64, MOVZ_I_D32, XOR>;
 234   defm : MovnPats<CPURegs, AFGR64, MOVN_I_D32, XOR>;
 235 }
 236 let Predicates = [IsFP64bit, HasStdEnc] in {
 237   defm : MovzPats0<CPURegs, FGR64, MOVZ_I_D64, SLT, SLTu, SLTi, SLTiu>;
 238   defm : MovzPats0<CPU64Regs, FGR64, MOVZ_I_D64, SLT64, SLTu64, SLTi64,
 239                    SLTiu64>;
 240   defm : MovzPats1<CPURegs, FGR64, MOVZ_I_D64, XOR>;
 241   defm : MovzPats1<CPU64Regs, FGR64, MOVZ_I64_D64, XOR64>;
 242   defm : MovnPats<CPURegs, FGR64, MOVN_I_D64, XOR>;
 243   defm : MovnPats<CPU64Regs, FGR64, MOVN_I64_D64, XOR64>;
 244 }