lib/Target/Mips/Mips32r6InstrInfo.td

   1 //=- Mips32r6InstrInfo.td - Mips32r6 Instruction Information -*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes Mips32r6 instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "Mips32r6InstrFormats.td"
  15
  16 // Notes about removals/changes from MIPS32r6:
  17 // Unclear: ssnop
  18 // Reencoded: cache, pref
  19 // Reencoded: clo, clz
  20 // Reencoded: jr -> jalr
  21 // Reencoded: jr.hb -> jalr.hb
  22 // Reencoded: ldc2
  23 // Reencoded: ll, sc
  24 // Reencoded: lwc2
  25 // Reencoded: sdbbp
  26 // Reencoded: sdc2
  27 // Reencoded: swc2
  28 // Removed: bc1any2, bc1any4
  29 // Removed: bc2[ft]
  30 // Removed: bc2f, bc2t
  31 // Removed: bgezal
  32 // Removed: bltzal
  33 // Removed: c.cond.fmt, bc1[ft]
  34 // Removed: jalx
  35 // Removed: ldxc1
  36 // Removed: luxc1
  37 // Removed: lwxc1
  38 // Removed: movf, movt
  39 // Removed: movf.fmt, movt.fmt, movn.fmt, movz.fmt
  40 // Removed: movn, movz
  41 // Removed: prefx
  42 // Removed: sdxc1
  43 // Removed: suxc1
  44 // Removed: swxc1
  45 // Rencoded: [ls][wd]c2
  46
  47 def brtarget21 : Operand<OtherVT> {
  48   let EncoderMethod = "getBranchTarget21OpValue";
  49   let OperandType = "OPERAND_PCREL";
  50   let DecoderMethod = "DecodeBranchTarget21";
  51   let ParserMatchClass = MipsJumpTargetAsmOperand;
  52 }
  53
  54 def brtarget26 : Operand<OtherVT> {
  55   let EncoderMethod = "getBranchTarget26OpValue";
  56   let OperandType = "OPERAND_PCREL";
  57   let DecoderMethod = "DecodeBranchTarget26";
  58   let ParserMatchClass = MipsJumpTargetAsmOperand;
  59 }
  60
  61 def jmpoffset16 : Operand<OtherVT> {
  62   let EncoderMethod = "getJumpOffset16OpValue";
  63   let ParserMatchClass = MipsJumpTargetAsmOperand;
  64 }
  65
  66 def calloffset16 : Operand<iPTR> {
  67   let EncoderMethod = "getJumpOffset16OpValue";
  68   let ParserMatchClass = MipsJumpTargetAsmOperand;
  69 }
  70
  71 //===----------------------------------------------------------------------===//
  72 //
  73 // Instruction Encodings
  74 //
  75 //===----------------------------------------------------------------------===//
  76
  77 class ADDIUPC_ENC : PCREL19_FM<OPCODE2_ADDIUPC>;
  78 class ALIGN_ENC  : SPECIAL3_ALIGN_FM<OPCODE6_ALIGN>;
  79 class ALUIPC_ENC : PCREL16_FM<OPCODE5_ALUIPC>;
  80 class AUI_ENC    : AUI_FM;
  81 class AUIPC_ENC  : PCREL16_FM<OPCODE5_AUIPC>;
  82
  83 class BALC_ENC  : BRANCH_OFF26_FM<0b111010>;
  84 class BC_ENC    : BRANCH_OFF26_FM<0b110010>;
  85 class BEQC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_ADDI>,
  86                   DecodeDisambiguates<"AddiGroupBranch">;
  87 class BEQZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_ADDI>,
  88                     DecodeDisambiguatedBy<"DaddiGroupBranch">;
  89 class BNEC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_DADDI>,
  90                   DecodeDisambiguates<"DaddiGroupBranch">;
  91 class BNEZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_DADDI>,
  92                     DecodeDisambiguatedBy<"DaddiGroupBranch">;
  93
  94 class BLTZC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BGTZL>,
  95                   DecodeDisambiguates<"BgtzlGroupBranch">;
  96 class BGEZC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BLEZL>,
  97                   DecodeDisambiguates<"BlezlGroupBranch">;
  98 class BGTZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BGTZ>,
  99                     DecodeDisambiguatedBy<"BgtzGroupBranch">;
 100
 101 class BLEZC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BLEZL>,
 102                   DecodeDisambiguatedBy<"BlezlGroupBranch">;
 103 class BLTZALC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BGTZ>,
 104                     DecodeDisambiguates<"BgtzGroupBranch">;
 105 class BGTZC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BGTZL>,
 106                   DecodeDisambiguatedBy<"BgtzlGroupBranch">;
 107
 108 class BEQZC_ENC : CMP_BRANCH_OFF21_FM<0b110110>;
 109 class BGEZALC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BLEZ>;
 110 class BNEZC_ENC : CMP_BRANCH_OFF21_FM<0b111110>;
 111
 112 class BC1EQZ_ENC : COP1_BCCZ_FM<OPCODE5_BC1EQZ>;
 113 class BC1NEZ_ENC : COP1_BCCZ_FM<OPCODE5_BC1NEZ>;
 114 class BC2EQZ_ENC : COP2_BCCZ_FM<OPCODE5_BC2EQZ>;
 115 class BC2NEZ_ENC : COP2_BCCZ_FM<OPCODE5_BC2NEZ>;
 116
 117 class JIALC_ENC : JMP_IDX_COMPACT_FM<0b111110>;
 118 class JIC_ENC   : JMP_IDX_COMPACT_FM<0b110110>;
 119 class JR_HB_R6_ENC : JR_HB_R6_FM<OPCODE6_JALR>;
 120 class BITSWAP_ENC : SPECIAL3_2R_FM<OPCODE6_BITSWAP>;
 121 class BLEZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BLEZ>;
 122 class BNVC_ENC   : CMP_BRANCH_2R_OFF16_FM<OPGROUP_DADDI>,
 123                    DecodeDisambiguatedBy<"DaddiGroupBranch">;
 124 class BOVC_ENC   : CMP_BRANCH_2R_OFF16_FM<OPGROUP_ADDI>,
 125                    DecodeDisambiguatedBy<"AddiGroupBranch">;
 126 class DIV_ENC    : SPECIAL_3R_FM<0b00010, 0b011010>;
 127 class DIVU_ENC   : SPECIAL_3R_FM<0b00010, 0b011011>;
 128 class MOD_ENC    : SPECIAL_3R_FM<0b00011, 0b011010>;
 129 class MODU_ENC   : SPECIAL_3R_FM<0b00011, 0b011011>;
 130 class MUH_ENC    : SPECIAL_3R_FM<0b00011, 0b011000>;
 131 class MUHU_ENC   : SPECIAL_3R_FM<0b00011, 0b011001>;
 132 class MUL_R6_ENC : SPECIAL_3R_FM<0b00010, 0b011000>;
 133 class MULU_ENC   : SPECIAL_3R_FM<0b00010, 0b011001>;
 134
 135 class MADDF_S_ENC  : COP1_3R_FM<0b011000, FIELD_FMT_S>;
 136 class MADDF_D_ENC  : COP1_3R_FM<0b011000, FIELD_FMT_D>;
 137 class MSUBF_S_ENC  : COP1_3R_FM<0b011001, FIELD_FMT_S>;
 138 class MSUBF_D_ENC  : COP1_3R_FM<0b011001, FIELD_FMT_D>;
 139
 140 class SEL_D_ENC  : COP1_3R_FM<0b010000, FIELD_FMT_D>;
 141 class SEL_S_ENC  : COP1_3R_FM<0b010000, FIELD_FMT_S>;
 142
 143 class SELEQZ_ENC : SPECIAL_3R_FM<0b00000, 0b110101>;
 144 class SELNEZ_ENC : SPECIAL_3R_FM<0b00000, 0b110111>;
 145
 146 class LWPC_ENC   : PCREL19_FM<OPCODE2_LWPC>;
 147 class LWUPC_ENC  : PCREL19_FM<OPCODE2_LWUPC>;
 148
 149 class MAX_S_ENC : COP1_3R_FM<0b011101, FIELD_FMT_S>;
 150 class MAX_D_ENC : COP1_3R_FM<0b011101, FIELD_FMT_D>;
 151 class MIN_S_ENC : COP1_3R_FM<0b011100, FIELD_FMT_S>;
 152 class MIN_D_ENC : COP1_3R_FM<0b011100, FIELD_FMT_D>;
 153
 154 class MAXA_S_ENC : COP1_3R_FM<0b011111, FIELD_FMT_S>;
 155 class MAXA_D_ENC : COP1_3R_FM<0b011111, FIELD_FMT_D>;
 156 class MINA_S_ENC : COP1_3R_FM<0b011110, FIELD_FMT_S>;
 157 class MINA_D_ENC : COP1_3R_FM<0b011110, FIELD_FMT_D>;
 158
 159 class SELEQZ_S_ENC : COP1_3R_FM<0b010100, FIELD_FMT_S>;
 160 class SELEQZ_D_ENC : COP1_3R_FM<0b010100, FIELD_FMT_D>;
 161 class SELNEZ_S_ENC : COP1_3R_FM<0b010111, FIELD_FMT_S>;
 162 class SELNEZ_D_ENC : COP1_3R_FM<0b010111, FIELD_FMT_D>;
 163
 164 class RINT_S_ENC : COP1_2R_FM<0b011010, FIELD_FMT_S>;
 165 class RINT_D_ENC : COP1_2R_FM<0b011010, FIELD_FMT_D>;
 166 class CLASS_S_ENC : COP1_2R_FM<0b011011, FIELD_FMT_S>;
 167 class CLASS_D_ENC : COP1_2R_FM<0b011011, FIELD_FMT_D>;
 168
 169 class CMP_CONDN_DESC_BASE<string CondStr, string Typestr, RegisterOperand FGROpnd> {
 170   dag OutOperandList = (outs FGROpnd:$fd);
 171   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 172   string AsmString = !strconcat("cmp.", CondStr, ".", Typestr, "\t$fd, $fs, $ft");
 173   list<dag> Pattern = [];
 174 }
 175
 176 //===----------------------------------------------------------------------===//
 177 //
 178 // Instruction Multiclasses
 179 //
 180 //===----------------------------------------------------------------------===//
 181
 182 multiclass CMP_CC_M <FIELD_CMP_FORMAT Format, string Typestr,
 183                      RegisterOperand FGROpnd>{
 184   def CMP_F_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_F>,
 185                     CMP_CONDN_DESC_BASE<"f", Typestr, FGROpnd>,
 186                     ISA_MIPS32R6;
 187   def CMP_UN_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_UN>,
 188                      CMP_CONDN_DESC_BASE<"un", Typestr, FGROpnd>,
 189                      ISA_MIPS32R6;
 190   def CMP_EQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_EQ>,
 191                      CMP_CONDN_DESC_BASE<"eq", Typestr, FGROpnd>,
 192                      ISA_MIPS32R6;
 193   def CMP_UEQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_UEQ>,
 194                       CMP_CONDN_DESC_BASE<"ueq", Typestr, FGROpnd>,
 195                       ISA_MIPS32R6;
 196   def CMP_OLT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_OLT>,
 197                       CMP_CONDN_DESC_BASE<"olt", Typestr, FGROpnd>,
 198                       ISA_MIPS32R6;
 199   def CMP_ULT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_ULT>,
 200                       CMP_CONDN_DESC_BASE<"ult", Typestr, FGROpnd>,
 201                       ISA_MIPS32R6;
 202   def CMP_OLE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_OLE>,
 203                       CMP_CONDN_DESC_BASE<"ole", Typestr, FGROpnd>,
 204                       ISA_MIPS32R6;
 205   def CMP_ULE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_ULE>,
 206                       CMP_CONDN_DESC_BASE<"ule", Typestr, FGROpnd>,
 207                       ISA_MIPS32R6;
 208   def CMP_SF_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SF>,
 209                      CMP_CONDN_DESC_BASE<"sf", Typestr, FGROpnd>,
 210                      ISA_MIPS32R6;
 211   def CMP_NGLE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGLE>,
 212                        CMP_CONDN_DESC_BASE<"ngle", Typestr, FGROpnd>,
 213                        ISA_MIPS32R6;
 214   def CMP_SEQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SEQ>,
 215                       CMP_CONDN_DESC_BASE<"seq", Typestr, FGROpnd>,
 216                       ISA_MIPS32R6;
 217   def CMP_NGL_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGL>,
 218                       CMP_CONDN_DESC_BASE<"ngl", Typestr, FGROpnd>,
 219                       ISA_MIPS32R6;
 220   def CMP_LT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_LT>,
 221                      CMP_CONDN_DESC_BASE<"lt", Typestr, FGROpnd>,
 222                      ISA_MIPS32R6;
 223   def CMP_NGE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGE>,
 224                       CMP_CONDN_DESC_BASE<"nge", Typestr, FGROpnd>,
 225                       ISA_MIPS32R6;
 226   def CMP_LE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_LE>,
 227                      CMP_CONDN_DESC_BASE<"le", Typestr, FGROpnd>,
 228                      ISA_MIPS32R6;
 229   def CMP_NGT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGT>,
 230                       CMP_CONDN_DESC_BASE<"ngt", Typestr, FGROpnd>,
 231                       ISA_MIPS32R6;
 232 }
 233
 234 //===----------------------------------------------------------------------===//
 235 //
 236 // Instruction Descriptions
 237 //
 238 //===----------------------------------------------------------------------===//
 239
 240 class PCREL_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 241                       Operand ImmOpnd> {
 242   dag OutOperandList = (outs GPROpnd:$rs);
 243   dag InOperandList = (ins ImmOpnd:$imm);
 244   string AsmString = !strconcat(instr_asm, "\t$rs, $imm");
 245   list<dag> Pattern = [];
 246 }
 247
 248 class ADDIUPC_DESC : PCREL_DESC_BASE<"addiupc", GPR32Opnd, simm19_lsl2>;
 249 class LWPC_DESC: PCREL_DESC_BASE<"lwpc", GPR32Opnd, simm19_lsl2>;
 250 class LWUPC_DESC: PCREL_DESC_BASE<"lwupc", GPR32Opnd, simm19_lsl2>;
 251
 252 class ALIGN_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 253                       Operand ImmOpnd> {
 254   dag OutOperandList = (outs GPROpnd:$rd);
 255   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, ImmOpnd:$bp);
 256   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt, $bp");
 257   list<dag> Pattern = [];
 258 }
 259
 260 class ALIGN_DESC : ALIGN_DESC_BASE<"align", GPR32Opnd, uimm2>;
 261
 262 class ALUIPC_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 263   dag OutOperandList = (outs GPROpnd:$rs);
 264   dag InOperandList = (ins simm16:$imm);
 265   string AsmString = !strconcat(instr_asm, "\t$rs, $imm");
 266   list<dag> Pattern = [];
 267 }
 268
 269 class ALUIPC_DESC : ALUIPC_DESC_BASE<"aluipc", GPR32Opnd>;
 270 class AUIPC_DESC : ALUIPC_DESC_BASE<"auipc", GPR32Opnd>;
 271
 272 class AUI_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 273   dag OutOperandList = (outs GPROpnd:$rs);
 274   dag InOperandList = (ins GPROpnd:$rt, simm16:$imm);
 275   string AsmString = !strconcat(instr_asm, "\t$rs, $rt, $imm");
 276   list<dag> Pattern = [];
 277 }
 278
 279 class AUI_DESC : AUI_DESC_BASE<"aui", GPR32Opnd>;
 280
 281 class BRANCH_DESC_BASE {
 282   bit isBranch = 1;
 283   bit isTerminator = 1;
 284   bit hasDelaySlot = 0;
 285 }
 286
 287 class BC_DESC_BASE<string instr_asm, DAGOperand opnd> : BRANCH_DESC_BASE {
 288   dag InOperandList = (ins opnd:$offset);
 289   dag OutOperandList = (outs);
 290   string AsmString = !strconcat(instr_asm, "\t$offset");
 291   bit isBarrier = 1;
 292 }
 293
 294 class CMP_BC_DESC_BASE<string instr_asm, DAGOperand opnd,
 295                        RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 296   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, opnd:$offset);
 297   dag OutOperandList = (outs);
 298   string AsmString = !strconcat(instr_asm, "\t$rs, $rt, $offset");
 299   list<Register> Defs = [AT];
 300 }
 301
 302 class CMP_CBR_EQNE_Z_DESC_BASE<string instr_asm, DAGOperand opnd,
 303                                RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 304   dag InOperandList = (ins GPROpnd:$rs, opnd:$offset);
 305   dag OutOperandList = (outs);
 306   string AsmString = !strconcat(instr_asm, "\t$rs, $offset");
 307   list<Register> Defs = [AT];
 308 }
 309
 310 class CMP_CBR_RT_Z_DESC_BASE<string instr_asm, DAGOperand opnd,
 311                              RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 312   dag InOperandList = (ins GPROpnd:$rt, opnd:$offset);
 313   dag OutOperandList = (outs);
 314   string AsmString = !strconcat(instr_asm, "\t$rt, $offset");
 315   list<Register> Defs = [AT];
 316 }
 317
 318 class BALC_DESC : BC_DESC_BASE<"balc", brtarget26> {
 319   bit isCall = 1;
 320   list<Register> Defs = [RA];
 321 }
 322
 323 class BC_DESC : BC_DESC_BASE<"bc", brtarget26>;
 324 class BEQC_DESC : CMP_BC_DESC_BASE<"beqc", brtarget, GPR32Opnd>;
 325 class BNEC_DESC : CMP_BC_DESC_BASE<"bnec", brtarget, GPR32Opnd>;
 326
 327 class BLTZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bltzc", brtarget, GPR32Opnd>;
 328 class BGEZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgezc", brtarget, GPR32Opnd>;
 329
 330 class BLEZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"blezc", brtarget, GPR32Opnd>;
 331 class BGTZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgtzc", brtarget, GPR32Opnd>;
 332
 333 class BEQZC_DESC : CMP_CBR_EQNE_Z_DESC_BASE<"beqzc", brtarget21, GPR32Opnd>;
 334 class BNEZC_DESC : CMP_CBR_EQNE_Z_DESC_BASE<"bnezc", brtarget21, GPR32Opnd>;
 335
 336 class COP1_BCCZ_DESC_BASE<string instr_asm> : BRANCH_DESC_BASE {
 337   dag InOperandList = (ins FGR64Opnd:$ft, brtarget:$offset);
 338   dag OutOperandList = (outs);
 339   string AsmString = instr_asm;
 340   bit hasDelaySlot = 1;
 341 }
 342
 343 class BC1EQZ_DESC : COP1_BCCZ_DESC_BASE<"bc1eqz $ft, $offset">;
 344 class BC1NEZ_DESC : COP1_BCCZ_DESC_BASE<"bc1nez $ft, $offset">;
 345
 346 class COP2_BCCZ_DESC_BASE<string instr_asm> : BRANCH_DESC_BASE {
 347   dag InOperandList = (ins COP2Opnd:$ct, brtarget:$offset);
 348   dag OutOperandList = (outs);
 349   string AsmString = instr_asm;
 350   bit hasDelaySlot = 1;
 351 }
 352
 353 class BC2EQZ_DESC : COP2_BCCZ_DESC_BASE<"bc2eqz $ct, $offset">;
 354 class BC2NEZ_DESC : COP2_BCCZ_DESC_BASE<"bc2nez $ct, $offset">;
 355
 356 class BOVC_DESC   : CMP_BC_DESC_BASE<"bovc", brtarget, GPR32Opnd>;
 357 class BNVC_DESC   : CMP_BC_DESC_BASE<"bnvc", brtarget, GPR32Opnd>;
 358
 359 class JMP_IDX_COMPACT_DESC_BASE<string opstr, DAGOperand opnd,
 360                                 RegisterOperand GPROpnd> {
 361   dag InOperandList = (ins GPROpnd:$rt, opnd:$offset);
 362   string AsmString = !strconcat(opstr, "\t$rt, $offset");
 363   list<dag> Pattern = [];
 364   bit isTerminator = 1;
 365   bit hasDelaySlot = 0;
 366   string DecoderMethod = "DecodeSimm16";
 367 }
 368
 369 class JIALC_DESC : JMP_IDX_COMPACT_DESC_BASE<"jialc", calloffset16,
 370                                              GPR32Opnd> {
 371   bit isCall = 1;
 372   list<Register> Defs = [RA];
 373 }
 374
 375 class JIC_DESC : JMP_IDX_COMPACT_DESC_BASE<"jic", jmpoffset16, GPR32Opnd> {
 376   bit isBarrier = 1;
 377   list<Register> Defs = [AT];
 378 }
 379
 380 class JR_HB_R6_DESC : JR_HB_DESC_BASE<"jr.hb", GPR32Opnd> {
 381   bit isBranch = 1;
 382   bit isIndirectBranch = 1;
 383   bit hasDelaySlot = 1;
 384   bit isTerminator=1;
 385   bit isBarrier=1;
 386 }
 387
 388 class BITSWAP_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 389   dag OutOperandList = (outs GPROpnd:$rd);
 390   dag InOperandList = (ins GPROpnd:$rt);
 391   string AsmString = !strconcat(instr_asm, "\t$rd, $rt");
 392   list<dag> Pattern = [];
 393 }
 394
 395 class BITSWAP_DESC : BITSWAP_DESC_BASE<"bitswap", GPR32Opnd>;
 396
 397 class DIVMOD_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 398                        SDPatternOperator Op=null_frag> {
 399   dag OutOperandList = (outs GPROpnd:$rd);
 400   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 401   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 402   list<dag> Pattern = [(set GPROpnd:$rd, (Op GPROpnd:$rs, GPROpnd:$rt))];
 403
 404   // This instruction doesn't trap division by zero itself. We must insert
 405   // teq instructions as well.
 406   bit usesCustomInserter = 1;
 407 }
 408
 409 class DIV_DESC  : DIVMOD_DESC_BASE<"div", GPR32Opnd, sdiv>;
 410 class DIVU_DESC : DIVMOD_DESC_BASE<"divu", GPR32Opnd, udiv>;
 411 class MOD_DESC  : DIVMOD_DESC_BASE<"mod", GPR32Opnd, srem>;
 412 class MODU_DESC : DIVMOD_DESC_BASE<"modu", GPR32Opnd, urem>;
 413
 414 class BEQZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"beqzalc", brtarget, GPR32Opnd> {
 415   list<Register> Defs = [RA];
 416 }
 417
 418 class BGEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgezalc", brtarget, GPR32Opnd> {
 419   list<Register> Defs = [RA];
 420 }
 421
 422 class BGTZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgtzalc", brtarget, GPR32Opnd> {
 423   list<Register> Defs = [RA];
 424 }
 425
 426 class BLEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"blezalc", brtarget, GPR32Opnd> {
 427   list<Register> Defs = [RA];
 428 }
 429
 430 class BLTZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bltzalc", brtarget, GPR32Opnd> {
 431   list<Register> Defs = [RA];
 432 }
 433
 434 class BNEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bnezalc", brtarget, GPR32Opnd> {
 435   list<Register> Defs = [RA];
 436 }
 437
 438 class MUL_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 439                        SDPatternOperator Op=null_frag> {
 440   dag OutOperandList = (outs GPROpnd:$rd);
 441   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 442   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 443   list<dag> Pattern = [(set GPROpnd:$rd, (Op GPROpnd:$rs, GPROpnd:$rt))];
 444 }
 445
 446 class MUH_DESC    : MUL_R6_DESC_BASE<"muh", GPR32Opnd, mulhs>;
 447 class MUHU_DESC   : MUL_R6_DESC_BASE<"muhu", GPR32Opnd, mulhu>;
 448 class MUL_R6_DESC : MUL_R6_DESC_BASE<"mul", GPR32Opnd, mul>;
 449 class MULU_DESC   : MUL_R6_DESC_BASE<"mulu", GPR32Opnd>;
 450
 451 class COP1_4R_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 452   dag OutOperandList = (outs FGROpnd:$fd);
 453   dag InOperandList = (ins FGROpnd:$fd_in, FGROpnd:$fs, FGROpnd:$ft);
 454   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 455   list<dag> Pattern = [];
 456   string Constraints = "$fd_in = $fd";
 457 }
 458
 459 class SEL_D_DESC : COP1_4R_DESC_BASE<"sel.d", FGR64Opnd>;
 460 class SEL_S_DESC : COP1_4R_DESC_BASE<"sel.s", FGR32Opnd>;
 461
 462 class SELEQNE_Z_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 463   dag OutOperandList = (outs GPROpnd:$rd);
 464   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 465   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 466   list<dag> Pattern = [];
 467 }
 468
 469 class SELEQZ_DESC : SELEQNE_Z_DESC_BASE<"seleqz", GPR32Opnd>;
 470 class SELNEZ_DESC : SELEQNE_Z_DESC_BASE<"selnez", GPR32Opnd>;
 471
 472 class MADDF_S_DESC  : COP1_4R_DESC_BASE<"maddf.s", FGR32Opnd>;
 473 class MADDF_D_DESC  : COP1_4R_DESC_BASE<"maddf.d", FGR64Opnd>;
 474 class MSUBF_S_DESC  : COP1_4R_DESC_BASE<"msubf.s", FGR32Opnd>;
 475 class MSUBF_D_DESC  : COP1_4R_DESC_BASE<"msubf.d", FGR64Opnd>;
 476
 477 class MAX_MIN_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 478   dag OutOperandList = (outs FGROpnd:$fd);
 479   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 480   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 481   list<dag> Pattern = [];
 482 }
 483
 484 class MAX_S_DESC : MAX_MIN_DESC_BASE<"max.s", FGR32Opnd>;
 485 class MAX_D_DESC : MAX_MIN_DESC_BASE<"max.d", FGR64Opnd>;
 486 class MIN_S_DESC : MAX_MIN_DESC_BASE<"min.s", FGR32Opnd>;
 487 class MIN_D_DESC : MAX_MIN_DESC_BASE<"min.d", FGR64Opnd>;
 488
 489 class MAXA_S_DESC : MAX_MIN_DESC_BASE<"maxa.s", FGR32Opnd>;
 490 class MAXA_D_DESC : MAX_MIN_DESC_BASE<"maxa.d", FGR64Opnd>;
 491 class MINA_S_DESC : MAX_MIN_DESC_BASE<"mina.s", FGR32Opnd>;
 492 class MINA_D_DESC : MAX_MIN_DESC_BASE<"mina.d", FGR64Opnd>;
 493
 494 class SELEQNEZ_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 495   dag OutOperandList = (outs FGROpnd:$fd);
 496   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 497   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 498   list<dag> Pattern = [];
 499 }
 500
 501 class SELEQZ_S_DESC : SELEQNEZ_DESC_BASE<"seleqz.s", FGR32Opnd>;
 502 class SELEQZ_D_DESC : SELEQNEZ_DESC_BASE<"seleqz.d", FGR64Opnd>;
 503 class SELNEZ_S_DESC : SELEQNEZ_DESC_BASE<"selnez.s", FGR32Opnd>;
 504 class SELNEZ_D_DESC : SELEQNEZ_DESC_BASE<"selnez.d", FGR64Opnd>;
 505
 506 class CLASS_RINT_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 507   dag OutOperandList = (outs FGROpnd:$fd);
 508   dag InOperandList = (ins FGROpnd:$fs);
 509   string AsmString = !strconcat(instr_asm, "\t$fd, $fs");
 510   list<dag> Pattern = [];
 511 }
 512
 513 class RINT_S_DESC : CLASS_RINT_DESC_BASE<"rint.s", FGR32Opnd>;
 514 class RINT_D_DESC : CLASS_RINT_DESC_BASE<"rint.d", FGR64Opnd>;
 515 class CLASS_S_DESC : CLASS_RINT_DESC_BASE<"class.s", FGR32Opnd>;
 516 class CLASS_D_DESC : CLASS_RINT_DESC_BASE<"class.d", FGR64Opnd>;
 517
 518 //===----------------------------------------------------------------------===//
 519 //
 520 // Instruction Definitions
 521 //
 522 //===----------------------------------------------------------------------===//
 523
 524 def ADDIUPC : ADDIUPC_ENC, ADDIUPC_DESC, ISA_MIPS32R6;
 525 def ALIGN : ALIGN_ENC, ALIGN_DESC, ISA_MIPS32R6;
 526 def ALUIPC : ALUIPC_ENC, ALUIPC_DESC, ISA_MIPS32R6;
 527 def AUI : AUI_ENC, AUI_DESC, ISA_MIPS32R6;
 528 def AUIPC : AUIPC_ENC, AUIPC_DESC, ISA_MIPS32R6;
 529 def BALC : BALC_ENC, BALC_DESC, ISA_MIPS32R6;
 530 def BC1EQZ : BC1EQZ_ENC, BC1EQZ_DESC, ISA_MIPS32R6;
 531 def BC1NEZ : BC1NEZ_ENC, BC1NEZ_DESC, ISA_MIPS32R6;
 532 def BC2EQZ : BC2EQZ_ENC, BC2EQZ_DESC, ISA_MIPS32R6;
 533 def BC2NEZ : BC2NEZ_ENC, BC2NEZ_DESC, ISA_MIPS32R6;
 534 def BC : BC_ENC, BC_DESC, ISA_MIPS32R6;
 535 def BEQC : BEQC_ENC, BEQC_DESC, ISA_MIPS32R6;
 536 def BEQZALC : BEQZALC_ENC, BEQZALC_DESC, ISA_MIPS32R6;
 537 def BEQZC : BEQZC_ENC, BEQZC_DESC, ISA_MIPS32R6;
 538 def BGEC;  // Also aliased to blec with operands swapped
 539 def BGEUC; // Also aliased to bleuc with operands swapped
 540 def BGEZALC : BGEZALC_ENC, BGEZALC_DESC, ISA_MIPS32R6;
 541 def BGEZC : BGEZC_ENC, BGEZC_DESC, ISA_MIPS32R6;
 542 def BGTZALC : BGTZALC_ENC, BGTZALC_DESC, ISA_MIPS32R6;
 543 def BGTZC : BGTZC_ENC, BGTZC_DESC, ISA_MIPS32R6;
 544 def BITSWAP : BITSWAP_ENC, BITSWAP_DESC, ISA_MIPS32R6;
 545 def BLEZALC : BLEZALC_ENC, BLEZALC_DESC, ISA_MIPS32R6;
 546 def BLEZC : BLEZC_ENC, BLEZC_DESC, ISA_MIPS32R6;
 547 def BLTC; // Also aliased to bgtc with operands swapped
 548 def BLTUC; // Also aliased to bgtuc with operands swapped
 549 def BLTZALC : BLTZALC_ENC, BLTZALC_DESC, ISA_MIPS32R6;
 550 def BLTZC : BLTZC_ENC, BLTZC_DESC, ISA_MIPS32R6;
 551 def BNEC : BNEC_ENC, BNEC_DESC, ISA_MIPS32R6;
 552 def BNEZALC : BNEZALC_ENC, BNEZALC_DESC, ISA_MIPS32R6;
 553 def BNEZC : BNEZC_ENC, BNEZC_DESC, ISA_MIPS32R6;
 554 def BNVC : BNVC_ENC, BNVC_DESC, ISA_MIPS32R6;
 555 def BOVC : BOVC_ENC, BOVC_DESC, ISA_MIPS32R6;
 556 def CLASS_D : CLASS_D_ENC, CLASS_D_DESC, ISA_MIPS32R6;
 557 def CLASS_S : CLASS_S_ENC, CLASS_S_DESC, ISA_MIPS32R6;
 558 defm S : CMP_CC_M<FIELD_CMP_FORMAT_S, "s", FGR32Opnd>;
 559 defm D : CMP_CC_M<FIELD_CMP_FORMAT_D, "d", FGR64Opnd>;
 560 def DIV : DIV_ENC, DIV_DESC, ISA_MIPS32R6;
 561 def DIVU : DIVU_ENC, DIVU_DESC, ISA_MIPS32R6;
 562 def JIALC : JIALC_ENC, JIALC_DESC, ISA_MIPS32R6;
 563 def JIC : JIC_ENC, JIC_DESC, ISA_MIPS32R6;
 564 def JR_HB_R6 : JR_HB_R6_ENC, JR_HB_R6_DESC, ISA_MIPS32R6;
 565 // def LSA; // See MSA
 566 def LWPC : LWPC_ENC, LWPC_DESC, ISA_MIPS32R6;
 567 def LWUPC : LWUPC_ENC, LWUPC_DESC, ISA_MIPS32R6;
 568 def MADDF_S : MADDF_S_ENC, MADDF_S_DESC, ISA_MIPS32R6;
 569 def MADDF_D : MADDF_D_ENC, MADDF_D_DESC, ISA_MIPS32R6;
 570 def MAXA_D : MAXA_D_ENC, MAXA_D_DESC, ISA_MIPS32R6;
 571 def MAXA_S : MAXA_S_ENC, MAXA_S_DESC, ISA_MIPS32R6;
 572 def MAX_D : MAX_D_ENC, MAX_D_DESC, ISA_MIPS32R6;
 573 def MAX_S : MAX_S_ENC, MAX_S_DESC, ISA_MIPS32R6;
 574 def MINA_D : MINA_D_ENC, MINA_D_DESC, ISA_MIPS32R6;
 575 def MINA_S : MINA_S_ENC, MINA_S_DESC, ISA_MIPS32R6;
 576 def MIN_D : MIN_D_ENC, MIN_D_DESC, ISA_MIPS32R6;
 577 def MIN_S : MIN_S_ENC, MIN_S_DESC, ISA_MIPS32R6;
 578 def MOD : MOD_ENC, MOD_DESC, ISA_MIPS32R6;
 579 def MODU : MODU_ENC, MODU_DESC, ISA_MIPS32R6;
 580 def MSUBF_S : MSUBF_S_ENC, MSUBF_S_DESC, ISA_MIPS32R6;
 581 def MSUBF_D : MSUBF_D_ENC, MSUBF_D_DESC, ISA_MIPS32R6;
 582 def MUH    : MUH_ENC, MUH_DESC, ISA_MIPS32R6;
 583 def MUHU   : MUHU_ENC, MUHU_DESC, ISA_MIPS32R6;
 584 def MUL_R6 : MUL_R6_ENC, MUL_R6_DESC, ISA_MIPS32R6;
 585 def MULU   : MULU_ENC, MULU_DESC, ISA_MIPS32R6;
 586 def NAL; // BAL with rd=0
 587 def RINT_D : RINT_D_ENC, RINT_D_DESC, ISA_MIPS32R6;
 588 def RINT_S : RINT_S_ENC, RINT_S_DESC, ISA_MIPS32R6;
 589 def SELEQZ : SELEQZ_ENC, SELEQZ_DESC, ISA_MIPS32R6;
 590 def SELEQZ_D : SELEQZ_D_ENC, SELEQZ_D_DESC, ISA_MIPS32R6;
 591 def SELEQZ_S : SELEQZ_S_ENC, SELEQZ_S_DESC, ISA_MIPS32R6;
 592 def SELNEZ : SELNEZ_ENC, SELNEZ_DESC, ISA_MIPS32R6;
 593 def SELNEZ_D : SELNEZ_D_ENC, SELNEZ_D_DESC, ISA_MIPS32R6;
 594 def SELNEZ_S : SELNEZ_S_ENC, SELNEZ_S_DESC, ISA_MIPS32R6;
 595 def SEL_D : SEL_D_ENC, SEL_D_DESC, ISA_MIPS32R6;
 596 def SEL_S : SEL_S_ENC, SEL_S_DESC, ISA_MIPS32R6;