lib/Target/ARM/ARMInstrThumb2.td

   1 //===- ARMInstrThumb2.td - Thumb2 support for ARM -------------------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Thumb2 instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 // Shifted operands. No register controlled shifts for Thumb2.
  15 // Note: We do not support rrx shifted operands yet.
  16 def t2_so_reg : Operand<i32>,    // reg imm
  17                 ComplexPattern<i32, 2, "SelectThumb2ShifterOperandReg",
  18                                [shl,srl,sra,rotr]> {
  19   let PrintMethod = "printSOOperand";
  20   let MIOperandInfo = (ops GPR, i32imm);
  21 }
  22
  23 // t2_so_imm_XFORM - Return a t2_so_imm value packed into the format
  24 // described for t2_so_imm def below.
  25 def t2_so_imm_XFORM : SDNodeXForm<imm, [{
  26   return CurDAG->getTargetConstant(
  27         ARM_AM::getT2SOImmVal(N->getZExtValue()), MVT::i32);
  28 }]>;
  29
  30 // t2_so_imm_not_XFORM - Return the complement of a t2_so_imm value
  31 def t2_so_imm_not_XFORM : SDNodeXForm<imm, [{
  32     return CurDAG->getTargetConstant(
  33         ARM_AM::getT2SOImmVal(~((uint32_t)N->getZExtValue())), MVT::i32);
  34 }]>;
  35
  36 // t2_so_imm_neg_XFORM - Return the negation of a t2_so_imm value
  37 def t2_so_imm_neg_XFORM : SDNodeXForm<imm, [{
  38     return CurDAG->getTargetConstant(
  39         ARM_AM::getT2SOImmVal(-((int)N->getZExtValue())), MVT::i32);
  40 }]>;
  41
  42 // t2_so_imm - Match a 32-bit immediate operand, which is an
  43 // 8-bit immediate rotated by an arbitrary number of bits, or an 8-bit
  44 // immediate splatted into multiple bytes of the word. t2_so_imm values are
  45 // represented in the imm field in the same 12-bit form that they are encoded
  46 // into t2_so_imm instructions: the 8-bit immediate is the least significant bits
  47 // [bits 0-7], the 4-bit shift/splat amount is the next 4 bits [bits 8-11].
  48 def t2_so_imm : Operand<i32>,
  49                 PatLeaf<(imm), [{
  50        return ARM_AM::getT2SOImmVal((uint32_t)N->getZExtValue()) != -1;
  51      }], t2_so_imm_XFORM> {
  52   let PrintMethod = "printT2SOImmOperand";
  53 }
  54
  55 // t2_so_imm_not - Match an immediate that is a complement
  56 // of a t2_so_imm.
  57 def t2_so_imm_not : Operand<i32>,
  58                     PatLeaf<(imm), [{
  59        return ARM_AM::getT2SOImmVal(~((uint32_t)N->getZExtValue())) != -1;
  60      }], t2_so_imm_not_XFORM> {
  61   let PrintMethod = "printT2SOImmOperand";
  62 }
  63
  64 // t2_so_imm_neg - Match an immediate that is a negation of a t2_so_imm.
  65 def t2_so_imm_neg : Operand<i32>,
  66                     PatLeaf<(imm), [{
  67        return ARM_AM::getT2SOImmVal(-((int)N->getZExtValue())) != -1;
  68      }], t2_so_imm_neg_XFORM> {
  69   let PrintMethod = "printT2SOImmOperand";
  70 }
  71
  72 /// imm1_31 predicate - True if the 32-bit immediate is in the range [1,31].
  73 def imm1_31 : PatLeaf<(i32 imm), [{
  74   return (int32_t)N->getZExtValue() >= 1 && (int32_t)N->getZExtValue() < 32;
  75 }]>;
  76
  77 /// imm0_4095 predicate - True if the 32-bit immediate is in the range [0.4095].
  78 def imm0_4095 : PatLeaf<(i32 imm), [{
  79   return (uint32_t)N->getZExtValue() < 4096;
  80 }]>;
  81
  82 def imm0_4095_neg : PatLeaf<(i32 imm), [{
  83  return (uint32_t)(-N->getZExtValue()) < 4096;
  84 }], imm_neg_XFORM>;
  85
  86 /// imm0_65535 predicate - True if the 32-bit immediate is in the range
  87 /// [0.65535].
  88 def imm0_65535 : PatLeaf<(i32 imm), [{
  89   return (uint32_t)N->getZExtValue() < 65536;
  90 }]>;
  91
  92
  93 /// bf_inv_mask_imm predicate - An AND mask to clear an arbitrary width bitfield
  94 /// e.g., 0xf000ffff
  95 def bf_inv_mask_imm : Operand<i32>,
  96                       PatLeaf<(imm), [{
  97   uint32_t v = (uint32_t)N->getZExtValue();
  98   if (v == 0xffffffff)
  99     return 0;
 100   // naive checker. should do better, but simple is best for now since it's
 101   // more likely to be correct.
 102   while (v & 1) v >>= 1;    // shift off the leading 1's
 103   if (v)
 104     {
 105       while (!(v & 1)) v >>=1;  // shift off the mask
 106       while (v & 1) v >>= 1;    // shift off the trailing 1's
 107     }
 108   // if this is a mask for clearing a bitfield, what's left should be zero.
 109   return (v == 0);
 110 }] > {
 111   let PrintMethod = "printBitfieldInvMaskImmOperand";
 112 }
 113
 114 /// Split a 32-bit immediate into two 16 bit parts.
 115 def t2_lo16 : SDNodeXForm<imm, [{
 116   return CurDAG->getTargetConstant((uint32_t)N->getZExtValue() & 0xffff,
 117                                    MVT::i32);
 118 }]>;
 119
 120 def t2_hi16 : SDNodeXForm<imm, [{
 121   return CurDAG->getTargetConstant((uint32_t)N->getZExtValue() >> 16, MVT::i32);
 122 }]>;
 123
 124 def t2_lo16AllZero : PatLeaf<(i32 imm), [{
 125   // Returns true if all low 16-bits are 0.
 126   return (((uint32_t)N->getZExtValue()) & 0xFFFFUL) == 0;
 127   }], t2_hi16>;
 128
 129 //===----------------------------------------------------------------------===//
 130 //  Thumb2 to cover the functionality of the ARM instruction set.
 131 //
 132
 133 /// T2I_un_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 134 //  unary operation that produces a value.
 135 multiclass T2I_un_irs<string opc, PatFrag opnode, bit Cheap = 0, bit ReMat = 0>{
 136    // shifted imm
 137    def i : T2I<(outs GPR:$dst), (ins t2_so_imm:$src),
 138                 !strconcat(opc, " $dst, $src"),
 139                 [(set GPR:$dst, (opnode t2_so_imm:$src))]> {
 140      let isAsCheapAsAMove = Cheap;
 141      let isReMaterializable = ReMat;
 142    }
 143    // register
 144    def r : T2I<(outs GPR:$dst), (ins GPR:$src),
 145                 !strconcat(opc, " $dst, $src"),
 146                 [(set GPR:$dst, (opnode GPR:$src))]>;
 147    // shifted register
 148    def s : T2I<(outs GPR:$dst), (ins t2_so_reg:$src),
 149                 !strconcat(opc, " $dst, $src"),
 150                 [(set GPR:$dst, (opnode t2_so_reg:$src))]>;
 151 }
 152
 153 /// T2I_bin_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 154 //  binary operation that produces a value.
 155 multiclass T2I_bin_irs<string opc, PatFrag opnode> {
 156    // shifted imm
 157    def ri : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 158                 !strconcat(opc, " $dst, $lhs, $rhs"),
 159                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 160    // register
 161    def rr : T2I<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 162                 !strconcat(opc, " $dst, $lhs, $rhs"),
 163                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 164    // shifted register
 165    def rs : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 166                 !strconcat(opc, " $dst, $lhs, $rhs"),
 167                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 168 }
 169
 170 /// T2I_rbin_is - Same as T2I_bin_irs except the order of operands are reversed.
 171 multiclass T2I_rbin_irs<string opc, PatFrag opnode> {
 172    // shifted imm
 173    def ri : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_imm:$lhs),
 174                 !strconcat(opc, " $dst, $rhs, $lhs"),
 175                 [(set GPR:$dst, (opnode t2_so_imm:$lhs, GPR:$rhs))]>;
 176    // register
 177    def rr : T2I<(outs GPR:$dst), (ins GPR:$rhs, GPR:$lhs),
 178                 !strconcat(opc, " $dst, $rhs, $lhs"),
 179                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 180    // shifted register
 181    def rs : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_reg:$lhs),
 182                 !strconcat(opc, " $dst, $rhs, $lhs"),
 183                 [(set GPR:$dst, (opnode t2_so_reg:$lhs, GPR:$rhs))]>;
 184 }
 185
 186 /// T2I_bin_s_irs - Similar to T2I_bin_irs except it sets the 's' bit so the
 187 /// instruction modifies the CPSR register.
 188 let Defs = [CPSR] in {
 189 multiclass T2I_bin_s_irs<string opc, PatFrag opnode> {
 190    // shifted imm
 191    def ri : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 192                 !strconcat(opc, "s $dst, $lhs, $rhs"),
 193                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 194    // register
 195    def rr : T2I<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 196                 !strconcat(opc, " $dst, $lhs, $rhs"),
 197                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 198    // shifted register
 199    def rs : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 200                 !strconcat(opc, "s $dst, $lhs, $rhs"),
 201                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 202 }
 203 }
 204
 205 /// T2I_rbin_s_irs - Same as T2I_bin_s_irs except the order of operands are
 206 /// reversed.
 207 let Defs = [CPSR] in {
 208 multiclass T2I_rbin_s_irs<string opc, PatFrag opnode> {
 209    // shifted imm
 210    def ri : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_imm:$lhs),
 211                 !strconcat(opc, "s $dst, $rhs, $lhs"),
 212                 [(set GPR:$dst, (opnode t2_so_imm:$lhs, GPR:$rhs))]>;
 213    // register
 214    def rr : T2I<(outs GPR:$dst), (ins GPR:$rhs, GPR:$lhs),
 215                 !strconcat(opc, " $dst, $rhs, $lhs"),
 216                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 217    // shifted register
 218    def rs : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_reg:$lhs),
 219                 !strconcat(opc, "s $dst, $rhs, $lhs"),
 220                 [(set GPR:$dst, (opnode t2_so_reg:$lhs, GPR:$rhs))]>;
 221 }
 222 }
 223
 224 /// T2I_bin_ii12rs - Defines a set of (op reg, {so_imm|imm0_4095|r|so_reg})
 225 /// patterns for a binary operation that produces a value.
 226 multiclass T2I_bin_ii12rs<string opc, PatFrag opnode> {
 227    // shifted imm
 228    def ri : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 229                 !strconcat(opc, " $dst, $lhs, $rhs"),
 230                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 231    // 12-bit imm
 232    def ri12 : T2I<(outs GPR:$dst), (ins GPR:$lhs, i32imm:$rhs),
 233                 !strconcat(opc, "w $dst, $lhs, $rhs"),
 234                 [(set GPR:$dst, (opnode GPR:$lhs, imm0_4095:$rhs))]>;
 235    // register
 236    def rr : T2I<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 237                 !strconcat(opc, " $dst, $lhs, $rhs"),
 238                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 239    // shifted register
 240    def rs : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 241                 !strconcat(opc, " $dst, $lhs, $rhs"),
 242                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 243 }
 244
 245 /// T2I_bin_c_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 246 //  binary operation that produces a value and set the carry bit. It can also
 247 /// optionally set CPSR.
 248 let Uses = [CPSR] in {
 249 multiclass T2I_bin_c_irs<string opc, PatFrag opnode> {
 250    // shifted imm
 251    def ri : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs, cc_out:$s),
 252                 !strconcat(opc, "${s} $dst, $lhs, $rhs"),
 253                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 254    // register
 255    def rr : T2I<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs, cc_out:$s),
 256                 !strconcat(opc, "${s} $dst, $lhs, $rhs"),
 257                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 258    // shifted register
 259    def rs : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs, cc_out:$s),
 260                 !strconcat(opc, "${s} $dst, $lhs, $rhs"),
 261                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 262 }
 263 }
 264
 265 /// T2I_rbin_c_irs - Same as T2I_bin_c_irs except the order of operands are
 266 /// reversed.
 267 let Uses = [CPSR] in {
 268 multiclass T2I_rbin_c_irs<string opc, PatFrag opnode> {
 269    // shifted imm
 270    def ri : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_imm:$lhs, cc_out:$s),
 271                 !strconcat(opc, "${s} $dst, $rhs, $lhs"),
 272                 [(set GPR:$dst, (opnode t2_so_imm:$lhs, GPR:$rhs))]>;
 273    // register
 274    def rr : T2I<(outs GPR:$dst), (ins GPR:$rhs, GPR:$lhs, cc_out:$s),
 275                 !strconcat(opc, "${s} $dst, $rhs, $lhs"),
 276                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 277    // shifted register
 278    def rs : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_reg:$lhs, cc_out:$s),
 279                 !strconcat(opc, "${s} $dst, $rhs, $lhs"),
 280                 [(set GPR:$dst, (opnode t2_so_reg:$lhs, GPR:$rhs))]>;
 281 }
 282 }
 283
 284 /// T2I_sh_ir - Defines a set of (op reg, {so_imm|r}) patterns for a shift /
 285 //  rotate operation that produces a value.
 286 multiclass T2I_sh_ir<string opc, PatFrag opnode> {
 287    // 5-bit imm
 288    def ri : T2I<(outs GPR:$dst), (ins GPR:$lhs, i32imm:$rhs),
 289                 !strconcat(opc, " $dst, $lhs, $rhs"),
 290                 [(set GPR:$dst, (opnode GPR:$lhs, imm1_31:$rhs))]>;
 291    // register
 292    def rr : T2I<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 293                 !strconcat(opc, " $dst, $lhs, $rhs"),
 294                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 295 }
 296
 297 /// T21_cmp_irs - Defines a set of (op r, {so_imm|r|so_reg}) cmp / test
 298 /// patterns. Similar to T2I_bin_irs except the instruction does not produce
 299 /// a explicit result, only implicitly set CPSR.
 300 let Uses = [CPSR] in {
 301 multiclass T2I_cmp_is<string opc, PatFrag opnode> {
 302    // shifted imm
 303    def ri : T2I<(outs), (ins GPR:$lhs, t2_so_imm:$rhs),
 304                 !strconcat(opc, " $lhs, $rhs"),
 305                 [(opnode GPR:$lhs, t2_so_imm:$rhs)]>;
 306    // register
 307    def rr : T2I<(outs), (ins GPR:$lhs, GPR:$rhs),
 308                 !strconcat(opc, " $lhs, $rhs"),
 309                 [(opnode GPR:$lhs, GPR:$rhs)]>;
 310    // shifted register
 311    def rs : T2I<(outs), (ins GPR:$lhs, t2_so_reg:$rhs),
 312                 !strconcat(opc, " $lhs, $rhs"),
 313                 [(opnode GPR:$lhs, t2_so_reg:$rhs)]>;
 314 }
 315 }
 316
 317 //===----------------------------------------------------------------------===//
 318 //  Miscellaneous Instructions.
 319 //
 320
 321 let isNotDuplicable = 1 in
 322 def t2PICADD : T2I<(outs tGPR:$dst), (ins tGPR:$lhs, pclabel:$cp),
 323                    "$cp:\n\tadd $dst, pc",
 324                    [(set tGPR:$dst, (ARMpic_add tGPR:$lhs, imm:$cp))]>;
 325
 326
 327 // LEApcrel - Load a pc-relative address into a register without offending the
 328 // assembler.
 329 def t2LEApcrel : T2I<(outs GPR:$dst), (ins i32imm:$label, pred:$p),
 330                    !strconcat(!strconcat(".set PCRELV${:uid}, ($label-(",
 331                                          "${:private}PCRELL${:uid}+8))\n"),
 332                               !strconcat("${:private}PCRELL${:uid}:\n\t",
 333                                          "add$p $dst, pc, #PCRELV${:uid}")),
 334                    []>;
 335
 336 def t2LEApcrelJT : T2I<(outs GPR:$dst),
 337                        (ins i32imm:$label, i32imm:$id, pred:$p),
 338           !strconcat(!strconcat(".set PCRELV${:uid}, (${label}_${id:no_hash}-(",
 339                                          "${:private}PCRELL${:uid}+8))\n"),
 340                               !strconcat("${:private}PCRELL${:uid}:\n\t",
 341                                          "add$p $dst, pc, #PCRELV${:uid}")),
 342                    []>;
 343
 344 // ADD rd, sp, #so_imm
 345 def t2ADDrSPi : T2I<(outs GPR:$dst), (ins GPR:$sp, t2_so_imm:$imm),
 346                     "add $dst, $sp, $imm",
 347                     []>;
 348
 349 // ADD rd, sp, #imm12
 350 def t2ADDrSPi12 : T2I<(outs GPR:$dst), (ins GPR:$sp, i32imm:$imm),
 351                     "addw $dst, $sp, $imm",
 352                     []>;
 353
 354 def t2ADDrSPs : T2I<(outs GPR:$dst), (ins GPR:$sp, t2_so_reg:$rhs),
 355                     "addw $dst, $sp, $rhs",
 356                     []>;
 357
 358
 359 //===----------------------------------------------------------------------===//
 360 //  Arithmetic Instructions.
 361 //
 362
 363 //===----------------------------------------------------------------------===//
 364 //  Move Instructions.
 365 //
 366
 367 let neverHasSideEffects = 1 in
 368 def t2MOVr : T2I<(outs GPR:$dst), (ins GPR:$src),
 369                   "mov $dst, $src", []>;
 370
 371 let isReMaterializable = 1, isAsCheapAsAMove = 1 in
 372 def t2MOVi16 : T2I<(outs GPR:$dst), (ins i32imm:$src),
 373                    "movw $dst, $src",
 374                    [(set GPR:$dst, imm0_65535:$src)]>;
 375
 376 // FIXME: Also available in ARM mode.
 377 let Constraints = "$src = $dst" in
 378 def t2MOVTi16 : T2I<(outs GPR:$dst), (ins GPR:$src, i32imm:$imm),
 379                    "movt $dst, $imm",
 380                    [(set GPR:$dst,
 381                          (or (and GPR:$src, 0xffff), t2_lo16AllZero:$imm))]>;
 382
 383 //===----------------------------------------------------------------------===//
 384 //  Arithmetic Instructions.
 385 //
 386
 387 defm t2ADD  : T2I_bin_ii12rs<"add", BinOpFrag<(add  node:$LHS, node:$RHS)>>;
 388 defm t2SUB  : T2I_bin_ii12rs<"sub", BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
 389
 390 // ADD and SUB with 's' bit set. No 12-bit immediate (T4) variants.
 391 defm t2ADDS : T2I_bin_s_irs<"add",  BinOpFrag<(addc node:$LHS, node:$RHS)>>;
 392 defm t2SUBS : T2I_bin_s_irs<"sub",  BinOpFrag<(subc node:$LHS, node:$RHS)>>;
 393
 394 // FIXME: predication support
 395 defm t2ADC  : T2I_bin_c_irs<"adc",  BinOpFrag<(adde node:$LHS, node:$RHS)>>;
 396 defm t2SBC  : T2I_bin_c_irs<"sbc",  BinOpFrag<(sube node:$LHS, node:$RHS)>>;
 397
 398 // RSB, RSC
 399 defm t2RSB  : T2I_rbin_irs  <"rsb", BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
 400 defm t2RSBS : T2I_rbin_c_irs<"rsb", BinOpFrag<(subc node:$LHS, node:$RHS)>>;
 401 defm t2RSC  : T2I_rbin_s_irs<"rsc", BinOpFrag<(sube node:$LHS, node:$RHS)>>;
 402
 403 // (sub X, imm) gets canonicalized to (add X, -imm).  Match this form.
 404 def : Thumb2Pat<(add       GPR:$src, t2_so_imm_neg:$imm),
 405                 (t2SUBri   GPR:$src, t2_so_imm_neg:$imm)>;
 406 def : Thumb2Pat<(add       GPR:$src, imm0_4095_neg:$imm),
 407                 (t2SUBri12 GPR:$src, imm0_4095_neg:$imm)>;
 408
 409
 410 //===----------------------------------------------------------------------===//
 411 //  Shift and rotate Instructions.
 412 //
 413
 414 defm t2LSL  : T2I_sh_ir<"lsl", BinOpFrag<(shl  node:$LHS, node:$RHS)>>;
 415 defm t2LSR  : T2I_sh_ir<"lsr", BinOpFrag<(srl  node:$LHS, node:$RHS)>>;
 416 defm t2ASR  : T2I_sh_ir<"asr", BinOpFrag<(sra  node:$LHS, node:$RHS)>>;
 417 defm t2ROR  : T2I_sh_ir<"ror", BinOpFrag<(rotr node:$LHS, node:$RHS)>>;
 418
 419 def t2MOVrx : T2I<(outs GPR:$dst), (ins GPR:$src),
 420                   "mov $dst, $src, rrx",
 421                   [(set GPR:$dst, (ARMrrx GPR:$src))]>;
 422
 423 //===----------------------------------------------------------------------===//
 424 //  Bitwise Instructions.
 425 //
 426
 427 defm t2AND  : T2I_bin_irs<"and", BinOpFrag<(and node:$LHS, node:$RHS)>>;
 428 defm t2ORR  : T2I_bin_irs<"orr", BinOpFrag<(or  node:$LHS, node:$RHS)>>;
 429 defm t2EOR  : T2I_bin_irs<"eor", BinOpFrag<(xor node:$LHS, node:$RHS)>>;
 430
 431 defm t2BIC  : T2I_bin_irs<"bic", BinOpFrag<(and node:$LHS, (not node:$RHS))>>;
 432
 433 def : Thumb2Pat<(and     GPR:$src, t2_so_imm_not:$imm),
 434                 (t2BICri GPR:$src, t2_so_imm_not:$imm)>;
 435
 436 defm t2ORN  : T2I_bin_irs<"orn", BinOpFrag<(or  node:$LHS, (not node:$RHS))>>;
 437
 438 def : Thumb2Pat<(or      GPR:$src, t2_so_imm_not:$imm),
 439                 (t2ORNri GPR:$src, t2_so_imm_not:$imm)>;
 440
 441 defm t2MVN  : T2I_un_irs  <"mvn", UnOpFrag<(not node:$Src)>, 1, 1>;
 442
 443 // A8.6.17  BFC - Bitfield clear
 444 // FIXME: Also available in ARM mode.
 445 let Constraints = "$src = $dst" in
 446 def t2BFC : T2I<(outs GPR:$dst), (ins GPR:$src, bf_inv_mask_imm:$imm),
 447                 "bfc $dst, $imm",
 448                 [(set GPR:$dst, (and GPR:$src, bf_inv_mask_imm:$imm))]>;
 449
 450 // FIXME: A8.6.18  BFI - Bitfield insert (Encoding T1)
 451
 452 //===----------------------------------------------------------------------===//
 453 //  Multiply Instructions.
 454 //
 455 def t2MUL: T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 456                 "mul $dst, $a, $b",
 457                 [(set GPR:$dst, (mul GPR:$a, GPR:$b))]>;
 458
 459 def t2MLA: T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 460                 "mla $dst, $a, $b, $c",
 461                 [(set GPR:$dst, (add (mul GPR:$a, GPR:$b), GPR:$c))]>;
 462
 463 def t2MLS: T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 464                 "mls $dst, $a, $b, $c",
 465                 [(set GPR:$dst, (sub GPR:$c, (mul GPR:$a, GPR:$b)))]>;
 466
 467 // FIXME: SMULL, etc.
 468
 469 //===----------------------------------------------------------------------===//
 470 //  Misc. Arithmetic Instructions.
 471 //
 472
 473 /////
 474 /// A8.6.31  CLZ
 475 /////
 476 // FIXME not firing? but ARM version does...
 477 def t2CLZ : T2I<(outs GPR:$dst), (ins GPR:$src),
 478                 "clz $dst, $src",
 479                 [(set GPR:$dst, (ctlz GPR:$src))]>;
 480
 481 def t2REV : T2I<(outs GPR:$dst), (ins GPR:$src),
 482                 "rev $dst, $src",
 483                 [(set GPR:$dst, (bswap GPR:$src))]>;
 484
 485 def t2REV16 : T2I<(outs GPR:$dst), (ins GPR:$src),
 486                 "rev16 $dst, $src",
 487                 [(set GPR:$dst,
 488                     (or (and (srl GPR:$src, (i32 8)), 0xFF),
 489                         (or (and (shl GPR:$src, (i32 8)), 0xFF00),
 490                             (or (and (srl GPR:$src, (i32 8)), 0xFF0000),
 491                                 (and (shl GPR:$src, (i32 8)), 0xFF000000)))))]>;
 492
 493 /////
 494 /// A8.6.137  REVSH
 495 /////
 496 def t2REVSH : T2I<(outs GPR:$dst), (ins GPR:$src),
 497                  "revsh $dst, $src",
 498                  [(set GPR:$dst,
 499                     (sext_inreg
 500                       (or (srl (and GPR:$src, 0xFFFF), (i32 8)),
 501                           (shl GPR:$src, (i32 8))), i16))]>;
 502
 503 // FIXME: PKHxx etc.
 504
 505 //===----------------------------------------------------------------------===//
 506 //  Comparison Instructions...
 507 //
 508
 509 defm t2CMP   : T2I_cmp_is<"cmp",
 510                           BinOpFrag<(ARMcmp node:$LHS, node:$RHS)>>;
 511 defm t2CMPnz : T2I_cmp_is<"cmp",
 512                           BinOpFrag<(ARMcmpNZ node:$LHS, node:$RHS)>>;
 513
 514 defm t2CMN   : T2I_cmp_is<"cmn",
 515                           BinOpFrag<(ARMcmp node:$LHS,(ineg node:$RHS))>>;
 516 defm t2CMNnz : T2I_cmp_is<"cmn",
 517                           BinOpFrag<(ARMcmpNZ node:$LHS,(ineg node:$RHS))>>;
 518
 519 def : Thumb2Pat<(ARMcmp  GPR:$src, t2_so_imm_neg:$imm),
 520                 (t2CMNri GPR:$src, t2_so_imm_neg:$imm)>;
 521
 522 def : Thumb2Pat<(ARMcmpNZ  GPR:$src, t2_so_imm_neg:$imm),
 523                 (t2CMNri   GPR:$src, t2_so_imm_neg:$imm)>;
 524
 525 // FIXME: TST, TEQ, etc.
 526
 527 // A8.6.27  CBNZ, CBZ - Compare and branch on (non)zero.
 528 // Short range conditional branch. Looks awesome for loops. Need to figure
 529 // out how to use this one.
 530
 531 // FIXME: Conditional moves
 532
 533
 534 //===----------------------------------------------------------------------===//
 535 // Non-Instruction Patterns
 536 //
 537
 538 // ConstantPool, GlobalAddress, and JumpTable
 539 def : Thumb2Pat<(ARMWrapper  tglobaladdr :$dst), (t2LEApcrel tglobaladdr :$dst)>;
 540 def : Thumb2Pat<(ARMWrapper  tconstpool  :$dst), (t2LEApcrel tconstpool  :$dst)>;
 541 def : Thumb2Pat<(ARMWrapperJT tjumptable:$dst, imm:$id),
 542                 (t2LEApcrelJT tjumptable:$dst, imm:$id)>;
 543
 544 // Large immediate handling.
 545
 546 def : Thumb2Pat<(i32 imm:$src),
 547                 (t2MOVTi16 (t2MOVi16 (t2_lo16 imm:$src)),
 548                            (t2_hi16 imm:$src))>;