lib/Target/ARM/ARMInstrThumb.td

   1 //===-- ARMInstrThumb.td - Thumb support for ARM -----------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Thumb instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Thumb specific DAG Nodes.
  16 //
  17
  18 def ARMtcall : SDNode<"ARMISD::tCALL", SDT_ARMcall,
  19                       [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
  20                        SDNPVariadic]>;
  21
  22 def imm_sr_XFORM: SDNodeXForm<imm, [{
  23   unsigned Imm = N->getZExtValue();
  24   return CurDAG->getTargetConstant((Imm == 32 ? 0 : Imm), MVT::i32);
  25 }]>;
  26 def ThumbSRImmAsmOperand: AsmOperandClass { let Name = "ImmThumbSR"; }
  27 def imm_sr : Operand<i32>, PatLeaf<(imm), [{
  28   uint64_t Imm = N->getZExtValue();
  29   return Imm > 0 && Imm <= 32;
  30 }], imm_sr_XFORM> {
  31   let PrintMethod = "printThumbSRImm";
  32   let ParserMatchClass = ThumbSRImmAsmOperand;
  33 }
  34
  35 def imm_comp_XFORM : SDNodeXForm<imm, [{
  36   return CurDAG->getTargetConstant(~((uint32_t)N->getZExtValue()), MVT::i32);
  37 }]>;
  38
  39 def imm0_7_neg : PatLeaf<(i32 imm), [{
  40   return (uint32_t)-N->getZExtValue() < 8;
  41 }], imm_neg_XFORM>;
  42
  43 def imm0_255_comp : PatLeaf<(i32 imm), [{
  44   return ~((uint32_t)N->getZExtValue()) < 256;
  45 }]>;
  46
  47 def imm8_255 : ImmLeaf<i32, [{
  48   return Imm >= 8 && Imm < 256;
  49 }]>;
  50 def imm8_255_neg : PatLeaf<(i32 imm), [{
  51   unsigned Val = -N->getZExtValue();
  52   return Val >= 8 && Val < 256;
  53 }], imm_neg_XFORM>;
  54
  55 // Break imm's up into two pieces: an immediate + a left shift. This uses
  56 // thumb_immshifted to match and thumb_immshifted_val and thumb_immshifted_shamt
  57 // to get the val/shift pieces.
  58 def thumb_immshifted : PatLeaf<(imm), [{
  59   return ARM_AM::isThumbImmShiftedVal((unsigned)N->getZExtValue());
  60 }]>;
  61
  62 def thumb_immshifted_val : SDNodeXForm<imm, [{
  63   unsigned V = ARM_AM::getThumbImmNonShiftedVal((unsigned)N->getZExtValue());
  64   return CurDAG->getTargetConstant(V, MVT::i32);
  65 }]>;
  66
  67 def thumb_immshifted_shamt : SDNodeXForm<imm, [{
  68   unsigned V = ARM_AM::getThumbImmValShift((unsigned)N->getZExtValue());
  69   return CurDAG->getTargetConstant(V, MVT::i32);
  70 }]>;
  71
  72 // Scaled 4 immediate.
  73 def t_imm0_1020s4_asmoperand: AsmOperandClass { let Name = "Imm0_1020s4"; }
  74 def t_imm0_1020s4 : Operand<i32> {
  75   let PrintMethod = "printThumbS4ImmOperand";
  76   let ParserMatchClass = t_imm0_1020s4_asmoperand;
  77   let OperandType = "OPERAND_IMMEDIATE";
  78 }
  79
  80 def t_imm0_508s4_asmoperand: AsmOperandClass { let Name = "Imm0_508s4"; }
  81 def t_imm0_508s4 : Operand<i32> {
  82   let PrintMethod = "printThumbS4ImmOperand";
  83   let ParserMatchClass = t_imm0_508s4_asmoperand;
  84   let OperandType = "OPERAND_IMMEDIATE";
  85 }
  86 // Alias use only, so no printer is necessary.
  87 def t_imm0_508s4_neg_asmoperand: AsmOperandClass { let Name = "Imm0_508s4Neg"; }
  88 def t_imm0_508s4_neg : Operand<i32> {
  89   let ParserMatchClass = t_imm0_508s4_neg_asmoperand;
  90   let OperandType = "OPERAND_IMMEDIATE";
  91 }
  92
  93 // Define Thumb specific addressing modes.
  94
  95 // unsigned 8-bit, 2-scaled memory offset
  96 class OperandUnsignedOffset_b8s2 : AsmOperandClass {
  97   let Name = "UnsignedOffset_b8s2";
  98   let PredicateMethod = "isUnsignedOffset<8, 2>";
  99 }
 100
 101 def UnsignedOffset_b8s2 : OperandUnsignedOffset_b8s2;
 102
 103 // thumb style PC relative operand. signed, 8 bits magnitude,
 104 // two bits shift. can be represented as either [pc, #imm], #imm,
 105 // or relocatable expression...
 106 def ThumbMemPC : AsmOperandClass {
 107   let Name = "ThumbMemPC";
 108 }
 109
 110 let OperandType = "OPERAND_PCREL" in {
 111 def t_brtarget : Operand<OtherVT> {
 112   let EncoderMethod = "getThumbBRTargetOpValue";
 113   let DecoderMethod = "DecodeThumbBROperand";
 114 }
 115
 116 // ADR instruction labels.
 117 def t_adrlabel : Operand<i32> {
 118   let EncoderMethod = "getThumbAdrLabelOpValue";
 119   let PrintMethod = "printAdrLabelOperand<2>";
 120   let ParserMatchClass = UnsignedOffset_b8s2;
 121 }
 122
 123 def t_bcctarget : Operand<i32> {
 124   let EncoderMethod = "getThumbBCCTargetOpValue";
 125   let DecoderMethod = "DecodeThumbBCCTargetOperand";
 126 }
 127
 128 def t_cbtarget : Operand<i32> {
 129   let EncoderMethod = "getThumbCBTargetOpValue";
 130   let DecoderMethod = "DecodeThumbCmpBROperand";
 131 }
 132
 133 def t_bltarget : Operand<i32> {
 134   let EncoderMethod = "getThumbBLTargetOpValue";
 135   let DecoderMethod = "DecodeThumbBLTargetOperand";
 136 }
 137
 138 def t_blxtarget : Operand<i32> {
 139   let EncoderMethod = "getThumbBLXTargetOpValue";
 140   let DecoderMethod = "DecodeThumbBLXOffset";
 141 }
 142
 143 // t_addrmode_pc := <label> => pc + imm8 * 4
 144 //
 145 def t_addrmode_pc : Operand<i32> {
 146   let EncoderMethod = "getAddrModePCOpValue";
 147   let DecoderMethod = "DecodeThumbAddrModePC";
 148   let PrintMethod = "printThumbLdrLabelOperand";
 149   let ParserMatchClass = ThumbMemPC;
 150 }
 151 }
 152
 153 // t_addrmode_rr := reg + reg
 154 //
 155 def t_addrmode_rr_asm_operand : AsmOperandClass { let Name = "MemThumbRR"; }
 156 def t_addrmode_rr : Operand<i32>,
 157                     ComplexPattern<i32, 2, "SelectThumbAddrModeRR", []> {
 158   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 159   let PrintMethod = "printThumbAddrModeRROperand";
 160   let DecoderMethod = "DecodeThumbAddrModeRR";
 161   let ParserMatchClass = t_addrmode_rr_asm_operand;
 162   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 163 }
 164
 165 // t_addrmode_rrs := reg + reg
 166 //
 167 // We use separate scaled versions because the Select* functions need
 168 // to explicitly check for a matching constant and return false here so that
 169 // the reg+imm forms will match instead. This is a horrible way to do that,
 170 // as it forces tight coupling between the methods, but it's how selectiondag
 171 // currently works.
 172 def t_addrmode_rrs1 : Operand<i32>,
 173                       ComplexPattern<i32, 2, "SelectThumbAddrModeRI5S1", []> {
 174   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 175   let PrintMethod = "printThumbAddrModeRROperand";
 176   let DecoderMethod = "DecodeThumbAddrModeRR";
 177   let ParserMatchClass = t_addrmode_rr_asm_operand;
 178   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 179 }
 180 def t_addrmode_rrs2 : Operand<i32>,
 181                       ComplexPattern<i32, 2, "SelectThumbAddrModeRI5S2", []> {
 182   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 183   let DecoderMethod = "DecodeThumbAddrModeRR";
 184   let PrintMethod = "printThumbAddrModeRROperand";
 185   let ParserMatchClass = t_addrmode_rr_asm_operand;
 186   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 187 }
 188 def t_addrmode_rrs4 : Operand<i32>,
 189                       ComplexPattern<i32, 2, "SelectThumbAddrModeRI5S4", []> {
 190   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 191   let DecoderMethod = "DecodeThumbAddrModeRR";
 192   let PrintMethod = "printThumbAddrModeRROperand";
 193   let ParserMatchClass = t_addrmode_rr_asm_operand;
 194   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 195 }
 196
 197 // t_addrmode_is4 := reg + imm5 * 4
 198 //
 199 def t_addrmode_is4_asm_operand : AsmOperandClass { let Name = "MemThumbRIs4"; }
 200 def t_addrmode_is4 : Operand<i32>,
 201                      ComplexPattern<i32, 2, "SelectThumbAddrModeImm5S4", []> {
 202   let EncoderMethod = "getAddrModeISOpValue";
 203   let DecoderMethod = "DecodeThumbAddrModeIS";
 204   let PrintMethod = "printThumbAddrModeImm5S4Operand";
 205   let ParserMatchClass = t_addrmode_is4_asm_operand;
 206   let MIOperandInfo = (ops tGPR:$base, i32imm:$offsimm);
 207 }
 208
 209 // t_addrmode_is2 := reg + imm5 * 2
 210 //
 211 def t_addrmode_is2_asm_operand : AsmOperandClass { let Name = "MemThumbRIs2"; }
 212 def t_addrmode_is2 : Operand<i32>,
 213                      ComplexPattern<i32, 2, "SelectThumbAddrModeImm5S2", []> {
 214   let EncoderMethod = "getAddrModeISOpValue";
 215   let DecoderMethod = "DecodeThumbAddrModeIS";
 216   let PrintMethod = "printThumbAddrModeImm5S2Operand";
 217   let ParserMatchClass = t_addrmode_is2_asm_operand;
 218   let MIOperandInfo = (ops tGPR:$base, i32imm:$offsimm);
 219 }
 220
 221 // t_addrmode_is1 := reg + imm5
 222 //
 223 def t_addrmode_is1_asm_operand : AsmOperandClass { let Name = "MemThumbRIs1"; }
 224 def t_addrmode_is1 : Operand<i32>,
 225                      ComplexPattern<i32, 2, "SelectThumbAddrModeImm5S1", []> {
 226   let EncoderMethod = "getAddrModeISOpValue";
 227   let DecoderMethod = "DecodeThumbAddrModeIS";
 228   let PrintMethod = "printThumbAddrModeImm5S1Operand";
 229   let ParserMatchClass = t_addrmode_is1_asm_operand;
 230   let MIOperandInfo = (ops tGPR:$base, i32imm:$offsimm);
 231 }
 232
 233 // t_addrmode_sp := sp + imm8 * 4
 234 //
 235 // FIXME: This really shouldn't have an explicit SP operand at all. It should
 236 // be implicit, just like in the instruction encoding itself.
 237 def t_addrmode_sp_asm_operand : AsmOperandClass { let Name = "MemThumbSPI"; }
 238 def t_addrmode_sp : Operand<i32>,
 239                     ComplexPattern<i32, 2, "SelectThumbAddrModeSP", []> {
 240   let EncoderMethod = "getAddrModeThumbSPOpValue";
 241   let DecoderMethod = "DecodeThumbAddrModeSP";
 242   let PrintMethod = "printThumbAddrModeSPOperand";
 243   let ParserMatchClass = t_addrmode_sp_asm_operand;
 244   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 245 }
 246
 247 //===----------------------------------------------------------------------===//
 248 //  Miscellaneous Instructions.
 249 //
 250
 251 // FIXME: Marking these as hasSideEffects is necessary to prevent machine DCE
 252 // from removing one half of the matched pairs. That breaks PEI, which assumes
 253 // these will always be in pairs, and asserts if it finds otherwise. Better way?
 254 let Defs = [SP], Uses = [SP], hasSideEffects = 1 in {
 255 def tADJCALLSTACKUP :
 256   PseudoInst<(outs), (ins i32imm:$amt1, i32imm:$amt2), NoItinerary,
 257              [(ARMcallseq_end imm:$amt1, imm:$amt2)]>,
 258             Requires<[IsThumb, IsThumb1Only]>;
 259
 260 def tADJCALLSTACKDOWN :
 261   PseudoInst<(outs), (ins i32imm:$amt), NoItinerary,
 262              [(ARMcallseq_start imm:$amt)]>,
 263             Requires<[IsThumb, IsThumb1Only]>;
 264 }
 265
 266 class T1SystemEncoding<bits<8> opc>
 267   : T1Encoding<0b101111> {
 268   let Inst{9-8} = 0b11;
 269   let Inst{7-0} = opc;
 270 }
 271
 272 def tNOP : T1pI<(outs), (ins), NoItinerary, "nop", "", []>,
 273            T1SystemEncoding<0x00>, // A8.6.110
 274         Requires<[IsThumb2]>;
 275
 276 def tYIELD : T1pI<(outs), (ins), NoItinerary, "yield", "", []>,
 277            T1SystemEncoding<0x10>, // A8.6.410
 278            Requires<[IsThumb2]>;
 279
 280 def tWFE : T1pI<(outs), (ins), NoItinerary, "wfe", "", []>,
 281            T1SystemEncoding<0x20>, // A8.6.408
 282            Requires<[IsThumb2]>;
 283
 284 def tWFI : T1pI<(outs), (ins), NoItinerary, "wfi", "", []>,
 285            T1SystemEncoding<0x30>, // A8.6.409
 286            Requires<[IsThumb2]>;
 287
 288 def tSEV : T1pI<(outs), (ins), NoItinerary, "sev", "", []>,
 289            T1SystemEncoding<0x40>, // A8.6.157
 290            Requires<[IsThumb2]>;
 291
 292 // The imm operand $val can be used by a debugger to store more information
 293 // about the breakpoint.
 294 def tBKPT : T1I<(outs), (ins imm0_255:$val), NoItinerary, "bkpt\t$val",
 295                 []>,
 296            T1Encoding<0b101111> {
 297   let Inst{9-8} = 0b10;
 298   // A8.6.22
 299   bits<8> val;
 300   let Inst{7-0} = val;
 301 }
 302
 303 def tSETEND : T1I<(outs), (ins setend_op:$end), NoItinerary, "setend\t$end",
 304                   []>, T1Encoding<0b101101> {
 305   bits<1> end;
 306   // A8.6.156
 307   let Inst{9-5} = 0b10010;
 308   let Inst{4}   = 1;
 309   let Inst{3}   = end;
 310   let Inst{2-0} = 0b000;
 311 }
 312
 313 // Change Processor State is a system instruction -- for disassembly only.
 314 def tCPS : T1I<(outs), (ins imod_op:$imod, iflags_op:$iflags),
 315                 NoItinerary, "cps$imod $iflags", []>,
 316            T1Misc<0b0110011> {
 317   // A8.6.38 & B6.1.1
 318   bit imod;
 319   bits<3> iflags;
 320
 321   let Inst{4}   = imod;
 322   let Inst{3}   = 0;
 323   let Inst{2-0} = iflags;
 324   let DecoderMethod = "DecodeThumbCPS";
 325 }
 326
 327 // For both thumb1 and thumb2.
 328 let isNotDuplicable = 1, isCodeGenOnly = 1 in
 329 def tPICADD : TIt<(outs GPR:$dst), (ins GPR:$lhs, pclabel:$cp), IIC_iALUr, "",
 330                   [(set GPR:$dst, (ARMpic_add GPR:$lhs, imm:$cp))]>,
 331               T1Special<{0,0,?,?}>, Sched<[WriteALU]> {
 332   // A8.6.6
 333   bits<3> dst;
 334   let Inst{6-3} = 0b1111; // Rm = pc
 335   let Inst{2-0} = dst;
 336 }
 337
 338 // ADD <Rd>, sp, #<imm8>
 339 // FIXME: This should not be marked as having side effects, and it should be
 340 // rematerializable. Clearing the side effect bit causes miscompilations,
 341 // probably because the instruction can be moved around.
 342 def tADDrSPi : T1pI<(outs tGPR:$dst), (ins GPRsp:$sp, t_imm0_1020s4:$imm),
 343                     IIC_iALUi, "add", "\t$dst, $sp, $imm", []>,
 344                T1Encoding<{1,0,1,0,1,?}>, Sched<[WriteALU]> {
 345   // A6.2 & A8.6.8
 346   bits<3> dst;
 347   bits<8> imm;
 348   let Inst{10-8} = dst;
 349   let Inst{7-0}  = imm;
 350   let DecoderMethod = "DecodeThumbAddSpecialReg";
 351 }
 352
 353 // ADD sp, sp, #<imm7>
 354 def tADDspi : T1pIt<(outs GPRsp:$Rdn), (ins GPRsp:$Rn, t_imm0_508s4:$imm),
 355                      IIC_iALUi, "add", "\t$Rdn, $imm", []>,
 356               T1Misc<{0,0,0,0,0,?,?}>, Sched<[WriteALU]> {
 357   // A6.2.5 & A8.6.8
 358   bits<7> imm;
 359   let Inst{6-0} = imm;
 360   let DecoderMethod = "DecodeThumbAddSPImm";
 361 }
 362
 363 // SUB sp, sp, #<imm7>
 364 // FIXME: The encoding and the ASM string don't match up.
 365 def tSUBspi : T1pIt<(outs GPRsp:$Rdn), (ins GPRsp:$Rn, t_imm0_508s4:$imm),
 366                     IIC_iALUi, "sub", "\t$Rdn, $imm", []>,
 367               T1Misc<{0,0,0,0,1,?,?}>, Sched<[WriteALU]> {
 368   // A6.2.5 & A8.6.214
 369   bits<7> imm;
 370   let Inst{6-0} = imm;
 371   let DecoderMethod = "DecodeThumbAddSPImm";
 372 }
 373
 374 def : tInstAlias<"add${p} sp, $imm",
 375                  (tSUBspi SP, t_imm0_508s4_neg:$imm, pred:$p)>;
 376 def : tInstAlias<"add${p} sp, sp, $imm",
 377                  (tSUBspi SP, t_imm0_508s4_neg:$imm, pred:$p)>;
 378
 379 // Can optionally specify SP as a three operand instruction.
 380 def : tInstAlias<"add${p} sp, sp, $imm",
 381                  (tADDspi SP, t_imm0_508s4:$imm, pred:$p)>;
 382 def : tInstAlias<"sub${p} sp, sp, $imm",
 383                  (tSUBspi SP, t_imm0_508s4:$imm, pred:$p)>;
 384
 385 // ADD <Rm>, sp
 386 def tADDrSP : T1pI<(outs GPR:$Rdn), (ins GPRsp:$sp, GPR:$Rn), IIC_iALUr,
 387                    "add", "\t$Rdn, $sp, $Rn", []>,
 388               T1Special<{0,0,?,?}>, Sched<[WriteALU]> {
 389   // A8.6.9 Encoding T1
 390   bits<4> Rdn;
 391   let Inst{7}   = Rdn{3};
 392   let Inst{6-3} = 0b1101;
 393   let Inst{2-0} = Rdn{2-0};
 394   let DecoderMethod = "DecodeThumbAddSPReg";
 395 }
 396
 397 // ADD sp, <Rm>
 398 def tADDspr : T1pIt<(outs GPRsp:$Rdn), (ins GPRsp:$Rn, GPR:$Rm), IIC_iALUr,
 399                   "add", "\t$Rdn, $Rm", []>,
 400               T1Special<{0,0,?,?}>, Sched<[WriteALU]> {
 401   // A8.6.9 Encoding T2
 402   bits<4> Rm;
 403   let Inst{7} = 1;
 404   let Inst{6-3} = Rm;
 405   let Inst{2-0} = 0b101;
 406   let DecoderMethod = "DecodeThumbAddSPReg";
 407 }
 408
 409 //===----------------------------------------------------------------------===//
 410 //  Control Flow Instructions.
 411 //
 412
 413 // Indirect branches
 414 let isBranch = 1, isTerminator = 1, isBarrier = 1, isIndirectBranch = 1 in {
 415   def tBX : TI<(outs), (ins GPR:$Rm, pred:$p), IIC_Br, "bx${p}\t$Rm", []>,
 416             T1Special<{1,1,0,?}>, Sched<[WriteBr]> {
 417     // A6.2.3 & A8.6.25
 418     bits<4> Rm;
 419     let Inst{6-3} = Rm;
 420     let Inst{2-0} = 0b000;
 421     let Unpredictable{2-0} = 0b111;
 422   }
 423 }
 424
 425 let isReturn = 1, isTerminator = 1, isBarrier = 1 in {
 426   def tBX_RET : tPseudoExpand<(outs), (ins pred:$p), 2, IIC_Br,
 427                    [(ARMretflag)], (tBX LR, pred:$p)>, Sched<[WriteBr]>;
 428
 429   // Alternative return instruction used by vararg functions.
 430   def tBX_RET_vararg : tPseudoExpand<(outs), (ins tGPR:$Rm, pred:$p),
 431                    2, IIC_Br, [],
 432                    (tBX GPR:$Rm, pred:$p)>, Sched<[WriteBr]>;
 433 }
 434
 435 // All calls clobber the non-callee saved registers. SP is marked as a use to
 436 // prevent stack-pointer assignments that appear immediately before calls from
 437 // potentially appearing dead.
 438 let isCall = 1,
 439   Defs = [LR], Uses = [SP] in {
 440   // Also used for Thumb2
 441   def tBL  : TIx2<0b11110, 0b11, 1,
 442                   (outs), (ins pred:$p, t_bltarget:$func), IIC_Br,
 443                   "bl${p}\t$func",
 444                   [(ARMtcall tglobaladdr:$func)]>,
 445              Requires<[IsThumb]>, Sched<[WriteBrL]> {
 446     bits<24> func;
 447     let Inst{26} = func{23};
 448     let Inst{25-16} = func{20-11};
 449     let Inst{13} = func{22};
 450     let Inst{11} = func{21};
 451     let Inst{10-0} = func{10-0};
 452   }
 453
 454   // ARMv5T and above, also used for Thumb2
 455   def tBLXi : TIx2<0b11110, 0b11, 0,
 456                  (outs), (ins pred:$p, t_blxtarget:$func), IIC_Br,
 457                    "blx${p}\t$func",
 458                    [(ARMcall tglobaladdr:$func)]>,
 459               Requires<[IsThumb, HasV5T]>, Sched<[WriteBrL]> {
 460     bits<24> func;
 461     let Inst{26} = func{23};
 462     let Inst{25-16} = func{20-11};
 463     let Inst{13} = func{22};
 464     let Inst{11} = func{21};
 465     let Inst{10-1} = func{10-1};
 466     let Inst{0} = 0; // func{0} is assumed zero
 467   }
 468
 469   // Also used for Thumb2
 470   def tBLXr : TI<(outs), (ins pred:$p, GPR:$func), IIC_Br,
 471                   "blx${p}\t$func",
 472                   [(ARMtcall GPR:$func)]>,
 473               Requires<[IsThumb, HasV5T]>,
 474               T1Special<{1,1,1,?}>, Sched<[WriteBrL]> { // A6.2.3 & A8.6.24;
 475     bits<4> func;
 476     let Inst{6-3} = func;
 477     let Inst{2-0} = 0b000;
 478   }
 479
 480   // ARMv4T
 481   def tBX_CALL : tPseudoInst<(outs), (ins tGPR:$func),
 482                   4, IIC_Br,
 483                   [(ARMcall_nolink tGPR:$func)]>,
 484             Requires<[IsThumb, IsThumb1Only]>, Sched<[WriteBr]>;
 485 }
 486
 487 let isBranch = 1, isTerminator = 1, isBarrier = 1 in {
 488   let isPredicable = 1 in
 489   def tB   : T1pI<(outs), (ins t_brtarget:$target), IIC_Br,
 490                  "b", "\t$target", [(br bb:$target)]>,
 491              T1Encoding<{1,1,1,0,0,?}>, Sched<[WriteBr]> {
 492     bits<11> target;
 493     let Inst{10-0} = target;
 494     let AsmMatchConverter = "cvtThumbBranches";
 495  }
 496
 497   // Far jump
 498   // Just a pseudo for a tBL instruction. Needed to let regalloc know about
 499   // the clobber of LR.
 500   let Defs = [LR] in
 501   def tBfar : tPseudoExpand<(outs), (ins t_bltarget:$target, pred:$p),
 502                           4, IIC_Br, [], (tBL pred:$p, t_bltarget:$target)>,
 503                           Sched<[WriteBrTbl]>;
 504
 505   def tBR_JTr : tPseudoInst<(outs),
 506                       (ins tGPR:$target, i32imm:$jt, i32imm:$id),
 507                       0, IIC_Br,
 508                       [(ARMbrjt tGPR:$target, tjumptable:$jt, imm:$id)]>,
 509                       Sched<[WriteBrTbl]> {
 510     list<Predicate> Predicates = [IsThumb, IsThumb1Only];
 511   }
 512 }
 513
 514 // FIXME: should be able to write a pattern for ARMBrcond, but can't use
 515 // a two-value operand where a dag node expects two operands. :(
 516 let isBranch = 1, isTerminator = 1 in
 517   def tBcc : T1I<(outs), (ins t_bcctarget:$target, pred:$p), IIC_Br,
 518                  "b${p}\t$target",
 519                  [/*(ARMbrcond bb:$target, imm:$cc)*/]>,
 520              T1BranchCond<{1,1,0,1}>, Sched<[WriteBr]> {
 521   bits<4> p;
 522   bits<8> target;
 523   let Inst{11-8} = p;
 524   let Inst{7-0} = target;
 525   let AsmMatchConverter = "cvtThumbBranches";
 526 }
 527
 528
 529 // Tail calls
 530 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1 in {
 531   // IOS versions.
 532   let Uses = [SP] in {
 533     def tTAILJMPr : tPseudoExpand<(outs), (ins tcGPR:$dst),
 534                      4, IIC_Br, [],
 535                      (tBX GPR:$dst, (ops 14, zero_reg))>,
 536                      Requires<[IsThumb]>, Sched<[WriteBr]>;
 537   }
 538   // tTAILJMPd: IOS version uses a Thumb2 branch (no Thumb1 tail calls
 539   // on IOS), so it's in ARMInstrThumb2.td.
 540   // Non-IOS version:
 541   let Uses = [SP] in {
 542     def tTAILJMPdND : tPseudoExpand<(outs),
 543                    (ins t_brtarget:$dst, pred:$p),
 544                    4, IIC_Br, [],
 545                    (tB t_brtarget:$dst, pred:$p)>,
 546                  Requires<[IsThumb, IsNotIOS]>, Sched<[WriteBr]>;
 547   }
 548 }
 549
 550
 551 // A8.6.218 Supervisor Call (Software Interrupt)
 552 // A8.6.16 B: Encoding T1
 553 // If Inst{11-8} == 0b1111 then SEE SVC
 554 let isCall = 1, Uses = [SP] in
 555 def tSVC : T1pI<(outs), (ins imm0_255:$imm), IIC_Br,
 556                 "svc", "\t$imm", []>, Encoding16, Sched<[WriteBr]> {
 557   bits<8> imm;
 558   let Inst{15-12} = 0b1101;
 559   let Inst{11-8}  = 0b1111;
 560   let Inst{7-0}   = imm;
 561 }
 562
 563 // The assembler uses 0xDEFE for a trap instruction.
 564 let isBarrier = 1, isTerminator = 1 in
 565 def tTRAP : TI<(outs), (ins), IIC_Br,
 566                "trap", [(trap)]>, Encoding16, Sched<[WriteBr]> {
 567   let Inst = 0xdefe;
 568 }
 569
 570 //===----------------------------------------------------------------------===//
 571 //  Load Store Instructions.
 572 //
 573
 574 // Loads: reg/reg and reg/imm5
 575 let canFoldAsLoad = 1, isReMaterializable = 1 in
 576 multiclass thumb_ld_rr_ri_enc<bits<3> reg_opc, bits<4> imm_opc,
 577                               Operand AddrMode_r, Operand AddrMode_i,
 578                               AddrMode am, InstrItinClass itin_r,
 579                               InstrItinClass itin_i, string asm,
 580                               PatFrag opnode> {
 581   def r : // reg/reg
 582     T1pILdStEncode<reg_opc,
 583                    (outs tGPR:$Rt), (ins AddrMode_r:$addr),
 584                    am, itin_r, asm, "\t$Rt, $addr",
 585                    [(set tGPR:$Rt, (opnode AddrMode_r:$addr))]>;
 586   def i : // reg/imm5
 587     T1pILdStEncodeImm<imm_opc, 1 /* Load */,
 588                       (outs tGPR:$Rt), (ins AddrMode_i:$addr),
 589                       am, itin_i, asm, "\t$Rt, $addr",
 590                       [(set tGPR:$Rt, (opnode AddrMode_i:$addr))]>;
 591 }
 592 // Stores: reg/reg and reg/imm5
 593 multiclass thumb_st_rr_ri_enc<bits<3> reg_opc, bits<4> imm_opc,
 594                               Operand AddrMode_r, Operand AddrMode_i,
 595                               AddrMode am, InstrItinClass itin_r,
 596                               InstrItinClass itin_i, string asm,
 597                               PatFrag opnode> {
 598   def r : // reg/reg
 599     T1pILdStEncode<reg_opc,
 600                    (outs), (ins tGPR:$Rt, AddrMode_r:$addr),
 601                    am, itin_r, asm, "\t$Rt, $addr",
 602                    [(opnode tGPR:$Rt, AddrMode_r:$addr)]>;
 603   def i : // reg/imm5
 604     T1pILdStEncodeImm<imm_opc, 0 /* Store */,
 605                       (outs), (ins tGPR:$Rt, AddrMode_i:$addr),
 606                       am, itin_i, asm, "\t$Rt, $addr",
 607                       [(opnode tGPR:$Rt, AddrMode_i:$addr)]>;
 608 }
 609
 610 // A8.6.57 & A8.6.60
 611 defm tLDR  : thumb_ld_rr_ri_enc<0b100, 0b0110, t_addrmode_rrs4,
 612                                 t_addrmode_is4, AddrModeT1_4,
 613                                 IIC_iLoad_r, IIC_iLoad_i, "ldr",
 614                                 UnOpFrag<(load node:$Src)>>;
 615
 616 // A8.6.64 & A8.6.61
 617 defm tLDRB : thumb_ld_rr_ri_enc<0b110, 0b0111, t_addrmode_rrs1,
 618                                 t_addrmode_is1, AddrModeT1_1,
 619                                 IIC_iLoad_bh_r, IIC_iLoad_bh_i, "ldrb",
 620                                 UnOpFrag<(zextloadi8 node:$Src)>>;
 621
 622 // A8.6.76 & A8.6.73
 623 defm tLDRH : thumb_ld_rr_ri_enc<0b101, 0b1000, t_addrmode_rrs2,
 624                                 t_addrmode_is2, AddrModeT1_2,
 625                                 IIC_iLoad_bh_r, IIC_iLoad_bh_i, "ldrh",
 626                                 UnOpFrag<(zextloadi16 node:$Src)>>;
 627
 628 let AddedComplexity = 10 in
 629 def tLDRSB :                    // A8.6.80
 630   T1pILdStEncode<0b011, (outs tGPR:$Rt), (ins t_addrmode_rr:$addr),
 631                  AddrModeT1_1, IIC_iLoad_bh_r,
 632                  "ldrsb", "\t$Rt, $addr",
 633                  [(set tGPR:$Rt, (sextloadi8 t_addrmode_rr:$addr))]>;
 634
 635 let AddedComplexity = 10 in
 636 def tLDRSH :                    // A8.6.84
 637   T1pILdStEncode<0b111, (outs tGPR:$Rt), (ins t_addrmode_rr:$addr),
 638                  AddrModeT1_2, IIC_iLoad_bh_r,
 639                  "ldrsh", "\t$Rt, $addr",
 640                  [(set tGPR:$Rt, (sextloadi16 t_addrmode_rr:$addr))]>;
 641
 642 let canFoldAsLoad = 1 in
 643 def tLDRspi : T1pIs<(outs tGPR:$Rt), (ins t_addrmode_sp:$addr), IIC_iLoad_i,
 644                     "ldr", "\t$Rt, $addr",
 645                     [(set tGPR:$Rt, (load t_addrmode_sp:$addr))]>,
 646               T1LdStSP<{1,?,?}> {
 647   bits<3> Rt;
 648   bits<8> addr;
 649   let Inst{10-8} = Rt;
 650   let Inst{7-0} = addr;
 651 }
 652
 653 let canFoldAsLoad = 1, isReMaterializable = 1 in
 654 def tLDRpci : T1pIs<(outs tGPR:$Rt), (ins t_addrmode_pc:$addr), IIC_iLoad_i,
 655                   "ldr", "\t$Rt, $addr",
 656                   [(set tGPR:$Rt, (load (ARMWrapper tconstpool:$addr)))]>,
 657               T1Encoding<{0,1,0,0,1,?}> {
 658   // A6.2 & A8.6.59
 659   bits<3> Rt;
 660   bits<8> addr;
 661   let Inst{10-8} = Rt;
 662   let Inst{7-0}  = addr;
 663 }
 664
 665 def : tInstAlias<"ldr${p}.n $Rt, $addr",
 666                  (tLDRpci tGPR:$Rt, t_addrmode_pc:$addr, pred:$p), 0>;
 667
 668 // A8.6.194 & A8.6.192
 669 defm tSTR  : thumb_st_rr_ri_enc<0b000, 0b0110, t_addrmode_rrs4,
 670                                 t_addrmode_is4, AddrModeT1_4,
 671                                 IIC_iStore_r, IIC_iStore_i, "str",
 672                                 BinOpFrag<(store node:$LHS, node:$RHS)>>;
 673
 674 // A8.6.197 & A8.6.195
 675 defm tSTRB : thumb_st_rr_ri_enc<0b010, 0b0111, t_addrmode_rrs1,
 676                                 t_addrmode_is1, AddrModeT1_1,
 677                                 IIC_iStore_bh_r, IIC_iStore_bh_i, "strb",
 678                                 BinOpFrag<(truncstorei8 node:$LHS, node:$RHS)>>;
 679
 680 // A8.6.207 & A8.6.205
 681 defm tSTRH : thumb_st_rr_ri_enc<0b001, 0b1000, t_addrmode_rrs2,
 682                                t_addrmode_is2, AddrModeT1_2,
 683                                IIC_iStore_bh_r, IIC_iStore_bh_i, "strh",
 684                                BinOpFrag<(truncstorei16 node:$LHS, node:$RHS)>>;
 685
 686
 687 def tSTRspi : T1pIs<(outs), (ins tGPR:$Rt, t_addrmode_sp:$addr), IIC_iStore_i,
 688                     "str", "\t$Rt, $addr",
 689                     [(store tGPR:$Rt, t_addrmode_sp:$addr)]>,
 690               T1LdStSP<{0,?,?}> {
 691   bits<3> Rt;
 692   bits<8> addr;
 693   let Inst{10-8} = Rt;
 694   let Inst{7-0} = addr;
 695 }
 696
 697 //===----------------------------------------------------------------------===//
 698 //  Load / store multiple Instructions.
 699 //
 700
 701 // These require base address to be written back or one of the loaded regs.
 702 let neverHasSideEffects = 1 in {
 703
 704 let mayLoad = 1, hasExtraDefRegAllocReq = 1 in
 705 def tLDMIA : T1I<(outs), (ins tGPR:$Rn, pred:$p, reglist:$regs, variable_ops),
 706         IIC_iLoad_m, "ldm${p}\t$Rn, $regs", []>, T1Encoding<{1,1,0,0,1,?}> {
 707   bits<3> Rn;
 708   bits<8> regs;
 709   let Inst{10-8} = Rn;
 710   let Inst{7-0}  = regs;
 711 }
 712
 713 // Writeback version is just a pseudo, as there's no encoding difference.
 714 // Writeback happens iff the base register is not in the destination register
 715 // list.
 716 def tLDMIA_UPD :
 717     InstTemplate<AddrModeNone, 0, IndexModeNone, Pseudo, GenericDomain,
 718                  "$Rn = $wb", IIC_iLoad_mu>,
 719     PseudoInstExpansion<(tLDMIA tGPR:$Rn, pred:$p, reglist:$regs)> {
 720   let Size = 2;
 721   let OutOperandList = (outs GPR:$wb);
 722   let InOperandList = (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops);
 723   let Pattern = [];
 724   let isCodeGenOnly = 1;
 725   let isPseudo = 1;
 726   list<Predicate> Predicates = [IsThumb];
 727 }
 728
 729 // There is no non-writeback version of STM for Thumb.
 730 let mayStore = 1, hasExtraSrcRegAllocReq = 1 in
 731 def tSTMIA_UPD : Thumb1I<(outs GPR:$wb),
 732                          (ins tGPR:$Rn, pred:$p, reglist:$regs, variable_ops),
 733                          AddrModeNone, 2, IIC_iStore_mu,
 734                          "stm${p}\t$Rn!, $regs", "$Rn = $wb", []>,
 735                      T1Encoding<{1,1,0,0,0,?}> {
 736   bits<3> Rn;
 737   bits<8> regs;
 738   let Inst{10-8} = Rn;
 739   let Inst{7-0}  = regs;
 740 }
 741
 742 } // neverHasSideEffects
 743
 744 def : InstAlias<"ldm${p} $Rn!, $regs",
 745                 (tLDMIA tGPR:$Rn, pred:$p, reglist:$regs)>,
 746         Requires<[IsThumb, IsThumb1Only]>;
 747
 748 let mayLoad = 1, Uses = [SP], Defs = [SP], hasExtraDefRegAllocReq = 1 in
 749 def tPOP : T1I<(outs), (ins pred:$p, reglist:$regs, variable_ops),
 750                IIC_iPop,
 751                "pop${p}\t$regs", []>,
 752            T1Misc<{1,1,0,?,?,?,?}> {
 753   bits<16> regs;
 754   let Inst{8}   = regs{15};
 755   let Inst{7-0} = regs{7-0};
 756 }
 757
 758 let mayStore = 1, Uses = [SP], Defs = [SP], hasExtraSrcRegAllocReq = 1 in
 759 def tPUSH : T1I<(outs), (ins pred:$p, reglist:$regs, variable_ops),
 760                 IIC_iStore_m,
 761                 "push${p}\t$regs", []>,
 762             T1Misc<{0,1,0,?,?,?,?}> {
 763   bits<16> regs;
 764   let Inst{8}   = regs{14};
 765   let Inst{7-0} = regs{7-0};
 766 }
 767
 768 //===----------------------------------------------------------------------===//
 769 //  Arithmetic Instructions.
 770 //
 771
 772 // Helper classes for encoding T1pI patterns:
 773 class T1pIDPEncode<bits<4> opA, dag oops, dag iops, InstrItinClass itin,
 774                    string opc, string asm, list<dag> pattern>
 775     : T1pI<oops, iops, itin, opc, asm, pattern>,
 776       T1DataProcessing<opA> {
 777   bits<3> Rm;
 778   bits<3> Rn;
 779   let Inst{5-3} = Rm;
 780   let Inst{2-0} = Rn;
 781 }
 782 class T1pIMiscEncode<bits<7> opA, dag oops, dag iops, InstrItinClass itin,
 783                      string opc, string asm, list<dag> pattern>
 784     : T1pI<oops, iops, itin, opc, asm, pattern>,
 785       T1Misc<opA> {
 786   bits<3> Rm;
 787   bits<3> Rd;
 788   let Inst{5-3} = Rm;
 789   let Inst{2-0} = Rd;
 790 }
 791
 792 // Helper classes for encoding T1sI patterns:
 793 class T1sIDPEncode<bits<4> opA, dag oops, dag iops, InstrItinClass itin,
 794                    string opc, string asm, list<dag> pattern>
 795     : T1sI<oops, iops, itin, opc, asm, pattern>,
 796       T1DataProcessing<opA> {
 797   bits<3> Rd;
 798   bits<3> Rn;
 799   let Inst{5-3} = Rn;
 800   let Inst{2-0} = Rd;
 801 }
 802 class T1sIGenEncode<bits<5> opA, dag oops, dag iops, InstrItinClass itin,
 803                     string opc, string asm, list<dag> pattern>
 804     : T1sI<oops, iops, itin, opc, asm, pattern>,
 805       T1General<opA> {
 806   bits<3> Rm;
 807   bits<3> Rn;
 808   bits<3> Rd;
 809   let Inst{8-6} = Rm;
 810   let Inst{5-3} = Rn;
 811   let Inst{2-0} = Rd;
 812 }
 813 class T1sIGenEncodeImm<bits<5> opA, dag oops, dag iops, InstrItinClass itin,
 814                        string opc, string asm, list<dag> pattern>
 815     : T1sI<oops, iops, itin, opc, asm, pattern>,
 816       T1General<opA> {
 817   bits<3> Rd;
 818   bits<3> Rm;
 819   let Inst{5-3} = Rm;
 820   let Inst{2-0} = Rd;
 821 }
 822
 823 // Helper classes for encoding T1sIt patterns:
 824 class T1sItDPEncode<bits<4> opA, dag oops, dag iops, InstrItinClass itin,
 825                     string opc, string asm, list<dag> pattern>
 826     : T1sIt<oops, iops, itin, opc, asm, pattern>,
 827       T1DataProcessing<opA> {
 828   bits<3> Rdn;
 829   bits<3> Rm;
 830   let Inst{5-3} = Rm;
 831   let Inst{2-0} = Rdn;
 832 }
 833 class T1sItGenEncodeImm<bits<5> opA, dag oops, dag iops, InstrItinClass itin,
 834                         string opc, string asm, list<dag> pattern>
 835     : T1sIt<oops, iops, itin, opc, asm, pattern>,
 836       T1General<opA> {
 837   bits<3> Rdn;
 838   bits<8> imm8;
 839   let Inst{10-8} = Rdn;
 840   let Inst{7-0}  = imm8;
 841 }
 842
 843 // Add with carry register
 844 let isCommutable = 1, Uses = [CPSR] in
 845 def tADC :                      // A8.6.2
 846   T1sItDPEncode<0b0101, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm), IIC_iALUr,
 847                 "adc", "\t$Rdn, $Rm",
 848                 [(set tGPR:$Rdn, (adde tGPR:$Rn, tGPR:$Rm))]>, Sched<[WriteALU]>;
 849
 850 // Add immediate
 851 def tADDi3 :                    // A8.6.4 T1
 852   T1sIGenEncodeImm<0b01110, (outs tGPR:$Rd), (ins tGPR:$Rm, imm0_7:$imm3),
 853                    IIC_iALUi,
 854                    "add", "\t$Rd, $Rm, $imm3",
 855                    [(set tGPR:$Rd, (add tGPR:$Rm, imm0_7:$imm3))]>,
 856                    Sched<[WriteALU]> {
 857   bits<3> imm3;
 858   let Inst{8-6} = imm3;
 859 }
 860
 861 def tADDi8 :                    // A8.6.4 T2
 862   T1sItGenEncodeImm<{1,1,0,?,?}, (outs tGPR:$Rdn),
 863                     (ins tGPR:$Rn, imm0_255:$imm8), IIC_iALUi,
 864                     "add", "\t$Rdn, $imm8",
 865                     [(set tGPR:$Rdn, (add tGPR:$Rn, imm8_255:$imm8))]>,
 866                     Sched<[WriteALU]>;
 867
 868 // Add register
 869 let isCommutable = 1 in
 870 def tADDrr :                    // A8.6.6 T1
 871   T1sIGenEncode<0b01100, (outs tGPR:$Rd), (ins tGPR:$Rn, tGPR:$Rm),
 872                 IIC_iALUr,
 873                 "add", "\t$Rd, $Rn, $Rm",
 874                 [(set tGPR:$Rd, (add tGPR:$Rn, tGPR:$Rm))]>, Sched<[WriteALU]>;
 875
 876 let neverHasSideEffects = 1 in
 877 def tADDhirr : T1pIt<(outs GPR:$Rdn), (ins GPR:$Rn, GPR:$Rm), IIC_iALUr,
 878                      "add", "\t$Rdn, $Rm", []>,
 879                T1Special<{0,0,?,?}>, Sched<[WriteALU]> {
 880   // A8.6.6 T2
 881   bits<4> Rdn;
 882   bits<4> Rm;
 883   let Inst{7}   = Rdn{3};
 884   let Inst{6-3} = Rm;
 885   let Inst{2-0} = Rdn{2-0};
 886 }
 887
 888 // AND register
 889 let isCommutable = 1 in
 890 def tAND :                      // A8.6.12
 891   T1sItDPEncode<0b0000, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 892                 IIC_iBITr,
 893                 "and", "\t$Rdn, $Rm",
 894                 [(set tGPR:$Rdn, (and tGPR:$Rn, tGPR:$Rm))]>, Sched<[WriteALU]>;
 895
 896 // ASR immediate
 897 def tASRri :                    // A8.6.14
 898   T1sIGenEncodeImm<{0,1,0,?,?}, (outs tGPR:$Rd), (ins tGPR:$Rm, imm_sr:$imm5),
 899                    IIC_iMOVsi,
 900                    "asr", "\t$Rd, $Rm, $imm5",
 901                    [(set tGPR:$Rd, (sra tGPR:$Rm, (i32 imm_sr:$imm5)))]>,
 902                    Sched<[WriteALU]> {
 903   bits<5> imm5;
 904   let Inst{10-6} = imm5;
 905 }
 906
 907 // ASR register
 908 def tASRrr :                    // A8.6.15
 909   T1sItDPEncode<0b0100, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 910                 IIC_iMOVsr,
 911                 "asr", "\t$Rdn, $Rm",
 912                 [(set tGPR:$Rdn, (sra tGPR:$Rn, tGPR:$Rm))]>, Sched<[WriteALU]>;
 913
 914 // BIC register
 915 def tBIC :                      // A8.6.20
 916   T1sItDPEncode<0b1110, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 917                 IIC_iBITr,
 918                 "bic", "\t$Rdn, $Rm",
 919                 [(set tGPR:$Rdn, (and tGPR:$Rn, (not tGPR:$Rm)))]>,
 920                 Sched<[WriteALU]>;
 921
 922 // CMN register
 923 let isCompare = 1, Defs = [CPSR] in {
 924 //FIXME: Disable CMN, as CCodes are backwards from compare expectations
 925 //       Compare-to-zero still works out, just not the relationals
 926 //def tCMN :                     // A8.6.33
 927 //  T1pIDPEncode<0b1011, (outs), (ins tGPR:$lhs, tGPR:$rhs),
 928 //               IIC_iCMPr,
 929 //               "cmn", "\t$lhs, $rhs",
 930 //               [(ARMcmp tGPR:$lhs, (ineg tGPR:$rhs))]>;
 931
 932 def tCMNz :                     // A8.6.33
 933   T1pIDPEncode<0b1011, (outs), (ins tGPR:$Rn, tGPR:$Rm),
 934                IIC_iCMPr,
 935                "cmn", "\t$Rn, $Rm",
 936                [(ARMcmpZ tGPR:$Rn, (ineg tGPR:$Rm))]>, Sched<[WriteCMP]>;
 937
 938 } // isCompare = 1, Defs = [CPSR]
 939
 940 // CMP immediate
 941 let isCompare = 1, Defs = [CPSR] in {
 942 def tCMPi8 : T1pI<(outs), (ins tGPR:$Rn, imm0_255:$imm8), IIC_iCMPi,
 943                   "cmp", "\t$Rn, $imm8",
 944                   [(ARMcmp tGPR:$Rn, imm0_255:$imm8)]>,
 945              T1General<{1,0,1,?,?}>, Sched<[WriteCMP]> {
 946   // A8.6.35
 947   bits<3> Rn;
 948   bits<8> imm8;
 949   let Inst{10-8} = Rn;
 950   let Inst{7-0}  = imm8;
 951 }
 952
 953 // CMP register
 954 def tCMPr :                     // A8.6.36 T1
 955   T1pIDPEncode<0b1010, (outs), (ins tGPR:$Rn, tGPR:$Rm),
 956                IIC_iCMPr,
 957                "cmp", "\t$Rn, $Rm",
 958                [(ARMcmp tGPR:$Rn, tGPR:$Rm)]>, Sched<[WriteCMP]>;
 959
 960 def tCMPhir : T1pI<(outs), (ins GPR:$Rn, GPR:$Rm), IIC_iCMPr,
 961                    "cmp", "\t$Rn, $Rm", []>,
 962               T1Special<{0,1,?,?}>, Sched<[WriteCMP]> {
 963   // A8.6.36 T2
 964   bits<4> Rm;
 965   bits<4> Rn;
 966   let Inst{7}   = Rn{3};
 967   let Inst{6-3} = Rm;
 968   let Inst{2-0} = Rn{2-0};
 969 }
 970 } // isCompare = 1, Defs = [CPSR]
 971
 972
 973 // XOR register
 974 let isCommutable = 1 in
 975 def tEOR :                      // A8.6.45
 976   T1sItDPEncode<0b0001, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 977                 IIC_iBITr,
 978                 "eor", "\t$Rdn, $Rm",
 979                 [(set tGPR:$Rdn, (xor tGPR:$Rn, tGPR:$Rm))]>, Sched<[WriteALU]>;
 980
 981 // LSL immediate
 982 def tLSLri :                    // A8.6.88
 983   T1sIGenEncodeImm<{0,0,0,?,?}, (outs tGPR:$Rd), (ins tGPR:$Rm, imm0_31:$imm5),
 984                    IIC_iMOVsi,
 985                    "lsl", "\t$Rd, $Rm, $imm5",
 986                    [(set tGPR:$Rd, (shl tGPR:$Rm, (i32 imm:$imm5)))]>,
 987                    Sched<[WriteALU]> {
 988   bits<5> imm5;
 989   let Inst{10-6} = imm5;
 990 }
 991
 992 // LSL register
 993 def tLSLrr :                    // A8.6.89
 994   T1sItDPEncode<0b0010, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 995                 IIC_iMOVsr,
 996                 "lsl", "\t$Rdn, $Rm",
 997                 [(set tGPR:$Rdn, (shl tGPR:$Rn, tGPR:$Rm))]>, Sched<[WriteALU]>;
 998
 999 // LSR immediate
1000 def tLSRri :                    // A8.6.90
1001   T1sIGenEncodeImm<{0,0,1,?,?}, (outs tGPR:$Rd), (ins tGPR:$Rm, imm_sr:$imm5),
1002                    IIC_iMOVsi,
1003                    "lsr", "\t$Rd, $Rm, $imm5",
1004                    [(set tGPR:$Rd, (srl tGPR:$Rm, (i32 imm_sr:$imm5)))]>,
1005                    Sched<[WriteALU]> {
1006   bits<5> imm5;
1007   let Inst{10-6} = imm5;
1008 }
1009
1010 // LSR register
1011 def tLSRrr :                    // A8.6.91
1012   T1sItDPEncode<0b0011, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1013                 IIC_iMOVsr,
1014                 "lsr", "\t$Rdn, $Rm",
1015                 [(set tGPR:$Rdn, (srl tGPR:$Rn, tGPR:$Rm))]>, Sched<[WriteALU]>;
1016
1017 // Move register
1018 let isMoveImm = 1 in
1019 def tMOVi8 : T1sI<(outs tGPR:$Rd), (ins imm0_255:$imm8), IIC_iMOVi,
1020                   "mov", "\t$Rd, $imm8",
1021                   [(set tGPR:$Rd, imm0_255:$imm8)]>,
1022              T1General<{1,0,0,?,?}>, Sched<[WriteALU]> {
1023   // A8.6.96
1024   bits<3> Rd;
1025   bits<8> imm8;
1026   let Inst{10-8} = Rd;
1027   let Inst{7-0}  = imm8;
1028 }
1029 // Because we have an explicit tMOVSr below, we need an alias to handle
1030 // the immediate "movs" form here. Blech.
1031 def : tInstAlias <"movs $Rdn, $imm",
1032                  (tMOVi8 tGPR:$Rdn, CPSR, imm0_255:$imm, 14, 0)>;
1033
1034 // A7-73: MOV(2) - mov setting flag.
1035
1036 let neverHasSideEffects = 1 in {
1037 def tMOVr : Thumb1pI<(outs GPR:$Rd), (ins GPR:$Rm), AddrModeNone,
1038                       2, IIC_iMOVr,
1039                       "mov", "\t$Rd, $Rm", "", []>,
1040                   T1Special<{1,0,?,?}>, Sched<[WriteALU]> {
1041   // A8.6.97
1042   bits<4> Rd;
1043   bits<4> Rm;
1044   let Inst{7}   = Rd{3};
1045   let Inst{6-3} = Rm;
1046   let Inst{2-0} = Rd{2-0};
1047 }
1048 let Defs = [CPSR] in
1049 def tMOVSr      : T1I<(outs tGPR:$Rd), (ins tGPR:$Rm), IIC_iMOVr,
1050                       "movs\t$Rd, $Rm", []>, Encoding16, Sched<[WriteALU]> {
1051   // A8.6.97
1052   bits<3> Rd;
1053   bits<3> Rm;
1054   let Inst{15-6} = 0b0000000000;
1055   let Inst{5-3}  = Rm;
1056   let Inst{2-0}  = Rd;
1057 }
1058 } // neverHasSideEffects
1059
1060 // Multiply register
1061 let isCommutable = 1 in
1062 def tMUL :                      // A8.6.105 T1
1063   Thumb1sI<(outs tGPR:$Rd), (ins tGPR:$Rn, tGPR:$Rm), AddrModeNone, 2,
1064            IIC_iMUL32, "mul", "\t$Rd, $Rn, $Rm", "$Rm = $Rd",
1065            [(set tGPR:$Rd, (mul tGPR:$Rn, tGPR:$Rm))]>,
1066       T1DataProcessing<0b1101> {
1067   bits<3> Rd;
1068   bits<3> Rn;
1069   let Inst{5-3} = Rn;
1070   let Inst{2-0} = Rd;
1071   let AsmMatchConverter = "cvtThumbMultiply";
1072 }
1073
1074 def :tInstAlias<"mul${s}${p} $Rdm, $Rn", (tMUL tGPR:$Rdm, s_cc_out:$s, tGPR:$Rn,
1075                                                pred:$p)>;
1076
1077 // Move inverse register
1078 def tMVN :                      // A8.6.107
1079   T1sIDPEncode<0b1111, (outs tGPR:$Rd), (ins tGPR:$Rn), IIC_iMVNr,
1080                "mvn", "\t$Rd, $Rn",
1081                [(set tGPR:$Rd, (not tGPR:$Rn))]>, Sched<[WriteALU]>;
1082
1083 // Bitwise or register
1084 let isCommutable = 1 in
1085 def tORR :                      // A8.6.114
1086   T1sItDPEncode<0b1100, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1087                 IIC_iBITr,
1088                 "orr", "\t$Rdn, $Rm",
1089                 [(set tGPR:$Rdn, (or tGPR:$Rn, tGPR:$Rm))]>, Sched<[WriteALU]>;
1090
1091 // Swaps
1092 def tREV :                      // A8.6.134
1093   T1pIMiscEncode<{1,0,1,0,0,0,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1094                  IIC_iUNAr,
1095                  "rev", "\t$Rd, $Rm",
1096                  [(set tGPR:$Rd, (bswap tGPR:$Rm))]>,
1097                  Requires<[IsThumb, IsThumb1Only, HasV6]>, Sched<[WriteALU]>;
1098
1099 def tREV16 :                    // A8.6.135
1100   T1pIMiscEncode<{1,0,1,0,0,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1101                  IIC_iUNAr,
1102                  "rev16", "\t$Rd, $Rm",
1103              [(set tGPR:$Rd, (rotr (bswap tGPR:$Rm), (i32 16)))]>,
1104                 Requires<[IsThumb, IsThumb1Only, HasV6]>, Sched<[WriteALU]>;
1105
1106 def tREVSH :                    // A8.6.136
1107   T1pIMiscEncode<{1,0,1,0,1,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1108                  IIC_iUNAr,
1109                  "revsh", "\t$Rd, $Rm",
1110                  [(set tGPR:$Rd, (sra (bswap tGPR:$Rm), (i32 16)))]>,
1111                  Requires<[IsThumb, IsThumb1Only, HasV6]>, Sched<[WriteALU]>;
1112
1113 // Rotate right register
1114 def tROR :                      // A8.6.139
1115   T1sItDPEncode<0b0111, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1116                 IIC_iMOVsr,
1117                 "ror", "\t$Rdn, $Rm",
1118                 [(set tGPR:$Rdn, (rotr tGPR:$Rn, tGPR:$Rm))]>,
1119                 Sched<[WriteALU]>;
1120
1121 // Negate register
1122 def tRSB :                      // A8.6.141
1123   T1sIDPEncode<0b1001, (outs tGPR:$Rd), (ins tGPR:$Rn),
1124                IIC_iALUi,
1125                "rsb", "\t$Rd, $Rn, #0",
1126                [(set tGPR:$Rd, (ineg tGPR:$Rn))]>, Sched<[WriteALU]>;
1127
1128 // Subtract with carry register
1129 let Uses = [CPSR] in
1130 def tSBC :                      // A8.6.151
1131   T1sItDPEncode<0b0110, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1132                 IIC_iALUr,
1133                 "sbc", "\t$Rdn, $Rm",
1134                 [(set tGPR:$Rdn, (sube tGPR:$Rn, tGPR:$Rm))]>,
1135                 Sched<[WriteALU]>;
1136
1137 // Subtract immediate
1138 def tSUBi3 :                    // A8.6.210 T1
1139   T1sIGenEncodeImm<0b01111, (outs tGPR:$Rd), (ins tGPR:$Rm, imm0_7:$imm3),
1140                    IIC_iALUi,
1141                    "sub", "\t$Rd, $Rm, $imm3",
1142                    [(set tGPR:$Rd, (add tGPR:$Rm, imm0_7_neg:$imm3))]>,
1143                    Sched<[WriteALU]> {
1144   bits<3> imm3;
1145   let Inst{8-6} = imm3;
1146 }
1147
1148 def tSUBi8 :                    // A8.6.210 T2
1149   T1sItGenEncodeImm<{1,1,1,?,?}, (outs tGPR:$Rdn),
1150                     (ins tGPR:$Rn, imm0_255:$imm8), IIC_iALUi,
1151                     "sub", "\t$Rdn, $imm8",
1152                     [(set tGPR:$Rdn, (add tGPR:$Rn, imm8_255_neg:$imm8))]>,
1153                     Sched<[WriteALU]>;
1154
1155 // Subtract register
1156 def tSUBrr :                    // A8.6.212
1157   T1sIGenEncode<0b01101, (outs tGPR:$Rd), (ins tGPR:$Rn, tGPR:$Rm),
1158                 IIC_iALUr,
1159                 "sub", "\t$Rd, $Rn, $Rm",
1160                 [(set tGPR:$Rd, (sub tGPR:$Rn, tGPR:$Rm))]>,
1161                 Sched<[WriteALU]>;
1162
1163 // Sign-extend byte
1164 def tSXTB :                     // A8.6.222
1165   T1pIMiscEncode<{0,0,1,0,0,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1166                  IIC_iUNAr,
1167                  "sxtb", "\t$Rd, $Rm",
1168                  [(set tGPR:$Rd, (sext_inreg tGPR:$Rm, i8))]>,
1169                  Requires<[IsThumb, IsThumb1Only, HasV6]>,
1170                  Sched<[WriteALU]>;
1171
1172 // Sign-extend short
1173 def tSXTH :                     // A8.6.224
1174   T1pIMiscEncode<{0,0,1,0,0,0,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1175                  IIC_iUNAr,
1176                  "sxth", "\t$Rd, $Rm",
1177                  [(set tGPR:$Rd, (sext_inreg tGPR:$Rm, i16))]>,
1178                  Requires<[IsThumb, IsThumb1Only, HasV6]>,
1179                  Sched<[WriteALU]>;
1180
1181 // Test
1182 let isCompare = 1, isCommutable = 1, Defs = [CPSR] in
1183 def tTST :                      // A8.6.230
1184   T1pIDPEncode<0b1000, (outs), (ins tGPR:$Rn, tGPR:$Rm), IIC_iTSTr,
1185                "tst", "\t$Rn, $Rm",
1186                [(ARMcmpZ (and_su tGPR:$Rn, tGPR:$Rm), 0)]>,
1187                Sched<[WriteALU]>;
1188
1189 // Zero-extend byte
1190 def tUXTB :                     // A8.6.262
1191   T1pIMiscEncode<{0,0,1,0,1,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1192                  IIC_iUNAr,
1193                  "uxtb", "\t$Rd, $Rm",
1194                  [(set tGPR:$Rd, (and tGPR:$Rm, 0xFF))]>,
1195                  Requires<[IsThumb, IsThumb1Only, HasV6]>,
1196                  Sched<[WriteALU]>;
1197
1198 // Zero-extend short
1199 def tUXTH :                     // A8.6.264
1200   T1pIMiscEncode<{0,0,1,0,1,0,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1201                  IIC_iUNAr,
1202                  "uxth", "\t$Rd, $Rm",
1203                  [(set tGPR:$Rd, (and tGPR:$Rm, 0xFFFF))]>,
1204                  Requires<[IsThumb, IsThumb1Only, HasV6]>, Sched<[WriteALU]>;
1205
1206 // Conditional move tMOVCCr - Used to implement the Thumb SELECT_CC operation.
1207 // Expanded after instruction selection into a branch sequence.
1208 let usesCustomInserter = 1 in  // Expanded after instruction selection.
1209   def tMOVCCr_pseudo :
1210   PseudoInst<(outs tGPR:$dst), (ins tGPR:$false, tGPR:$true, pred:$cc),
1211               NoItinerary,
1212              [/*(set tGPR:$dst, (ARMcmov tGPR:$false, tGPR:$true, imm:$cc))*/]>;
1213
1214 // tLEApcrel - Load a pc-relative address into a register without offending the
1215 // assembler.
1216
1217 def tADR : T1I<(outs tGPR:$Rd), (ins t_adrlabel:$addr, pred:$p),
1218                IIC_iALUi, "adr{$p}\t$Rd, $addr", []>,
1219                T1Encoding<{1,0,1,0,0,?}>, Sched<[WriteALU]> {
1220   bits<3> Rd;
1221   bits<8> addr;
1222   let Inst{10-8} = Rd;
1223   let Inst{7-0} = addr;
1224   let DecoderMethod = "DecodeThumbAddSpecialReg";
1225 }
1226
1227 let neverHasSideEffects = 1, isReMaterializable = 1 in
1228 def tLEApcrel   : tPseudoInst<(outs tGPR:$Rd), (ins i32imm:$label, pred:$p),
1229                               2, IIC_iALUi, []>, Sched<[WriteALU]>;
1230
1231 let hasSideEffects = 1 in
1232 def tLEApcrelJT : tPseudoInst<(outs tGPR:$Rd),
1233                               (ins i32imm:$label, nohash_imm:$id, pred:$p),
1234                               2, IIC_iALUi, []>, Sched<[WriteALU]>;
1235
1236 //===----------------------------------------------------------------------===//
1237 // TLS Instructions
1238 //
1239
1240 // __aeabi_read_tp preserves the registers r1-r3.
1241 // This is a pseudo inst so that we can get the encoding right,
1242 // complete with fixup for the aeabi_read_tp function.
1243 let isCall = 1, Defs = [R0, R12, LR, CPSR], Uses = [SP] in
1244 def tTPsoft : tPseudoInst<(outs), (ins), 4, IIC_Br,
1245                           [(set R0, ARMthread_pointer)]>,
1246                           Sched<[WriteBr]>;
1247
1248 //===----------------------------------------------------------------------===//
1249 // SJLJ Exception handling intrinsics
1250 //
1251
1252 // eh_sjlj_setjmp() is an instruction sequence to store the return address and
1253 // save #0 in R0 for the non-longjmp case.  Since by its nature we may be coming
1254 // from some other function to get here, and we're using the stack frame for the
1255 // containing function to save/restore registers, we can't keep anything live in
1256 // regs across the eh_sjlj_setjmp(), else it will almost certainly have been
1257 // tromped upon when we get here from a longjmp(). We force everything out of
1258 // registers except for our own input by listing the relevant registers in
1259 // Defs. By doing so, we also cause the prologue/epilogue code to actively
1260 // preserve all of the callee-saved resgisters, which is exactly what we want.
1261 // $val is a scratch register for our use.
1262 let Defs = [ R0,  R1,  R2,  R3,  R4,  R5,  R6,  R7, R12, CPSR ],
1263     hasSideEffects = 1, isBarrier = 1, isCodeGenOnly = 1,
1264     usesCustomInserter = 1 in
1265 def tInt_eh_sjlj_setjmp : ThumbXI<(outs),(ins tGPR:$src, tGPR:$val),
1266                                   AddrModeNone, 0, NoItinerary, "","",
1267                           [(set R0, (ARMeh_sjlj_setjmp tGPR:$src, tGPR:$val))]>;
1268
1269 // FIXME: Non-IOS version(s)
1270 let isBarrier = 1, hasSideEffects = 1, isTerminator = 1, isCodeGenOnly = 1,
1271     Defs = [ R7, LR, SP ] in
1272 def tInt_eh_sjlj_longjmp : XI<(outs), (ins GPR:$src, GPR:$scratch),
1273                               AddrModeNone, 0, IndexModeNone,
1274                               Pseudo, NoItinerary, "", "",
1275                               [(ARMeh_sjlj_longjmp GPR:$src, GPR:$scratch)]>,
1276                              Requires<[IsThumb, IsIOS]>;
1277
1278 //===----------------------------------------------------------------------===//
1279 // Non-Instruction Patterns
1280 //
1281
1282 // Comparisons
1283 def : T1Pat<(ARMcmpZ tGPR:$Rn, imm0_255:$imm8),
1284             (tCMPi8  tGPR:$Rn, imm0_255:$imm8)>;
1285 def : T1Pat<(ARMcmpZ tGPR:$Rn, tGPR:$Rm),
1286             (tCMPr   tGPR:$Rn, tGPR:$Rm)>;
1287
1288 // Add with carry
1289 def : T1Pat<(addc   tGPR:$lhs, imm0_7:$rhs),
1290             (tADDi3 tGPR:$lhs, imm0_7:$rhs)>;
1291 def : T1Pat<(addc   tGPR:$lhs, imm8_255:$rhs),
1292             (tADDi8 tGPR:$lhs, imm8_255:$rhs)>;
1293 def : T1Pat<(addc   tGPR:$lhs, tGPR:$rhs),
1294             (tADDrr tGPR:$lhs, tGPR:$rhs)>;
1295
1296 // Subtract with carry
1297 def : T1Pat<(addc   tGPR:$lhs, imm0_7_neg:$rhs),
1298             (tSUBi3 tGPR:$lhs, imm0_7_neg:$rhs)>;
1299 def : T1Pat<(addc   tGPR:$lhs, imm8_255_neg:$rhs),
1300             (tSUBi8 tGPR:$lhs, imm8_255_neg:$rhs)>;
1301 def : T1Pat<(subc   tGPR:$lhs, tGPR:$rhs),
1302             (tSUBrr tGPR:$lhs, tGPR:$rhs)>;
1303
1304 // ConstantPool, GlobalAddress
1305 def : T1Pat<(ARMWrapper  tglobaladdr :$dst), (tLEApcrel tglobaladdr :$dst)>;
1306 def : T1Pat<(ARMWrapper  tconstpool  :$dst), (tLEApcrel tconstpool  :$dst)>;
1307
1308 // JumpTable
1309 def : T1Pat<(ARMWrapperJT tjumptable:$dst, imm:$id),
1310             (tLEApcrelJT tjumptable:$dst, imm:$id)>;
1311
1312 // Direct calls
1313 def : T1Pat<(ARMtcall texternalsym:$func), (tBL texternalsym:$func)>,
1314       Requires<[IsThumb]>;
1315
1316 def : Tv5Pat<(ARMcall texternalsym:$func), (tBLXi texternalsym:$func)>,
1317       Requires<[IsThumb, HasV5T]>;
1318
1319 // Indirect calls to ARM routines
1320 def : Tv5Pat<(ARMcall GPR:$dst), (tBLXr GPR:$dst)>,
1321       Requires<[IsThumb, HasV5T]>;
1322
1323 // zextload i1 -> zextload i8
1324 def : T1Pat<(zextloadi1 t_addrmode_rrs1:$addr),
1325             (tLDRBr t_addrmode_rrs1:$addr)>;
1326 def : T1Pat<(zextloadi1 t_addrmode_is1:$addr),
1327             (tLDRBi t_addrmode_is1:$addr)>;
1328
1329 // extload -> zextload
1330 def : T1Pat<(extloadi1  t_addrmode_rrs1:$addr), (tLDRBr t_addrmode_rrs1:$addr)>;
1331 def : T1Pat<(extloadi1  t_addrmode_is1:$addr),  (tLDRBi t_addrmode_is1:$addr)>;
1332 def : T1Pat<(extloadi8  t_addrmode_rrs1:$addr), (tLDRBr t_addrmode_rrs1:$addr)>;
1333 def : T1Pat<(extloadi8  t_addrmode_is1:$addr),  (tLDRBi t_addrmode_is1:$addr)>;
1334 def : T1Pat<(extloadi16 t_addrmode_rrs2:$addr), (tLDRHr t_addrmode_rrs2:$addr)>;
1335 def : T1Pat<(extloadi16 t_addrmode_is2:$addr),  (tLDRHi t_addrmode_is2:$addr)>;
1336
1337 // If it's impossible to use [r,r] address mode for sextload, select to
1338 // ldr{b|h} + sxt{b|h} instead.
1339 def : T1Pat<(sextloadi8 t_addrmode_is1:$addr),
1340             (tSXTB (tLDRBi t_addrmode_is1:$addr))>,
1341       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1342 def : T1Pat<(sextloadi8 t_addrmode_rrs1:$addr),
1343             (tSXTB (tLDRBr t_addrmode_rrs1:$addr))>,
1344       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1345 def : T1Pat<(sextloadi16 t_addrmode_is2:$addr),
1346             (tSXTH (tLDRHi t_addrmode_is2:$addr))>,
1347       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1348 def : T1Pat<(sextloadi16 t_addrmode_rrs2:$addr),
1349             (tSXTH (tLDRHr t_addrmode_rrs2:$addr))>,
1350       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1351
1352 def : T1Pat<(sextloadi8 t_addrmode_rrs1:$addr),
1353             (tASRri (tLSLri (tLDRBr t_addrmode_rrs1:$addr), 24), 24)>;
1354 def : T1Pat<(sextloadi8 t_addrmode_is1:$addr),
1355             (tASRri (tLSLri (tLDRBi t_addrmode_is1:$addr), 24), 24)>;
1356 def : T1Pat<(sextloadi16 t_addrmode_rrs2:$addr),
1357             (tASRri (tLSLri (tLDRHr t_addrmode_rrs2:$addr), 16), 16)>;
1358 def : T1Pat<(sextloadi16 t_addrmode_is2:$addr),
1359             (tASRri (tLSLri (tLDRHi t_addrmode_is2:$addr), 16), 16)>;
1360
1361 def : T1Pat<(atomic_load_8 t_addrmode_is1:$src),
1362              (tLDRBi t_addrmode_is1:$src)>;
1363 def : T1Pat<(atomic_load_8 t_addrmode_rrs1:$src),
1364              (tLDRBr t_addrmode_rrs1:$src)>;
1365 def : T1Pat<(atomic_load_16 t_addrmode_is2:$src),
1366              (tLDRHi t_addrmode_is2:$src)>;
1367 def : T1Pat<(atomic_load_16 t_addrmode_rrs2:$src),
1368              (tLDRHr t_addrmode_rrs2:$src)>;
1369 def : T1Pat<(atomic_load_32 t_addrmode_is4:$src),
1370              (tLDRi t_addrmode_is4:$src)>;
1371 def : T1Pat<(atomic_load_32 t_addrmode_rrs4:$src),
1372              (tLDRr t_addrmode_rrs4:$src)>;
1373 def : T1Pat<(atomic_store_8 t_addrmode_is1:$ptr, tGPR:$val),
1374              (tSTRBi tGPR:$val, t_addrmode_is1:$ptr)>;
1375 def : T1Pat<(atomic_store_8 t_addrmode_rrs1:$ptr, tGPR:$val),
1376              (tSTRBr tGPR:$val, t_addrmode_rrs1:$ptr)>;
1377 def : T1Pat<(atomic_store_16 t_addrmode_is2:$ptr, tGPR:$val),
1378              (tSTRHi tGPR:$val, t_addrmode_is2:$ptr)>;
1379 def : T1Pat<(atomic_store_16 t_addrmode_rrs2:$ptr, tGPR:$val),
1380              (tSTRHr tGPR:$val, t_addrmode_rrs2:$ptr)>;
1381 def : T1Pat<(atomic_store_32 t_addrmode_is4:$ptr, tGPR:$val),
1382              (tSTRi tGPR:$val, t_addrmode_is4:$ptr)>;
1383 def : T1Pat<(atomic_store_32 t_addrmode_rrs4:$ptr, tGPR:$val),
1384              (tSTRr tGPR:$val, t_addrmode_rrs4:$ptr)>;
1385
1386 // Large immediate handling.
1387
1388 // Two piece imms.
1389 def : T1Pat<(i32 thumb_immshifted:$src),
1390             (tLSLri (tMOVi8 (thumb_immshifted_val imm:$src)),
1391                     (thumb_immshifted_shamt imm:$src))>;
1392
1393 def : T1Pat<(i32 imm0_255_comp:$src),
1394             (tMVN (tMOVi8 (imm_comp_XFORM imm:$src)))>;
1395
1396 // Pseudo instruction that combines ldr from constpool and add pc. This should
1397 // be expanded into two instructions late to allow if-conversion and
1398 // scheduling.
1399 let isReMaterializable = 1 in
1400 def tLDRpci_pic : PseudoInst<(outs GPR:$dst), (ins i32imm:$addr, pclabel:$cp),
1401                              NoItinerary,
1402                [(set GPR:$dst, (ARMpic_add (load (ARMWrapper tconstpool:$addr)),
1403                                            imm:$cp))]>,
1404                Requires<[IsThumb, IsThumb1Only]>;
1405
1406 // Pseudo-instruction for merged POP and return.
1407 // FIXME: remove when we have a way to marking a MI with these properties.
1408 let isReturn = 1, isTerminator = 1, isBarrier = 1, mayLoad = 1,
1409     hasExtraDefRegAllocReq = 1 in
1410 def tPOP_RET : tPseudoExpand<(outs), (ins pred:$p, reglist:$regs, variable_ops),
1411                            2, IIC_iPop_Br, [],
1412                            (tPOP pred:$p, reglist:$regs)>, Sched<[WriteBrL]>;
1413
1414 // Indirect branch using "mov pc, $Rm"
1415 let isBranch = 1, isTerminator = 1, isBarrier = 1, isIndirectBranch = 1 in {
1416   def tBRIND : tPseudoExpand<(outs), (ins GPR:$Rm, pred:$p),
1417                   2, IIC_Br, [(brind GPR:$Rm)],
1418                   (tMOVr PC, GPR:$Rm, pred:$p)>, Sched<[WriteBr]>;
1419 }
1420
1421
1422 // In Thumb1, "nop" is encoded as a "mov r8, r8". Technically, the bf00
1423 // encoding is available on ARMv6K, but we don't differentiate that finely.
1424 def : InstAlias<"nop", (tMOVr R8, R8, 14, 0)>,Requires<[IsThumb, IsThumb1Only]>;
1425
1426
1427 // For round-trip assembly/disassembly, we have to handle a CPS instruction
1428 // without any iflags. That's not, strictly speaking, valid syntax, but it's
1429 // a useful extension and assembles to defined behaviour (the insn does
1430 // nothing).
1431 def : tInstAlias<"cps$imod", (tCPS imod_op:$imod, 0)>;
1432 def : tInstAlias<"cps$imod", (tCPS imod_op:$imod, 0)>;
1433
1434 // "neg" is and alias for "rsb rd, rn, #0"
1435 def : tInstAlias<"neg${s}${p} $Rd, $Rm",
1436                  (tRSB tGPR:$Rd, s_cc_out:$s, tGPR:$Rm, pred:$p)>;
1437
1438
1439 // Implied destination operand forms for shifts.
1440 def : tInstAlias<"lsl${s}${p} $Rdm, $imm",
1441              (tLSLri tGPR:$Rdm, cc_out:$s, tGPR:$Rdm, imm0_31:$imm, pred:$p)>;
1442 def : tInstAlias<"lsr${s}${p} $Rdm, $imm",
1443              (tLSRri tGPR:$Rdm, cc_out:$s, tGPR:$Rdm, imm_sr:$imm, pred:$p)>;
1444 def : tInstAlias<"asr${s}${p} $Rdm, $imm",
1445              (tASRri tGPR:$Rdm, cc_out:$s, tGPR:$Rdm, imm_sr:$imm, pred:$p)>;