lib/Target/Mips/Mips32r6InstrInfo.td

   1 //=- Mips32r6InstrInfo.td - Mips32r6 Instruction Information -*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes Mips32r6 instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "Mips32r6InstrFormats.td"
  15
  16 // Notes about removals/changes from MIPS32r6:
  17 // Unclear: ssnop
  18 // Reencoded: clo, clz
  19 // Reencoded: jr -> jalr
  20 // Reencoded: jr.hb -> jalr.hb
  21 // Reencoded: ldc2
  22 // Reencoded: ll, sc
  23 // Reencoded: lwc2
  24 // Reencoded: sdbbp
  25 // Reencoded: sdc2
  26 // Reencoded: swc2
  27 // Rencoded: [ls][wd]c2
  28
  29 def brtarget21 : Operand<OtherVT> {
  30   let EncoderMethod = "getBranchTarget21OpValue";
  31   let OperandType = "OPERAND_PCREL";
  32   let DecoderMethod = "DecodeBranchTarget21";
  33   let ParserMatchClass = MipsJumpTargetAsmOperand;
  34 }
  35
  36 def brtarget26 : Operand<OtherVT> {
  37   let EncoderMethod = "getBranchTarget26OpValue";
  38   let OperandType = "OPERAND_PCREL";
  39   let DecoderMethod = "DecodeBranchTarget26";
  40   let ParserMatchClass = MipsJumpTargetAsmOperand;
  41 }
  42
  43 def jmpoffset16 : Operand<OtherVT> {
  44   let EncoderMethod = "getJumpOffset16OpValue";
  45   let ParserMatchClass = MipsJumpTargetAsmOperand;
  46 }
  47
  48 def calloffset16 : Operand<iPTR> {
  49   let EncoderMethod = "getJumpOffset16OpValue";
  50   let ParserMatchClass = MipsJumpTargetAsmOperand;
  51 }
  52
  53 //===----------------------------------------------------------------------===//
  54 //
  55 // Instruction Encodings
  56 //
  57 //===----------------------------------------------------------------------===//
  58
  59 class ADDIUPC_ENC : PCREL19_FM<OPCODE2_ADDIUPC>;
  60 class ALIGN_ENC  : SPECIAL3_ALIGN_FM<OPCODE6_ALIGN>;
  61 class ALUIPC_ENC : PCREL16_FM<OPCODE5_ALUIPC>;
  62 class AUI_ENC    : AUI_FM;
  63 class AUIPC_ENC  : PCREL16_FM<OPCODE5_AUIPC>;
  64
  65 class BAL_ENC   : BAL_FM;
  66 class BALC_ENC  : BRANCH_OFF26_FM<0b111010>;
  67 class BC_ENC    : BRANCH_OFF26_FM<0b110010>;
  68 class BEQC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_ADDI>,
  69                   DecodeDisambiguates<"AddiGroupBranch">;
  70 class BEQZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_ADDI>,
  71                     DecodeDisambiguatedBy<"DaddiGroupBranch">;
  72 class BNEC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_DADDI>,
  73                   DecodeDisambiguates<"DaddiGroupBranch">;
  74 class BNEZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_DADDI>,
  75                     DecodeDisambiguatedBy<"DaddiGroupBranch">;
  76
  77 class BLTZC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BGTZL>,
  78                   DecodeDisambiguates<"BgtzlGroupBranch">;
  79 class BGEC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_BLEZL>,
  80                   DecodeDisambiguatedBy<"BlezlGroupBranch">;
  81 class BGEUC_ENC : CMP_BRANCH_2R_OFF16_FM<OPGROUP_BLEZ>,
  82                   DecodeDisambiguatedBy<"BlezGroupBranch">;
  83 class BGEZC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BLEZL>,
  84                   DecodeDisambiguates<"BlezlGroupBranch">;
  85 class BGTZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BGTZ>,
  86                     DecodeDisambiguatedBy<"BgtzGroupBranch">;
  87
  88 class BLEZC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BLEZL>,
  89                   DecodeDisambiguatedBy<"BlezlGroupBranch">;
  90 class BLTZALC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BGTZ>,
  91                     DecodeDisambiguates<"BgtzGroupBranch">;
  92 class BGTZC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BGTZL>,
  93                   DecodeDisambiguatedBy<"BgtzlGroupBranch">;
  94
  95 class BEQZC_ENC : CMP_BRANCH_OFF21_FM<0b110110>;
  96 class BGEZALC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BLEZ>,
  97                     DecodeDisambiguates<"BlezGroupBranch">;
  98 class BNEZC_ENC : CMP_BRANCH_OFF21_FM<0b111110>;
  99
 100 class BC1EQZ_ENC : COP1_BCCZ_FM<OPCODE5_BC1EQZ>;
 101 class BC1NEZ_ENC : COP1_BCCZ_FM<OPCODE5_BC1NEZ>;
 102 class BC2EQZ_ENC : COP2_BCCZ_FM<OPCODE5_BC2EQZ>;
 103 class BC2NEZ_ENC : COP2_BCCZ_FM<OPCODE5_BC2NEZ>;
 104
 105 class JIALC_ENC : JMP_IDX_COMPACT_FM<0b111110>;
 106 class JIC_ENC   : JMP_IDX_COMPACT_FM<0b110110>;
 107 class JR_HB_R6_ENC : JR_HB_R6_FM<OPCODE6_JALR>;
 108 class BITSWAP_ENC : SPECIAL3_2R_FM<OPCODE6_BITSWAP>;
 109 class BLEZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BLEZ>,
 110                     DecodeDisambiguatedBy<"BlezGroupBranch">;
 111 class BNVC_ENC   : CMP_BRANCH_2R_OFF16_FM<OPGROUP_DADDI>,
 112                    DecodeDisambiguatedBy<"DaddiGroupBranch">;
 113 class BOVC_ENC   : CMP_BRANCH_2R_OFF16_FM<OPGROUP_ADDI>,
 114                    DecodeDisambiguatedBy<"AddiGroupBranch">;
 115 class DIV_ENC    : SPECIAL_3R_FM<0b00010, 0b011010>;
 116 class DIVU_ENC   : SPECIAL_3R_FM<0b00010, 0b011011>;
 117 class MOD_ENC    : SPECIAL_3R_FM<0b00011, 0b011010>;
 118 class MODU_ENC   : SPECIAL_3R_FM<0b00011, 0b011011>;
 119 class MUH_ENC    : SPECIAL_3R_FM<0b00011, 0b011000>;
 120 class MUHU_ENC   : SPECIAL_3R_FM<0b00011, 0b011001>;
 121 class MUL_R6_ENC : SPECIAL_3R_FM<0b00010, 0b011000>;
 122 class MULU_ENC   : SPECIAL_3R_FM<0b00010, 0b011001>;
 123
 124 class MADDF_S_ENC  : COP1_3R_FM<0b011000, FIELD_FMT_S>;
 125 class MADDF_D_ENC  : COP1_3R_FM<0b011000, FIELD_FMT_D>;
 126 class MSUBF_S_ENC  : COP1_3R_FM<0b011001, FIELD_FMT_S>;
 127 class MSUBF_D_ENC  : COP1_3R_FM<0b011001, FIELD_FMT_D>;
 128
 129 class SEL_D_ENC  : COP1_3R_FM<0b010000, FIELD_FMT_D>;
 130 class SEL_S_ENC  : COP1_3R_FM<0b010000, FIELD_FMT_S>;
 131
 132 class SELEQZ_ENC : SPECIAL_3R_FM<0b00000, 0b110101>;
 133 class SELNEZ_ENC : SPECIAL_3R_FM<0b00000, 0b110111>;
 134
 135 class LWPC_ENC   : PCREL19_FM<OPCODE2_LWPC>;
 136 class LWUPC_ENC  : PCREL19_FM<OPCODE2_LWUPC>;
 137
 138 class MAX_S_ENC : COP1_3R_FM<0b011101, FIELD_FMT_S>;
 139 class MAX_D_ENC : COP1_3R_FM<0b011101, FIELD_FMT_D>;
 140 class MIN_S_ENC : COP1_3R_FM<0b011100, FIELD_FMT_S>;
 141 class MIN_D_ENC : COP1_3R_FM<0b011100, FIELD_FMT_D>;
 142
 143 class MAXA_S_ENC : COP1_3R_FM<0b011111, FIELD_FMT_S>;
 144 class MAXA_D_ENC : COP1_3R_FM<0b011111, FIELD_FMT_D>;
 145 class MINA_S_ENC : COP1_3R_FM<0b011110, FIELD_FMT_S>;
 146 class MINA_D_ENC : COP1_3R_FM<0b011110, FIELD_FMT_D>;
 147
 148 class SELEQZ_S_ENC : COP1_3R_FM<0b010100, FIELD_FMT_S>;
 149 class SELEQZ_D_ENC : COP1_3R_FM<0b010100, FIELD_FMT_D>;
 150 class SELNEZ_S_ENC : COP1_3R_FM<0b010111, FIELD_FMT_S>;
 151 class SELNEZ_D_ENC : COP1_3R_FM<0b010111, FIELD_FMT_D>;
 152
 153 class RINT_S_ENC : COP1_2R_FM<0b011010, FIELD_FMT_S>;
 154 class RINT_D_ENC : COP1_2R_FM<0b011010, FIELD_FMT_D>;
 155 class CLASS_S_ENC : COP1_2R_FM<0b011011, FIELD_FMT_S>;
 156 class CLASS_D_ENC : COP1_2R_FM<0b011011, FIELD_FMT_D>;
 157
 158 class CACHE_ENC : SPECIAL3_MEM_FM<OPCODE6_CACHE>;
 159 class PREF_ENC : SPECIAL3_MEM_FM<OPCODE6_PREF>;
 160
 161 class CMP_CONDN_DESC_BASE<string CondStr, string Typestr,
 162                           RegisterOperand FGROpnd,
 163                           SDPatternOperator Op = null_frag> {
 164   dag OutOperandList = (outs FGRCCOpnd:$fd);
 165   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 166   string AsmString = !strconcat("cmp.", CondStr, ".", Typestr, "\t$fd, $fs, $ft");
 167   list<dag> Pattern = [(set FGRCCOpnd:$fd, (Op FGROpnd:$fs, FGROpnd:$ft))];
 168 }
 169
 170 //===----------------------------------------------------------------------===//
 171 //
 172 // Instruction Multiclasses
 173 //
 174 //===----------------------------------------------------------------------===//
 175
 176 multiclass CMP_CC_M <FIELD_CMP_FORMAT Format, string Typestr,
 177                      RegisterOperand FGROpnd>{
 178   def CMP_F_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_F>,
 179                     CMP_CONDN_DESC_BASE<"f", Typestr, FGROpnd>,
 180                     ISA_MIPS32R6;
 181   def CMP_UN_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_UN>,
 182                      CMP_CONDN_DESC_BASE<"un", Typestr, FGROpnd, setuo>,
 183                      ISA_MIPS32R6;
 184   def CMP_EQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_EQ>,
 185                      CMP_CONDN_DESC_BASE<"eq", Typestr, FGROpnd, setoeq>,
 186                      ISA_MIPS32R6;
 187   def CMP_UEQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_UEQ>,
 188                       CMP_CONDN_DESC_BASE<"ueq", Typestr, FGROpnd, setueq>,
 189                       ISA_MIPS32R6;
 190   def CMP_OLT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_OLT>,
 191                       CMP_CONDN_DESC_BASE<"olt", Typestr, FGROpnd, setolt>,
 192                       ISA_MIPS32R6;
 193   def CMP_ULT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_ULT>,
 194                       CMP_CONDN_DESC_BASE<"ult", Typestr, FGROpnd, setult>,
 195                       ISA_MIPS32R6;
 196   def CMP_OLE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_OLE>,
 197                       CMP_CONDN_DESC_BASE<"ole", Typestr, FGROpnd, setole>,
 198                       ISA_MIPS32R6;
 199   def CMP_ULE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_ULE>,
 200                       CMP_CONDN_DESC_BASE<"ule", Typestr, FGROpnd, setule>,
 201                       ISA_MIPS32R6;
 202   def CMP_SF_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SF>,
 203                      CMP_CONDN_DESC_BASE<"sf", Typestr, FGROpnd>,
 204                      ISA_MIPS32R6;
 205   def CMP_NGLE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGLE>,
 206                        CMP_CONDN_DESC_BASE<"ngle", Typestr, FGROpnd>,
 207                        ISA_MIPS32R6;
 208   def CMP_SEQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SEQ>,
 209                       CMP_CONDN_DESC_BASE<"seq", Typestr, FGROpnd>,
 210                       ISA_MIPS32R6;
 211   def CMP_NGL_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGL>,
 212                       CMP_CONDN_DESC_BASE<"ngl", Typestr, FGROpnd>,
 213                       ISA_MIPS32R6;
 214   def CMP_LT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_LT>,
 215                      CMP_CONDN_DESC_BASE<"lt", Typestr, FGROpnd>,
 216                      ISA_MIPS32R6;
 217   def CMP_NGE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGE>,
 218                       CMP_CONDN_DESC_BASE<"nge", Typestr, FGROpnd>,
 219                       ISA_MIPS32R6;
 220   def CMP_LE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_LE>,
 221                      CMP_CONDN_DESC_BASE<"le", Typestr, FGROpnd>,
 222                      ISA_MIPS32R6;
 223   def CMP_NGT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGT>,
 224                       CMP_CONDN_DESC_BASE<"ngt", Typestr, FGROpnd>,
 225                       ISA_MIPS32R6;
 226 }
 227
 228 //===----------------------------------------------------------------------===//
 229 //
 230 // Instruction Descriptions
 231 //
 232 //===----------------------------------------------------------------------===//
 233
 234 class PCREL_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 235                       Operand ImmOpnd> {
 236   dag OutOperandList = (outs GPROpnd:$rs);
 237   dag InOperandList = (ins ImmOpnd:$imm);
 238   string AsmString = !strconcat(instr_asm, "\t$rs, $imm");
 239   list<dag> Pattern = [];
 240 }
 241
 242 class ADDIUPC_DESC : PCREL_DESC_BASE<"addiupc", GPR32Opnd, simm19_lsl2>;
 243 class LWPC_DESC: PCREL_DESC_BASE<"lwpc", GPR32Opnd, simm19_lsl2>;
 244 class LWUPC_DESC: PCREL_DESC_BASE<"lwupc", GPR32Opnd, simm19_lsl2>;
 245
 246 class ALIGN_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 247                       Operand ImmOpnd> {
 248   dag OutOperandList = (outs GPROpnd:$rd);
 249   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, ImmOpnd:$bp);
 250   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt, $bp");
 251   list<dag> Pattern = [];
 252 }
 253
 254 class ALIGN_DESC : ALIGN_DESC_BASE<"align", GPR32Opnd, uimm2>;
 255
 256 class ALUIPC_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 257   dag OutOperandList = (outs GPROpnd:$rs);
 258   dag InOperandList = (ins simm16:$imm);
 259   string AsmString = !strconcat(instr_asm, "\t$rs, $imm");
 260   list<dag> Pattern = [];
 261 }
 262
 263 class ALUIPC_DESC : ALUIPC_DESC_BASE<"aluipc", GPR32Opnd>;
 264 class AUIPC_DESC : ALUIPC_DESC_BASE<"auipc", GPR32Opnd>;
 265
 266 class AUI_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 267   dag OutOperandList = (outs GPROpnd:$rs);
 268   dag InOperandList = (ins GPROpnd:$rt, simm16:$imm);
 269   string AsmString = !strconcat(instr_asm, "\t$rs, $rt, $imm");
 270   list<dag> Pattern = [];
 271 }
 272
 273 class AUI_DESC : AUI_DESC_BASE<"aui", GPR32Opnd>;
 274
 275 class BRANCH_DESC_BASE {
 276   bit isBranch = 1;
 277   bit isTerminator = 1;
 278   bit hasDelaySlot = 0;
 279 }
 280
 281 class BC_DESC_BASE<string instr_asm, DAGOperand opnd> : BRANCH_DESC_BASE {
 282   dag InOperandList = (ins opnd:$offset);
 283   dag OutOperandList = (outs);
 284   string AsmString = !strconcat(instr_asm, "\t$offset");
 285   bit isBarrier = 1;
 286 }
 287
 288 class CMP_BC_DESC_BASE<string instr_asm, DAGOperand opnd,
 289                        RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 290   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, opnd:$offset);
 291   dag OutOperandList = (outs);
 292   string AsmString = !strconcat(instr_asm, "\t$rs, $rt, $offset");
 293   list<Register> Defs = [AT];
 294 }
 295
 296 class CMP_CBR_EQNE_Z_DESC_BASE<string instr_asm, DAGOperand opnd,
 297                                RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 298   dag InOperandList = (ins GPROpnd:$rs, opnd:$offset);
 299   dag OutOperandList = (outs);
 300   string AsmString = !strconcat(instr_asm, "\t$rs, $offset");
 301   list<Register> Defs = [AT];
 302 }
 303
 304 class CMP_CBR_RT_Z_DESC_BASE<string instr_asm, DAGOperand opnd,
 305                              RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 306   dag InOperandList = (ins GPROpnd:$rt, opnd:$offset);
 307   dag OutOperandList = (outs);
 308   string AsmString = !strconcat(instr_asm, "\t$rt, $offset");
 309   list<Register> Defs = [AT];
 310 }
 311
 312 class BAL_DESC : BC_DESC_BASE<"bal", brtarget> {
 313   bit isCall = 1;
 314   bit hasDelaySlot = 1;
 315   list<Register> Defs = [RA];
 316 }
 317
 318 class BALC_DESC : BC_DESC_BASE<"balc", brtarget26> {
 319   bit isCall = 1;
 320   list<Register> Defs = [RA];
 321 }
 322
 323 class BC_DESC : BC_DESC_BASE<"bc", brtarget26>;
 324 class BGEC_DESC : CMP_BC_DESC_BASE<"bgec", brtarget, GPR32Opnd>;
 325 class BGEUC_DESC : CMP_BC_DESC_BASE<"bgeuc", brtarget, GPR32Opnd>;
 326 class BEQC_DESC : CMP_BC_DESC_BASE<"beqc", brtarget, GPR32Opnd>;
 327 class BNEC_DESC : CMP_BC_DESC_BASE<"bnec", brtarget, GPR32Opnd>;
 328
 329 class BLTZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bltzc", brtarget, GPR32Opnd>;
 330 class BGEZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgezc", brtarget, GPR32Opnd>;
 331
 332 class BLEZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"blezc", brtarget, GPR32Opnd>;
 333 class BGTZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgtzc", brtarget, GPR32Opnd>;
 334
 335 class BEQZC_DESC : CMP_CBR_EQNE_Z_DESC_BASE<"beqzc", brtarget21, GPR32Opnd>;
 336 class BNEZC_DESC : CMP_CBR_EQNE_Z_DESC_BASE<"bnezc", brtarget21, GPR32Opnd>;
 337
 338 class COP1_BCCZ_DESC_BASE<string instr_asm> : BRANCH_DESC_BASE {
 339   dag InOperandList = (ins FGR64Opnd:$ft, brtarget:$offset);
 340   dag OutOperandList = (outs);
 341   string AsmString = instr_asm;
 342   bit hasDelaySlot = 1;
 343 }
 344
 345 class BC1EQZ_DESC : COP1_BCCZ_DESC_BASE<"bc1eqz $ft, $offset">;
 346 class BC1NEZ_DESC : COP1_BCCZ_DESC_BASE<"bc1nez $ft, $offset">;
 347
 348 class COP2_BCCZ_DESC_BASE<string instr_asm> : BRANCH_DESC_BASE {
 349   dag InOperandList = (ins COP2Opnd:$ct, brtarget:$offset);
 350   dag OutOperandList = (outs);
 351   string AsmString = instr_asm;
 352   bit hasDelaySlot = 1;
 353 }
 354
 355 class BC2EQZ_DESC : COP2_BCCZ_DESC_BASE<"bc2eqz $ct, $offset">;
 356 class BC2NEZ_DESC : COP2_BCCZ_DESC_BASE<"bc2nez $ct, $offset">;
 357
 358 class BOVC_DESC   : CMP_BC_DESC_BASE<"bovc", brtarget, GPR32Opnd>;
 359 class BNVC_DESC   : CMP_BC_DESC_BASE<"bnvc", brtarget, GPR32Opnd>;
 360
 361 class JMP_IDX_COMPACT_DESC_BASE<string opstr, DAGOperand opnd,
 362                                 RegisterOperand GPROpnd> {
 363   dag InOperandList = (ins GPROpnd:$rt, opnd:$offset);
 364   string AsmString = !strconcat(opstr, "\t$rt, $offset");
 365   list<dag> Pattern = [];
 366   bit isTerminator = 1;
 367   bit hasDelaySlot = 0;
 368   string DecoderMethod = "DecodeSimm16";
 369 }
 370
 371 class JIALC_DESC : JMP_IDX_COMPACT_DESC_BASE<"jialc", calloffset16,
 372                                              GPR32Opnd> {
 373   bit isCall = 1;
 374   list<Register> Defs = [RA];
 375 }
 376
 377 class JIC_DESC : JMP_IDX_COMPACT_DESC_BASE<"jic", jmpoffset16, GPR32Opnd> {
 378   bit isBarrier = 1;
 379   list<Register> Defs = [AT];
 380 }
 381
 382 class JR_HB_R6_DESC : JR_HB_DESC_BASE<"jr.hb", GPR32Opnd> {
 383   bit isBranch = 1;
 384   bit isIndirectBranch = 1;
 385   bit hasDelaySlot = 1;
 386   bit isTerminator=1;
 387   bit isBarrier=1;
 388 }
 389
 390 class BITSWAP_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 391   dag OutOperandList = (outs GPROpnd:$rd);
 392   dag InOperandList = (ins GPROpnd:$rt);
 393   string AsmString = !strconcat(instr_asm, "\t$rd, $rt");
 394   list<dag> Pattern = [];
 395 }
 396
 397 class BITSWAP_DESC : BITSWAP_DESC_BASE<"bitswap", GPR32Opnd>;
 398
 399 class DIVMOD_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 400                        SDPatternOperator Op=null_frag> {
 401   dag OutOperandList = (outs GPROpnd:$rd);
 402   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 403   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 404   list<dag> Pattern = [(set GPROpnd:$rd, (Op GPROpnd:$rs, GPROpnd:$rt))];
 405
 406   // This instruction doesn't trap division by zero itself. We must insert
 407   // teq instructions as well.
 408   bit usesCustomInserter = 1;
 409 }
 410
 411 class DIV_DESC  : DIVMOD_DESC_BASE<"div", GPR32Opnd, sdiv>;
 412 class DIVU_DESC : DIVMOD_DESC_BASE<"divu", GPR32Opnd, udiv>;
 413 class MOD_DESC  : DIVMOD_DESC_BASE<"mod", GPR32Opnd, srem>;
 414 class MODU_DESC : DIVMOD_DESC_BASE<"modu", GPR32Opnd, urem>;
 415
 416 class BEQZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"beqzalc", brtarget, GPR32Opnd> {
 417   list<Register> Defs = [RA];
 418 }
 419
 420 class BGEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgezalc", brtarget, GPR32Opnd> {
 421   list<Register> Defs = [RA];
 422 }
 423
 424 class BGTZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgtzalc", brtarget, GPR32Opnd> {
 425   list<Register> Defs = [RA];
 426 }
 427
 428 class BLEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"blezalc", brtarget, GPR32Opnd> {
 429   list<Register> Defs = [RA];
 430 }
 431
 432 class BLTZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bltzalc", brtarget, GPR32Opnd> {
 433   list<Register> Defs = [RA];
 434 }
 435
 436 class BNEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bnezalc", brtarget, GPR32Opnd> {
 437   list<Register> Defs = [RA];
 438 }
 439
 440 class MUL_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 441                        SDPatternOperator Op=null_frag> {
 442   dag OutOperandList = (outs GPROpnd:$rd);
 443   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 444   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 445   list<dag> Pattern = [(set GPROpnd:$rd, (Op GPROpnd:$rs, GPROpnd:$rt))];
 446 }
 447
 448 class MUH_DESC    : MUL_R6_DESC_BASE<"muh", GPR32Opnd, mulhs>;
 449 class MUHU_DESC   : MUL_R6_DESC_BASE<"muhu", GPR32Opnd, mulhu>;
 450 class MUL_R6_DESC : MUL_R6_DESC_BASE<"mul", GPR32Opnd, mul>;
 451 class MULU_DESC   : MUL_R6_DESC_BASE<"mulu", GPR32Opnd>;
 452
 453 class COP1_SEL_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 454   dag OutOperandList = (outs FGROpnd:$fd);
 455   dag InOperandList = (ins FGRCCOpnd:$fd_in, FGROpnd:$fs, FGROpnd:$ft);
 456   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 457   list<dag> Pattern = [(set FGROpnd:$fd, (select FGRCCOpnd:$fd_in,
 458                                                  FGROpnd:$ft,
 459                                                  FGROpnd:$fs))];
 460   string Constraints = "$fd_in = $fd";
 461 }
 462
 463 class SEL_D_DESC : COP1_SEL_DESC_BASE<"sel.d", FGR64Opnd> {
 464   // We must insert a SUBREG_TO_REG around $fd_in
 465   bit usesCustomInserter = 1;
 466 }
 467 class SEL_S_DESC : COP1_SEL_DESC_BASE<"sel.s", FGR32Opnd>;
 468
 469 class SELEQNE_Z_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 470   dag OutOperandList = (outs GPROpnd:$rd);
 471   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 472   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 473   list<dag> Pattern = [];
 474 }
 475
 476 class SELEQZ_DESC : SELEQNE_Z_DESC_BASE<"seleqz", GPR32Opnd>;
 477 class SELNEZ_DESC : SELEQNE_Z_DESC_BASE<"selnez", GPR32Opnd>;
 478
 479 class COP1_4R_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 480   dag OutOperandList = (outs FGROpnd:$fd);
 481   dag InOperandList = (ins FGROpnd:$fd_in, FGROpnd:$fs, FGROpnd:$ft);
 482   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 483   list<dag> Pattern = [];
 484   string Constraints = "$fd_in = $fd";
 485 }
 486
 487 class MADDF_S_DESC  : COP1_4R_DESC_BASE<"maddf.s", FGR32Opnd>;
 488 class MADDF_D_DESC  : COP1_4R_DESC_BASE<"maddf.d", FGR64Opnd>;
 489 class MSUBF_S_DESC  : COP1_4R_DESC_BASE<"msubf.s", FGR32Opnd>;
 490 class MSUBF_D_DESC  : COP1_4R_DESC_BASE<"msubf.d", FGR64Opnd>;
 491
 492 class MAX_MIN_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 493   dag OutOperandList = (outs FGROpnd:$fd);
 494   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 495   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 496   list<dag> Pattern = [];
 497 }
 498
 499 class MAX_S_DESC : MAX_MIN_DESC_BASE<"max.s", FGR32Opnd>;
 500 class MAX_D_DESC : MAX_MIN_DESC_BASE<"max.d", FGR64Opnd>;
 501 class MIN_S_DESC : MAX_MIN_DESC_BASE<"min.s", FGR32Opnd>;
 502 class MIN_D_DESC : MAX_MIN_DESC_BASE<"min.d", FGR64Opnd>;
 503
 504 class MAXA_S_DESC : MAX_MIN_DESC_BASE<"maxa.s", FGR32Opnd>;
 505 class MAXA_D_DESC : MAX_MIN_DESC_BASE<"maxa.d", FGR64Opnd>;
 506 class MINA_S_DESC : MAX_MIN_DESC_BASE<"mina.s", FGR32Opnd>;
 507 class MINA_D_DESC : MAX_MIN_DESC_BASE<"mina.d", FGR64Opnd>;
 508
 509 class SELEQNEZ_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 510   dag OutOperandList = (outs FGROpnd:$fd);
 511   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 512   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 513   list<dag> Pattern = [];
 514 }
 515
 516 class SELEQZ_S_DESC : SELEQNEZ_DESC_BASE<"seleqz.s", FGR32Opnd>;
 517 class SELEQZ_D_DESC : SELEQNEZ_DESC_BASE<"seleqz.d", FGR64Opnd>;
 518 class SELNEZ_S_DESC : SELEQNEZ_DESC_BASE<"selnez.s", FGR32Opnd>;
 519 class SELNEZ_D_DESC : SELEQNEZ_DESC_BASE<"selnez.d", FGR64Opnd>;
 520
 521 class CLASS_RINT_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 522   dag OutOperandList = (outs FGROpnd:$fd);
 523   dag InOperandList = (ins FGROpnd:$fs);
 524   string AsmString = !strconcat(instr_asm, "\t$fd, $fs");
 525   list<dag> Pattern = [];
 526 }
 527
 528 class RINT_S_DESC : CLASS_RINT_DESC_BASE<"rint.s", FGR32Opnd>;
 529 class RINT_D_DESC : CLASS_RINT_DESC_BASE<"rint.d", FGR64Opnd>;
 530 class CLASS_S_DESC : CLASS_RINT_DESC_BASE<"class.s", FGR32Opnd>;
 531 class CLASS_D_DESC : CLASS_RINT_DESC_BASE<"class.d", FGR64Opnd>;
 532
 533 class CACHE_HINT_DESC<string instr_asm, Operand MemOpnd,
 534                       RegisterOperand GPROpnd> {
 535   dag OutOperandList = (outs);
 536   dag InOperandList = (ins MemOpnd:$addr, uimm5:$hint);
 537   string AsmString = !strconcat(instr_asm, "\t$hint, $addr");
 538   list<dag> Pattern = [];
 539 }
 540
 541 class CACHE_DESC : CACHE_HINT_DESC<"cache", mem_simm9, GPR32Opnd>;
 542 class PREF_DESC : CACHE_HINT_DESC<"pref", mem_simm9, GPR32Opnd>;
 543
 544 //===----------------------------------------------------------------------===//
 545 //
 546 // Instruction Definitions
 547 //
 548 //===----------------------------------------------------------------------===//
 549
 550 def ADDIUPC : ADDIUPC_ENC, ADDIUPC_DESC, ISA_MIPS32R6;
 551 def ALIGN : ALIGN_ENC, ALIGN_DESC, ISA_MIPS32R6;
 552 def ALUIPC : ALUIPC_ENC, ALUIPC_DESC, ISA_MIPS32R6;
 553 def AUI : AUI_ENC, AUI_DESC, ISA_MIPS32R6;
 554 def AUIPC : AUIPC_ENC, AUIPC_DESC, ISA_MIPS32R6;
 555 def BAL : BAL_ENC, BAL_DESC, ISA_MIPS32R6;
 556 def BALC : BALC_ENC, BALC_DESC, ISA_MIPS32R6;
 557 def BC1EQZ : BC1EQZ_ENC, BC1EQZ_DESC, ISA_MIPS32R6;
 558 def BC1NEZ : BC1NEZ_ENC, BC1NEZ_DESC, ISA_MIPS32R6;
 559 def BC2EQZ : BC2EQZ_ENC, BC2EQZ_DESC, ISA_MIPS32R6;
 560 def BC2NEZ : BC2NEZ_ENC, BC2NEZ_DESC, ISA_MIPS32R6;
 561 def BC : BC_ENC, BC_DESC, ISA_MIPS32R6;
 562 def BEQC : BEQC_ENC, BEQC_DESC, ISA_MIPS32R6;
 563 def BEQZALC : BEQZALC_ENC, BEQZALC_DESC, ISA_MIPS32R6;
 564 def BEQZC : BEQZC_ENC, BEQZC_DESC, ISA_MIPS32R6;
 565 def BGEC : BGEC_ENC, BGEC_DESC, ISA_MIPS32R6;
 566 def BGEUC : BGEUC_ENC, BGEUC_DESC, ISA_MIPS32R6;
 567 def BGEZALC : BGEZALC_ENC, BGEZALC_DESC, ISA_MIPS32R6;
 568 def BGEZC : BGEZC_ENC, BGEZC_DESC, ISA_MIPS32R6;
 569 def BGTZALC : BGTZALC_ENC, BGTZALC_DESC, ISA_MIPS32R6;
 570 def BGTZC : BGTZC_ENC, BGTZC_DESC, ISA_MIPS32R6;
 571 def BITSWAP : BITSWAP_ENC, BITSWAP_DESC, ISA_MIPS32R6;
 572 def BLEZALC : BLEZALC_ENC, BLEZALC_DESC, ISA_MIPS32R6;
 573 def BLEZC : BLEZC_ENC, BLEZC_DESC, ISA_MIPS32R6;
 574 def BLTC; // Also aliased to bgtc with operands swapped
 575 def BLTUC; // Also aliased to bgtuc with operands swapped
 576 def BLTZALC : BLTZALC_ENC, BLTZALC_DESC, ISA_MIPS32R6;
 577 def BLTZC : BLTZC_ENC, BLTZC_DESC, ISA_MIPS32R6;
 578 def BNEC : BNEC_ENC, BNEC_DESC, ISA_MIPS32R6;
 579 def BNEZALC : BNEZALC_ENC, BNEZALC_DESC, ISA_MIPS32R6;
 580 def BNEZC : BNEZC_ENC, BNEZC_DESC, ISA_MIPS32R6;
 581 def BNVC : BNVC_ENC, BNVC_DESC, ISA_MIPS32R6;
 582 def BOVC : BOVC_ENC, BOVC_DESC, ISA_MIPS32R6;
 583 def CACHE_R6 : CACHE_ENC, CACHE_DESC, ISA_MIPS32R6;
 584 def CLASS_D : CLASS_D_ENC, CLASS_D_DESC, ISA_MIPS32R6;
 585 def CLASS_S : CLASS_S_ENC, CLASS_S_DESC, ISA_MIPS32R6;
 586 defm S : CMP_CC_M<FIELD_CMP_FORMAT_S, "s", FGR32Opnd>;
 587 defm D : CMP_CC_M<FIELD_CMP_FORMAT_D, "d", FGR64Opnd>;
 588 def DIV : DIV_ENC, DIV_DESC, ISA_MIPS32R6;
 589 def DIVU : DIVU_ENC, DIVU_DESC, ISA_MIPS32R6;
 590 def JIALC : JIALC_ENC, JIALC_DESC, ISA_MIPS32R6;
 591 def JIC : JIC_ENC, JIC_DESC, ISA_MIPS32R6;
 592 def JR_HB_R6 : JR_HB_R6_ENC, JR_HB_R6_DESC, ISA_MIPS32R6;
 593 // def LSA; // See MSA
 594 def LWPC : LWPC_ENC, LWPC_DESC, ISA_MIPS32R6;
 595 def LWUPC : LWUPC_ENC, LWUPC_DESC, ISA_MIPS32R6;
 596 def MADDF_S : MADDF_S_ENC, MADDF_S_DESC, ISA_MIPS32R6;
 597 def MADDF_D : MADDF_D_ENC, MADDF_D_DESC, ISA_MIPS32R6;
 598 def MAXA_D : MAXA_D_ENC, MAXA_D_DESC, ISA_MIPS32R6;
 599 def MAXA_S : MAXA_S_ENC, MAXA_S_DESC, ISA_MIPS32R6;
 600 def MAX_D : MAX_D_ENC, MAX_D_DESC, ISA_MIPS32R6;
 601 def MAX_S : MAX_S_ENC, MAX_S_DESC, ISA_MIPS32R6;
 602 def MINA_D : MINA_D_ENC, MINA_D_DESC, ISA_MIPS32R6;
 603 def MINA_S : MINA_S_ENC, MINA_S_DESC, ISA_MIPS32R6;
 604 def MIN_D : MIN_D_ENC, MIN_D_DESC, ISA_MIPS32R6;
 605 def MIN_S : MIN_S_ENC, MIN_S_DESC, ISA_MIPS32R6;
 606 def MOD : MOD_ENC, MOD_DESC, ISA_MIPS32R6;
 607 def MODU : MODU_ENC, MODU_DESC, ISA_MIPS32R6;
 608 def MSUBF_S : MSUBF_S_ENC, MSUBF_S_DESC, ISA_MIPS32R6;
 609 def MSUBF_D : MSUBF_D_ENC, MSUBF_D_DESC, ISA_MIPS32R6;
 610 def MUH    : MUH_ENC, MUH_DESC, ISA_MIPS32R6;
 611 def MUHU   : MUHU_ENC, MUHU_DESC, ISA_MIPS32R6;
 612 def MUL_R6 : MUL_R6_ENC, MUL_R6_DESC, ISA_MIPS32R6;
 613 def MULU   : MULU_ENC, MULU_DESC, ISA_MIPS32R6;
 614 def NAL; // BAL with rd=0
 615 def PREF_R6 : PREF_ENC, PREF_DESC, ISA_MIPS32R6;
 616 def RINT_D : RINT_D_ENC, RINT_D_DESC, ISA_MIPS32R6;
 617 def RINT_S : RINT_S_ENC, RINT_S_DESC, ISA_MIPS32R6;
 618 def SELEQZ : SELEQZ_ENC, SELEQZ_DESC, ISA_MIPS32R6, GPR_32;
 619 def SELEQZ_D : SELEQZ_D_ENC, SELEQZ_D_DESC, ISA_MIPS32R6;
 620 def SELEQZ_S : SELEQZ_S_ENC, SELEQZ_S_DESC, ISA_MIPS32R6;
 621 def SELNEZ : SELNEZ_ENC, SELNEZ_DESC, ISA_MIPS32R6, GPR_32;
 622 def SELNEZ_D : SELNEZ_D_ENC, SELNEZ_D_DESC, ISA_MIPS32R6;
 623 def SELNEZ_S : SELNEZ_S_ENC, SELNEZ_S_DESC, ISA_MIPS32R6;
 624 def SEL_D : SEL_D_ENC, SEL_D_DESC, ISA_MIPS32R6;
 625 def SEL_S : SEL_S_ENC, SEL_S_DESC, ISA_MIPS32R6;
 626
 627 //===----------------------------------------------------------------------===//
 628 //
 629 // Patterns and Pseudo Instructions
 630 //
 631 //===----------------------------------------------------------------------===//
 632
 633 // f32 comparisons supported via another comparison
 634 def : MipsPat<(setone f32:$lhs, f32:$rhs),
 635               (NOR (CMP_UEQ_S f32:$lhs, f32:$rhs), ZERO)>, ISA_MIPS32R6;
 636 def : MipsPat<(seto f32:$lhs, f32:$rhs),
 637               (NOR (CMP_UN_S f32:$lhs, f32:$rhs), ZERO)>, ISA_MIPS32R6;
 638 def : MipsPat<(setune f32:$lhs, f32:$rhs),
 639               (NOR (CMP_EQ_S f32:$lhs, f32:$rhs), ZERO)>, ISA_MIPS32R6;
 640 def : MipsPat<(seteq f32:$lhs, f32:$rhs), (CMP_EQ_S f32:$lhs, f32:$rhs)>,
 641       ISA_MIPS32R6;
 642 def : MipsPat<(setgt f32:$lhs, f32:$rhs), (CMP_LE_S f32:$rhs, f32:$lhs)>,
 643       ISA_MIPS32R6;
 644 def : MipsPat<(setge f32:$lhs, f32:$rhs), (CMP_LT_S f32:$rhs, f32:$lhs)>,
 645       ISA_MIPS32R6;
 646 def : MipsPat<(setlt f32:$lhs, f32:$rhs), (CMP_OLT_S f32:$lhs, f32:$rhs)>,
 647       ISA_MIPS32R6;
 648 def : MipsPat<(setlt f32:$lhs, f32:$rhs), (CMP_OLE_S f32:$lhs, f32:$rhs)>,
 649       ISA_MIPS32R6;
 650 def : MipsPat<(setne f32:$lhs, f32:$rhs),
 651               (NOR (CMP_EQ_S f32:$lhs, f32:$rhs), ZERO)>, ISA_MIPS32R6;
 652
 653 // f64 comparisons supported via another comparison
 654 def : MipsPat<(setone f64:$lhs, f64:$rhs),
 655               (NOR (CMP_UEQ_D f64:$lhs, f64:$rhs), ZERO)>, ISA_MIPS32R6;
 656 def : MipsPat<(seto f64:$lhs, f64:$rhs),
 657               (NOR (CMP_UN_D f64:$lhs, f64:$rhs), ZERO)>, ISA_MIPS32R6;
 658 def : MipsPat<(setune f64:$lhs, f64:$rhs),
 659               (NOR (CMP_EQ_D f64:$lhs, f64:$rhs), ZERO)>, ISA_MIPS32R6;
 660 def : MipsPat<(seteq f64:$lhs, f64:$rhs), (CMP_EQ_D f64:$lhs, f64:$rhs)>,
 661       ISA_MIPS32R6;
 662 def : MipsPat<(setgt f64:$lhs, f64:$rhs), (CMP_LE_D f64:$rhs, f64:$lhs)>,
 663       ISA_MIPS32R6;
 664 def : MipsPat<(setge f64:$lhs, f64:$rhs), (CMP_LT_D f64:$rhs, f64:$lhs)>,
 665       ISA_MIPS32R6;
 666 def : MipsPat<(setlt f64:$lhs, f64:$rhs), (CMP_OLT_D f64:$lhs, f64:$rhs)>,
 667       ISA_MIPS32R6;
 668 def : MipsPat<(setlt f64:$lhs, f64:$rhs), (CMP_OLE_D f64:$lhs, f64:$rhs)>,
 669       ISA_MIPS32R6;
 670 def : MipsPat<(setne f64:$lhs, f64:$rhs),
 671               (NOR (CMP_EQ_D f64:$lhs, f64:$rhs), ZERO)>, ISA_MIPS32R6;
 672
 673 // i32 selects
 674 def : MipsPat<(select i32:$cond, i32:$t, i32:$f),
 675               (OR (SELNEZ i32:$t, i32:$cond), (SELEQZ i32:$f, i32:$cond))>,
 676               ISA_MIPS32R6;
 677 def : MipsPat<(select (i32 (seteq i32:$cond, immz)), i32:$t, i32:$f),
 678               (OR (SELNEZ i32:$t, i32:$cond), (SELEQZ i32:$f, i32:$cond))>,
 679               ISA_MIPS32R6;
 680 def : MipsPat<(select (i32 (setne i32:$cond, immz)), i32:$t, i32:$f),
 681               (OR (SELNEZ i32:$f, i32:$cond), (SELEQZ i32:$t, i32:$cond))>,
 682               ISA_MIPS32R6;
 683 def : MipsPat<(select (i32 (seteq i32:$cond, immZExt16:$imm)), i32:$t, i32:$f),
 684               (OR (SELNEZ i32:$t, (XORi i32:$cond, immZExt16:$imm)),
 685                   (SELEQZ i32:$f, (XORi i32:$cond, immZExt16:$imm)))>,
 686               ISA_MIPS32R6;
 687 def : MipsPat<(select (i32 (setne i32:$cond, immZExt16:$imm)), i32:$t, i32:$f),
 688               (OR (SELNEZ i32:$f, (XORi i32:$cond, immZExt16:$imm)),
 689                   (SELEQZ i32:$t, (XORi i32:$cond, immZExt16:$imm)))>,
 690               ISA_MIPS32R6;
 691 def : MipsPat<(select (i32 (setgt i32:$cond, immSExt16Plus1:$imm)), i32:$t,
 692                       i32:$f),
 693               (OR (SELNEZ i32:$t, (SLTi i32:$cond, (Plus1 imm:$imm))),
 694                   (SELEQZ i32:$f, (SLTi i32:$cond, (Plus1 imm:$imm))))>,
 695               ISA_MIPS32R6;
 696 def : MipsPat<(select (i32 (setugt i32:$cond, immSExt16Plus1:$imm)),
 697                       i32:$t, i32:$f),
 698               (OR (SELNEZ i32:$t, (SLTiu i32:$cond, (Plus1 imm:$imm))),
 699                   (SELEQZ i32:$f, (SLTiu i32:$cond, (Plus1 imm:$imm))))>,
 700               ISA_MIPS32R6;
 701
 702 def : MipsPat<(select i32:$cond, i32:$t, immz),
 703               (SELNEZ i32:$t, i32:$cond)>, ISA_MIPS32R6;
 704 def : MipsPat<(select (i32 (setne i32:$cond, immz)), i32:$t, immz),
 705               (SELNEZ i32:$t, i32:$cond)>, ISA_MIPS32R6;
 706 def : MipsPat<(select (i32 (seteq i32:$cond, immz)), i32:$t, immz),
 707               (SELEQZ i32:$t, i32:$cond)>, ISA_MIPS32R6;
 708 def : MipsPat<(select i32:$cond, immz, i32:$f),
 709               (SELEQZ i32:$f, i32:$cond)>, ISA_MIPS32R6;
 710 def : MipsPat<(select (i32 (setne i32:$cond, immz)), immz, i32:$f),
 711               (SELEQZ i32:$f, i32:$cond)>, ISA_MIPS32R6;
 712 def : MipsPat<(select (i32 (seteq i32:$cond, immz)), immz, i32:$f),
 713               (SELNEZ i32:$f, i32:$cond)>, ISA_MIPS32R6;