lib/Target/Mips/Mips64InstrInfo.td

   1 //===- Mips64InstrInfo.td - Mips64 Instruction Information -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes Mips64 instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Mips Operand, Complex Patterns and Transformations Definitions.
  16 //===----------------------------------------------------------------------===//
  17
  18 // Unsigned Operand
  19 def uimm16_64      : Operand<i64> {
  20   let PrintMethod = "printUnsignedImm";
  21 }
  22
  23 // Signed Operand
  24 def simm10_64 : Operand<i64>;
  25
  26 // Transformation Function - get Imm - 32.
  27 def Subtract32 : SDNodeXForm<imm, [{
  28   return getImm(N, (unsigned)N->getZExtValue() - 32);
  29 }]>;
  30
  31 // shamt must fit in 6 bits.
  32 def immZExt6 : ImmLeaf<i32, [{return Imm == (Imm & 0x3f);}]>;
  33
  34 // Node immediate fits as 10-bit sign extended on target immediate.
  35 // e.g. seqi, snei
  36 def immSExt10_64 : PatLeaf<(i64 imm),
  37                            [{ return isInt<10>(N->getSExtValue()); }]>;
  38
  39 def immZExt16_64 : PatLeaf<(i64 imm),
  40                            [{ return isInt<16>(N->getZExtValue()); }]>;
  41
  42 //===----------------------------------------------------------------------===//
  43 // Instructions specific format
  44 //===----------------------------------------------------------------------===//
  45 let usesCustomInserter = 1 in {
  46   def ATOMIC_LOAD_ADD_I64  : Atomic2Ops<atomic_load_add_64, GPR64>;
  47   def ATOMIC_LOAD_SUB_I64  : Atomic2Ops<atomic_load_sub_64, GPR64>;
  48   def ATOMIC_LOAD_AND_I64  : Atomic2Ops<atomic_load_and_64, GPR64>;
  49   def ATOMIC_LOAD_OR_I64   : Atomic2Ops<atomic_load_or_64, GPR64>;
  50   def ATOMIC_LOAD_XOR_I64  : Atomic2Ops<atomic_load_xor_64, GPR64>;
  51   def ATOMIC_LOAD_NAND_I64 : Atomic2Ops<atomic_load_nand_64, GPR64>;
  52   def ATOMIC_SWAP_I64      : Atomic2Ops<atomic_swap_64, GPR64>;
  53   def ATOMIC_CMP_SWAP_I64  : AtomicCmpSwap<atomic_cmp_swap_64, GPR64>;
  54 }
  55
  56 /// Pseudo instructions for loading and storing accumulator registers.
  57 let isPseudo = 1, isCodeGenOnly = 1 in {
  58   def LOAD_ACC128  : Load<"", ACC128>;
  59   def STORE_ACC128 : Store<"", ACC128>;
  60 }
  61
  62 //===----------------------------------------------------------------------===//
  63 // Instruction definition
  64 //===----------------------------------------------------------------------===//
  65 let DecoderNamespace = "Mips64" in {
  66 /// Arithmetic Instructions (ALU Immediate)
  67 def DADDi   : ArithLogicI<"daddi", simm16_64, GPR64Opnd>, ADDI_FM<0x18>,
  68               ISA_MIPS3_NOT_32R6_64R6;
  69 def DADDiu  : ArithLogicI<"daddiu", simm16_64, GPR64Opnd, II_DADDIU,
  70                           immSExt16, add>,
  71               ADDI_FM<0x19>, IsAsCheapAsAMove, ISA_MIPS3;
  72
  73 let isCodeGenOnly = 1 in {
  74 def SLTi64  : SetCC_I<"slti", setlt, simm16_64, immSExt16, GPR64Opnd>,
  75               SLTI_FM<0xa>;
  76 def SLTiu64 : SetCC_I<"sltiu", setult, simm16_64, immSExt16, GPR64Opnd>,
  77               SLTI_FM<0xb>;
  78 def ANDi64 : ArithLogicI<"andi", uimm16_64, GPR64Opnd, II_AND, immZExt16, and>,
  79              ADDI_FM<0xc>;
  80 def ORi64   : ArithLogicI<"ori", uimm16_64, GPR64Opnd, II_OR, immZExt16, or>,
  81               ADDI_FM<0xd>;
  82 def XORi64  : ArithLogicI<"xori", uimm16_64, GPR64Opnd, II_XOR, immZExt16, xor>,
  83               ADDI_FM<0xe>;
  84 def LUi64   : LoadUpper<"lui", GPR64Opnd, uimm16_64>, LUI_FM;
  85 }
  86
  87 /// Arithmetic Instructions (3-Operand, R-Type)
  88 def DADD   : ArithLogicR<"dadd", GPR64Opnd, 1, II_DADD>, ADD_FM<0, 0x2c>,
  89              ISA_MIPS3;
  90 def DADDu  : ArithLogicR<"daddu", GPR64Opnd, 1, II_DADDU, add>, ADD_FM<0, 0x2d>,
  91              ISA_MIPS3;
  92 def DSUBu  : ArithLogicR<"dsubu", GPR64Opnd, 0, II_DSUBU, sub>, ADD_FM<0, 0x2f>,
  93              ISA_MIPS3;
  94 def DSUB   : ArithLogicR<"dsub", GPR64Opnd, 0, II_DSUB>, ADD_FM<0, 0x2e>,
  95              ISA_MIPS3;
  96
  97 let isCodeGenOnly = 1 in {
  98 def SLT64  : SetCC_R<"slt", setlt, GPR64Opnd>, ADD_FM<0, 0x2a>;
  99 def SLTu64 : SetCC_R<"sltu", setult, GPR64Opnd>, ADD_FM<0, 0x2b>;
 100 def AND64  : ArithLogicR<"and", GPR64Opnd, 1, II_AND, and>, ADD_FM<0, 0x24>;
 101 def OR64   : ArithLogicR<"or", GPR64Opnd, 1, II_OR, or>, ADD_FM<0, 0x25>;
 102 def XOR64  : ArithLogicR<"xor", GPR64Opnd, 1, II_XOR, xor>, ADD_FM<0, 0x26>;
 103 def NOR64  : LogicNOR<"nor", GPR64Opnd>, ADD_FM<0, 0x27>;
 104 }
 105
 106 /// Shift Instructions
 107 def DSLL   : shift_rotate_imm<"dsll", uimm6, GPR64Opnd, II_DSLL, shl, immZExt6>,
 108              SRA_FM<0x38, 0>, ISA_MIPS3;
 109 def DSRL   : shift_rotate_imm<"dsrl", uimm6, GPR64Opnd, II_DSRL, srl, immZExt6>,
 110              SRA_FM<0x3a, 0>, ISA_MIPS3;
 111 def DSRA   : shift_rotate_imm<"dsra", uimm6, GPR64Opnd, II_DSRA, sra, immZExt6>,
 112              SRA_FM<0x3b, 0>, ISA_MIPS3;
 113 def DSLLV  : shift_rotate_reg<"dsllv", GPR64Opnd, II_DSLLV, shl>,
 114              SRLV_FM<0x14, 0>, ISA_MIPS3;
 115 def DSRLV  : shift_rotate_reg<"dsrlv", GPR64Opnd, II_DSRLV, srl>,
 116              SRLV_FM<0x16, 0>, ISA_MIPS3;
 117 def DSRAV  : shift_rotate_reg<"dsrav", GPR64Opnd, II_DSRAV, sra>,
 118              SRLV_FM<0x17, 0>, ISA_MIPS3;
 119 def DSLL32 : shift_rotate_imm<"dsll32", uimm5, GPR64Opnd, II_DSLL32>,
 120              SRA_FM<0x3c, 0>, ISA_MIPS3;
 121 def DSRL32 : shift_rotate_imm<"dsrl32", uimm5, GPR64Opnd, II_DSRL32>,
 122              SRA_FM<0x3e, 0>, ISA_MIPS3;
 123 def DSRA32 : shift_rotate_imm<"dsra32", uimm5, GPR64Opnd, II_DSRA32>,
 124              SRA_FM<0x3f, 0>, ISA_MIPS3;
 125
 126 // Rotate Instructions
 127 def DROTR  : shift_rotate_imm<"drotr", uimm6, GPR64Opnd, II_DROTR, rotr,
 128                               immZExt6>,
 129              SRA_FM<0x3a, 1>, ISA_MIPS64R2;
 130 def DROTRV : shift_rotate_reg<"drotrv", GPR64Opnd, II_DROTRV, rotr>,
 131              SRLV_FM<0x16, 1>, ISA_MIPS64R2;
 132 def DROTR32 : shift_rotate_imm<"drotr32", uimm5, GPR64Opnd, II_DROTR32>,
 133               SRA_FM<0x3e, 1>, ISA_MIPS64R2;
 134
 135 /// Load and Store Instructions
 136 ///  aligned
 137 let isCodeGenOnly = 1 in {
 138 def LB64  : Load<"lb", GPR64Opnd, sextloadi8, II_LB>, LW_FM<0x20>;
 139 def LBu64 : Load<"lbu", GPR64Opnd, zextloadi8, II_LBU>, LW_FM<0x24>;
 140 def LH64  : Load<"lh", GPR64Opnd, sextloadi16, II_LH>, LW_FM<0x21>;
 141 def LHu64 : Load<"lhu", GPR64Opnd, zextloadi16, II_LHU>, LW_FM<0x25>;
 142 def LW64  : Load<"lw", GPR64Opnd, sextloadi32, II_LW>, LW_FM<0x23>;
 143 def SB64  : Store<"sb", GPR64Opnd, truncstorei8, II_SB>, LW_FM<0x28>;
 144 def SH64  : Store<"sh", GPR64Opnd, truncstorei16, II_SH>, LW_FM<0x29>;
 145 def SW64  : Store<"sw", GPR64Opnd, truncstorei32, II_SW>, LW_FM<0x2b>;
 146 }
 147
 148 def LWu   : Load<"lwu", GPR64Opnd, zextloadi32, II_LWU>, LW_FM<0x27>, ISA_MIPS3;
 149 def LD    : Load<"ld", GPR64Opnd, load, II_LD>, LW_FM<0x37>, ISA_MIPS3;
 150 def SD    : Store<"sd", GPR64Opnd, store, II_SD>, LW_FM<0x3f>, ISA_MIPS3;
 151
 152 /// load/store left/right
 153 let isCodeGenOnly = 1 in {
 154 def LWL64 : LoadLeftRight<"lwl", MipsLWL, GPR64Opnd, II_LWL>, LW_FM<0x22>;
 155 def LWR64 : LoadLeftRight<"lwr", MipsLWR, GPR64Opnd, II_LWR>, LW_FM<0x26>;
 156 def SWL64 : StoreLeftRight<"swl", MipsSWL, GPR64Opnd, II_SWL>, LW_FM<0x2a>;
 157 def SWR64 : StoreLeftRight<"swr", MipsSWR, GPR64Opnd, II_SWR>, LW_FM<0x2e>;
 158 }
 159
 160 def LDL   : LoadLeftRight<"ldl", MipsLDL, GPR64Opnd, II_LDL>, LW_FM<0x1a>,
 161             ISA_MIPS3_NOT_32R6_64R6;
 162 def LDR   : LoadLeftRight<"ldr", MipsLDR, GPR64Opnd, II_LDR>, LW_FM<0x1b>,
 163             ISA_MIPS3_NOT_32R6_64R6;
 164 def SDL   : StoreLeftRight<"sdl", MipsSDL, GPR64Opnd, II_SDL>, LW_FM<0x2c>,
 165             ISA_MIPS3_NOT_32R6_64R6;
 166 def SDR   : StoreLeftRight<"sdr", MipsSDR, GPR64Opnd, II_SDR>, LW_FM<0x2d>,
 167             ISA_MIPS3_NOT_32R6_64R6;
 168
 169 /// Load-linked, Store-conditional
 170 def LLD : LLBase<"lld", GPR64Opnd>, LW_FM<0x34>, ISA_MIPS3_NOT_32R6_64R6;
 171 def SCD : SCBase<"scd", GPR64Opnd>, LW_FM<0x3c>, ISA_MIPS3_NOT_32R6_64R6;
 172
 173 /// Jump and Branch Instructions
 174 let isCodeGenOnly = 1 in {
 175 def JR64   : IndirectBranch<"jr", GPR64Opnd>, MTLO_FM<8>;
 176 def BEQ64  : CBranch<"beq", brtarget, seteq, GPR64Opnd>, BEQ_FM<4>;
 177 def BNE64  : CBranch<"bne", brtarget, setne, GPR64Opnd>, BEQ_FM<5>;
 178 def BGEZ64 : CBranchZero<"bgez", brtarget, setge, GPR64Opnd>, BGEZ_FM<1, 1>;
 179 def BGTZ64 : CBranchZero<"bgtz", brtarget, setgt, GPR64Opnd>, BGEZ_FM<7, 0>;
 180 def BLEZ64 : CBranchZero<"blez", brtarget, setle, GPR64Opnd>, BGEZ_FM<6, 0>;
 181 def BLTZ64 : CBranchZero<"bltz", brtarget, setlt, GPR64Opnd>, BGEZ_FM<1, 0>;
 182 def JALR64 : JumpLinkReg<"jalr", GPR64Opnd>, JALR_FM;
 183 def JALR64Pseudo : JumpLinkRegPseudo<GPR64Opnd, JALR, RA, GPR32Opnd>;
 184 def TAILCALL64_R : TailCallReg<GPR64Opnd, JR, GPR32Opnd>;
 185 }
 186
 187 /// Multiply and Divide Instructions.
 188 def DMULT  : Mult<"dmult", II_DMULT, GPR64Opnd, [HI0_64, LO0_64]>,
 189              MULT_FM<0, 0x1c>, ISA_MIPS3_NOT_32R6_64R6;
 190 def DMULTu : Mult<"dmultu", II_DMULTU, GPR64Opnd, [HI0_64, LO0_64]>,
 191              MULT_FM<0, 0x1d>, ISA_MIPS3_NOT_32R6_64R6;
 192 def PseudoDMULT  : MultDivPseudo<DMULT, ACC128, GPR64Opnd, MipsMult,
 193                                  II_DMULT>, ISA_MIPS3_NOT_32R6_64R6;
 194 def PseudoDMULTu : MultDivPseudo<DMULTu, ACC128, GPR64Opnd, MipsMultu,
 195                                  II_DMULTU>, ISA_MIPS3_NOT_32R6_64R6;
 196 def DSDIV : Div<"ddiv", II_DDIV, GPR64Opnd, [HI0_64, LO0_64]>,
 197             MULT_FM<0, 0x1e>, ISA_MIPS3_NOT_32R6_64R6;
 198 def DUDIV : Div<"ddivu", II_DDIVU, GPR64Opnd, [HI0_64, LO0_64]>,
 199             MULT_FM<0, 0x1f>, ISA_MIPS3_NOT_32R6_64R6;
 200 def PseudoDSDIV : MultDivPseudo<DSDIV, ACC128, GPR64Opnd, MipsDivRem,
 201                                 II_DDIV, 0, 1, 1>, ISA_MIPS3_NOT_32R6_64R6;
 202 def PseudoDUDIV : MultDivPseudo<DUDIV, ACC128, GPR64Opnd, MipsDivRemU,
 203                                 II_DDIVU, 0, 1, 1>, ISA_MIPS3_NOT_32R6_64R6;
 204
 205 let isCodeGenOnly = 1 in {
 206 def MTHI64 : MoveToLOHI<"mthi", GPR64Opnd, [HI0_64]>, MTLO_FM<0x11>,
 207              ISA_MIPS3_NOT_32R6_64R6;
 208 def MTLO64 : MoveToLOHI<"mtlo", GPR64Opnd, [LO0_64]>, MTLO_FM<0x13>,
 209              ISA_MIPS3_NOT_32R6_64R6;
 210 def MFHI64 : MoveFromLOHI<"mfhi", GPR64Opnd, AC0_64>, MFLO_FM<0x10>,
 211              ISA_MIPS3_NOT_32R6_64R6;
 212 def MFLO64 : MoveFromLOHI<"mflo", GPR64Opnd, AC0_64>, MFLO_FM<0x12>,
 213              ISA_MIPS3_NOT_32R6_64R6;
 214 def PseudoMFHI64 : PseudoMFLOHI<GPR64, ACC128, MipsMFHI>,
 215                    ISA_MIPS3_NOT_32R6_64R6;
 216 def PseudoMFLO64 : PseudoMFLOHI<GPR64, ACC128, MipsMFLO>,
 217                    ISA_MIPS3_NOT_32R6_64R6;
 218 def PseudoMTLOHI64 : PseudoMTLOHI<ACC128, GPR64>, ISA_MIPS3_NOT_32R6_64R6;
 219
 220 /// Sign Ext In Register Instructions.
 221 def SEB64 : SignExtInReg<"seb", i8, GPR64Opnd, II_SEB>, SEB_FM<0x10, 0x20>,
 222             ISA_MIPS32R2;
 223 def SEH64 : SignExtInReg<"seh", i16, GPR64Opnd, II_SEH>, SEB_FM<0x18, 0x20>,
 224             ISA_MIPS32R2;
 225 }
 226
 227 /// Count Leading
 228 def DCLZ : CountLeading0<"dclz", GPR64Opnd>, CLO_FM<0x24>, ISA_MIPS64_NOT_64R6;
 229 def DCLO : CountLeading1<"dclo", GPR64Opnd>, CLO_FM<0x25>, ISA_MIPS64_NOT_64R6;
 230
 231 /// Double Word Swap Bytes/HalfWords
 232 def DSBH : SubwordSwap<"dsbh", GPR64Opnd>, SEB_FM<2, 0x24>, ISA_MIPS64R2;
 233 def DSHD : SubwordSwap<"dshd", GPR64Opnd>, SEB_FM<5, 0x24>, ISA_MIPS64R2;
 234
 235 def LEA_ADDiu64 : EffectiveAddress<"daddiu", GPR64Opnd>, LW_FM<0x19>;
 236
 237 let isCodeGenOnly = 1 in
 238 def RDHWR64 : ReadHardware<GPR64Opnd, HWRegsOpnd>, RDHWR_FM;
 239
 240 def DEXT : ExtBase<"dext", GPR64Opnd, uimm6, MipsExt>, EXT_FM<3>;
 241 def DEXTU : ExtBase<"dextu", GPR64Opnd, uimm6>, EXT_FM<2>;
 242 def DEXTM : ExtBase<"dextm", GPR64Opnd, uimm5>, EXT_FM<1>;
 243
 244 def DINS : InsBase<"dins", GPR64Opnd, uimm6, MipsIns>, EXT_FM<7>;
 245 def DINSU : InsBase<"dinsu", GPR64Opnd, uimm6>, EXT_FM<6>;
 246 def DINSM : InsBase<"dinsm", GPR64Opnd, uimm5>, EXT_FM<5>;
 247
 248 let isCodeGenOnly = 1, rs = 0, shamt = 0 in {
 249   def DSLL64_32 : FR<0x00, 0x3c, (outs GPR64:$rd), (ins GPR32:$rt),
 250                      "dsll\t$rd, $rt, 32", [], II_DSLL>;
 251   def SLL64_32 : FR<0x0, 0x00, (outs GPR64:$rd), (ins GPR32:$rt),
 252                     "sll\t$rd, $rt, 0", [], II_SLL>;
 253   def SLL64_64 : FR<0x0, 0x00, (outs GPR64:$rd), (ins GPR64:$rt),
 254                     "sll\t$rd, $rt, 0", [], II_SLL>;
 255 }
 256
 257 // We need the following pseudo instruction to avoid offset calculation for
 258 // long branches.  See the comment in file MipsLongBranch.cpp for detailed
 259 // explanation.
 260
 261 // Expands to: daddiu $dst, $src, %PART($tgt - $baltgt)
 262 // where %PART may be %hi or %lo, depending on the relocation kind
 263 // that $tgt is annotated with.
 264 def LONG_BRANCH_DADDiu : PseudoSE<(outs GPR64Opnd:$dst),
 265   (ins GPR64Opnd:$src, brtarget:$tgt, brtarget:$baltgt), []>;
 266
 267 // Cavium Octeon cmMIPS instructions
 268 let EncodingPredicates = []<Predicate>, // FIXME: The lack of HasStdEnc is probably a bug
 269     AdditionalPredicates = [HasCnMips] in {
 270
 271 class Count1s<string opstr, RegisterOperand RO>:
 272   InstSE<(outs RO:$rd), (ins RO:$rs), !strconcat(opstr, "\t$rd, $rs"),
 273          [(set RO:$rd, (ctpop RO:$rs))], II_POP, FrmR, opstr> {
 274   let TwoOperandAliasConstraint = "$rd = $rs";
 275 }
 276
 277 class ExtsCins<string opstr, SDPatternOperator Op = null_frag>:
 278   InstSE<(outs GPR64Opnd:$rt), (ins GPR64Opnd:$rs, uimm5:$pos, uimm5:$lenm1),
 279          !strconcat(opstr, " $rt, $rs, $pos, $lenm1"),
 280          [(set GPR64Opnd:$rt, (Op GPR64Opnd:$rs, imm:$pos, imm:$lenm1))],
 281          NoItinerary, FrmR, opstr> {
 282   let TwoOperandAliasConstraint = "$rt = $rs";
 283 }
 284
 285 class SetCC64_R<string opstr, PatFrag cond_op> :
 286   InstSE<(outs GPR64Opnd:$rd), (ins GPR64Opnd:$rs, GPR64Opnd:$rt),
 287          !strconcat(opstr, "\t$rd, $rs, $rt"),
 288          [(set GPR64Opnd:$rd, (cond_op GPR64Opnd:$rs, GPR64Opnd:$rt))],
 289          II_SEQ_SNE, FrmR, opstr> {
 290   let TwoOperandAliasConstraint = "$rd = $rs";
 291 }
 292
 293 class SetCC64_I<string opstr, PatFrag cond_op>:
 294   InstSE<(outs GPR64Opnd:$rt), (ins GPR64Opnd:$rs, simm10_64:$imm10),
 295          !strconcat(opstr, "\t$rt, $rs, $imm10"),
 296          [(set GPR64Opnd:$rt, (cond_op GPR64Opnd:$rs, immSExt10_64:$imm10))],
 297          II_SEQI_SNEI, FrmI, opstr> {
 298   let TwoOperandAliasConstraint = "$rt = $rs";
 299 }
 300
 301 // Unsigned Byte Add
 302 let Pattern = [(set GPR64Opnd:$rd,
 303                     (and (add GPR64Opnd:$rs, GPR64Opnd:$rt), 255))] in
 304 def BADDu  : ArithLogicR<"baddu", GPR64Opnd, 1, II_BADDU>,
 305                               ADD_FM<0x1c, 0x28>;
 306
 307 // Multiply Doubleword to GPR
 308 let Defs = [HI0, LO0, P0, P1, P2] in
 309 def DMUL  : ArithLogicR<"dmul", GPR64Opnd, 1, II_DMUL, mul>,
 310                               ADD_FM<0x1c, 0x03>;
 311
 312 // Extract a signed bit field /+32
 313 def EXTS  : ExtsCins<"exts">, EXTS_FM<0x3a>;
 314 def EXTS32: ExtsCins<"exts32">, EXTS_FM<0x3b>;
 315
 316 // Clear and insert a bit field /+32
 317 def CINS  : ExtsCins<"cins">, EXTS_FM<0x32>;
 318 def CINS32: ExtsCins<"cins32">, EXTS_FM<0x33>;
 319
 320 // Move to multiplier/product register
 321 def MTM0   : MoveToLOHI<"mtm0", GPR64Opnd, [MPL0, P0, P1, P2]>, MTMR_FM<0x08>;
 322 def MTM1   : MoveToLOHI<"mtm1", GPR64Opnd, [MPL1, P0, P1, P2]>, MTMR_FM<0x0c>;
 323 def MTM2   : MoveToLOHI<"mtm2", GPR64Opnd, [MPL2, P0, P1, P2]>, MTMR_FM<0x0d>;
 324 def MTP0   : MoveToLOHI<"mtp0", GPR64Opnd, [P0]>, MTMR_FM<0x09>;
 325 def MTP1   : MoveToLOHI<"mtp1", GPR64Opnd, [P1]>, MTMR_FM<0x0a>;
 326 def MTP2   : MoveToLOHI<"mtp2", GPR64Opnd, [P2]>, MTMR_FM<0x0b>;
 327
 328 // Count Ones in a Word/Doubleword
 329 def POP   : Count1s<"pop", GPR32Opnd>, POP_FM<0x2c>;
 330 def DPOP  : Count1s<"dpop", GPR64Opnd>, POP_FM<0x2d>;
 331
 332 // Set on equal/not equal
 333 def SEQ   : SetCC64_R<"seq", seteq>, SEQ_FM<0x2a>;
 334 def SEQi  : SetCC64_I<"seqi", seteq>, SEQI_FM<0x2e>;
 335 def SNE   : SetCC64_R<"sne", setne>, SEQ_FM<0x2b>;
 336 def SNEi  : SetCC64_I<"snei", setne>, SEQI_FM<0x2f>;
 337
 338 // 192-bit x 64-bit Unsigned Multiply and Add
 339 let Defs = [P0, P1, P2] in
 340 def V3MULU: ArithLogicR<"v3mulu", GPR64Opnd, 0, II_DMUL>,
 341                                   ADD_FM<0x1c, 0x11>;
 342
 343 // 64-bit Unsigned Multiply and Add Move
 344 let Defs = [MPL0, P0, P1, P2] in
 345 def VMM0  : ArithLogicR<"vmm0", GPR64Opnd, 0, II_DMUL>,
 346                                 ADD_FM<0x1c, 0x10>;
 347
 348 // 64-bit Unsigned Multiply and Add
 349 let Defs = [MPL1, MPL2, P0, P1, P2] in
 350 def VMULU : ArithLogicR<"vmulu", GPR64Opnd, 0, II_DMUL>,
 351                                  ADD_FM<0x1c, 0x0f>;
 352
 353 }
 354
 355 }
 356
 357 //===----------------------------------------------------------------------===//
 358 //  Arbitrary patterns that map to one or more instructions
 359 //===----------------------------------------------------------------------===//
 360
 361 // extended loads
 362 def : MipsPat<(i64 (extloadi1  addr:$src)), (LB64 addr:$src)>;
 363 def : MipsPat<(i64 (extloadi8  addr:$src)), (LB64 addr:$src)>;
 364 def : MipsPat<(i64 (extloadi16 addr:$src)), (LH64 addr:$src)>;
 365 def : MipsPat<(i64 (extloadi32 addr:$src)), (LW64 addr:$src)>;
 366
 367 // hi/lo relocs
 368 def : MipsPat<(MipsHi tglobaladdr:$in), (LUi64 tglobaladdr:$in)>;
 369 def : MipsPat<(MipsHi tblockaddress:$in), (LUi64 tblockaddress:$in)>;
 370 def : MipsPat<(MipsHi tjumptable:$in), (LUi64 tjumptable:$in)>;
 371 def : MipsPat<(MipsHi tconstpool:$in), (LUi64 tconstpool:$in)>;
 372 def : MipsPat<(MipsHi tglobaltlsaddr:$in), (LUi64 tglobaltlsaddr:$in)>;
 373 def : MipsPat<(MipsHi texternalsym:$in), (LUi64 texternalsym:$in)>;
 374
 375 def : MipsPat<(MipsLo tglobaladdr:$in), (DADDiu ZERO_64, tglobaladdr:$in)>;
 376 def : MipsPat<(MipsLo tblockaddress:$in), (DADDiu ZERO_64, tblockaddress:$in)>;
 377 def : MipsPat<(MipsLo tjumptable:$in), (DADDiu ZERO_64, tjumptable:$in)>;
 378 def : MipsPat<(MipsLo tconstpool:$in), (DADDiu ZERO_64, tconstpool:$in)>;
 379 def : MipsPat<(MipsLo tglobaltlsaddr:$in),
 380               (DADDiu ZERO_64, tglobaltlsaddr:$in)>;
 381 def : MipsPat<(MipsLo texternalsym:$in), (DADDiu ZERO_64, texternalsym:$in)>;
 382
 383 def : MipsPat<(add GPR64:$hi, (MipsLo tglobaladdr:$lo)),
 384               (DADDiu GPR64:$hi, tglobaladdr:$lo)>;
 385 def : MipsPat<(add GPR64:$hi, (MipsLo tblockaddress:$lo)),
 386               (DADDiu GPR64:$hi, tblockaddress:$lo)>;
 387 def : MipsPat<(add GPR64:$hi, (MipsLo tjumptable:$lo)),
 388               (DADDiu GPR64:$hi, tjumptable:$lo)>;
 389 def : MipsPat<(add GPR64:$hi, (MipsLo tconstpool:$lo)),
 390               (DADDiu GPR64:$hi, tconstpool:$lo)>;
 391 def : MipsPat<(add GPR64:$hi, (MipsLo tglobaltlsaddr:$lo)),
 392               (DADDiu GPR64:$hi, tglobaltlsaddr:$lo)>;
 393
 394 def : WrapperPat<tglobaladdr, DADDiu, GPR64>;
 395 def : WrapperPat<tconstpool, DADDiu, GPR64>;
 396 def : WrapperPat<texternalsym, DADDiu, GPR64>;
 397 def : WrapperPat<tblockaddress, DADDiu, GPR64>;
 398 def : WrapperPat<tjumptable, DADDiu, GPR64>;
 399 def : WrapperPat<tglobaltlsaddr, DADDiu, GPR64>;
 400
 401 defm : BrcondPats<GPR64, BEQ64, BNE64, SLT64, SLTu64, SLTi64, SLTiu64,
 402                   ZERO_64>;
 403
 404 def : MipsPat<(brcond (i32 (setlt i64:$lhs, 1)), bb:$dst),
 405               (BLEZ64 i64:$lhs, bb:$dst)>;
 406 def : MipsPat<(brcond (i32 (setgt i64:$lhs, -1)), bb:$dst),
 407               (BGEZ64 i64:$lhs, bb:$dst)>;
 408
 409 // setcc patterns
 410 defm : SeteqPats<GPR64, SLTiu64, XOR64, SLTu64, ZERO_64>;
 411 defm : SetlePats<GPR64, SLT64, SLTu64>;
 412 defm : SetgtPats<GPR64, SLT64, SLTu64>;
 413 defm : SetgePats<GPR64, SLT64, SLTu64>;
 414 defm : SetgeImmPats<GPR64, SLTi64, SLTiu64>;
 415
 416 // truncate
 417 def : MipsPat<(i32 (trunc GPR64:$src)),
 418               (SLL (EXTRACT_SUBREG GPR64:$src, sub_32), 0)>;
 419
 420 // 32-to-64-bit extension
 421 def : MipsPat<(i64 (anyext GPR32:$src)), (SLL64_32 GPR32:$src)>;
 422 def : MipsPat<(i64 (zext GPR32:$src)), (DSRL (DSLL64_32 GPR32:$src), 32)>;
 423 def : MipsPat<(i64 (sext GPR32:$src)), (SLL64_32 GPR32:$src)>;
 424
 425 // Sign extend in register
 426 def : MipsPat<(i64 (sext_inreg GPR64:$src, i32)),
 427               (SLL64_64 GPR64:$src)>;
 428
 429 // bswap MipsPattern
 430 def : MipsPat<(bswap GPR64:$rt), (DSHD (DSBH GPR64:$rt))>;
 431
 432 //===----------------------------------------------------------------------===//
 433 // Instruction aliases
 434 //===----------------------------------------------------------------------===//
 435 def : MipsInstAlias<"move $dst, $src",
 436                     (DADDu GPR64Opnd:$dst,  GPR64Opnd:$src, ZERO_64), 1>,
 437       GPR_64;
 438 def : MipsInstAlias<"daddu $rs, $rt, $imm",
 439                     (DADDiu GPR64Opnd:$rs, GPR64Opnd:$rt, simm16_64:$imm),
 440                     0>;
 441 def : MipsInstAlias<"dadd $rs, $rt, $imm",
 442                     (DADDi GPR64Opnd:$rs, GPR64Opnd:$rt, simm16_64:$imm),
 443                     0>, ISA_MIPS3_NOT_32R6_64R6;
 444 def : MipsInstAlias<"daddu $rs, $imm",
 445                     (DADDiu GPR64Opnd:$rs, GPR64Opnd:$rs, simm16_64:$imm),
 446                     0>;
 447 def : MipsInstAlias<"dadd $rs, $imm",
 448                     (DADDi GPR64Opnd:$rs, GPR64Opnd:$rs, simm16_64:$imm),
 449                     0>, ISA_MIPS3_NOT_32R6_64R6;
 450 def : MipsInstAlias<"add $rs, $imm",
 451                     (ADDi GPR32Opnd:$rs, GPR32Opnd:$rs, simm16:$imm),
 452                     0>;
 453 def : MipsInstAlias<"addu $rs, $imm",
 454                     (ADDiu GPR32Opnd:$rs, GPR32Opnd:$rs, simm16:$imm),
 455                     0>;
 456 def : MipsInstAlias<"dsll $rd, $rt, $rs",
 457                     (DSLLV GPR64Opnd:$rd, GPR64Opnd:$rt, GPR32Opnd:$rs), 0>,
 458                     ISA_MIPS3;
 459 def : MipsInstAlias<"dsubu $rt, $rs, $imm",
 460                     (DADDiu GPR64Opnd:$rt, GPR64Opnd:$rs,
 461                             InvertedImOperand64:$imm), 0>;
 462 def : MipsInstAlias<"dsubi $rs, $rt, $imm",
 463                     (DADDi GPR64Opnd:$rs, GPR64Opnd:$rt,
 464                            InvertedImOperand64:$imm),
 465                     0>, ISA_MIPS3_NOT_32R6_64R6;
 466 def : MipsInstAlias<"dsubi $rs, $imm",
 467                     (DADDi GPR64Opnd:$rs, GPR64Opnd:$rs,
 468                            InvertedImOperand64:$imm),
 469                     0>, ISA_MIPS3_NOT_32R6_64R6;
 470 def : MipsInstAlias<"dsub $rs, $rt, $imm",
 471                     (DADDi GPR64Opnd:$rs, GPR64Opnd:$rt,
 472                            InvertedImOperand64:$imm),
 473                     0>, ISA_MIPS3_NOT_32R6_64R6;
 474 def : MipsInstAlias<"dsub $rs, $imm",
 475                     (DADDi GPR64Opnd:$rs, GPR64Opnd:$rs,
 476                            InvertedImOperand64:$imm),
 477                     0>, ISA_MIPS3_NOT_32R6_64R6;
 478 def : MipsInstAlias<"dsubu $rs, $imm",
 479                     (DADDiu GPR64Opnd:$rs, GPR64Opnd:$rs,
 480                             InvertedImOperand64:$imm),
 481                     0>;
 482 def : MipsInstAlias<"dsra $rd, $rt, $rs",
 483                     (DSRAV GPR64Opnd:$rd, GPR64Opnd:$rt, GPR32Opnd:$rs), 0>,
 484                     ISA_MIPS3;
 485 def : MipsInstAlias<"dsrl $rd, $rt, $rs",
 486                     (DSRLV GPR64Opnd:$rd, GPR64Opnd:$rt, GPR32Opnd:$rs), 0>,
 487                     ISA_MIPS3;
 488
 489 /// Move between CPU and coprocessor registers
 490 let DecoderNamespace = "Mips64", Predicates = [HasMips64] in {
 491 def DMFC0 : MFC3OP<"dmfc0", GPR64Opnd>, MFC3OP_FM<0x10, 1>;
 492 def DMTC0 : MFC3OP<"dmtc0", GPR64Opnd>, MFC3OP_FM<0x10, 5>, ISA_MIPS3;
 493 def DMFC2 : MFC3OP<"dmfc2", GPR64Opnd>, MFC3OP_FM<0x12, 1>, ISA_MIPS3;
 494 def DMTC2 : MFC3OP<"dmtc2", GPR64Opnd>, MFC3OP_FM<0x12, 5>, ISA_MIPS3;
 495 }
 496
 497 // Two operand (implicit 0 selector) versions:
 498 def : MipsInstAlias<"dmfc0 $rt, $rd", (DMFC0 GPR64Opnd:$rt, GPR64Opnd:$rd, 0), 0>;
 499 def : MipsInstAlias<"dmtc0 $rt, $rd", (DMTC0 GPR64Opnd:$rt, GPR64Opnd:$rd, 0), 0>;
 500 def : MipsInstAlias<"dmfc2 $rt, $rd", (DMFC2 GPR64Opnd:$rt, GPR64Opnd:$rd, 0), 0>;
 501 def : MipsInstAlias<"dmtc2 $rt, $rd", (DMTC2 GPR64Opnd:$rt, GPR64Opnd:$rd, 0), 0>;
 502