lib/Target/Mips/MipsCallingConv.td

   1 //===- MipsCallingConv.td - Calling Conventions for Mips ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 // This describes the calling conventions for Mips architecture.
  10 //===----------------------------------------------------------------------===//
  11
  12 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  13 class CCIfSubtarget<string F, CCAction A>:
  14   CCIf<!strconcat("State.getTarget().getSubtarget<MipsSubtarget>().", F), A>;
  15
  16 //===----------------------------------------------------------------------===//
  17 // Mips O32 Calling Convention
  18 //===----------------------------------------------------------------------===//
  19
  20 // Only the return rules are defined here for O32. The rules for argument
  21 // passing are defined in MipsISelLowering.cpp.
  22 def RetCC_MipsO32 : CallingConv<[
  23   // i32 are returned in registers V0, V1, A0, A1
  24   CCIfType<[i32], CCAssignToReg<[V0, V1, A0, A1]>>,
  25
  26   // f32 are returned in registers F0, F2
  27   CCIfType<[f32], CCAssignToReg<[F0, F2]>>,
  28
  29   // f64 are returned in register D0, D1
  30   CCIfType<[f64], CCIfSubtarget<"isNotSingleFloat()", CCAssignToReg<[D0, D1]>>>
  31 ]>;
  32
  33 //===----------------------------------------------------------------------===//
  34 // Mips N32/64 Calling Convention
  35 //===----------------------------------------------------------------------===//
  36
  37 def CC_MipsN : CallingConv<[
  38    // Handles byval parameters.
  39   CCIfByVal<CCCustom<"CC_Mips64Byval">>,
  40
  41   // Promote i8/i16/i32 arguments to i64.
  42   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
  43
  44   // Integer arguments are passed in integer registers.
  45   CCIfType<[i64], CCAssignToRegWithShadow<[A0_64, A1_64, A2_64, A3_64,
  46                                            T0_64, T1_64, T2_64, T3_64],
  47                                           [D12_64, D13_64, D14_64, D15_64,
  48                                            D16_64, D17_64, D18_64, D19_64]>>,
  49
  50   // f32 arguments are passed in single precision FP registers.
  51   CCIfType<[f32], CCAssignToRegWithShadow<[F12, F13, F14, F15,
  52                                            F16, F17, F18, F19],
  53                                           [A0_64, A1_64, A2_64, A3_64,
  54                                            T0_64, T1_64, T2_64, T3_64]>>,
  55
  56   // f64 arguments are passed in double precision FP registers.
  57   CCIfType<[f64], CCAssignToRegWithShadow<[D12_64, D13_64, D14_64, D15_64,
  58                                            D16_64, D17_64, D18_64, D19_64],
  59                                           [A0_64, A1_64, A2_64, A3_64,
  60                                            T0_64, T1_64, T2_64, T3_64]>>,
  61
  62   // All stack parameter slots become 64-bit doublewords and are 8-byte aligned.
  63   CCIfType<[i64, f64], CCAssignToStack<8, 8>>,
  64   CCIfType<[f32], CCAssignToStack<4, 8>>
  65 ]>;
  66
  67 def RetCC_MipsN : CallingConv<[
  68   // FIXME: Handle complex and float double return values.
  69
  70   // i32 are returned in registers V0, V1
  71   CCIfType<[i32], CCAssignToReg<[V0, V1]>>,
  72
  73   // i64 are returned in registers V0_64, V1_64
  74   CCIfType<[i64], CCAssignToReg<[V0_64, V1_64]>>,
  75
  76   // f32 are returned in registers F0, F2
  77   CCIfType<[f32], CCAssignToReg<[F0, F2]>>,
  78
  79   // f64 are returned in registers D0, D2
  80   CCIfType<[f64], CCAssignToReg<[D0_64, D2_64]>>
  81 ]>;
  82
  83 //===----------------------------------------------------------------------===//
  84 // Mips EABI Calling Convention
  85 //===----------------------------------------------------------------------===//
  86
  87 def CC_MipsEABI : CallingConv<[
  88   // Promote i8/i16 arguments to i32.
  89   CCIfType<[i8, i16], CCPromoteToType<i32>>,
  90
  91   // Integer arguments are passed in integer registers.
  92   CCIfType<[i32], CCAssignToReg<[A0, A1, A2, A3, T0, T1, T2, T3]>>,
  93
  94   // Single fp arguments are passed in pairs within 32-bit mode
  95   CCIfType<[f32], CCIfSubtarget<"isSingleFloat()",
  96                   CCAssignToReg<[F12, F13, F14, F15, F16, F17, F18, F19]>>>,
  97
  98   CCIfType<[f32], CCIfSubtarget<"isNotSingleFloat()",
  99                   CCAssignToReg<[F12, F14, F16, F18]>>>,
 100
 101   // The first 4 double fp arguments are passed in single fp registers.
 102   CCIfType<[f64], CCIfSubtarget<"isNotSingleFloat()",
 103                   CCAssignToReg<[D6, D7, D8, D9]>>>,
 104
 105   // Integer values get stored in stack slots that are 4 bytes in
 106   // size and 4-byte aligned.
 107   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 108
 109   // Integer values get stored in stack slots that are 8 bytes in
 110   // size and 8-byte aligned.
 111   CCIfType<[f64], CCIfSubtarget<"isNotSingleFloat()", CCAssignToStack<8, 8>>>
 112 ]>;
 113
 114 def RetCC_MipsEABI : CallingConv<[
 115   // i32 are returned in registers V0, V1
 116   CCIfType<[i32], CCAssignToReg<[V0, V1]>>,
 117
 118   // f32 are returned in registers F0, F1
 119   CCIfType<[f32], CCAssignToReg<[F0, F1]>>,
 120
 121   // f64 are returned in register D0
 122   CCIfType<[f64], CCIfSubtarget<"isNotSingleFloat()", CCAssignToReg<[D0]>>>
 123 ]>;
 124
 125 //===----------------------------------------------------------------------===//
 126 // Mips Calling Convention Dispatch
 127 //===----------------------------------------------------------------------===//
 128
 129 def CC_Mips : CallingConv<[
 130   CCIfSubtarget<"isABI_EABI()", CCDelegateTo<CC_MipsEABI>>,
 131   CCIfSubtarget<"isABI_N32()", CCDelegateTo<CC_MipsN>>,
 132   CCIfSubtarget<"isABI_N64()", CCDelegateTo<CC_MipsN>>
 133 ]>;
 134
 135 def RetCC_Mips : CallingConv<[
 136   CCIfSubtarget<"isABI_EABI()", CCDelegateTo<RetCC_MipsEABI>>,
 137   CCIfSubtarget<"isABI_N32()", CCDelegateTo<RetCC_MipsN>>,
 138   CCIfSubtarget<"isABI_N64()", CCDelegateTo<RetCC_MipsN>>,
 139   CCDelegateTo<RetCC_MipsO32>
 140 ]>;