lib/Target/ARM/ARMInstrThumb2.td

   1 //===- ARMInstrThumb2.td - Thumb2 support for ARM -------------------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Thumb2 instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 // Shifted operands. No register controlled shifts for Thumb2.
  15 // Note: We do not support rrx shifted operands yet.
  16 def t2_so_reg : Operand<i32>,    // reg imm
  17                 ComplexPattern<i32, 2, "SelectT2ShifterOperandReg",
  18                                [shl,srl,sra,rotr]> {
  19   let PrintMethod = "printT2SOOperand";
  20   let MIOperandInfo = (ops GPR, i32imm);
  21 }
  22
  23 // t2_so_imm_XFORM - Return a t2_so_imm value packed into the format
  24 // described for t2_so_imm def below.
  25 def t2_so_imm_XFORM : SDNodeXForm<imm, [{
  26   return CurDAG->getTargetConstant(
  27         ARM_AM::getT2SOImmVal(N->getZExtValue()), MVT::i32);
  28 }]>;
  29
  30 // t2_so_imm_not_XFORM - Return the complement of a t2_so_imm value
  31 def t2_so_imm_not_XFORM : SDNodeXForm<imm, [{
  32     return CurDAG->getTargetConstant(
  33         ARM_AM::getT2SOImmVal(~((uint32_t)N->getZExtValue())), MVT::i32);
  34 }]>;
  35
  36 // t2_so_imm_neg_XFORM - Return the negation of a t2_so_imm value
  37 def t2_so_imm_neg_XFORM : SDNodeXForm<imm, [{
  38     return CurDAG->getTargetConstant(
  39         ARM_AM::getT2SOImmVal(-((int)N->getZExtValue())), MVT::i32);
  40 }]>;
  41
  42 // t2_so_imm - Match a 32-bit immediate operand, which is an
  43 // 8-bit immediate rotated by an arbitrary number of bits, or an 8-bit
  44 // immediate splatted into multiple bytes of the word. t2_so_imm values are
  45 // represented in the imm field in the same 12-bit form that they are encoded
  46 // into t2_so_imm instructions: the 8-bit immediate is the least significant bits
  47 // [bits 0-7], the 4-bit shift/splat amount is the next 4 bits [bits 8-11].
  48 def t2_so_imm : Operand<i32>,
  49                 PatLeaf<(imm), [{
  50        return ARM_AM::getT2SOImmVal((uint32_t)N->getZExtValue()) != -1;
  51      }], t2_so_imm_XFORM> {
  52   let PrintMethod = "printT2SOImmOperand";
  53 }
  54
  55 // t2_so_imm_not - Match an immediate that is a complement
  56 // of a t2_so_imm.
  57 def t2_so_imm_not : Operand<i32>,
  58                     PatLeaf<(imm), [{
  59        return ARM_AM::getT2SOImmVal(~((uint32_t)N->getZExtValue())) != -1;
  60      }], t2_so_imm_not_XFORM> {
  61   let PrintMethod = "printT2SOImmOperand";
  62 }
  63
  64 // t2_so_imm_neg - Match an immediate that is a negation of a t2_so_imm.
  65 def t2_so_imm_neg : Operand<i32>,
  66                     PatLeaf<(imm), [{
  67        return ARM_AM::getT2SOImmVal(-((int)N->getZExtValue())) != -1;
  68      }], t2_so_imm_neg_XFORM> {
  69   let PrintMethod = "printT2SOImmOperand";
  70 }
  71
  72 /// imm1_31 predicate - True if the 32-bit immediate is in the range [1,31].
  73 def imm1_31 : PatLeaf<(i32 imm), [{
  74   return (int32_t)N->getZExtValue() >= 1 && (int32_t)N->getZExtValue() < 32;
  75 }]>;
  76
  77 /// imm0_4095 predicate - True if the 32-bit immediate is in the range [0.4095].
  78 def imm0_4095 : PatLeaf<(i32 imm), [{
  79   return (uint32_t)N->getZExtValue() < 4096;
  80 }]>;
  81
  82 def imm0_4095_neg : PatLeaf<(i32 imm), [{
  83  return (uint32_t)(-N->getZExtValue()) < 4096;
  84 }], imm_neg_XFORM>;
  85
  86 /// imm0_65535 predicate - True if the 32-bit immediate is in the range
  87 /// [0.65535].
  88 def imm0_65535 : PatLeaf<(i32 imm), [{
  89   return (uint32_t)N->getZExtValue() < 65536;
  90 }]>;
  91
  92
  93 /// bf_inv_mask_imm predicate - An AND mask to clear an arbitrary width bitfield
  94 /// e.g., 0xf000ffff
  95 def bf_inv_mask_imm : Operand<i32>,
  96                       PatLeaf<(imm), [{
  97   uint32_t v = (uint32_t)N->getZExtValue();
  98   if (v == 0xffffffff)
  99     return 0;
 100   // naive checker. should do better, but simple is best for now since it's
 101   // more likely to be correct.
 102   while (v & 1) v >>= 1;    // shift off the leading 1's
 103   if (v)
 104     {
 105       while (!(v & 1)) v >>=1;  // shift off the mask
 106       while (v & 1) v >>= 1;    // shift off the trailing 1's
 107     }
 108   // if this is a mask for clearing a bitfield, what's left should be zero.
 109   return (v == 0);
 110 }] > {
 111   let PrintMethod = "printBitfieldInvMaskImmOperand";
 112 }
 113
 114 /// Split a 32-bit immediate into two 16 bit parts.
 115 def t2_lo16 : SDNodeXForm<imm, [{
 116   return CurDAG->getTargetConstant((uint32_t)N->getZExtValue() & 0xffff,
 117                                    MVT::i32);
 118 }]>;
 119
 120 def t2_hi16 : SDNodeXForm<imm, [{
 121   return CurDAG->getTargetConstant((uint32_t)N->getZExtValue() >> 16, MVT::i32);
 122 }]>;
 123
 124 def t2_lo16AllZero : PatLeaf<(i32 imm), [{
 125   // Returns true if all low 16-bits are 0.
 126   return (((uint32_t)N->getZExtValue()) & 0xFFFFUL) == 0;
 127   }], t2_hi16>;
 128
 129
 130 // Define Thumb2 specific addressing modes.
 131
 132 // t2addrmode_imm12  := reg + imm12
 133 def t2addrmode_imm12 : Operand<i32>,
 134                        ComplexPattern<i32, 2, "SelectT2AddrModeImm12", []> {
 135   let PrintMethod = "printT2AddrModeImm12Operand";
 136   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 137 }
 138
 139 // t2addrmode_imm8  := reg - imm8
 140 def t2addrmode_imm8 : Operand<i32>,
 141                       ComplexPattern<i32, 2, "SelectT2AddrModeImm8", []> {
 142   let PrintMethod = "printT2AddrModeImm8Operand";
 143   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 144 }
 145
 146 // t2addrmode_so_reg  := reg + reg << imm2
 147 def t2addrmode_so_reg : Operand<i32>,
 148                         ComplexPattern<i32, 3, "SelectT2AddrModeSoReg", []> {
 149   let PrintMethod = "printT2AddrModeSoRegOperand";
 150   let MIOperandInfo = (ops GPR:$base, GPR:$offsreg, i32imm:$offsimm);
 151 }
 152
 153
 154 //===----------------------------------------------------------------------===//
 155 // Multiclass helpers...
 156 //
 157
 158 /// T2I_un_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 159 /// unary operation that produces a value. These are predicable and can be
 160 /// changed to modify CPSR.
 161 multiclass T2I_un_irs<string opc, PatFrag opnode, bit Cheap = 0, bit ReMat = 0>{
 162    // shifted imm
 163    def i : T2sI<(outs GPR:$dst), (ins t2_so_imm:$src),
 164                 opc, " $dst, $src",
 165                 [(set GPR:$dst, (opnode t2_so_imm:$src))]> {
 166      let isAsCheapAsAMove = Cheap;
 167      let isReMaterializable = ReMat;
 168    }
 169    // register
 170    def r : T2I<(outs GPR:$dst), (ins GPR:$src),
 171                opc, " $dst, $src",
 172                 [(set GPR:$dst, (opnode GPR:$src))]>;
 173    // shifted register
 174    def s : T2I<(outs GPR:$dst), (ins t2_so_reg:$src),
 175                opc, " $dst, $src",
 176                [(set GPR:$dst, (opnode t2_so_reg:$src))]>;
 177 }
 178
 179 /// T2I_bin_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 180 //  binary operation that produces a value. These are predicable and can be
 181 /// changed to modify CPSR.
 182 multiclass T2I_bin_irs<string opc, PatFrag opnode, bit Commutable = 0> {
 183    // shifted imm
 184    def ri : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 185                  opc, " $dst, $lhs, $rhs",
 186                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 187    // register
 188    def rr : T2sI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 189                  opc, " $dst, $lhs, $rhs",
 190                  [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]> {
 191      let isCommutable = Commutable;
 192    }
 193    // shifted register
 194    def rs : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 195                  opc, " $dst, $lhs, $rhs",
 196                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 197 }
 198
 199 /// T2I_rbin_is - Same as T2I_bin_irs except the order of operands are
 200 /// reversed. It doesn't define the 'rr' form since it's handled by its
 201 /// T2I_bin_irs counterpart.
 202 multiclass T2I_rbin_is<string opc, PatFrag opnode> {
 203    // shifted imm
 204    def ri : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_imm:$lhs),
 205                 opc, " $dst, $rhs, $lhs",
 206                 [(set GPR:$dst, (opnode t2_so_imm:$lhs, GPR:$rhs))]>;
 207    // shifted register
 208    def rs : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_reg:$lhs),
 209                 opc, " $dst, $rhs, $lhs",
 210                 [(set GPR:$dst, (opnode t2_so_reg:$lhs, GPR:$rhs))]>;
 211 }
 212
 213 /// T2I_bin_s_irs - Similar to T2I_bin_irs except it sets the 's' bit so the
 214 /// instruction modifies the CPSR register.
 215 let Defs = [CPSR] in {
 216 multiclass T2I_bin_s_irs<string opc, PatFrag opnode, bit Commutable = 0> {
 217    // shifted imm
 218    def ri : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 219                 !strconcat(opc, "s"), " $dst, $lhs, $rhs",
 220                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 221    // register
 222    def rr : T2I<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 223                 !strconcat(opc, "s"), " $dst, $lhs, $rhs",
 224                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]> {
 225      let isCommutable = Commutable;
 226    }
 227    // shifted register
 228    def rs : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 229                 !strconcat(opc, "s"), " $dst, $lhs, $rhs",
 230                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 231 }
 232 }
 233
 234 /// T2I_bin_ii12rs - Defines a set of (op reg, {so_imm|imm0_4095|r|so_reg})
 235 /// patterns for a binary operation that produces a value.
 236 multiclass T2I_bin_ii12rs<string opc, PatFrag opnode, bit Commutable = 0> {
 237    // shifted imm
 238    def ri : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 239                  opc, " $dst, $lhs, $rhs",
 240                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 241    // 12-bit imm
 242    def ri12 : T2sI<(outs GPR:$dst), (ins GPR:$lhs, i32imm:$rhs),
 243                    !strconcat(opc, "w"), " $dst, $lhs, $rhs",
 244                    [(set GPR:$dst, (opnode GPR:$lhs, imm0_4095:$rhs))]>;
 245    // register
 246    def rr : T2sI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 247                  opc, " $dst, $lhs, $rhs",
 248                  [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]> {
 249      let isCommutable = Commutable;
 250    }
 251    // shifted register
 252    def rs : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 253                  opc, " $dst, $lhs, $rhs",
 254                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 255 }
 256
 257 /// T2I_adde_sube_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 258 /// binary operation that produces a value and use and define the carry bit.
 259 /// It's not predicable.
 260 let Uses = [CPSR] in {
 261 multiclass T2I_adde_sube_irs<string opc, PatFrag opnode, bit Commutable = 0> {
 262    // shifted imm
 263    def ri : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 264                  opc, " $dst, $lhs, $rhs",
 265                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>,
 266                  Requires<[IsThumb, HasThumb2, CarryDefIsUnused]>;
 267    // register
 268    def rr : T2sI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 269                  opc, " $dst, $lhs, $rhs",
 270                  [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>,
 271                  Requires<[IsThumb, HasThumb2, CarryDefIsUnused]> {
 272      let isCommutable = Commutable;
 273    }
 274    // shifted register
 275    def rs : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 276                  opc, " $dst, $lhs, $rhs",
 277                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>,
 278                  Requires<[IsThumb, HasThumb2, CarryDefIsUnused]>;
 279    // Carry setting variants
 280    // shifted imm
 281    def Sri : T2XI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 282                   !strconcat(opc, "s $dst, $lhs, $rhs"),
 283                   [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>,
 284                   Requires<[IsThumb, HasThumb2, CarryDefIsUsed]> {
 285                     let Defs = [CPSR];
 286                   }
 287    // register
 288    def Srr : T2XI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 289                   !strconcat(opc, "s $dst, $lhs, $rhs"),
 290                   [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>,
 291                   Requires<[IsThumb, HasThumb2, CarryDefIsUsed]> {
 292                     let Defs = [CPSR];
 293                     let isCommutable = Commutable;
 294    }
 295    // shifted register
 296    def Srs : T2XI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 297                   !strconcat(opc, "s $dst, $lhs, $rhs"),
 298                   [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>,
 299                   Requires<[IsThumb, HasThumb2, CarryDefIsUsed]> {
 300                     let Defs = [CPSR];
 301    }
 302 }
 303 }
 304
 305 /// T2I_rsc_is - Same as T2I_adde_sube_irs except the order of operands are
 306 /// reversed. It doesn't define the 'rr' form since it's handled by its
 307 /// T2I_adde_sube_irs counterpart.
 308 let Defs = [CPSR], Uses = [CPSR] in {
 309 multiclass T2I_rsc_is<string opc, PatFrag opnode> {
 310    // shifted imm
 311    def ri : T2sI<(outs GPR:$dst), (ins GPR:$rhs, t2_so_imm:$lhs),
 312                  opc, " $dst, $rhs, $lhs",
 313                  [(set GPR:$dst, (opnode t2_so_imm:$lhs, GPR:$rhs))]>,
 314                  Requires<[IsThumb, HasThumb2, CarryDefIsUnused]>;
 315    // shifted register
 316    def rs : T2sI<(outs GPR:$dst), (ins GPR:$rhs, t2_so_reg:$lhs),
 317                  opc, " $dst, $rhs, $lhs",
 318                  [(set GPR:$dst, (opnode t2_so_reg:$lhs, GPR:$rhs))]>,
 319                  Requires<[IsThumb, HasThumb2, CarryDefIsUnused]>;
 320    // shifted imm
 321    def Sri : T2XI<(outs GPR:$dst), (ins GPR:$rhs, t2_so_imm:$lhs),
 322                  !strconcat(opc, "s $dst, $rhs, $lhs"),
 323                  [(set GPR:$dst, (opnode t2_so_imm:$lhs, GPR:$rhs))]>,
 324                  Requires<[IsThumb, HasThumb2, CarryDefIsUsed]> {
 325                    let Defs = [CPSR];
 326    }
 327    // shifted register
 328    def Srs : T2XI<(outs GPR:$dst), (ins GPR:$rhs, t2_so_reg:$lhs),
 329                  !strconcat(opc, "s $dst, $rhs, $lhs"),
 330                  [(set GPR:$dst, (opnode t2_so_reg:$lhs, GPR:$rhs))]>,
 331                  Requires<[IsThumb, HasThumb2, CarryDefIsUsed]> {
 332                    let Defs = [CPSR];
 333    }
 334 }
 335 }
 336
 337 /// T2I_rbin_s_is - Same as T2I_bin_s_irs except the order of operands are
 338 /// reversed. It doesn't define the 'rr' form since it's handled by its
 339 /// T2I_bin_s_irs counterpart.
 340 let Defs = [CPSR] in {
 341 multiclass T2I_rbin_s_is<string opc, PatFrag opnode> {
 342    // shifted imm
 343    def ri : T2XI<(outs GPR:$dst), (ins GPR:$rhs, t2_so_imm:$lhs, cc_out:$s),
 344                  !strconcat(opc, "${s} $dst, $rhs, $lhs"),
 345                  [(set GPR:$dst, (opnode t2_so_imm:$lhs, GPR:$rhs))]>;
 346    // shifted register
 347    def rs : T2XI<(outs GPR:$dst), (ins GPR:$rhs, t2_so_reg:$lhs, cc_out:$s),
 348                  !strconcat(opc, "${s} $dst, $rhs, $lhs"),
 349                  [(set GPR:$dst, (opnode t2_so_reg:$lhs, GPR:$rhs))]>;
 350 }
 351 }
 352
 353 /// T2I_sh_ir - Defines a set of (op reg, {so_imm|r}) patterns for a shift /
 354 //  rotate operation that produces a value.
 355 multiclass T2I_sh_ir<string opc, PatFrag opnode> {
 356    // 5-bit imm
 357    def ri : T2sI<(outs GPR:$dst), (ins GPR:$lhs, i32imm:$rhs),
 358                  opc, " $dst, $lhs, $rhs",
 359                  [(set GPR:$dst, (opnode GPR:$lhs, imm1_31:$rhs))]>;
 360    // register
 361    def rr : T2sI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 362                  opc, " $dst, $lhs, $rhs",
 363                  [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 364 }
 365
 366 /// T21_cmp_irs - Defines a set of (op r, {so_imm|r|so_reg}) cmp / test
 367 /// patterns. Similar to T2I_bin_irs except the instruction does not produce
 368 /// a explicit result, only implicitly set CPSR.
 369 let Uses = [CPSR] in {
 370 multiclass T2I_cmp_is<string opc, PatFrag opnode> {
 371    // shifted imm
 372    def ri : T2I<(outs), (ins GPR:$lhs, t2_so_imm:$rhs),
 373                 opc, " $lhs, $rhs",
 374                 [(opnode GPR:$lhs, t2_so_imm:$rhs)]>;
 375    // register
 376    def rr : T2I<(outs), (ins GPR:$lhs, GPR:$rhs),
 377                 opc, " $lhs, $rhs",
 378                 [(opnode GPR:$lhs, GPR:$rhs)]>;
 379    // shifted register
 380    def rs : T2I<(outs), (ins GPR:$lhs, t2_so_reg:$rhs),
 381                 opc, " $lhs, $rhs",
 382                 [(opnode GPR:$lhs, t2_so_reg:$rhs)]>;
 383 }
 384 }
 385
 386 //===----------------------------------------------------------------------===//
 387 // Instructions
 388 //===----------------------------------------------------------------------===//
 389
 390 //===----------------------------------------------------------------------===//
 391 //  Miscellaneous Instructions.
 392 //
 393
 394 let isNotDuplicable = 1 in
 395 def t2PICADD : T2XI<(outs tGPR:$dst), (ins tGPR:$lhs, pclabel:$cp),
 396                     "$cp:\n\tadd $dst, pc",
 397                     [(set tGPR:$dst, (ARMpic_add tGPR:$lhs, imm:$cp))]>;
 398
 399
 400 // LEApcrel - Load a pc-relative address into a register without offending the
 401 // assembler.
 402 def t2LEApcrel : T2XI<(outs GPR:$dst), (ins i32imm:$label, pred:$p),
 403                    !strconcat(!strconcat(".set PCRELV${:uid}, ($label-(",
 404                                          "${:private}PCRELL${:uid}+8))\n"),
 405                               !strconcat("${:private}PCRELL${:uid}:\n\t",
 406                                          "add$p $dst, pc, #PCRELV${:uid}")),
 407                    []>;
 408
 409 def t2LEApcrelJT : T2XI<(outs GPR:$dst),
 410                        (ins i32imm:$label, i32imm:$id, pred:$p),
 411           !strconcat(!strconcat(".set PCRELV${:uid}, (${label}_${id:no_hash}-(",
 412                                          "${:private}PCRELL${:uid}+8))\n"),
 413                               !strconcat("${:private}PCRELL${:uid}:\n\t",
 414                                          "add$p $dst, pc, #PCRELV${:uid}")),
 415                    []>;
 416
 417 // ADD rd, sp, #so_imm
 418 def t2ADDrSPi : T2XI<(outs GPR:$dst), (ins GPR:$sp, t2_so_imm:$imm),
 419                      "add $dst, $sp, $imm",
 420                      []>;
 421
 422 // ADD rd, sp, #imm12
 423 def t2ADDrSPi12 : T2XI<(outs GPR:$dst), (ins GPR:$sp, i32imm:$imm),
 424                        "addw $dst, $sp, $imm",
 425                        []>;
 426
 427 def t2ADDrSPs : T2XI<(outs GPR:$dst), (ins GPR:$sp, t2_so_reg:$rhs),
 428                      "addw $dst, $sp, $rhs",
 429                      []>;
 430
 431
 432 //===----------------------------------------------------------------------===//
 433 //  Load / store Instructions.
 434 //
 435
 436 // Load
 437 let canFoldAsLoad = 1 in {
 438 def t2LDRi12 : T2Ii12<(outs GPR:$dst), (ins t2addrmode_imm12:$addr),
 439                       "ldr", " $dst, $addr",
 440                       [(set GPR:$dst, (load t2addrmode_imm12:$addr))]>;
 441
 442 def t2LDRi8 : T2Ii8<(outs GPR:$dst), (ins t2addrmode_imm8:$addr),
 443                     "ldr", " $dst, $addr",
 444                     [(set GPR:$dst, (load t2addrmode_imm8:$addr))]>;
 445
 446 def t2LDRs : T2Iso<(outs GPR:$dst), (ins t2addrmode_so_reg:$addr),
 447                    "ldr", " $dst, $addr",
 448                    [(set GPR:$dst, (load t2addrmode_so_reg:$addr))]>;
 449
 450 // Load tconstpool
 451 def t2LDRpci : T2Ipc<(outs GPR:$dst), (ins i32imm:$addr),
 452                      "ldr", " $dst, $addr",
 453                      [(set GPR:$dst, (load (ARMWrapper tconstpool:$addr)))]>;
 454 } // canFoldAsLoad
 455
 456 //===----------------------------------------------------------------------===//
 457 //  Move Instructions.
 458 //
 459
 460 let neverHasSideEffects = 1 in
 461 def t2MOVr : T2sI<(outs GPR:$dst), (ins GPR:$src),
 462                    "mov", " $dst, $src", []>;
 463
 464 let isReMaterializable = 1, isAsCheapAsAMove = 1 in
 465 def t2MOVi : T2sI<(outs GPR:$dst), (ins t2_so_imm:$src),
 466                    "mov", " $dst, $src",
 467                    [(set GPR:$dst, t2_so_imm:$src)]>;
 468
 469 let isReMaterializable = 1, isAsCheapAsAMove = 1 in
 470 def t2MOVi16 : T2I<(outs GPR:$dst), (ins i32imm:$src),
 471                    "movw", " $dst, $src",
 472                    [(set GPR:$dst, imm0_65535:$src)]>;
 473
 474 // FIXME: Also available in ARM mode.
 475 let Constraints = "$src = $dst" in
 476 def t2MOVTi16 : T2sI<(outs GPR:$dst), (ins GPR:$src, i32imm:$imm),
 477                      "movt", " $dst, $imm",
 478                      [(set GPR:$dst,
 479                            (or (and GPR:$src, 0xffff), t2_lo16AllZero:$imm))]>;
 480
 481 //===----------------------------------------------------------------------===//
 482 //  Arithmetic Instructions.
 483 //
 484
 485 defm t2ADD  : T2I_bin_ii12rs<"add", BinOpFrag<(add  node:$LHS, node:$RHS)>, 1>;
 486 defm t2SUB  : T2I_bin_ii12rs<"sub", BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
 487
 488 // ADD and SUB with 's' bit set. No 12-bit immediate (T4) variants.
 489 defm t2ADDS : T2I_bin_s_irs <"add",  BinOpFrag<(addc node:$LHS, node:$RHS)>, 1>;
 490 defm t2SUBS : T2I_bin_s_irs <"sub",  BinOpFrag<(subc node:$LHS, node:$RHS)>>;
 491
 492 defm t2ADC  : T2I_adde_sube_irs<"adc",BinOpFrag<(adde node:$LHS, node:$RHS)>,1>;
 493 defm t2SBC  : T2I_adde_sube_irs<"sbc",BinOpFrag<(sube node:$LHS, node:$RHS)>>;
 494
 495 // RSB, RSC
 496 defm t2RSB  : T2I_rbin_is   <"rsb", BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
 497 defm t2RSBS : T2I_rbin_s_is <"rsb", BinOpFrag<(subc node:$LHS, node:$RHS)>>;
 498 defm t2RSC  : T2I_rsc_is    <"rsc", BinOpFrag<(sube node:$LHS, node:$RHS)>>;
 499
 500 // (sub X, imm) gets canonicalized to (add X, -imm).  Match this form.
 501 def : T2Pat<(add       GPR:$src, t2_so_imm_neg:$imm),
 502             (t2SUBri   GPR:$src, t2_so_imm_neg:$imm)>;
 503 def : T2Pat<(add       GPR:$src, imm0_4095_neg:$imm),
 504             (t2SUBri12 GPR:$src, imm0_4095_neg:$imm)>;
 505
 506
 507 //===----------------------------------------------------------------------===//
 508 //  Shift and rotate Instructions.
 509 //
 510
 511 defm t2LSL  : T2I_sh_ir<"lsl", BinOpFrag<(shl  node:$LHS, node:$RHS)>>;
 512 defm t2LSR  : T2I_sh_ir<"lsr", BinOpFrag<(srl  node:$LHS, node:$RHS)>>;
 513 defm t2ASR  : T2I_sh_ir<"asr", BinOpFrag<(sra  node:$LHS, node:$RHS)>>;
 514 defm t2ROR  : T2I_sh_ir<"ror", BinOpFrag<(rotr node:$LHS, node:$RHS)>>;
 515
 516 def t2MOVrx : T2sI<(outs GPR:$dst), (ins GPR:$src),
 517                    "mov", " $dst, $src, rrx",
 518                    [(set GPR:$dst, (ARMrrx GPR:$src))]>;
 519
 520 //===----------------------------------------------------------------------===//
 521 //  Bitwise Instructions.
 522 //
 523
 524 defm t2AND  : T2I_bin_irs<"and", BinOpFrag<(and node:$LHS, node:$RHS)>, 1>;
 525 defm t2ORR  : T2I_bin_irs<"orr", BinOpFrag<(or  node:$LHS, node:$RHS)>, 1>;
 526 defm t2EOR  : T2I_bin_irs<"eor", BinOpFrag<(xor node:$LHS, node:$RHS)>, 1>;
 527
 528 defm t2BIC  : T2I_bin_irs<"bic", BinOpFrag<(and node:$LHS, (not node:$RHS))>>;
 529
 530 def : T2Pat<(and     GPR:$src, t2_so_imm_not:$imm),
 531             (t2BICri GPR:$src, t2_so_imm_not:$imm)>;
 532
 533 defm t2ORN  : T2I_bin_irs<"orn", BinOpFrag<(or  node:$LHS, (not node:$RHS))>>;
 534
 535 def : T2Pat<(or      GPR:$src, t2_so_imm_not:$imm),
 536             (t2ORNri GPR:$src, t2_so_imm_not:$imm)>;
 537
 538 // Prefer over of t2EORri ra, rb, -1 because mvn has 16-bit version
 539 let AddedComplexity = 1 in
 540 defm t2MVN  : T2I_un_irs  <"mvn", UnOpFrag<(not node:$Src)>, 1, 1>;
 541
 542 def : T2Pat<(t2_so_imm_not:$src),
 543             (t2MVNi t2_so_imm_not:$src)>;
 544
 545 // A8.6.17  BFC - Bitfield clear
 546 // FIXME: Also available in ARM mode.
 547 let Constraints = "$src = $dst" in
 548 def t2BFC : T2I<(outs GPR:$dst), (ins GPR:$src, bf_inv_mask_imm:$imm),
 549                 "bfc", " $dst, $imm",
 550                 [(set GPR:$dst, (and GPR:$src, bf_inv_mask_imm:$imm))]>;
 551
 552 // FIXME: A8.6.18  BFI - Bitfield insert (Encoding T1)
 553
 554 //===----------------------------------------------------------------------===//
 555 //  Multiply Instructions.
 556 //
 557 let isCommutable = 1 in
 558 def t2MUL: T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 559                 "mul", " $dst, $a, $b",
 560                 [(set GPR:$dst, (mul GPR:$a, GPR:$b))]>;
 561
 562 def t2MLA: T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 563                 "mla", " $dst, $a, $b, $c",
 564                 [(set GPR:$dst, (add (mul GPR:$a, GPR:$b), GPR:$c))]>;
 565
 566 def t2MLS: T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 567                 "mls", " $dst, $a, $b, $c",
 568                 [(set GPR:$dst, (sub GPR:$c, (mul GPR:$a, GPR:$b)))]>;
 569
 570 // FIXME: SMULL, etc.
 571
 572 //===----------------------------------------------------------------------===//
 573 //  Misc. Arithmetic Instructions.
 574 //
 575
 576 def t2CLZ : T2I<(outs GPR:$dst), (ins GPR:$src),
 577                 "clz", " $dst, $src",
 578                 [(set GPR:$dst, (ctlz GPR:$src))]>;
 579
 580 def t2REV : T2I<(outs GPR:$dst), (ins GPR:$src),
 581                 "rev", " $dst, $src",
 582                 [(set GPR:$dst, (bswap GPR:$src))]>;
 583
 584 def t2REV16 : T2I<(outs GPR:$dst), (ins GPR:$src),
 585                 "rev16", " $dst, $src",
 586                 [(set GPR:$dst,
 587                     (or (and (srl GPR:$src, (i32 8)), 0xFF),
 588                         (or (and (shl GPR:$src, (i32 8)), 0xFF00),
 589                             (or (and (srl GPR:$src, (i32 8)), 0xFF0000),
 590                                 (and (shl GPR:$src, (i32 8)), 0xFF000000)))))]>;
 591
 592 /////
 593 /// A8.6.137  REVSH
 594 /////
 595 def t2REVSH : T2I<(outs GPR:$dst), (ins GPR:$src),
 596                  "revsh", " $dst, $src",
 597                  [(set GPR:$dst,
 598                     (sext_inreg
 599                       (or (srl (and GPR:$src, 0xFFFF), (i32 8)),
 600                           (shl GPR:$src, (i32 8))), i16))]>;
 601
 602 // FIXME: PKHxx etc.
 603
 604 //===----------------------------------------------------------------------===//
 605 //  Comparison Instructions...
 606 //
 607
 608 defm t2CMP   : T2I_cmp_is<"cmp",
 609                           BinOpFrag<(ARMcmp node:$LHS, node:$RHS)>>;
 610 defm t2CMPz : T2I_cmp_is<"cmp",
 611                          BinOpFrag<(ARMcmpZ node:$LHS, node:$RHS)>>;
 612
 613 defm t2CMN   : T2I_cmp_is<"cmn",
 614                           BinOpFrag<(ARMcmp node:$LHS,(ineg node:$RHS))>>;
 615 defm t2CMNz : T2I_cmp_is<"cmn",
 616                          BinOpFrag<(ARMcmpZ node:$LHS,(ineg node:$RHS))>>;
 617
 618 def : T2Pat<(ARMcmp  GPR:$src, t2_so_imm_neg:$imm),
 619             (t2CMNri GPR:$src, t2_so_imm_neg:$imm)>;
 620
 621 def : T2Pat<(ARMcmpZ  GPR:$src, t2_so_imm_neg:$imm),
 622             (t2CMNri   GPR:$src, t2_so_imm_neg:$imm)>;
 623
 624 // FIXME: TST, TEQ, etc.
 625
 626 // A8.6.27  CBNZ, CBZ - Compare and branch on (non)zero.
 627 // Short range conditional branch. Looks awesome for loops. Need to figure
 628 // out how to use this one.
 629
 630 // FIXME: Conditional moves
 631
 632
 633 //===----------------------------------------------------------------------===//
 634 // Non-Instruction Patterns
 635 //
 636
 637 // ConstantPool, GlobalAddress, and JumpTable
 638 def : T2Pat<(ARMWrapper  tglobaladdr :$dst), (t2LEApcrel tglobaladdr :$dst)>;
 639 def : T2Pat<(ARMWrapper  tconstpool  :$dst), (t2LEApcrel tconstpool  :$dst)>;
 640 def : T2Pat<(ARMWrapperJT tjumptable:$dst, imm:$id),
 641             (t2LEApcrelJT tjumptable:$dst, imm:$id)>;
 642
 643 // Large immediate handling.
 644
 645 def : T2Pat<(i32 imm:$src),
 646             (t2MOVTi16 (t2MOVi16 (t2_lo16 imm:$src)), (t2_hi16 imm:$src))>;