lib/Target/Mips/Mips32r6InstrInfo.td

   1 //=- Mips32r6InstrInfo.td - Mips32r6 Instruction Information -*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes Mips32r6 instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "Mips32r6InstrFormats.td"
  15
  16 // Notes about removals/changes from MIPS32r6:
  17 // Reencoded: jr -> jalr
  18 // Reencoded: jr.hb -> jalr.hb
  19
  20 def brtarget21 : Operand<OtherVT> {
  21   let EncoderMethod = "getBranchTarget21OpValue";
  22   let OperandType = "OPERAND_PCREL";
  23   let DecoderMethod = "DecodeBranchTarget21";
  24   let ParserMatchClass = MipsJumpTargetAsmOperand;
  25 }
  26
  27 def brtarget26 : Operand<OtherVT> {
  28   let EncoderMethod = "getBranchTarget26OpValue";
  29   let OperandType = "OPERAND_PCREL";
  30   let DecoderMethod = "DecodeBranchTarget26";
  31   let ParserMatchClass = MipsJumpTargetAsmOperand;
  32 }
  33
  34 def jmpoffset16 : Operand<OtherVT> {
  35   let EncoderMethod = "getJumpOffset16OpValue";
  36   let ParserMatchClass = MipsJumpTargetAsmOperand;
  37 }
  38
  39 def calloffset16 : Operand<iPTR> {
  40   let EncoderMethod = "getJumpOffset16OpValue";
  41   let ParserMatchClass = MipsJumpTargetAsmOperand;
  42 }
  43
  44 //===----------------------------------------------------------------------===//
  45 //
  46 // Instruction Encodings
  47 //
  48 //===----------------------------------------------------------------------===//
  49
  50 class ADDIUPC_ENC : PCREL19_FM<OPCODE2_ADDIUPC>;
  51 class ALIGN_ENC  : SPECIAL3_ALIGN_FM<OPCODE6_ALIGN>;
  52 class ALUIPC_ENC : PCREL16_FM<OPCODE5_ALUIPC>;
  53 class AUI_ENC    : AUI_FM;
  54 class AUIPC_ENC  : PCREL16_FM<OPCODE5_AUIPC>;
  55
  56 class BAL_ENC   : BAL_FM;
  57 class BALC_ENC  : BRANCH_OFF26_FM<0b111010>;
  58 class BC_ENC    : BRANCH_OFF26_FM<0b110010>;
  59 class BEQC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_ADDI>,
  60                   DecodeDisambiguates<"AddiGroupBranch">;
  61 class BEQZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_ADDI>,
  62                     DecodeDisambiguatedBy<"DaddiGroupBranch">;
  63 class BNEC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_DADDI>,
  64                   DecodeDisambiguates<"DaddiGroupBranch">;
  65 class BNEZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_DADDI>,
  66                     DecodeDisambiguatedBy<"DaddiGroupBranch">;
  67
  68 class BLTZC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BGTZL>,
  69                   DecodeDisambiguates<"BgtzlGroupBranch">;
  70 class BGEC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_BLEZL>,
  71                   DecodeDisambiguatedBy<"BlezlGroupBranch">;
  72 class BGEUC_ENC : CMP_BRANCH_2R_OFF16_FM<OPGROUP_BLEZ>,
  73                   DecodeDisambiguatedBy<"BlezGroupBranch">;
  74 class BGEZC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BLEZL>,
  75                   DecodeDisambiguates<"BlezlGroupBranch">;
  76 class BGTZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BGTZ>,
  77                     DecodeDisambiguatedBy<"BgtzGroupBranch">;
  78
  79 class BLTC_ENC : CMP_BRANCH_2R_OFF16_FM<OPGROUP_BGTZL>,
  80                  DecodeDisambiguatedBy<"BgtzlGroupBranch">;
  81 class BLTUC_ENC : CMP_BRANCH_2R_OFF16_FM<OPGROUP_BGTZ>,
  82                   DecodeDisambiguatedBy<"BgtzGroupBranch">;
  83
  84 class BLEZC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BLEZL>,
  85                   DecodeDisambiguatedBy<"BlezlGroupBranch">;
  86 class BLTZALC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BGTZ>,
  87                     DecodeDisambiguates<"BgtzGroupBranch">;
  88 class BGTZC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BGTZL>,
  89                   DecodeDisambiguatedBy<"BgtzlGroupBranch">;
  90
  91 class BEQZC_ENC : CMP_BRANCH_OFF21_FM<0b110110>;
  92 class BGEZALC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BLEZ>,
  93                     DecodeDisambiguates<"BlezGroupBranch">;
  94 class BNEZC_ENC : CMP_BRANCH_OFF21_FM<0b111110>;
  95
  96 class BC1EQZ_ENC : COP1_BCCZ_FM<OPCODE5_BC1EQZ>;
  97 class BC1NEZ_ENC : COP1_BCCZ_FM<OPCODE5_BC1NEZ>;
  98 class BC2EQZ_ENC : COP2_BCCZ_FM<OPCODE5_BC2EQZ>;
  99 class BC2NEZ_ENC : COP2_BCCZ_FM<OPCODE5_BC2NEZ>;
 100
 101 class JIALC_ENC : JMP_IDX_COMPACT_FM<0b111110>;
 102 class JIC_ENC   : JMP_IDX_COMPACT_FM<0b110110>;
 103 class JR_HB_R6_ENC : JR_HB_R6_FM<OPCODE6_JALR>;
 104 class BITSWAP_ENC : SPECIAL3_2R_FM<OPCODE6_BITSWAP>;
 105 class BLEZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BLEZ>,
 106                     DecodeDisambiguatedBy<"BlezGroupBranch">;
 107 class BNVC_ENC   : CMP_BRANCH_2R_OFF16_FM<OPGROUP_DADDI>,
 108                    DecodeDisambiguatedBy<"DaddiGroupBranch">;
 109 class BOVC_ENC   : CMP_BRANCH_2R_OFF16_FM<OPGROUP_ADDI>,
 110                    DecodeDisambiguatedBy<"AddiGroupBranch">;
 111 class DIV_ENC    : SPECIAL_3R_FM<0b00010, 0b011010>;
 112 class DIVU_ENC   : SPECIAL_3R_FM<0b00010, 0b011011>;
 113 class MOD_ENC    : SPECIAL_3R_FM<0b00011, 0b011010>;
 114 class MODU_ENC   : SPECIAL_3R_FM<0b00011, 0b011011>;
 115 class MUH_ENC    : SPECIAL_3R_FM<0b00011, 0b011000>;
 116 class MUHU_ENC   : SPECIAL_3R_FM<0b00011, 0b011001>;
 117 class MUL_R6_ENC : SPECIAL_3R_FM<0b00010, 0b011000>;
 118 class MULU_ENC   : SPECIAL_3R_FM<0b00010, 0b011001>;
 119
 120 class MADDF_S_ENC  : COP1_3R_FM<0b011000, FIELD_FMT_S>;
 121 class MADDF_D_ENC  : COP1_3R_FM<0b011000, FIELD_FMT_D>;
 122 class MSUBF_S_ENC  : COP1_3R_FM<0b011001, FIELD_FMT_S>;
 123 class MSUBF_D_ENC  : COP1_3R_FM<0b011001, FIELD_FMT_D>;
 124
 125 class SEL_D_ENC  : COP1_3R_FM<0b010000, FIELD_FMT_D>;
 126 class SEL_S_ENC  : COP1_3R_FM<0b010000, FIELD_FMT_S>;
 127
 128 class SELEQZ_ENC : SPECIAL_3R_FM<0b00000, 0b110101>;
 129 class SELNEZ_ENC : SPECIAL_3R_FM<0b00000, 0b110111>;
 130
 131 class LWPC_ENC   : PCREL19_FM<OPCODE2_LWPC>;
 132 class LWUPC_ENC  : PCREL19_FM<OPCODE2_LWUPC>;
 133
 134 class MAX_S_ENC : COP1_3R_FM<0b011101, FIELD_FMT_S>;
 135 class MAX_D_ENC : COP1_3R_FM<0b011101, FIELD_FMT_D>;
 136 class MIN_S_ENC : COP1_3R_FM<0b011100, FIELD_FMT_S>;
 137 class MIN_D_ENC : COP1_3R_FM<0b011100, FIELD_FMT_D>;
 138
 139 class MAXA_S_ENC : COP1_3R_FM<0b011111, FIELD_FMT_S>;
 140 class MAXA_D_ENC : COP1_3R_FM<0b011111, FIELD_FMT_D>;
 141 class MINA_S_ENC : COP1_3R_FM<0b011110, FIELD_FMT_S>;
 142 class MINA_D_ENC : COP1_3R_FM<0b011110, FIELD_FMT_D>;
 143
 144 class SELEQZ_S_ENC : COP1_3R_FM<0b010100, FIELD_FMT_S>;
 145 class SELEQZ_D_ENC : COP1_3R_FM<0b010100, FIELD_FMT_D>;
 146 class SELNEZ_S_ENC : COP1_3R_FM<0b010111, FIELD_FMT_S>;
 147 class SELNEZ_D_ENC : COP1_3R_FM<0b010111, FIELD_FMT_D>;
 148
 149 class RINT_S_ENC : COP1_2R_FM<0b011010, FIELD_FMT_S>;
 150 class RINT_D_ENC : COP1_2R_FM<0b011010, FIELD_FMT_D>;
 151 class CLASS_S_ENC : COP1_2R_FM<0b011011, FIELD_FMT_S>;
 152 class CLASS_D_ENC : COP1_2R_FM<0b011011, FIELD_FMT_D>;
 153
 154 class CACHE_ENC : SPECIAL3_MEM_FM<OPCODE6_CACHE>;
 155 class PREF_ENC : SPECIAL3_MEM_FM<OPCODE6_PREF>;
 156
 157 class LDC2_R6_ENC : COP2LDST_FM<OPCODE5_LDC2>;
 158 class LWC2_R6_ENC : COP2LDST_FM<OPCODE5_LWC2>;
 159 class SDC2_R6_ENC : COP2LDST_FM<OPCODE5_SDC2>;
 160 class SWC2_R6_ENC : COP2LDST_FM<OPCODE5_SWC2>;
 161
 162 class LSA_R6_ENC : SPECIAL_LSA_FM<OPCODE6_LSA>;
 163
 164 class LL_R6_ENC : SPECIAL3_LL_SC_FM<OPCODE6_LL>;
 165 class SC_R6_ENC : SPECIAL3_LL_SC_FM<OPCODE6_SC>;
 166
 167 class CLO_R6_ENC : SPECIAL_2R_FM<OPCODE6_CLO>;
 168 class CLZ_R6_ENC : SPECIAL_2R_FM<OPCODE6_CLZ>;
 169
 170 class SDBBP_R6_ENC : SPECIAL_SDBBP_FM;
 171
 172 //===----------------------------------------------------------------------===//
 173 //
 174 // Instruction Multiclasses
 175 //
 176 //===----------------------------------------------------------------------===//
 177
 178 class CMP_CONDN_DESC_BASE<string CondStr, string Typestr,
 179                           RegisterOperand FGROpnd,
 180                           SDPatternOperator Op = null_frag> {
 181   dag OutOperandList = (outs FGRCCOpnd:$fd);
 182   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 183   string AsmString = !strconcat("cmp.", CondStr, ".", Typestr, "\t$fd, $fs, $ft");
 184   list<dag> Pattern = [(set FGRCCOpnd:$fd, (Op FGROpnd:$fs, FGROpnd:$ft))];
 185 }
 186
 187 multiclass CMP_CC_M <FIELD_CMP_FORMAT Format, string Typestr,
 188                      RegisterOperand FGROpnd>{
 189   def CMP_F_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_AF>,
 190                     CMP_CONDN_DESC_BASE<"af", Typestr, FGROpnd>,
 191                     ISA_MIPS32R6, HARDFLOAT;
 192   def CMP_UN_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_UN>,
 193                      CMP_CONDN_DESC_BASE<"un", Typestr, FGROpnd, setuo>,
 194                      ISA_MIPS32R6, HARDFLOAT;
 195   def CMP_EQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_EQ>,
 196                      CMP_CONDN_DESC_BASE<"eq", Typestr, FGROpnd, setoeq>,
 197                      ISA_MIPS32R6, HARDFLOAT;
 198   def CMP_UEQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_UEQ>,
 199                       CMP_CONDN_DESC_BASE<"ueq", Typestr, FGROpnd, setueq>,
 200                       ISA_MIPS32R6, HARDFLOAT;
 201   def CMP_LT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_LT>,
 202                      CMP_CONDN_DESC_BASE<"lt", Typestr, FGROpnd, setolt>,
 203                      ISA_MIPS32R6, HARDFLOAT;
 204   def CMP_ULT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_ULT>,
 205                       CMP_CONDN_DESC_BASE<"ult", Typestr, FGROpnd, setult>,
 206                       ISA_MIPS32R6, HARDFLOAT;
 207   def CMP_LE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_LE>,
 208                      CMP_CONDN_DESC_BASE<"le", Typestr, FGROpnd, setole>,
 209                      ISA_MIPS32R6, HARDFLOAT;
 210   def CMP_ULE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_ULE>,
 211                       CMP_CONDN_DESC_BASE<"ule", Typestr, FGROpnd, setule>,
 212                       ISA_MIPS32R6, HARDFLOAT;
 213   def CMP_SAF_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SAF>,
 214                       CMP_CONDN_DESC_BASE<"saf", Typestr, FGROpnd>,
 215                       ISA_MIPS32R6, HARDFLOAT;
 216   def CMP_SUN_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SUN>,
 217                       CMP_CONDN_DESC_BASE<"sun", Typestr, FGROpnd>,
 218                       ISA_MIPS32R6, HARDFLOAT;
 219   def CMP_SEQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SEQ>,
 220                       CMP_CONDN_DESC_BASE<"seq", Typestr, FGROpnd>,
 221                       ISA_MIPS32R6, HARDFLOAT;
 222   def CMP_SUEQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SUEQ>,
 223                        CMP_CONDN_DESC_BASE<"sueq", Typestr, FGROpnd>,
 224                        ISA_MIPS32R6, HARDFLOAT;
 225   def CMP_SLT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SLT>,
 226                       CMP_CONDN_DESC_BASE<"slt", Typestr, FGROpnd>,
 227                       ISA_MIPS32R6, HARDFLOAT;
 228   def CMP_SULT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SULT>,
 229                        CMP_CONDN_DESC_BASE<"sult", Typestr, FGROpnd>,
 230                        ISA_MIPS32R6, HARDFLOAT;
 231   def CMP_SLE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SLE>,
 232                       CMP_CONDN_DESC_BASE<"sle", Typestr, FGROpnd>,
 233                       ISA_MIPS32R6, HARDFLOAT;
 234   def CMP_SULE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SULE>,
 235                        CMP_CONDN_DESC_BASE<"sule", Typestr, FGROpnd>,
 236                        ISA_MIPS32R6, HARDFLOAT;
 237 }
 238
 239 //===----------------------------------------------------------------------===//
 240 //
 241 // Instruction Descriptions
 242 //
 243 //===----------------------------------------------------------------------===//
 244
 245 class PCREL_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 246                       Operand ImmOpnd> : MipsR6Arch<instr_asm> {
 247   dag OutOperandList = (outs GPROpnd:$rs);
 248   dag InOperandList = (ins ImmOpnd:$imm);
 249   string AsmString = !strconcat(instr_asm, "\t$rs, $imm");
 250   list<dag> Pattern = [];
 251 }
 252
 253 class ADDIUPC_DESC : PCREL_DESC_BASE<"addiupc", GPR32Opnd, simm19_lsl2>;
 254 class LWPC_DESC: PCREL_DESC_BASE<"lwpc", GPR32Opnd, simm19_lsl2>;
 255 class LWUPC_DESC: PCREL_DESC_BASE<"lwupc", GPR32Opnd, simm19_lsl2>;
 256
 257 class ALIGN_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 258                       Operand ImmOpnd> {
 259   dag OutOperandList = (outs GPROpnd:$rd);
 260   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, ImmOpnd:$bp);
 261   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt, $bp");
 262   list<dag> Pattern = [];
 263 }
 264
 265 class ALIGN_DESC : ALIGN_DESC_BASE<"align", GPR32Opnd, uimm2>;
 266
 267 class ALUIPC_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 268   dag OutOperandList = (outs GPROpnd:$rs);
 269   dag InOperandList = (ins simm16:$imm);
 270   string AsmString = !strconcat(instr_asm, "\t$rs, $imm");
 271   list<dag> Pattern = [];
 272 }
 273
 274 class ALUIPC_DESC : ALUIPC_DESC_BASE<"aluipc", GPR32Opnd>;
 275 class AUIPC_DESC : ALUIPC_DESC_BASE<"auipc", GPR32Opnd>;
 276
 277 class AUI_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 278   dag OutOperandList = (outs GPROpnd:$rs);
 279   dag InOperandList = (ins GPROpnd:$rt, simm16:$imm);
 280   string AsmString = !strconcat(instr_asm, "\t$rs, $rt, $imm");
 281   list<dag> Pattern = [];
 282 }
 283
 284 class AUI_DESC : AUI_DESC_BASE<"aui", GPR32Opnd>;
 285
 286 class BRANCH_DESC_BASE {
 287   bit isBranch = 1;
 288   bit isTerminator = 1;
 289   bit hasDelaySlot = 0;
 290 }
 291
 292 class BC_DESC_BASE<string instr_asm, DAGOperand opnd> : BRANCH_DESC_BASE,
 293     MipsR6Arch<instr_asm> {
 294   dag InOperandList = (ins opnd:$offset);
 295   dag OutOperandList = (outs);
 296   string AsmString = !strconcat(instr_asm, "\t$offset");
 297   bit isBarrier = 1;
 298 }
 299
 300 class CMP_BC_DESC_BASE<string instr_asm, DAGOperand opnd,
 301                        RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 302   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, opnd:$offset);
 303   dag OutOperandList = (outs);
 304   string AsmString = !strconcat(instr_asm, "\t$rs, $rt, $offset");
 305   list<Register> Defs = [AT];
 306 }
 307
 308 class CMP_CBR_EQNE_Z_DESC_BASE<string instr_asm, DAGOperand opnd,
 309                                RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 310   dag InOperandList = (ins GPROpnd:$rs, opnd:$offset);
 311   dag OutOperandList = (outs);
 312   string AsmString = !strconcat(instr_asm, "\t$rs, $offset");
 313   list<Register> Defs = [AT];
 314 }
 315
 316 class CMP_CBR_RT_Z_DESC_BASE<string instr_asm, DAGOperand opnd,
 317                              RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 318   dag InOperandList = (ins GPROpnd:$rt, opnd:$offset);
 319   dag OutOperandList = (outs);
 320   string AsmString = !strconcat(instr_asm, "\t$rt, $offset");
 321   list<Register> Defs = [AT];
 322 }
 323
 324 class BAL_DESC : BC_DESC_BASE<"bal", brtarget> {
 325   bit isCall = 1;
 326   bit hasDelaySlot = 1;
 327   list<Register> Defs = [RA];
 328 }
 329
 330 class BALC_DESC : BC_DESC_BASE<"balc", brtarget26> {
 331   bit isCall = 1;
 332   list<Register> Defs = [RA];
 333 }
 334
 335 class BC_DESC : BC_DESC_BASE<"bc", brtarget26>;
 336 class BGEC_DESC : CMP_BC_DESC_BASE<"bgec", brtarget, GPR32Opnd>;
 337 class BGEUC_DESC : CMP_BC_DESC_BASE<"bgeuc", brtarget, GPR32Opnd>;
 338 class BEQC_DESC : CMP_BC_DESC_BASE<"beqc", brtarget, GPR32Opnd>;
 339 class BNEC_DESC : CMP_BC_DESC_BASE<"bnec", brtarget, GPR32Opnd>;
 340
 341 class BLTC_DESC : CMP_BC_DESC_BASE<"bltc", brtarget, GPR32Opnd>;
 342 class BLTUC_DESC : CMP_BC_DESC_BASE<"bltuc", brtarget, GPR32Opnd>;
 343
 344 class BLTZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bltzc", brtarget, GPR32Opnd>;
 345 class BGEZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgezc", brtarget, GPR32Opnd>;
 346
 347 class BLEZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"blezc", brtarget, GPR32Opnd>;
 348 class BGTZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgtzc", brtarget, GPR32Opnd>;
 349
 350 class BEQZC_DESC : CMP_CBR_EQNE_Z_DESC_BASE<"beqzc", brtarget21, GPR32Opnd>;
 351 class BNEZC_DESC : CMP_CBR_EQNE_Z_DESC_BASE<"bnezc", brtarget21, GPR32Opnd>;
 352
 353 class COP1_BCCZ_DESC_BASE<string instr_asm> : BRANCH_DESC_BASE {
 354   dag InOperandList = (ins FGR64Opnd:$ft, brtarget:$offset);
 355   dag OutOperandList = (outs);
 356   string AsmString = instr_asm;
 357   bit hasDelaySlot = 1;
 358 }
 359
 360 class BC1EQZ_DESC : COP1_BCCZ_DESC_BASE<"bc1eqz $ft, $offset">;
 361 class BC1NEZ_DESC : COP1_BCCZ_DESC_BASE<"bc1nez $ft, $offset">;
 362
 363 class COP2_BCCZ_DESC_BASE<string instr_asm> : BRANCH_DESC_BASE {
 364   dag InOperandList = (ins COP2Opnd:$ct, brtarget:$offset);
 365   dag OutOperandList = (outs);
 366   string AsmString = instr_asm;
 367   bit hasDelaySlot = 1;
 368 }
 369
 370 class BC2EQZ_DESC : COP2_BCCZ_DESC_BASE<"bc2eqz $ct, $offset">;
 371 class BC2NEZ_DESC : COP2_BCCZ_DESC_BASE<"bc2nez $ct, $offset">;
 372
 373 class BOVC_DESC   : CMP_BC_DESC_BASE<"bovc", brtarget, GPR32Opnd>;
 374 class BNVC_DESC   : CMP_BC_DESC_BASE<"bnvc", brtarget, GPR32Opnd>;
 375
 376 class JMP_IDX_COMPACT_DESC_BASE<string opstr, DAGOperand opnd,
 377                                 RegisterOperand GPROpnd>
 378     : MipsR6Arch<opstr> {
 379   dag InOperandList = (ins GPROpnd:$rt, opnd:$offset);
 380   string AsmString = !strconcat(opstr, "\t$rt, $offset");
 381   list<dag> Pattern = [];
 382   bit isTerminator = 1;
 383   bit hasDelaySlot = 0;
 384 }
 385
 386 class JIALC_DESC : JMP_IDX_COMPACT_DESC_BASE<"jialc", calloffset16,
 387                                              GPR32Opnd> {
 388   bit isCall = 1;
 389   list<Register> Defs = [RA];
 390 }
 391
 392 class JIC_DESC : JMP_IDX_COMPACT_DESC_BASE<"jic", jmpoffset16, GPR32Opnd> {
 393   bit isBarrier = 1;
 394   list<Register> Defs = [AT];
 395 }
 396
 397 class JR_HB_R6_DESC : JR_HB_DESC_BASE<"jr.hb", GPR32Opnd> {
 398   bit isBranch = 1;
 399   bit isIndirectBranch = 1;
 400   bit hasDelaySlot = 1;
 401   bit isTerminator=1;
 402   bit isBarrier=1;
 403 }
 404
 405 class BITSWAP_DESC_BASE<string instr_asm, RegisterOperand GPROpnd>
 406     : MipsR6Arch<instr_asm> {
 407   dag OutOperandList = (outs GPROpnd:$rd);
 408   dag InOperandList = (ins GPROpnd:$rt);
 409   string AsmString = !strconcat(instr_asm, "\t$rd, $rt");
 410   list<dag> Pattern = [];
 411 }
 412
 413 class BITSWAP_DESC : BITSWAP_DESC_BASE<"bitswap", GPR32Opnd>;
 414
 415 class DIVMOD_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 416                        SDPatternOperator Op=null_frag> {
 417   dag OutOperandList = (outs GPROpnd:$rd);
 418   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 419   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 420   list<dag> Pattern = [(set GPROpnd:$rd, (Op GPROpnd:$rs, GPROpnd:$rt))];
 421
 422   // This instruction doesn't trap division by zero itself. We must insert
 423   // teq instructions as well.
 424   bit usesCustomInserter = 1;
 425 }
 426
 427 class DIV_DESC  : DIVMOD_DESC_BASE<"div", GPR32Opnd, sdiv>;
 428 class DIVU_DESC : DIVMOD_DESC_BASE<"divu", GPR32Opnd, udiv>;
 429 class MOD_DESC  : DIVMOD_DESC_BASE<"mod", GPR32Opnd, srem>;
 430 class MODU_DESC : DIVMOD_DESC_BASE<"modu", GPR32Opnd, urem>;
 431
 432 class BEQZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"beqzalc", brtarget, GPR32Opnd> {
 433   list<Register> Defs = [RA];
 434 }
 435
 436 class BGEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgezalc", brtarget, GPR32Opnd> {
 437   list<Register> Defs = [RA];
 438 }
 439
 440 class BGTZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgtzalc", brtarget, GPR32Opnd> {
 441   list<Register> Defs = [RA];
 442 }
 443
 444 class BLEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"blezalc", brtarget, GPR32Opnd> {
 445   list<Register> Defs = [RA];
 446 }
 447
 448 class BLTZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bltzalc", brtarget, GPR32Opnd> {
 449   list<Register> Defs = [RA];
 450 }
 451
 452 class BNEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bnezalc", brtarget, GPR32Opnd> {
 453   list<Register> Defs = [RA];
 454 }
 455
 456 class MUL_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 457                        SDPatternOperator Op=null_frag> : MipsR6Arch<instr_asm> {
 458   dag OutOperandList = (outs GPROpnd:$rd);
 459   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 460   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 461   list<dag> Pattern = [(set GPROpnd:$rd, (Op GPROpnd:$rs, GPROpnd:$rt))];
 462 }
 463
 464 class MUH_DESC    : MUL_R6_DESC_BASE<"muh", GPR32Opnd, mulhs>;
 465 class MUHU_DESC   : MUL_R6_DESC_BASE<"muhu", GPR32Opnd, mulhu>;
 466 class MUL_R6_DESC : MUL_R6_DESC_BASE<"mul", GPR32Opnd, mul>;
 467 class MULU_DESC   : MUL_R6_DESC_BASE<"mulu", GPR32Opnd>;
 468
 469 class COP1_SEL_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 470   dag OutOperandList = (outs FGROpnd:$fd);
 471   dag InOperandList = (ins FGRCCOpnd:$fd_in, FGROpnd:$fs, FGROpnd:$ft);
 472   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 473   list<dag> Pattern = [(set FGROpnd:$fd, (select FGRCCOpnd:$fd_in,
 474                                                  FGROpnd:$ft,
 475                                                  FGROpnd:$fs))];
 476   string Constraints = "$fd_in = $fd";
 477 }
 478
 479 class SEL_D_DESC : COP1_SEL_DESC_BASE<"sel.d", FGR64Opnd> {
 480   // We must insert a SUBREG_TO_REG around $fd_in
 481   bit usesCustomInserter = 1;
 482 }
 483 class SEL_S_DESC : COP1_SEL_DESC_BASE<"sel.s", FGR32Opnd>;
 484
 485 class SELEQNE_Z_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 486   dag OutOperandList = (outs GPROpnd:$rd);
 487   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 488   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 489   list<dag> Pattern = [];
 490 }
 491
 492 class SELEQZ_DESC : SELEQNE_Z_DESC_BASE<"seleqz", GPR32Opnd>;
 493 class SELNEZ_DESC : SELEQNE_Z_DESC_BASE<"selnez", GPR32Opnd>;
 494
 495 class COP1_4R_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 496   dag OutOperandList = (outs FGROpnd:$fd);
 497   dag InOperandList = (ins FGROpnd:$fd_in, FGROpnd:$fs, FGROpnd:$ft);
 498   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 499   list<dag> Pattern = [];
 500   string Constraints = "$fd_in = $fd";
 501 }
 502
 503 class MADDF_S_DESC  : COP1_4R_DESC_BASE<"maddf.s", FGR32Opnd>;
 504 class MADDF_D_DESC  : COP1_4R_DESC_BASE<"maddf.d", FGR64Opnd>;
 505 class MSUBF_S_DESC  : COP1_4R_DESC_BASE<"msubf.s", FGR32Opnd>;
 506 class MSUBF_D_DESC  : COP1_4R_DESC_BASE<"msubf.d", FGR64Opnd>;
 507
 508 class MAX_MIN_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 509   dag OutOperandList = (outs FGROpnd:$fd);
 510   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 511   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 512   list<dag> Pattern = [];
 513 }
 514
 515 class MAX_S_DESC : MAX_MIN_DESC_BASE<"max.s", FGR32Opnd>;
 516 class MAX_D_DESC : MAX_MIN_DESC_BASE<"max.d", FGR64Opnd>;
 517 class MIN_S_DESC : MAX_MIN_DESC_BASE<"min.s", FGR32Opnd>;
 518 class MIN_D_DESC : MAX_MIN_DESC_BASE<"min.d", FGR64Opnd>;
 519
 520 class MAXA_S_DESC : MAX_MIN_DESC_BASE<"maxa.s", FGR32Opnd>;
 521 class MAXA_D_DESC : MAX_MIN_DESC_BASE<"maxa.d", FGR64Opnd>;
 522 class MINA_S_DESC : MAX_MIN_DESC_BASE<"mina.s", FGR32Opnd>;
 523 class MINA_D_DESC : MAX_MIN_DESC_BASE<"mina.d", FGR64Opnd>;
 524
 525 class SELEQNEZ_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 526   dag OutOperandList = (outs FGROpnd:$fd);
 527   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 528   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 529   list<dag> Pattern = [];
 530 }
 531
 532 class SELEQZ_S_DESC : SELEQNEZ_DESC_BASE<"seleqz.s", FGR32Opnd>;
 533 class SELEQZ_D_DESC : SELEQNEZ_DESC_BASE<"seleqz.d", FGR64Opnd>;
 534 class SELNEZ_S_DESC : SELEQNEZ_DESC_BASE<"selnez.s", FGR32Opnd>;
 535 class SELNEZ_D_DESC : SELEQNEZ_DESC_BASE<"selnez.d", FGR64Opnd>;
 536
 537 class CLASS_RINT_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 538   dag OutOperandList = (outs FGROpnd:$fd);
 539   dag InOperandList = (ins FGROpnd:$fs);
 540   string AsmString = !strconcat(instr_asm, "\t$fd, $fs");
 541   list<dag> Pattern = [];
 542 }
 543
 544 class RINT_S_DESC : CLASS_RINT_DESC_BASE<"rint.s", FGR32Opnd>;
 545 class RINT_D_DESC : CLASS_RINT_DESC_BASE<"rint.d", FGR64Opnd>;
 546 class CLASS_S_DESC : CLASS_RINT_DESC_BASE<"class.s", FGR32Opnd>;
 547 class CLASS_D_DESC : CLASS_RINT_DESC_BASE<"class.d", FGR64Opnd>;
 548
 549 class CACHE_HINT_DESC<string instr_asm, Operand MemOpnd,
 550                       RegisterOperand GPROpnd> : MipsR6Arch<instr_asm> {
 551   dag OutOperandList = (outs);
 552   dag InOperandList = (ins MemOpnd:$addr, uimm5:$hint);
 553   string AsmString = !strconcat(instr_asm, "\t$hint, $addr");
 554   list<dag> Pattern = [];
 555   string DecoderMethod = "DecodeCacheOpR6";
 556 }
 557
 558 class CACHE_DESC : CACHE_HINT_DESC<"cache", mem_simm9, GPR32Opnd>;
 559 class PREF_DESC : CACHE_HINT_DESC<"pref", mem_simm9, GPR32Opnd>;
 560
 561 class COP2LD_DESC_BASE<string instr_asm, RegisterOperand COPOpnd> {
 562   dag OutOperandList = (outs COPOpnd:$rt);
 563   dag InOperandList = (ins mem_simm11:$addr);
 564   string AsmString = !strconcat(instr_asm, "\t$rt, $addr");
 565   list<dag> Pattern = [];
 566   bit mayLoad = 1;
 567   string DecoderMethod = "DecodeFMemCop2R6";
 568 }
 569
 570 class LDC2_R6_DESC : COP2LD_DESC_BASE<"ldc2", COP2Opnd>;
 571 class LWC2_R6_DESC : COP2LD_DESC_BASE<"lwc2", COP2Opnd>;
 572
 573 class COP2ST_DESC_BASE<string instr_asm, RegisterOperand COPOpnd> {
 574   dag OutOperandList = (outs);
 575   dag InOperandList = (ins COPOpnd:$rt, mem_simm11:$addr);
 576   string AsmString = !strconcat(instr_asm, "\t$rt, $addr");
 577   list<dag> Pattern = [];
 578   bit mayStore = 1;
 579   string DecoderMethod = "DecodeFMemCop2R6";
 580 }
 581
 582 class SDC2_R6_DESC : COP2ST_DESC_BASE<"sdc2", COP2Opnd>;
 583 class SWC2_R6_DESC : COP2ST_DESC_BASE<"swc2", COP2Opnd>;
 584
 585 class LSA_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 586                        Operand ImmOpnd> {
 587   dag OutOperandList = (outs GPROpnd:$rd);
 588   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, ImmOpnd:$imm2);
 589   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt, $imm2");
 590   list<dag> Pattern = [];
 591 }
 592
 593 class LSA_R6_DESC : LSA_R6_DESC_BASE<"lsa", GPR32Opnd, uimm2>;
 594
 595 class LL_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 596   dag OutOperandList = (outs GPROpnd:$rt);
 597   dag InOperandList = (ins mem_simm9:$addr);
 598   string AsmString = !strconcat(instr_asm, "\t$rt, $addr");
 599   list<dag> Pattern = [];
 600   bit mayLoad = 1;
 601 }
 602
 603 class LL_R6_DESC : LL_R6_DESC_BASE<"ll", GPR32Opnd>;
 604
 605 class SC_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 606   dag OutOperandList = (outs GPROpnd:$dst);
 607   dag InOperandList = (ins GPROpnd:$rt, mem_simm9:$addr);
 608   string AsmString = !strconcat(instr_asm, "\t$rt, $addr");
 609   list<dag> Pattern = [];
 610   bit mayStore = 1;
 611   string Constraints = "$rt = $dst";
 612 }
 613
 614 class SC_R6_DESC : SC_R6_DESC_BASE<"sc", GPR32Opnd>;
 615
 616 class CLO_CLZ_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 617   dag OutOperandList = (outs GPROpnd:$rd);
 618   dag InOperandList = (ins GPROpnd:$rs);
 619   string AsmString = !strconcat(instr_asm, "\t$rd, $rs");
 620 }
 621
 622 class CLO_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> :
 623     CLO_CLZ_R6_DESC_BASE<instr_asm, GPROpnd> {
 624   list<dag> Pattern = [(set GPROpnd:$rd, (ctlz (not GPROpnd:$rs)))];
 625 }
 626
 627 class CLZ_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> :
 628     CLO_CLZ_R6_DESC_BASE<instr_asm, GPROpnd> {
 629   list<dag> Pattern = [(set GPROpnd:$rd, (ctlz GPROpnd:$rs))];
 630 }
 631
 632 class CLO_R6_DESC : CLO_R6_DESC_BASE<"clo", GPR32Opnd>;
 633 class CLZ_R6_DESC : CLZ_R6_DESC_BASE<"clz", GPR32Opnd>;
 634
 635 class SDBBP_R6_DESC {
 636   dag OutOperandList = (outs);
 637   dag InOperandList = (ins uimm20:$code_);
 638   string AsmString = "sdbbp\t$code_";
 639   list<dag> Pattern = [];
 640 }
 641
 642 //===----------------------------------------------------------------------===//
 643 //
 644 // Instruction Definitions
 645 //
 646 //===----------------------------------------------------------------------===//
 647
 648 def ADDIUPC : R6MMR6Rel, ADDIUPC_ENC, ADDIUPC_DESC, ISA_MIPS32R6;
 649 def ALIGN : ALIGN_ENC, ALIGN_DESC, ISA_MIPS32R6;
 650 def ALUIPC : ALUIPC_ENC, ALUIPC_DESC, ISA_MIPS32R6;
 651 def AUI : AUI_ENC, AUI_DESC, ISA_MIPS32R6;
 652 def AUIPC : AUIPC_ENC, AUIPC_DESC, ISA_MIPS32R6;
 653 def BAL : BAL_ENC, BAL_DESC, ISA_MIPS32R6;
 654 def BALC : R6MMR6Rel, BALC_ENC, BALC_DESC, ISA_MIPS32R6;
 655 def BC1EQZ : BC1EQZ_ENC, BC1EQZ_DESC, ISA_MIPS32R6, HARDFLOAT;
 656 def BC1NEZ : BC1NEZ_ENC, BC1NEZ_DESC, ISA_MIPS32R6, HARDFLOAT;
 657 def BC2EQZ : BC2EQZ_ENC, BC2EQZ_DESC, ISA_MIPS32R6;
 658 def BC2NEZ : BC2NEZ_ENC, BC2NEZ_DESC, ISA_MIPS32R6;
 659 def BC : R6MMR6Rel, BC_ENC, BC_DESC, ISA_MIPS32R6;
 660 def BEQC : BEQC_ENC, BEQC_DESC, ISA_MIPS32R6;
 661 def BEQZALC : BEQZALC_ENC, BEQZALC_DESC, ISA_MIPS32R6;
 662 def BEQZC : BEQZC_ENC, BEQZC_DESC, ISA_MIPS32R6;
 663 def BGEC : BGEC_ENC, BGEC_DESC, ISA_MIPS32R6;
 664 def BGEUC : BGEUC_ENC, BGEUC_DESC, ISA_MIPS32R6;
 665 def BGEZALC : BGEZALC_ENC, BGEZALC_DESC, ISA_MIPS32R6;
 666 def BGEZC : BGEZC_ENC, BGEZC_DESC, ISA_MIPS32R6;
 667 def BGTZALC : BGTZALC_ENC, BGTZALC_DESC, ISA_MIPS32R6;
 668 def BGTZC : BGTZC_ENC, BGTZC_DESC, ISA_MIPS32R6;
 669 def BITSWAP : R6MMR6Rel, BITSWAP_ENC, BITSWAP_DESC, ISA_MIPS32R6;
 670 def BLEZALC : BLEZALC_ENC, BLEZALC_DESC, ISA_MIPS32R6;
 671 def BLEZC : BLEZC_ENC, BLEZC_DESC, ISA_MIPS32R6;
 672 def BLTC : BLTC_ENC, BLTC_DESC, ISA_MIPS32R6;
 673 def BLTUC : BLTUC_ENC, BLTUC_DESC, ISA_MIPS32R6;
 674 def BLTZALC : BLTZALC_ENC, BLTZALC_DESC, ISA_MIPS32R6;
 675 def BLTZC : BLTZC_ENC, BLTZC_DESC, ISA_MIPS32R6;
 676 def BNEC : BNEC_ENC, BNEC_DESC, ISA_MIPS32R6;
 677 def BNEZALC : BNEZALC_ENC, BNEZALC_DESC, ISA_MIPS32R6;
 678 def BNEZC : BNEZC_ENC, BNEZC_DESC, ISA_MIPS32R6;
 679 def BNVC : BNVC_ENC, BNVC_DESC, ISA_MIPS32R6;
 680 def BOVC : BOVC_ENC, BOVC_DESC, ISA_MIPS32R6;
 681 def CACHE_R6 : R6MMR6Rel, CACHE_ENC, CACHE_DESC, ISA_MIPS32R6;
 682 def CLASS_D : CLASS_D_ENC, CLASS_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 683 def CLASS_S : CLASS_S_ENC, CLASS_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 684 def CLO_R6 : CLO_R6_ENC, CLO_R6_DESC, ISA_MIPS32R6;
 685 def CLZ_R6 : CLZ_R6_ENC, CLZ_R6_DESC, ISA_MIPS32R6;
 686 defm S : CMP_CC_M<FIELD_CMP_FORMAT_S, "s", FGR32Opnd>;
 687 defm D : CMP_CC_M<FIELD_CMP_FORMAT_D, "d", FGR64Opnd>;
 688 def DIV : DIV_ENC, DIV_DESC, ISA_MIPS32R6;
 689 def DIVU : DIVU_ENC, DIVU_DESC, ISA_MIPS32R6;
 690 def JIALC : R6MMR6Rel, JIALC_ENC, JIALC_DESC, ISA_MIPS32R6;
 691 def JIC : R6MMR6Rel, JIC_ENC, JIC_DESC, ISA_MIPS32R6;
 692 def JR_HB_R6 : JR_HB_R6_ENC, JR_HB_R6_DESC, ISA_MIPS32R6;
 693 def LDC2_R6 : LDC2_R6_ENC, LDC2_R6_DESC, ISA_MIPS32R6;
 694 def LL_R6 : LL_R6_ENC, LL_R6_DESC, ISA_MIPS32R6;
 695 def LSA_R6 : LSA_R6_ENC, LSA_R6_DESC, ISA_MIPS32R6;
 696 def LWC2_R6 : LWC2_R6_ENC, LWC2_R6_DESC, ISA_MIPS32R6;
 697 def LWPC : R6MMR6Rel, LWPC_ENC, LWPC_DESC, ISA_MIPS32R6;
 698 def LWUPC : LWUPC_ENC, LWUPC_DESC, ISA_MIPS32R6;
 699 def MADDF_S : MADDF_S_ENC, MADDF_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 700 def MADDF_D : MADDF_D_ENC, MADDF_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 701 def MAXA_D  : MAXA_D_ENC, MAXA_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 702 def MAXA_S  : MAXA_S_ENC, MAXA_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 703 def MAX_D   : MAX_D_ENC, MAX_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 704 def MAX_S   : MAX_S_ENC, MAX_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 705 def MINA_D  : MINA_D_ENC, MINA_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 706 def MINA_S  : MINA_S_ENC, MINA_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 707 def MIN_D   : MIN_D_ENC, MIN_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 708 def MIN_S   : MIN_S_ENC, MIN_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 709 def MOD : MOD_ENC, MOD_DESC, ISA_MIPS32R6;
 710 def MODU : MODU_ENC, MODU_DESC, ISA_MIPS32R6;
 711 def MSUBF_S : MSUBF_S_ENC, MSUBF_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 712 def MSUBF_D : MSUBF_D_ENC, MSUBF_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 713 def MUH    : R6MMR6Rel, MUH_ENC, MUH_DESC, ISA_MIPS32R6;
 714 def MUHU   : R6MMR6Rel, MUHU_ENC, MUHU_DESC, ISA_MIPS32R6;
 715 def MUL_R6 : R6MMR6Rel, MUL_R6_ENC, MUL_R6_DESC, ISA_MIPS32R6;
 716 def MULU   : R6MMR6Rel, MULU_ENC, MULU_DESC, ISA_MIPS32R6;
 717 def NAL; // BAL with rd=0
 718 def PREF_R6 : R6MMR6Rel, PREF_ENC, PREF_DESC, ISA_MIPS32R6;
 719 def RINT_D : RINT_D_ENC, RINT_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 720 def RINT_S : RINT_S_ENC, RINT_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 721 def SC_R6 : SC_R6_ENC, SC_R6_DESC, ISA_MIPS32R6;
 722 def SDBBP_R6 : SDBBP_R6_ENC, SDBBP_R6_DESC, ISA_MIPS32R6;
 723 def SDC2_R6 : SDC2_R6_ENC, SDC2_R6_DESC, ISA_MIPS32R6;
 724 def SELEQZ : SELEQZ_ENC, SELEQZ_DESC, ISA_MIPS32R6, GPR_32;
 725 def SELEQZ_D : SELEQZ_D_ENC, SELEQZ_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 726 def SELEQZ_S : SELEQZ_S_ENC, SELEQZ_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 727 def SELNEZ : SELNEZ_ENC, SELNEZ_DESC, ISA_MIPS32R6, GPR_32;
 728 def SELNEZ_D : SELNEZ_D_ENC, SELNEZ_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 729 def SELNEZ_S : SELNEZ_S_ENC, SELNEZ_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 730 def SEL_D    : SEL_D_ENC, SEL_D_DESC, ISA_MIPS32R6, HARDFLOAT;
 731 def SEL_S    : SEL_S_ENC, SEL_S_DESC, ISA_MIPS32R6, HARDFLOAT;
 732 def SWC2_R6 : SWC2_R6_ENC, SWC2_R6_DESC, ISA_MIPS32R6;
 733
 734 //===----------------------------------------------------------------------===//
 735 //
 736 // Instruction Aliases
 737 //
 738 //===----------------------------------------------------------------------===//
 739
 740 def : MipsInstAlias<"sdbbp", (SDBBP_R6 0)>, ISA_MIPS32R6;
 741 def : MipsInstAlias<"jr $rs", (JALR ZERO, GPR32Opnd:$rs), 1>, ISA_MIPS32R6;
 742
 743 //===----------------------------------------------------------------------===//
 744 //
 745 // Patterns and Pseudo Instructions
 746 //
 747 //===----------------------------------------------------------------------===//
 748
 749 // f32 comparisons supported via another comparison
 750 def : MipsPat<(setone f32:$lhs, f32:$rhs),
 751               (NOR (CMP_UEQ_S f32:$lhs, f32:$rhs), ZERO)>, ISA_MIPS32R6;
 752 def : MipsPat<(seto f32:$lhs, f32:$rhs),
 753               (NOR (CMP_UN_S f32:$lhs, f32:$rhs), ZERO)>, ISA_MIPS32R6;
 754 def : MipsPat<(setune f32:$lhs, f32:$rhs),
 755               (NOR (CMP_EQ_S f32:$lhs, f32:$rhs), ZERO)>, ISA_MIPS32R6;
 756 def : MipsPat<(seteq f32:$lhs, f32:$rhs), (CMP_EQ_S f32:$lhs, f32:$rhs)>,
 757       ISA_MIPS32R6;
 758 def : MipsPat<(setgt f32:$lhs, f32:$rhs), (CMP_LE_S f32:$rhs, f32:$lhs)>,
 759       ISA_MIPS32R6;
 760 def : MipsPat<(setge f32:$lhs, f32:$rhs), (CMP_LT_S f32:$rhs, f32:$lhs)>,
 761       ISA_MIPS32R6;
 762 def : MipsPat<(setlt f32:$lhs, f32:$rhs), (CMP_LT_S f32:$lhs, f32:$rhs)>,
 763       ISA_MIPS32R6;
 764 def : MipsPat<(setle f32:$lhs, f32:$rhs), (CMP_LE_S f32:$lhs, f32:$rhs)>,
 765       ISA_MIPS32R6;
 766 def : MipsPat<(setne f32:$lhs, f32:$rhs),
 767               (NOR (CMP_EQ_S f32:$lhs, f32:$rhs), ZERO)>, ISA_MIPS32R6;
 768
 769 // f64 comparisons supported via another comparison
 770 def : MipsPat<(setone f64:$lhs, f64:$rhs),
 771               (NOR (CMP_UEQ_D f64:$lhs, f64:$rhs), ZERO)>, ISA_MIPS32R6;
 772 def : MipsPat<(seto f64:$lhs, f64:$rhs),
 773               (NOR (CMP_UN_D f64:$lhs, f64:$rhs), ZERO)>, ISA_MIPS32R6;
 774 def : MipsPat<(setune f64:$lhs, f64:$rhs),
 775               (NOR (CMP_EQ_D f64:$lhs, f64:$rhs), ZERO)>, ISA_MIPS32R6;
 776 def : MipsPat<(seteq f64:$lhs, f64:$rhs), (CMP_EQ_D f64:$lhs, f64:$rhs)>,
 777       ISA_MIPS32R6;
 778 def : MipsPat<(setgt f64:$lhs, f64:$rhs), (CMP_LE_D f64:$rhs, f64:$lhs)>,
 779       ISA_MIPS32R6;
 780 def : MipsPat<(setge f64:$lhs, f64:$rhs), (CMP_LT_D f64:$rhs, f64:$lhs)>,
 781       ISA_MIPS32R6;
 782 def : MipsPat<(setlt f64:$lhs, f64:$rhs), (CMP_LT_D f64:$lhs, f64:$rhs)>,
 783       ISA_MIPS32R6;
 784 def : MipsPat<(setle f64:$lhs, f64:$rhs), (CMP_LE_D f64:$lhs, f64:$rhs)>,
 785       ISA_MIPS32R6;
 786 def : MipsPat<(setne f64:$lhs, f64:$rhs),
 787               (NOR (CMP_EQ_D f64:$lhs, f64:$rhs), ZERO)>, ISA_MIPS32R6;
 788
 789 // i32 selects
 790 def : MipsPat<(select i32:$cond, i32:$t, i32:$f),
 791               (OR (SELNEZ i32:$t, i32:$cond), (SELEQZ i32:$f, i32:$cond))>,
 792               ISA_MIPS32R6;
 793 def : MipsPat<(select (i32 (seteq i32:$cond, immz)), i32:$t, i32:$f),
 794               (OR (SELEQZ i32:$t, i32:$cond), (SELNEZ i32:$f, i32:$cond))>,
 795               ISA_MIPS32R6;
 796 def : MipsPat<(select (i32 (setne i32:$cond, immz)), i32:$t, i32:$f),
 797               (OR (SELNEZ i32:$t, i32:$cond), (SELEQZ i32:$f, i32:$cond))>,
 798               ISA_MIPS32R6;
 799 def : MipsPat<(select (i32 (seteq i32:$cond, immZExt16:$imm)), i32:$t, i32:$f),
 800               (OR (SELEQZ i32:$t, (XORi i32:$cond, immZExt16:$imm)),
 801                   (SELNEZ i32:$f, (XORi i32:$cond, immZExt16:$imm)))>,
 802               ISA_MIPS32R6;
 803 def : MipsPat<(select (i32 (setne i32:$cond, immZExt16:$imm)), i32:$t, i32:$f),
 804               (OR (SELNEZ i32:$t, (XORi i32:$cond, immZExt16:$imm)),
 805                   (SELEQZ i32:$f, (XORi i32:$cond, immZExt16:$imm)))>,
 806               ISA_MIPS32R6;
 807 def : MipsPat<(select (i32 (setgt i32:$cond, immSExt16Plus1:$imm)), i32:$t,
 808                       i32:$f),
 809               (OR (SELEQZ i32:$t, (SLTi i32:$cond, (Plus1 imm:$imm))),
 810                   (SELNEZ i32:$f, (SLTi i32:$cond, (Plus1 imm:$imm))))>,
 811               ISA_MIPS32R6;
 812 def : MipsPat<(select (i32 (setugt i32:$cond, immSExt16Plus1:$imm)),
 813                       i32:$t, i32:$f),
 814               (OR (SELEQZ i32:$t, (SLTiu i32:$cond, (Plus1 imm:$imm))),
 815                   (SELNEZ i32:$f, (SLTiu i32:$cond, (Plus1 imm:$imm))))>,
 816               ISA_MIPS32R6;
 817
 818 def : MipsPat<(select i32:$cond, i32:$t, immz),
 819               (SELNEZ i32:$t, i32:$cond)>, ISA_MIPS32R6;
 820 def : MipsPat<(select (i32 (setne i32:$cond, immz)), i32:$t, immz),
 821               (SELNEZ i32:$t, i32:$cond)>, ISA_MIPS32R6;
 822 def : MipsPat<(select (i32 (seteq i32:$cond, immz)), i32:$t, immz),
 823               (SELEQZ i32:$t, i32:$cond)>, ISA_MIPS32R6;
 824 def : MipsPat<(select i32:$cond, immz, i32:$f),
 825               (SELEQZ i32:$f, i32:$cond)>, ISA_MIPS32R6;
 826 def : MipsPat<(select (i32 (setne i32:$cond, immz)), immz, i32:$f),
 827               (SELEQZ i32:$f, i32:$cond)>, ISA_MIPS32R6;
 828 def : MipsPat<(select (i32 (seteq i32:$cond, immz)), immz, i32:$f),
 829               (SELNEZ i32:$f, i32:$cond)>, ISA_MIPS32R6;