lib/Target/Mips/Mips64InstrInfo.td

   1 //===- Mips64InstrInfo.td - Mips64 Instruction Information -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes Mips64 instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Mips Operand, Complex Patterns and Transformations Definitions.
  16 //===----------------------------------------------------------------------===//
  17
  18 // Instruction operand types
  19 def shamt_64       : Operand<i64>;
  20
  21 // Unsigned Operand
  22 def uimm16_64      : Operand<i64> {
  23   let PrintMethod = "printUnsignedImm";
  24 }
  25
  26 // Transformation Function - get Imm - 32.
  27 def Subtract32 : SDNodeXForm<imm, [{
  28   return getI32Imm((unsigned)N->getZExtValue() - 32);
  29 }]>;
  30
  31 // shamt field must fit in 5 bits.
  32 def immZExt5_64 : ImmLeaf<i64, [{return Imm == (Imm & 0x1f);}]>;
  33
  34 // imm32_63 predicate - True if imm is in range [32, 63].
  35 def imm32_63 : ImmLeaf<i32,
  36                        [{return (int32_t)Imm >= 32 && (int32_t)Imm < 64;}],
  37                        Subtract32>;
  38
  39 //===----------------------------------------------------------------------===//
  40 // Instructions specific format
  41 //===----------------------------------------------------------------------===//
  42 // Shifts
  43 // 64-bit shift instructions.
  44 class shift_rotate_imm64<bits<6> func, bits<5> isRotate, string instr_asm,
  45                          SDNode OpNode>:
  46   shift_rotate_imm<func, isRotate, instr_asm, OpNode, immZExt5, shamt,
  47                    CPU64Regs>;
  48
  49 class shift_rotate_imm64_32<bits<6> func, bits<5> isRotate, string instr_asm,
  50                             SDNode OpNode>:
  51   shift_rotate_imm<func, isRotate, instr_asm, OpNode, imm32_63, shamt,
  52                    CPU64Regs>;
  53
  54 // Jump and Link (Call)
  55 let isCall=1, hasDelaySlot=1,
  56   // All calls clobber the non-callee saved registers...
  57   Defs = [AT, V0, V1, A0, A1, A2, A3, T0, T1, T2, T3, T4, T5, T6, T7, T8, T9,
  58           K0, K1, D0, D1, D2, D3, D4, D5, D6, D7, D8, D9], Uses = [GP] in {
  59   class JumpLink64<bits<6> op, string instr_asm>:
  60     FJ<op, (outs), (ins calltarget64:$target, variable_ops),
  61        !strconcat(instr_asm, "\t$target"), [(MipsJmpLink imm:$target)],
  62        IIBranch>;
  63
  64   class JumpLinkReg64<bits<6> op, bits<6> func, string instr_asm>:
  65     FR<op, func, (outs), (ins CPU64Regs:$rs, variable_ops),
  66        !strconcat(instr_asm, "\t$rs"),
  67        [(MipsJmpLink CPU64Regs:$rs)], IIBranch> {
  68     let rt = 0;
  69     let rd = 31;
  70     let shamt = 0;
  71   }
  72
  73   class BranchLink64<string instr_asm>:
  74     FI<0x1, (outs), (ins CPU64Regs:$rs, brtarget:$imm16, variable_ops),
  75        !strconcat(instr_asm, "\t$rs, $imm16"), [], IIBranch>;
  76 }
  77
  78 // Mul, Div
  79 class Mult64<bits<6> func, string instr_asm, InstrItinClass itin>:
  80   Mult<func, instr_asm, itin, CPU64Regs, [HI64, LO64]>;
  81 class Div64<SDNode op, bits<6> func, string instr_asm, InstrItinClass itin>:
  82   Div<op, func, instr_asm, itin, CPU64Regs, [HI64, LO64]>;
  83
  84 multiclass Atomic2Ops64<PatFrag Op, string Opstr> {
  85   def #NAME# : Atomic2Ops<Op, Opstr, CPU64Regs, CPURegs>, Requires<[NotN64]>;
  86   def _P8    : Atomic2Ops<Op, Opstr, CPU64Regs, CPU64Regs>, Requires<[IsN64]>;
  87 }
  88
  89 multiclass AtomicCmpSwap64<PatFrag Op, string Width>  {
  90   def #NAME# : AtomicCmpSwap<Op, Width, CPU64Regs, CPURegs>, Requires<[NotN64]>;
  91   def _P8    : AtomicCmpSwap<Op, Width, CPU64Regs, CPU64Regs>,
  92                Requires<[IsN64]>;
  93 }
  94
  95 let usesCustomInserter = 1, Predicates = [HasMips64] in {
  96   defm ATOMIC_LOAD_ADD_I64  : Atomic2Ops64<atomic_load_add_64, "load_add_64">;
  97   defm ATOMIC_LOAD_SUB_I64  : Atomic2Ops64<atomic_load_sub_64, "load_sub_64">;
  98   defm ATOMIC_LOAD_AND_I64  : Atomic2Ops64<atomic_load_and_64, "load_and_64">;
  99   defm ATOMIC_LOAD_OR_I64   : Atomic2Ops64<atomic_load_or_64, "load_or_64">;
 100   defm ATOMIC_LOAD_XOR_I64  : Atomic2Ops64<atomic_load_xor_64, "load_xor_64">;
 101   defm ATOMIC_LOAD_NAND_I64 : Atomic2Ops64<atomic_load_nand_64, "load_nand_64">;
 102   defm ATOMIC_SWAP_I64      : Atomic2Ops64<atomic_swap_64, "swap_64">;
 103   defm ATOMIC_CMP_SWAP_I64  : AtomicCmpSwap64<atomic_cmp_swap_64, "64">;
 104 }
 105
 106 //===----------------------------------------------------------------------===//
 107 // Instruction definition
 108 //===----------------------------------------------------------------------===//
 109
 110 /// Arithmetic Instructions (ALU Immediate)
 111 def DADDiu   : ArithLogicI<0x19, "daddiu", add, simm16_64, immSExt16,
 112                            CPU64Regs>;
 113 def DANDi    : ArithLogicI<0x0c, "andi", and, uimm16_64, immZExt16, CPU64Regs>;
 114 def SLTi64   : SetCC_I<0x0a, "slti", setlt, simm16_64, immSExt16, CPU64Regs>;
 115 def SLTiu64  : SetCC_I<0x0b, "sltiu", setult, simm16_64, immSExt16, CPU64Regs>;
 116 def ORi64    : ArithLogicI<0x0d, "ori", or, uimm16_64, immZExt16, CPU64Regs>;
 117 def XORi64   : ArithLogicI<0x0e, "xori", xor, uimm16_64, immZExt16, CPU64Regs>;
 118 def LUi64    : LoadUpper<0x0f, "lui", CPU64Regs, uimm16_64>;
 119
 120 /// Arithmetic Instructions (3-Operand, R-Type)
 121 def DADDu    : ArithLogicR<0x00, 0x2d, "daddu", add, IIAlu, CPU64Regs, 1>;
 122 def DSUBu    : ArithLogicR<0x00, 0x2f, "dsubu", sub, IIAlu, CPU64Regs>;
 123 def SLT64    : SetCC_R<0x00, 0x2a, "slt", setlt, CPU64Regs>;
 124 def SLTu64   : SetCC_R<0x00, 0x2b, "sltu", setult, CPU64Regs>;
 125 def AND64    : ArithLogicR<0x00, 0x24, "and", and, IIAlu, CPU64Regs, 1>;
 126 def OR64     : ArithLogicR<0x00, 0x25, "or", or, IIAlu, CPU64Regs, 1>;
 127 def XOR64    : ArithLogicR<0x00, 0x26, "xor", xor, IIAlu, CPU64Regs, 1>;
 128 def NOR64    : LogicNOR<0x00, 0x27, "nor", CPU64Regs>;
 129
 130 /// Shift Instructions
 131 def DSLL     : shift_rotate_imm64<0x38, 0x00, "dsll", shl>;
 132 def DSRL     : shift_rotate_imm64<0x3a, 0x00, "dsrl", srl>;
 133 def DSRA     : shift_rotate_imm64<0x3b, 0x00, "dsra", sra>;
 134 def DSLL32   : shift_rotate_imm64_32<0x3c, 0x00, "dsll32", shl>;
 135 def DSRL32   : shift_rotate_imm64_32<0x3e, 0x00, "dsrl32", srl>;
 136 def DSRA32   : shift_rotate_imm64_32<0x3f, 0x00, "dsra32", sra>;
 137 def DSLLV    : shift_rotate_reg<0x24, 0x00, "dsllv", shl, CPU64Regs>;
 138 def DSRLV    : shift_rotate_reg<0x26, 0x00, "dsrlv", srl, CPU64Regs>;
 139 def DSRAV    : shift_rotate_reg<0x27, 0x00, "dsrav", sra, CPU64Regs>;
 140
 141 // Rotate Instructions
 142 let Predicates = [HasMips64r2] in {
 143   def DROTR    : shift_rotate_imm64<0x3a, 0x01, "drotr", rotr>;
 144   def DROTR32  : shift_rotate_imm64_32<0x3e, 0x01, "drotr32", rotr>;
 145   def DROTRV   : shift_rotate_reg<0x16, 0x01, "drotrv", rotr, CPU64Regs>;
 146 }
 147
 148 /// Load and Store Instructions
 149 ///  aligned
 150 defm LB64    : LoadM64<0x20, "lb",  sextloadi8>;
 151 defm LBu64   : LoadM64<0x24, "lbu", zextloadi8>;
 152 defm LH64    : LoadM64<0x21, "lh",  sextloadi16_a>;
 153 defm LHu64   : LoadM64<0x25, "lhu", zextloadi16_a>;
 154 defm LW64    : LoadM64<0x23, "lw",  sextloadi32_a>;
 155 defm LWu64   : LoadM64<0x27, "lwu", zextloadi32_a>;
 156 defm SB64    : StoreM64<0x28, "sb", truncstorei8>;
 157 defm SH64    : StoreM64<0x29, "sh", truncstorei16_a>;
 158 defm SW64    : StoreM64<0x2b, "sw", truncstorei32_a>;
 159 defm LD      : LoadM64<0x37, "ld",  load_a>;
 160 defm SD      : StoreM64<0x3f, "sd", store_a>;
 161
 162 ///  unaligned
 163 defm ULH64     : LoadM64<0x21, "ulh",  sextloadi16_u, 1>;
 164 defm ULHu64    : LoadM64<0x25, "ulhu", zextloadi16_u, 1>;
 165 defm ULW64     : LoadM64<0x23, "ulw",  sextloadi32_u, 1>;
 166 defm USH64     : StoreM64<0x29, "ush", truncstorei16_u, 1>;
 167 defm USW64     : StoreM64<0x2b, "usw", truncstorei32_u, 1>;
 168 defm ULD       : LoadM64<0x37, "uld",  load_u, 1>;
 169 defm USD       : StoreM64<0x3f, "usd", store_u, 1>;
 170
 171 /// Load-linked, Store-conditional
 172 def LLD    : LLBase<0x34, "lld", CPU64Regs, mem>, Requires<[NotN64]>;
 173 def LLD_P8 : LLBase<0x34, "lld", CPU64Regs, mem64>, Requires<[IsN64]>;
 174 def SCD    : SCBase<0x3c, "scd", CPU64Regs, mem>, Requires<[NotN64]>;
 175 def SCD_P8 : SCBase<0x3c, "scd", CPU64Regs, mem64>, Requires<[IsN64]>;
 176
 177 /// Jump and Branch Instructions
 178 def JR64   : JumpFR<0x00, 0x08, "jr", CPU64Regs>;
 179 def JAL64  : JumpLink64<0x03, "jal">;
 180 def JALR64 : JumpLinkReg64<0x00, 0x09, "jalr">;
 181 def BEQ64  : CBranch<0x04, "beq", seteq, CPU64Regs>;
 182 def BNE64  : CBranch<0x05, "bne", setne, CPU64Regs>;
 183 def BGEZ64 : CBranchZero<0x01, 1, "bgez", setge, CPU64Regs>;
 184 def BGTZ64 : CBranchZero<0x07, 0, "bgtz", setgt, CPU64Regs>;
 185 def BLEZ64 : CBranchZero<0x07, 0, "blez", setle, CPU64Regs>;
 186 def BLTZ64 : CBranchZero<0x01, 0, "bltz", setlt, CPU64Regs>;
 187
 188 /// Multiply and Divide Instructions.
 189 def DMULT    : Mult64<0x1c, "dmult", IIImul>;
 190 def DMULTu   : Mult64<0x1d, "dmultu", IIImul>;
 191 def DSDIV    : Div64<MipsDivRem, 0x1e, "ddiv", IIIdiv>;
 192 def DUDIV    : Div64<MipsDivRemU, 0x1f, "ddivu", IIIdiv>;
 193
 194 def MTHI64 : MoveToLOHI<0x11, "mthi", CPU64Regs, [HI64]>;
 195 def MTLO64 : MoveToLOHI<0x13, "mtlo", CPU64Regs, [LO64]>;
 196 def MFHI64 : MoveFromLOHI<0x10, "mfhi", CPU64Regs, [HI64]>;
 197 def MFLO64 : MoveFromLOHI<0x12, "mflo", CPU64Regs, [LO64]>;
 198
 199 /// Count Leading
 200 def DCLZ : CountLeading0<0x24, "dclz", CPU64Regs>;
 201 def DCLO : CountLeading1<0x25, "dclo", CPU64Regs>;
 202
 203 def LEA_ADDiu64 : EffectiveAddress<"addiu\t$rt, $addr", CPU64Regs, mem_ea_64>;
 204
 205 let Uses = [SP_64] in
 206 def DynAlloc64 : EffectiveAddress<"daddiu\t$rt, $addr", CPU64Regs, mem_ea_64>,
 207                  Requires<[IsN64]>;
 208
 209 //===----------------------------------------------------------------------===//
 210 //  Arbitrary patterns that map to one or more instructions
 211 //===----------------------------------------------------------------------===//
 212
 213 // Small immediates
 214 def : Pat<(i64 immSExt16:$in),
 215           (DADDiu ZERO_64, imm:$in)>;
 216 def : Pat<(i64 immZExt16:$in),
 217           (ORi64 ZERO_64, imm:$in)>;
 218
 219 // Arbitrary immediates
 220 def : Pat<(i64 imm:$imm),
 221           (ORi64 (LUi64 (HI16 imm:$imm)), (LO16 imm:$imm))>;
 222
 223 // extended loads
 224 let Predicates = [NotN64] in {
 225   def : Pat<(extloadi32_a addr:$a), (DSRL32 (DSLL32 (LW64 addr:$a), 0), 0)>;
 226   def : Pat<(zextloadi32_u addr:$a), (DSRL32 (DSLL32 (ULW64 addr:$a), 0), 0)>;
 227 }
 228 let Predicates = [IsN64] in {
 229   def : Pat<(extloadi32_a addr:$a), (DSRL32 (DSLL32 (LW64_P8 addr:$a), 0), 0)>;
 230   def : Pat<(zextloadi32_u addr:$a),
 231             (DSRL32 (DSLL32 (ULW64_P8 addr:$a), 0), 0)>;
 232 }
 233
 234 // hi/lo relocs
 235 def : Pat<(MipsHi tglobaladdr:$in), (LUi64 tglobaladdr:$in)>;
 236 def : Pat<(MipsHi tblockaddress:$in), (LUi64 tblockaddress:$in)>;
 237 def : Pat<(MipsHi tjumptable:$in), (LUi64 tjumptable:$in)>;
 238 def : Pat<(MipsHi tconstpool:$in), (LUi64 tconstpool:$in)>;
 239
 240 def : Pat<(MipsLo tglobaladdr:$in), (DADDiu ZERO_64, tglobaladdr:$in)>;
 241 def : Pat<(MipsLo tblockaddress:$in), (DADDiu ZERO_64, tblockaddress:$in)>;
 242 def : Pat<(MipsLo tjumptable:$in), (DADDiu ZERO_64, tjumptable:$in)>;
 243 def : Pat<(MipsLo tconstpool:$in), (DADDiu ZERO_64, tconstpool:$in)>;
 244
 245 def : Pat<(add CPU64Regs:$hi, (MipsLo tglobaladdr:$lo)),
 246           (DADDiu CPU64Regs:$hi, tglobaladdr:$lo)>;
 247 def : Pat<(add CPU64Regs:$hi, (MipsLo tblockaddress:$lo)),
 248           (DADDiu CPU64Regs:$hi, tblockaddress:$lo)>;
 249 def : Pat<(add CPU64Regs:$hi, (MipsLo tjumptable:$lo)),
 250           (DADDiu CPU64Regs:$hi, tjumptable:$lo)>;
 251 def : Pat<(add CPU64Regs:$hi, (MipsLo tconstpool:$lo)),
 252           (DADDiu CPU64Regs:$hi, tconstpool:$lo)>;
 253
 254 defm : BrcondPats<CPU64Regs, BEQ64, BNE64, SLT64, SLTu64, SLTi64, SLTiu64,
 255                   ZERO_64>;
 256
 257 // setcc patterns
 258 defm : SeteqPats<CPU64Regs, SLTiu64, XOR64, SLTu64, ZERO_64>;
 259 defm : SetlePats<CPU64Regs, SLT64, SLTu64>;
 260 defm : SetgtPats<CPU64Regs, SLT64, SLTu64>;
 261 defm : SetgePats<CPU64Regs, SLT64, SLTu64>;
 262 defm : SetgeImmPats<CPU64Regs, SLTi64, SLTiu64>;
 263
 264 // select MipsDynAlloc
 265 def : Pat<(MipsDynAlloc addr:$f), (DynAlloc64 addr:$f)>, Requires<[IsN64]>;
 266
 267 // truncate
 268 def : Pat<(i32 (trunc CPU64Regs:$src)),
 269           (SLL (EXTRACT_SUBREG CPU64Regs:$src, sub_32), 0)>, Requires<[IsN64]>;
 270