lib/Target/ARM/ARMInstrThumb.td

   1 //===- ARMInstrThumb.td - Thumb support for ARM ------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Thumb instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Thumb specific DAG Nodes.
  16 //
  17
  18 def ARMtcall : SDNode<"ARMISD::tCALL", SDT_ARMcall,
  19                       [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
  20                        SDNPVariadic]>;
  21
  22 def imm_sr_XFORM: SDNodeXForm<imm, [{
  23   unsigned Imm = N->getZExtValue();
  24   return CurDAG->getTargetConstant((Imm == 32 ? 0 : Imm), MVT::i32);
  25 }]>;
  26 def ThumbSRImmAsmOperand: AsmOperandClass { let Name = "ImmThumbSR"; }
  27 def imm_sr : Operand<i32>, PatLeaf<(imm), [{
  28   uint64_t Imm = N->getZExtValue();
  29   return Imm > 0 && Imm <= 32;
  30 }], imm_sr_XFORM> {
  31   let PrintMethod = "printThumbSRImm";
  32   let ParserMatchClass = ThumbSRImmAsmOperand;
  33 }
  34
  35 def imm_neg_XFORM : SDNodeXForm<imm, [{
  36   return CurDAG->getTargetConstant(-(int)N->getZExtValue(), MVT::i32);
  37 }]>;
  38 def imm_comp_XFORM : SDNodeXForm<imm, [{
  39   return CurDAG->getTargetConstant(~((uint32_t)N->getZExtValue()), MVT::i32);
  40 }]>;
  41
  42 def imm0_7_neg : PatLeaf<(i32 imm), [{
  43   return (uint32_t)-N->getZExtValue() < 8;
  44 }], imm_neg_XFORM>;
  45
  46 def imm0_255_comp : PatLeaf<(i32 imm), [{
  47   return ~((uint32_t)N->getZExtValue()) < 256;
  48 }]>;
  49
  50 def imm8_255 : ImmLeaf<i32, [{
  51   return Imm >= 8 && Imm < 256;
  52 }]>;
  53 def imm8_255_neg : PatLeaf<(i32 imm), [{
  54   unsigned Val = -N->getZExtValue();
  55   return Val >= 8 && Val < 256;
  56 }], imm_neg_XFORM>;
  57
  58 // Break imm's up into two pieces: an immediate + a left shift. This uses
  59 // thumb_immshifted to match and thumb_immshifted_val and thumb_immshifted_shamt
  60 // to get the val/shift pieces.
  61 def thumb_immshifted : PatLeaf<(imm), [{
  62   return ARM_AM::isThumbImmShiftedVal((unsigned)N->getZExtValue());
  63 }]>;
  64
  65 def thumb_immshifted_val : SDNodeXForm<imm, [{
  66   unsigned V = ARM_AM::getThumbImmNonShiftedVal((unsigned)N->getZExtValue());
  67   return CurDAG->getTargetConstant(V, MVT::i32);
  68 }]>;
  69
  70 def thumb_immshifted_shamt : SDNodeXForm<imm, [{
  71   unsigned V = ARM_AM::getThumbImmValShift((unsigned)N->getZExtValue());
  72   return CurDAG->getTargetConstant(V, MVT::i32);
  73 }]>;
  74
  75 // ADR instruction labels.
  76 def t_adrlabel : Operand<i32> {
  77   let EncoderMethod = "getThumbAdrLabelOpValue";
  78 }
  79
  80 // Scaled 4 immediate.
  81 def t_imm0_1020s4_asmoperand: AsmOperandClass { let Name = "Imm0_1020s4"; }
  82 def t_imm0_1020s4 : Operand<i32> {
  83   let PrintMethod = "printThumbS4ImmOperand";
  84   let ParserMatchClass = t_imm0_1020s4_asmoperand;
  85   let OperandType = "OPERAND_IMMEDIATE";
  86 }
  87
  88 def t_imm0_508s4_asmoperand: AsmOperandClass { let Name = "Imm0_508s4"; }
  89 def t_imm0_508s4 : Operand<i32> {
  90   let PrintMethod = "printThumbS4ImmOperand";
  91   let ParserMatchClass = t_imm0_508s4_asmoperand;
  92   let OperandType = "OPERAND_IMMEDIATE";
  93 }
  94
  95 // Define Thumb specific addressing modes.
  96
  97 let OperandType = "OPERAND_PCREL" in {
  98 def t_brtarget : Operand<OtherVT> {
  99   let EncoderMethod = "getThumbBRTargetOpValue";
 100   let DecoderMethod = "DecodeThumbBROperand";
 101 }
 102
 103 def t_bcctarget : Operand<i32> {
 104   let EncoderMethod = "getThumbBCCTargetOpValue";
 105   let DecoderMethod = "DecodeThumbBCCTargetOperand";
 106 }
 107
 108 def t_cbtarget : Operand<i32> {
 109   let EncoderMethod = "getThumbCBTargetOpValue";
 110   let DecoderMethod = "DecodeThumbCmpBROperand";
 111 }
 112
 113 def t_bltarget : Operand<i32> {
 114   let EncoderMethod = "getThumbBLTargetOpValue";
 115   let DecoderMethod = "DecodeThumbBLTargetOperand";
 116 }
 117
 118 def t_blxtarget : Operand<i32> {
 119   let EncoderMethod = "getThumbBLXTargetOpValue";
 120   let DecoderMethod = "DecodeThumbBLXOffset";
 121 }
 122 }
 123
 124 // t_addrmode_rr := reg + reg
 125 //
 126 def t_addrmode_rr_asm_operand : AsmOperandClass { let Name = "MemThumbRR"; }
 127 def t_addrmode_rr : Operand<i32>,
 128                     ComplexPattern<i32, 2, "SelectThumbAddrModeRR", []> {
 129   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 130   let PrintMethod = "printThumbAddrModeRROperand";
 131   let DecoderMethod = "DecodeThumbAddrModeRR";
 132   let ParserMatchClass = t_addrmode_rr_asm_operand;
 133   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 134 }
 135
 136 // t_addrmode_rrs := reg + reg
 137 //
 138 // We use separate scaled versions because the Select* functions need
 139 // to explicitly check for a matching constant and return false here so that
 140 // the reg+imm forms will match instead. This is a horrible way to do that,
 141 // as it forces tight coupling between the methods, but it's how selectiondag
 142 // currently works.
 143 def t_addrmode_rrs1 : Operand<i32>,
 144                       ComplexPattern<i32, 2, "SelectThumbAddrModeRI5S1", []> {
 145   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 146   let PrintMethod = "printThumbAddrModeRROperand";
 147   let DecoderMethod = "DecodeThumbAddrModeRR";
 148   let ParserMatchClass = t_addrmode_rr_asm_operand;
 149   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 150 }
 151 def t_addrmode_rrs2 : Operand<i32>,
 152                       ComplexPattern<i32, 2, "SelectThumbAddrModeRI5S2", []> {
 153   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 154   let DecoderMethod = "DecodeThumbAddrModeRR";
 155   let PrintMethod = "printThumbAddrModeRROperand";
 156   let ParserMatchClass = t_addrmode_rr_asm_operand;
 157   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 158 }
 159 def t_addrmode_rrs4 : Operand<i32>,
 160                       ComplexPattern<i32, 2, "SelectThumbAddrModeRI5S4", []> {
 161   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 162   let DecoderMethod = "DecodeThumbAddrModeRR";
 163   let PrintMethod = "printThumbAddrModeRROperand";
 164   let ParserMatchClass = t_addrmode_rr_asm_operand;
 165   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 166 }
 167
 168 // t_addrmode_is4 := reg + imm5 * 4
 169 //
 170 def t_addrmode_is4_asm_operand : AsmOperandClass { let Name = "MemThumbRIs4"; }
 171 def t_addrmode_is4 : Operand<i32>,
 172                      ComplexPattern<i32, 2, "SelectThumbAddrModeImm5S4", []> {
 173   let EncoderMethod = "getAddrModeISOpValue";
 174   let DecoderMethod = "DecodeThumbAddrModeIS";
 175   let PrintMethod = "printThumbAddrModeImm5S4Operand";
 176   let ParserMatchClass = t_addrmode_is4_asm_operand;
 177   let MIOperandInfo = (ops tGPR:$base, i32imm:$offsimm);
 178 }
 179
 180 // t_addrmode_is2 := reg + imm5 * 2
 181 //
 182 def t_addrmode_is2_asm_operand : AsmOperandClass { let Name = "MemThumbRIs2"; }
 183 def t_addrmode_is2 : Operand<i32>,
 184                      ComplexPattern<i32, 2, "SelectThumbAddrModeImm5S2", []> {
 185   let EncoderMethod = "getAddrModeISOpValue";
 186   let DecoderMethod = "DecodeThumbAddrModeIS";
 187   let PrintMethod = "printThumbAddrModeImm5S2Operand";
 188   let ParserMatchClass = t_addrmode_is2_asm_operand;
 189   let MIOperandInfo = (ops tGPR:$base, i32imm:$offsimm);
 190 }
 191
 192 // t_addrmode_is1 := reg + imm5
 193 //
 194 def t_addrmode_is1_asm_operand : AsmOperandClass { let Name = "MemThumbRIs1"; }
 195 def t_addrmode_is1 : Operand<i32>,
 196                      ComplexPattern<i32, 2, "SelectThumbAddrModeImm5S1", []> {
 197   let EncoderMethod = "getAddrModeISOpValue";
 198   let DecoderMethod = "DecodeThumbAddrModeIS";
 199   let PrintMethod = "printThumbAddrModeImm5S1Operand";
 200   let ParserMatchClass = t_addrmode_is1_asm_operand;
 201   let MIOperandInfo = (ops tGPR:$base, i32imm:$offsimm);
 202 }
 203
 204 // t_addrmode_sp := sp + imm8 * 4
 205 //
 206 // FIXME: This really shouldn't have an explicit SP operand at all. It should
 207 // be implicit, just like in the instruction encoding itself.
 208 def t_addrmode_sp_asm_operand : AsmOperandClass { let Name = "MemThumbSPI"; }
 209 def t_addrmode_sp : Operand<i32>,
 210                     ComplexPattern<i32, 2, "SelectThumbAddrModeSP", []> {
 211   let EncoderMethod = "getAddrModeThumbSPOpValue";
 212   let DecoderMethod = "DecodeThumbAddrModeSP";
 213   let PrintMethod = "printThumbAddrModeSPOperand";
 214   let ParserMatchClass = t_addrmode_sp_asm_operand;
 215   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 216 }
 217
 218 // t_addrmode_pc := <label> => pc + imm8 * 4
 219 //
 220 def t_addrmode_pc : Operand<i32> {
 221   let EncoderMethod = "getAddrModePCOpValue";
 222   let DecoderMethod = "DecodeThumbAddrModePC";
 223 }
 224
 225 //===----------------------------------------------------------------------===//
 226 //  Miscellaneous Instructions.
 227 //
 228
 229 // FIXME: Marking these as hasSideEffects is necessary to prevent machine DCE
 230 // from removing one half of the matched pairs. That breaks PEI, which assumes
 231 // these will always be in pairs, and asserts if it finds otherwise. Better way?
 232 let Defs = [SP], Uses = [SP], hasSideEffects = 1 in {
 233 def tADJCALLSTACKUP :
 234   PseudoInst<(outs), (ins i32imm:$amt1, i32imm:$amt2), NoItinerary,
 235              [(ARMcallseq_end imm:$amt1, imm:$amt2)]>,
 236             Requires<[IsThumb, IsThumb1Only]>;
 237
 238 def tADJCALLSTACKDOWN :
 239   PseudoInst<(outs), (ins i32imm:$amt), NoItinerary,
 240              [(ARMcallseq_start imm:$amt)]>,
 241             Requires<[IsThumb, IsThumb1Only]>;
 242 }
 243
 244 class T1SystemEncoding<bits<8> opc>
 245   : T1Encoding<0b101111> {
 246   let Inst{9-8} = 0b11;
 247   let Inst{7-0} = opc;
 248 }
 249
 250 def tNOP : T1pI<(outs), (ins), NoItinerary, "nop", "", []>,
 251            T1SystemEncoding<0x00>, // A8.6.110
 252         Requires<[IsThumb2]>;
 253
 254 def tYIELD : T1pI<(outs), (ins), NoItinerary, "yield", "", []>,
 255            T1SystemEncoding<0x10>; // A8.6.410
 256
 257 def tWFE : T1pI<(outs), (ins), NoItinerary, "wfe", "", []>,
 258            T1SystemEncoding<0x20>; // A8.6.408
 259
 260 def tWFI : T1pI<(outs), (ins), NoItinerary, "wfi", "", []>,
 261            T1SystemEncoding<0x30>; // A8.6.409
 262
 263 def tSEV : T1pI<(outs), (ins), NoItinerary, "sev", "", []>,
 264            T1SystemEncoding<0x40>; // A8.6.157
 265
 266 // The imm operand $val can be used by a debugger to store more information
 267 // about the breakpoint.
 268 def tBKPT : T1I<(outs), (ins imm0_255:$val), NoItinerary, "bkpt\t$val",
 269                 []>,
 270            T1Encoding<0b101111> {
 271   let Inst{9-8} = 0b10;
 272   // A8.6.22
 273   bits<8> val;
 274   let Inst{7-0} = val;
 275 }
 276
 277 def tSETEND : T1I<(outs), (ins setend_op:$end), NoItinerary, "setend\t$end",
 278                   []>, T1Encoding<0b101101> {
 279   bits<1> end;
 280   // A8.6.156
 281   let Inst{9-5} = 0b10010;
 282   let Inst{4}   = 1;
 283   let Inst{3}   = end;
 284   let Inst{2-0} = 0b000;
 285 }
 286
 287 // Change Processor State is a system instruction -- for disassembly only.
 288 def tCPS : T1I<(outs), (ins imod_op:$imod, iflags_op:$iflags),
 289                 NoItinerary, "cps$imod $iflags",
 290                 [/* For disassembly only; pattern left blank */]>,
 291            T1Misc<0b0110011> {
 292   // A8.6.38 & B6.1.1
 293   bit imod;
 294   bits<3> iflags;
 295
 296   let Inst{4}   = imod;
 297   let Inst{3}   = 0;
 298   let Inst{2-0} = iflags;
 299   let DecoderMethod = "DecodeThumbCPS";
 300 }
 301
 302 // For both thumb1 and thumb2.
 303 let isNotDuplicable = 1, isCodeGenOnly = 1 in
 304 def tPICADD : TIt<(outs GPR:$dst), (ins GPR:$lhs, pclabel:$cp), IIC_iALUr, "",
 305                   [(set GPR:$dst, (ARMpic_add GPR:$lhs, imm:$cp))]>,
 306               T1Special<{0,0,?,?}> {
 307   // A8.6.6
 308   bits<3> dst;
 309   let Inst{6-3} = 0b1111; // Rm = pc
 310   let Inst{2-0} = dst;
 311 }
 312
 313 // ADD <Rd>, sp, #<imm8>
 314 // This is rematerializable, which is particularly useful for taking the
 315 // address of locals.
 316 let isReMaterializable = 1 in
 317 def tADDrSPi : T1pI<(outs tGPR:$dst), (ins GPRsp:$sp, t_imm0_1020s4:$imm),
 318                     IIC_iALUi, "add", "\t$dst, $sp, $imm", []>,
 319                T1Encoding<{1,0,1,0,1,?}> {
 320   // A6.2 & A8.6.8
 321   bits<3> dst;
 322   bits<8> imm;
 323   let Inst{10-8} = dst;
 324   let Inst{7-0}  = imm;
 325   let DecoderMethod = "DecodeThumbAddSpecialReg";
 326 }
 327
 328 // ADD sp, sp, #<imm7>
 329 def tADDspi : T1pIt<(outs GPRsp:$Rdn), (ins GPRsp:$Rn, t_imm0_508s4:$imm),
 330                      IIC_iALUi, "add", "\t$Rdn, $imm", []>,
 331               T1Misc<{0,0,0,0,0,?,?}> {
 332   // A6.2.5 & A8.6.8
 333   bits<7> imm;
 334   let Inst{6-0} = imm;
 335   let DecoderMethod = "DecodeThumbAddSPImm";
 336 }
 337
 338 // SUB sp, sp, #<imm7>
 339 // FIXME: The encoding and the ASM string don't match up.
 340 def tSUBspi : T1pIt<(outs GPRsp:$Rdn), (ins GPRsp:$Rn, t_imm0_508s4:$imm),
 341                     IIC_iALUi, "sub", "\t$Rdn, $imm", []>,
 342               T1Misc<{0,0,0,0,1,?,?}> {
 343   // A6.2.5 & A8.6.214
 344   bits<7> imm;
 345   let Inst{6-0} = imm;
 346   let DecoderMethod = "DecodeThumbAddSPImm";
 347 }
 348
 349 // Can optionally specify SP as a three operand instruction.
 350 def : tInstAlias<"add${p} sp, sp, $imm",
 351                  (tADDspi SP, t_imm0_508s4:$imm, pred:$p)>;
 352 def : tInstAlias<"sub${p} sp, sp, $imm",
 353                  (tSUBspi SP, t_imm0_508s4:$imm, pred:$p)>;
 354
 355 // ADD <Rm>, sp
 356 def tADDrSP : T1pIt<(outs GPR:$Rdn), (ins GPR:$Rn, GPRsp:$sp), IIC_iALUr,
 357                   "add", "\t$Rdn, $sp, $Rn", []>,
 358               T1Special<{0,0,?,?}> {
 359   // A8.6.9 Encoding T1
 360   bits<4> Rdn;
 361   let Inst{7}   = Rdn{3};
 362   let Inst{6-3} = 0b1101;
 363   let Inst{2-0} = Rdn{2-0};
 364   let DecoderMethod = "DecodeThumbAddSPReg";
 365 }
 366
 367 // ADD sp, <Rm>
 368 def tADDspr : T1pIt<(outs GPRsp:$Rdn), (ins GPRsp:$Rn, GPR:$Rm), IIC_iALUr,
 369                   "add", "\t$Rdn, $Rm", []>,
 370               T1Special<{0,0,?,?}> {
 371   // A8.6.9 Encoding T2
 372   bits<4> Rm;
 373   let Inst{7} = 1;
 374   let Inst{6-3} = Rm;
 375   let Inst{2-0} = 0b101;
 376   let DecoderMethod = "DecodeThumbAddSPReg";
 377 }
 378
 379 //===----------------------------------------------------------------------===//
 380 //  Control Flow Instructions.
 381 //
 382
 383 // Indirect branches
 384 let isBranch = 1, isTerminator = 1, isBarrier = 1, isIndirectBranch = 1 in {
 385   def tBX : TI<(outs), (ins GPR:$Rm, pred:$p), IIC_Br, "bx${p}\t$Rm", []>,
 386             T1Special<{1,1,0,?}> {
 387     // A6.2.3 & A8.6.25
 388     bits<4> Rm;
 389     let Inst{6-3} = Rm;
 390     let Inst{2-0} = 0b000;
 391   }
 392 }
 393
 394 let isReturn = 1, isTerminator = 1, isBarrier = 1 in {
 395   def tBX_RET : tPseudoExpand<(outs), (ins pred:$p), 2, IIC_Br,
 396                    [(ARMretflag)], (tBX LR, pred:$p)>;
 397
 398   // Alternative return instruction used by vararg functions.
 399   def tBX_RET_vararg : tPseudoExpand<(outs), (ins tGPR:$Rm, pred:$p),
 400                    2, IIC_Br, [],
 401                    (tBX GPR:$Rm, pred:$p)>;
 402 }
 403
 404 // All calls clobber the non-callee saved registers. SP is marked as a use to
 405 // prevent stack-pointer assignments that appear immediately before calls from
 406 // potentially appearing dead.
 407 let isCall = 1,
 408   // On non-Darwin platforms R9 is callee-saved.
 409   Defs = [R0,  R1,  R2,  R3,  R12, LR, QQQQ0, QQQQ2, QQQQ3, CPSR, FPSCR],
 410   Uses = [SP] in {
 411   // Also used for Thumb2
 412   def tBL  : TIx2<0b11110, 0b11, 1,
 413                   (outs), (ins pred:$p, t_bltarget:$func, variable_ops), IIC_Br,
 414                   "bl${p}\t$func",
 415                   [(ARMtcall tglobaladdr:$func)]>,
 416              Requires<[IsThumb, IsNotDarwin]> {
 417     bits<22> func;
 418     let Inst{26} = func{21};
 419     let Inst{25-16} = func{20-11};
 420     let Inst{13} = 1;
 421     let Inst{11} = 1;
 422     let Inst{10-0} = func{10-0};
 423   }
 424
 425   // ARMv5T and above, also used for Thumb2
 426   def tBLXi : TIx2<0b11110, 0b11, 0,
 427                  (outs), (ins pred:$p, t_blxtarget:$func, variable_ops), IIC_Br,
 428                    "blx${p}\t$func",
 429                    [(ARMcall tglobaladdr:$func)]>,
 430               Requires<[IsThumb, HasV5T, IsNotDarwin]> {
 431     bits<21> func;
 432     let Inst{25-16} = func{20-11};
 433     let Inst{13} = 1;
 434     let Inst{11} = 1;
 435     let Inst{10-1} = func{10-1};
 436     let Inst{0} = 0; // func{0} is assumed zero
 437   }
 438
 439   // Also used for Thumb2
 440   def tBLXr : TI<(outs), (ins pred:$p, GPR:$func, variable_ops), IIC_Br,
 441                   "blx${p}\t$func",
 442                   [(ARMtcall GPR:$func)]>,
 443               Requires<[IsThumb, HasV5T, IsNotDarwin]>,
 444               T1Special<{1,1,1,?}> { // A6.2.3 & A8.6.24;
 445     bits<4> func;
 446     let Inst{6-3} = func;
 447     let Inst{2-0} = 0b000;
 448   }
 449
 450   // ARMv4T
 451   def tBX_CALL : tPseudoInst<(outs), (ins tGPR:$func, variable_ops),
 452                   4, IIC_Br,
 453                   [(ARMcall_nolink tGPR:$func)]>,
 454             Requires<[IsThumb, IsThumb1Only, IsNotDarwin]>;
 455 }
 456
 457 let isCall = 1,
 458   // On Darwin R9 is call-clobbered.
 459   // R7 is marked as a use to prevent frame-pointer assignments from being
 460   // moved above / below calls.
 461   Defs = [R0,  R1,  R2,  R3,  R9,  R12, LR, QQQQ0, QQQQ2, QQQQ3, CPSR, FPSCR],
 462   Uses = [R7, SP] in {
 463   // Also used for Thumb2
 464   def tBLr9 : tPseudoExpand<(outs), (ins pred:$p, t_bltarget:$func, variable_ops),
 465                           4, IIC_Br, [(ARMtcall tglobaladdr:$func)],
 466                           (tBL pred:$p, t_bltarget:$func)>,
 467               Requires<[IsThumb, IsDarwin]>;
 468
 469   // ARMv5T and above, also used for Thumb2
 470   def tBLXi_r9 : tPseudoExpand<(outs), (ins pred:$p, t_blxtarget:$func, variable_ops),
 471                       4, IIC_Br, [(ARMcall tglobaladdr:$func)],
 472                       (tBLXi pred:$p, t_blxtarget:$func)>,
 473                  Requires<[IsThumb, HasV5T, IsDarwin]>;
 474
 475   // Also used for Thumb2
 476   def tBLXr_r9 : tPseudoExpand<(outs), (ins pred:$p, GPR:$func, variable_ops),
 477                     2, IIC_Br, [(ARMtcall GPR:$func)],
 478                     (tBLXr pred:$p, GPR:$func)>,
 479                  Requires<[IsThumb, HasV5T, IsDarwin]>;
 480
 481   // ARMv4T
 482   def tBXr9_CALL : tPseudoInst<(outs), (ins tGPR:$func, variable_ops),
 483                    4, IIC_Br,
 484                    [(ARMcall_nolink tGPR:$func)]>,
 485               Requires<[IsThumb, IsThumb1Only, IsDarwin]>;
 486 }
 487
 488 let isBranch = 1, isTerminator = 1, isBarrier = 1 in {
 489   let isPredicable = 1 in
 490   def tB   : T1pI<(outs), (ins t_brtarget:$target), IIC_Br,
 491                  "b", "\t$target", [(br bb:$target)]>,
 492              T1Encoding<{1,1,1,0,0,?}> {
 493     bits<11> target;
 494     let Inst{10-0} = target;
 495   }
 496
 497   // Far jump
 498   // Just a pseudo for a tBL instruction. Needed to let regalloc know about
 499   // the clobber of LR.
 500   let Defs = [LR] in
 501   def tBfar : tPseudoExpand<(outs), (ins t_bltarget:$target, pred:$p),
 502                           4, IIC_Br, [], (tBL pred:$p, t_bltarget:$target)>;
 503
 504   def tBR_JTr : tPseudoInst<(outs),
 505                       (ins tGPR:$target, i32imm:$jt, i32imm:$id),
 506                       0, IIC_Br,
 507                       [(ARMbrjt tGPR:$target, tjumptable:$jt, imm:$id)]> {
 508     list<Predicate> Predicates = [IsThumb, IsThumb1Only];
 509   }
 510 }
 511
 512 // FIXME: should be able to write a pattern for ARMBrcond, but can't use
 513 // a two-value operand where a dag node expects two operands. :(
 514 let isBranch = 1, isTerminator = 1 in
 515   def tBcc : T1I<(outs), (ins t_bcctarget:$target, pred:$p), IIC_Br,
 516                  "b${p}\t$target",
 517                  [/*(ARMbrcond bb:$target, imm:$cc)*/]>,
 518              T1BranchCond<{1,1,0,1}> {
 519   bits<4> p;
 520   bits<8> target;
 521   let Inst{11-8} = p;
 522   let Inst{7-0} = target;
 523 }
 524
 525 // Tail calls
 526 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1 in {
 527   // Darwin versions.
 528   let Defs = [R0, R1, R2, R3, R9, R12, QQQQ0, QQQQ2, QQQQ3, PC],
 529       Uses = [SP] in {
 530     // tTAILJMPd: Darwin version uses a Thumb2 branch (no Thumb1 tail calls
 531     // on Darwin), so it's in ARMInstrThumb2.td.
 532     def tTAILJMPr : tPseudoExpand<(outs), (ins tcGPR:$dst, variable_ops),
 533                      4, IIC_Br, [],
 534                      (tBX GPR:$dst, (ops 14, zero_reg))>,
 535                      Requires<[IsThumb, IsDarwin]>;
 536   }
 537   // Non-Darwin versions (the difference is R9).
 538   let Defs = [R0, R1, R2, R3, R12, QQQQ0, QQQQ2, QQQQ3, PC],
 539       Uses = [SP] in {
 540     def tTAILJMPdND : tPseudoExpand<(outs),
 541                    (ins t_brtarget:$dst, pred:$p, variable_ops),
 542                    4, IIC_Br, [],
 543                    (tB t_brtarget:$dst, pred:$p)>,
 544                  Requires<[IsThumb, IsNotDarwin]>;
 545     def tTAILJMPrND : tPseudoExpand<(outs), (ins tcGPR:$dst, variable_ops),
 546                      4, IIC_Br, [],
 547                      (tBX GPR:$dst, (ops 14, zero_reg))>,
 548                      Requires<[IsThumb, IsNotDarwin]>;
 549   }
 550 }
 551
 552
 553 // A8.6.218 Supervisor Call (Software Interrupt)
 554 // A8.6.16 B: Encoding T1
 555 // If Inst{11-8} == 0b1111 then SEE SVC
 556 let isCall = 1, Uses = [SP] in
 557 def tSVC : T1pI<(outs), (ins imm0_255:$imm), IIC_Br,
 558                 "svc", "\t$imm", []>, Encoding16 {
 559   bits<8> imm;
 560   let Inst{15-12} = 0b1101;
 561   let Inst{11-8}  = 0b1111;
 562   let Inst{7-0}   = imm;
 563 }
 564
 565 // The assembler uses 0xDEFE for a trap instruction.
 566 let isBarrier = 1, isTerminator = 1 in
 567 def tTRAP : TI<(outs), (ins), IIC_Br,
 568                "trap", [(trap)]>, Encoding16 {
 569   let Inst = 0xdefe;
 570 }
 571
 572 //===----------------------------------------------------------------------===//
 573 //  Load Store Instructions.
 574 //
 575
 576 // Loads: reg/reg and reg/imm5
 577 let canFoldAsLoad = 1, isReMaterializable = 1 in
 578 multiclass thumb_ld_rr_ri_enc<bits<3> reg_opc, bits<4> imm_opc,
 579                               Operand AddrMode_r, Operand AddrMode_i,
 580                               AddrMode am, InstrItinClass itin_r,
 581                               InstrItinClass itin_i, string asm,
 582                               PatFrag opnode> {
 583   def r : // reg/reg
 584     T1pILdStEncode<reg_opc,
 585                    (outs tGPR:$Rt), (ins AddrMode_r:$addr),
 586                    am, itin_r, asm, "\t$Rt, $addr",
 587                    [(set tGPR:$Rt, (opnode AddrMode_r:$addr))]>;
 588   def i : // reg/imm5
 589     T1pILdStEncodeImm<imm_opc, 1 /* Load */,
 590                       (outs tGPR:$Rt), (ins AddrMode_i:$addr),
 591                       am, itin_i, asm, "\t$Rt, $addr",
 592                       [(set tGPR:$Rt, (opnode AddrMode_i:$addr))]>;
 593 }
 594 // Stores: reg/reg and reg/imm5
 595 multiclass thumb_st_rr_ri_enc<bits<3> reg_opc, bits<4> imm_opc,
 596                               Operand AddrMode_r, Operand AddrMode_i,
 597                               AddrMode am, InstrItinClass itin_r,
 598                               InstrItinClass itin_i, string asm,
 599                               PatFrag opnode> {
 600   def r : // reg/reg
 601     T1pILdStEncode<reg_opc,
 602                    (outs), (ins tGPR:$Rt, AddrMode_r:$addr),
 603                    am, itin_r, asm, "\t$Rt, $addr",
 604                    [(opnode tGPR:$Rt, AddrMode_r:$addr)]>;
 605   def i : // reg/imm5
 606     T1pILdStEncodeImm<imm_opc, 0 /* Store */,
 607                       (outs), (ins tGPR:$Rt, AddrMode_i:$addr),
 608                       am, itin_i, asm, "\t$Rt, $addr",
 609                       [(opnode tGPR:$Rt, AddrMode_i:$addr)]>;
 610 }
 611
 612 // A8.6.57 & A8.6.60
 613 defm tLDR  : thumb_ld_rr_ri_enc<0b100, 0b0110, t_addrmode_rrs4,
 614                                 t_addrmode_is4, AddrModeT1_4,
 615                                 IIC_iLoad_r, IIC_iLoad_i, "ldr",
 616                                 UnOpFrag<(load node:$Src)>>;
 617
 618 // A8.6.64 & A8.6.61
 619 defm tLDRB : thumb_ld_rr_ri_enc<0b110, 0b0111, t_addrmode_rrs1,
 620                                 t_addrmode_is1, AddrModeT1_1,
 621                                 IIC_iLoad_bh_r, IIC_iLoad_bh_i, "ldrb",
 622                                 UnOpFrag<(zextloadi8 node:$Src)>>;
 623
 624 // A8.6.76 & A8.6.73
 625 defm tLDRH : thumb_ld_rr_ri_enc<0b101, 0b1000, t_addrmode_rrs2,
 626                                 t_addrmode_is2, AddrModeT1_2,
 627                                 IIC_iLoad_bh_r, IIC_iLoad_bh_i, "ldrh",
 628                                 UnOpFrag<(zextloadi16 node:$Src)>>;
 629
 630 let AddedComplexity = 10 in
 631 def tLDRSB :                    // A8.6.80
 632   T1pILdStEncode<0b011, (outs tGPR:$Rt), (ins t_addrmode_rr:$addr),
 633                  AddrModeT1_1, IIC_iLoad_bh_r,
 634                  "ldrsb", "\t$Rt, $addr",
 635                  [(set tGPR:$Rt, (sextloadi8 t_addrmode_rr:$addr))]>;
 636
 637 let AddedComplexity = 10 in
 638 def tLDRSH :                    // A8.6.84
 639   T1pILdStEncode<0b111, (outs tGPR:$Rt), (ins t_addrmode_rr:$addr),
 640                  AddrModeT1_2, IIC_iLoad_bh_r,
 641                  "ldrsh", "\t$Rt, $addr",
 642                  [(set tGPR:$Rt, (sextloadi16 t_addrmode_rr:$addr))]>;
 643
 644 let canFoldAsLoad = 1 in
 645 def tLDRspi : T1pIs<(outs tGPR:$Rt), (ins t_addrmode_sp:$addr), IIC_iLoad_i,
 646                     "ldr", "\t$Rt, $addr",
 647                     [(set tGPR:$Rt, (load t_addrmode_sp:$addr))]>,
 648               T1LdStSP<{1,?,?}> {
 649   bits<3> Rt;
 650   bits<8> addr;
 651   let Inst{10-8} = Rt;
 652   let Inst{7-0} = addr;
 653 }
 654
 655 // Load tconstpool
 656 // FIXME: Use ldr.n to work around a Darwin assembler bug.
 657 let canFoldAsLoad = 1, isReMaterializable = 1, isCodeGenOnly = 1 in
 658 def tLDRpci : T1pIs<(outs tGPR:$Rt), (ins t_addrmode_pc:$addr), IIC_iLoad_i,
 659                   "ldr", ".n\t$Rt, $addr",
 660                   [(set tGPR:$Rt, (load (ARMWrapper tconstpool:$addr)))]>,
 661               T1Encoding<{0,1,0,0,1,?}> {
 662   // A6.2 & A8.6.59
 663   bits<3> Rt;
 664   bits<8> addr;
 665   let Inst{10-8} = Rt;
 666   let Inst{7-0}  = addr;
 667 }
 668
 669 // FIXME: Remove this entry when the above ldr.n workaround is fixed.
 670 // For disassembly use only.
 671 def tLDRpciDIS : T1pIs<(outs tGPR:$Rt), (ins t_addrmode_pc:$addr), IIC_iLoad_i,
 672                        "ldr", "\t$Rt, $addr",
 673                        [/* disassembly only */]>,
 674                  T1Encoding<{0,1,0,0,1,?}> {
 675   // A6.2 & A8.6.59
 676   bits<3> Rt;
 677   bits<8> addr;
 678   let Inst{10-8} = Rt;
 679   let Inst{7-0}  = addr;
 680 }
 681
 682 // A8.6.194 & A8.6.192
 683 defm tSTR  : thumb_st_rr_ri_enc<0b000, 0b0110, t_addrmode_rrs4,
 684                                 t_addrmode_is4, AddrModeT1_4,
 685                                 IIC_iStore_r, IIC_iStore_i, "str",
 686                                 BinOpFrag<(store node:$LHS, node:$RHS)>>;
 687
 688 // A8.6.197 & A8.6.195
 689 defm tSTRB : thumb_st_rr_ri_enc<0b010, 0b0111, t_addrmode_rrs1,
 690                                 t_addrmode_is1, AddrModeT1_1,
 691                                 IIC_iStore_bh_r, IIC_iStore_bh_i, "strb",
 692                                 BinOpFrag<(truncstorei8 node:$LHS, node:$RHS)>>;
 693
 694 // A8.6.207 & A8.6.205
 695 defm tSTRH : thumb_st_rr_ri_enc<0b001, 0b1000, t_addrmode_rrs2,
 696                                t_addrmode_is2, AddrModeT1_2,
 697                                IIC_iStore_bh_r, IIC_iStore_bh_i, "strh",
 698                                BinOpFrag<(truncstorei16 node:$LHS, node:$RHS)>>;
 699
 700
 701 def tSTRspi : T1pIs<(outs), (ins tGPR:$Rt, t_addrmode_sp:$addr), IIC_iStore_i,
 702                     "str", "\t$Rt, $addr",
 703                     [(store tGPR:$Rt, t_addrmode_sp:$addr)]>,
 704               T1LdStSP<{0,?,?}> {
 705   bits<3> Rt;
 706   bits<8> addr;
 707   let Inst{10-8} = Rt;
 708   let Inst{7-0} = addr;
 709 }
 710
 711 //===----------------------------------------------------------------------===//
 712 //  Load / store multiple Instructions.
 713 //
 714
 715 // These require base address to be written back or one of the loaded regs.
 716 let neverHasSideEffects = 1 in {
 717
 718 let mayLoad = 1, hasExtraDefRegAllocReq = 1 in
 719 def tLDMIA : T1I<(outs), (ins tGPR:$Rn, pred:$p, reglist:$regs, variable_ops),
 720         IIC_iLoad_m, "ldm${p}\t$Rn, $regs", []>, T1Encoding<{1,1,0,0,1,?}> {
 721   bits<3> Rn;
 722   bits<8> regs;
 723   let Inst{10-8} = Rn;
 724   let Inst{7-0}  = regs;
 725 }
 726
 727 // Writeback version is just a pseudo, as there's no encoding difference.
 728 // Writeback happens iff the base register is not in the destination register
 729 // list.
 730 def tLDMIA_UPD :
 731     InstTemplate<AddrModeNone, 0, IndexModeNone, Pseudo, GenericDomain,
 732                  "$Rn = $wb", IIC_iLoad_mu>,
 733     PseudoInstExpansion<(tLDMIA tGPR:$Rn, pred:$p, reglist:$regs)> {
 734   let Size = 2;
 735   let OutOperandList = (outs GPR:$wb);
 736   let InOperandList = (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops);
 737   let Pattern = [];
 738   let isCodeGenOnly = 1;
 739   let isPseudo = 1;
 740   list<Predicate> Predicates = [IsThumb];
 741 }
 742
 743 // There is no non-writeback version of STM for Thumb.
 744 let mayStore = 1, hasExtraSrcRegAllocReq = 1 in
 745 def tSTMIA_UPD : Thumb1I<(outs GPR:$wb),
 746                          (ins tGPR:$Rn, pred:$p, reglist:$regs, variable_ops),
 747                          AddrModeNone, 2, IIC_iStore_mu,
 748                          "stm${p}\t$Rn!, $regs", "$Rn = $wb", []>,
 749                      T1Encoding<{1,1,0,0,0,?}> {
 750   bits<3> Rn;
 751   bits<8> regs;
 752   let Inst{10-8} = Rn;
 753   let Inst{7-0}  = regs;
 754 }
 755
 756 } // neverHasSideEffects
 757
 758 def : InstAlias<"ldm${p} $Rn!, $regs",
 759                 (tLDMIA tGPR:$Rn, pred:$p, reglist:$regs)>,
 760         Requires<[IsThumb, IsThumb1Only]>;
 761
 762 let mayLoad = 1, Uses = [SP], Defs = [SP], hasExtraDefRegAllocReq = 1 in
 763 def tPOP : T1I<(outs), (ins pred:$p, reglist:$regs, variable_ops),
 764                IIC_iPop,
 765                "pop${p}\t$regs", []>,
 766            T1Misc<{1,1,0,?,?,?,?}> {
 767   bits<16> regs;
 768   let Inst{8}   = regs{15};
 769   let Inst{7-0} = regs{7-0};
 770 }
 771
 772 let mayStore = 1, Uses = [SP], Defs = [SP], hasExtraSrcRegAllocReq = 1 in
 773 def tPUSH : T1I<(outs), (ins pred:$p, reglist:$regs, variable_ops),
 774                 IIC_iStore_m,
 775                 "push${p}\t$regs", []>,
 776             T1Misc<{0,1,0,?,?,?,?}> {
 777   bits<16> regs;
 778   let Inst{8}   = regs{14};
 779   let Inst{7-0} = regs{7-0};
 780 }
 781
 782 //===----------------------------------------------------------------------===//
 783 //  Arithmetic Instructions.
 784 //
 785
 786 // Helper classes for encoding T1pI patterns:
 787 class T1pIDPEncode<bits<4> opA, dag oops, dag iops, InstrItinClass itin,
 788                    string opc, string asm, list<dag> pattern>
 789     : T1pI<oops, iops, itin, opc, asm, pattern>,
 790       T1DataProcessing<opA> {
 791   bits<3> Rm;
 792   bits<3> Rn;
 793   let Inst{5-3} = Rm;
 794   let Inst{2-0} = Rn;
 795 }
 796 class T1pIMiscEncode<bits<7> opA, dag oops, dag iops, InstrItinClass itin,
 797                      string opc, string asm, list<dag> pattern>
 798     : T1pI<oops, iops, itin, opc, asm, pattern>,
 799       T1Misc<opA> {
 800   bits<3> Rm;
 801   bits<3> Rd;
 802   let Inst{5-3} = Rm;
 803   let Inst{2-0} = Rd;
 804 }
 805
 806 // Helper classes for encoding T1sI patterns:
 807 class T1sIDPEncode<bits<4> opA, dag oops, dag iops, InstrItinClass itin,
 808                    string opc, string asm, list<dag> pattern>
 809     : T1sI<oops, iops, itin, opc, asm, pattern>,
 810       T1DataProcessing<opA> {
 811   bits<3> Rd;
 812   bits<3> Rn;
 813   let Inst{5-3} = Rn;
 814   let Inst{2-0} = Rd;
 815 }
 816 class T1sIGenEncode<bits<5> opA, dag oops, dag iops, InstrItinClass itin,
 817                     string opc, string asm, list<dag> pattern>
 818     : T1sI<oops, iops, itin, opc, asm, pattern>,
 819       T1General<opA> {
 820   bits<3> Rm;
 821   bits<3> Rn;
 822   bits<3> Rd;
 823   let Inst{8-6} = Rm;
 824   let Inst{5-3} = Rn;
 825   let Inst{2-0} = Rd;
 826 }
 827 class T1sIGenEncodeImm<bits<5> opA, dag oops, dag iops, InstrItinClass itin,
 828                        string opc, string asm, list<dag> pattern>
 829     : T1sI<oops, iops, itin, opc, asm, pattern>,
 830       T1General<opA> {
 831   bits<3> Rd;
 832   bits<3> Rm;
 833   let Inst{5-3} = Rm;
 834   let Inst{2-0} = Rd;
 835 }
 836
 837 // Helper classes for encoding T1sIt patterns:
 838 class T1sItDPEncode<bits<4> opA, dag oops, dag iops, InstrItinClass itin,
 839                     string opc, string asm, list<dag> pattern>
 840     : T1sIt<oops, iops, itin, opc, asm, pattern>,
 841       T1DataProcessing<opA> {
 842   bits<3> Rdn;
 843   bits<3> Rm;
 844   let Inst{5-3} = Rm;
 845   let Inst{2-0} = Rdn;
 846 }
 847 class T1sItGenEncodeImm<bits<5> opA, dag oops, dag iops, InstrItinClass itin,
 848                         string opc, string asm, list<dag> pattern>
 849     : T1sIt<oops, iops, itin, opc, asm, pattern>,
 850       T1General<opA> {
 851   bits<3> Rdn;
 852   bits<8> imm8;
 853   let Inst{10-8} = Rdn;
 854   let Inst{7-0}  = imm8;
 855 }
 856
 857 // Add with carry register
 858 let isCommutable = 1, Uses = [CPSR] in
 859 def tADC :                      // A8.6.2
 860   T1sItDPEncode<0b0101, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm), IIC_iALUr,
 861                 "adc", "\t$Rdn, $Rm",
 862                 [(set tGPR:$Rdn, (adde tGPR:$Rn, tGPR:$Rm))]>;
 863
 864 // Add immediate
 865 def tADDi3 :                    // A8.6.4 T1
 866   T1sIGenEncodeImm<0b01110, (outs tGPR:$Rd), (ins tGPR:$Rm, imm0_7:$imm3),
 867                    IIC_iALUi,
 868                    "add", "\t$Rd, $Rm, $imm3",
 869                    [(set tGPR:$Rd, (add tGPR:$Rm, imm0_7:$imm3))]> {
 870   bits<3> imm3;
 871   let Inst{8-6} = imm3;
 872 }
 873
 874 def tADDi8 :                    // A8.6.4 T2
 875   T1sItGenEncodeImm<{1,1,0,?,?}, (outs tGPR:$Rdn),
 876                     (ins tGPR:$Rn, imm0_255:$imm8), IIC_iALUi,
 877                     "add", "\t$Rdn, $imm8",
 878                     [(set tGPR:$Rdn, (add tGPR:$Rn, imm8_255:$imm8))]>;
 879
 880 // Add register
 881 let isCommutable = 1 in
 882 def tADDrr :                    // A8.6.6 T1
 883   T1sIGenEncode<0b01100, (outs tGPR:$Rd), (ins tGPR:$Rn, tGPR:$Rm),
 884                 IIC_iALUr,
 885                 "add", "\t$Rd, $Rn, $Rm",
 886                 [(set tGPR:$Rd, (add tGPR:$Rn, tGPR:$Rm))]>;
 887
 888 let neverHasSideEffects = 1 in
 889 def tADDhirr : T1pIt<(outs GPR:$Rdn), (ins GPR:$Rn, GPR:$Rm), IIC_iALUr,
 890                      "add", "\t$Rdn, $Rm", []>,
 891                T1Special<{0,0,?,?}> {
 892   // A8.6.6 T2
 893   bits<4> Rdn;
 894   bits<4> Rm;
 895   let Inst{7}   = Rdn{3};
 896   let Inst{6-3} = Rm;
 897   let Inst{2-0} = Rdn{2-0};
 898 }
 899
 900 // AND register
 901 let isCommutable = 1 in
 902 def tAND :                      // A8.6.12
 903   T1sItDPEncode<0b0000, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 904                 IIC_iBITr,
 905                 "and", "\t$Rdn, $Rm",
 906                 [(set tGPR:$Rdn, (and tGPR:$Rn, tGPR:$Rm))]>;
 907
 908 // ASR immediate
 909 def tASRri :                    // A8.6.14
 910   T1sIGenEncodeImm<{0,1,0,?,?}, (outs tGPR:$Rd), (ins tGPR:$Rm, imm_sr:$imm5),
 911                    IIC_iMOVsi,
 912                    "asr", "\t$Rd, $Rm, $imm5",
 913                    [(set tGPR:$Rd, (sra tGPR:$Rm, (i32 imm_sr:$imm5)))]> {
 914   bits<5> imm5;
 915   let Inst{10-6} = imm5;
 916 }
 917
 918 // ASR register
 919 def tASRrr :                    // A8.6.15
 920   T1sItDPEncode<0b0100, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 921                 IIC_iMOVsr,
 922                 "asr", "\t$Rdn, $Rm",
 923                 [(set tGPR:$Rdn, (sra tGPR:$Rn, tGPR:$Rm))]>;
 924
 925 // BIC register
 926 def tBIC :                      // A8.6.20
 927   T1sItDPEncode<0b1110, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 928                 IIC_iBITr,
 929                 "bic", "\t$Rdn, $Rm",
 930                 [(set tGPR:$Rdn, (and tGPR:$Rn, (not tGPR:$Rm)))]>;
 931
 932 // CMN register
 933 let isCompare = 1, Defs = [CPSR] in {
 934 //FIXME: Disable CMN, as CCodes are backwards from compare expectations
 935 //       Compare-to-zero still works out, just not the relationals
 936 //def tCMN :                     // A8.6.33
 937 //  T1pIDPEncode<0b1011, (outs), (ins tGPR:$lhs, tGPR:$rhs),
 938 //               IIC_iCMPr,
 939 //               "cmn", "\t$lhs, $rhs",
 940 //               [(ARMcmp tGPR:$lhs, (ineg tGPR:$rhs))]>;
 941
 942 def tCMNz :                     // A8.6.33
 943   T1pIDPEncode<0b1011, (outs), (ins tGPR:$Rn, tGPR:$Rm),
 944                IIC_iCMPr,
 945                "cmn", "\t$Rn, $Rm",
 946                [(ARMcmpZ tGPR:$Rn, (ineg tGPR:$Rm))]>;
 947
 948 } // isCompare = 1, Defs = [CPSR]
 949
 950 // CMP immediate
 951 let isCompare = 1, Defs = [CPSR] in {
 952 def tCMPi8 : T1pI<(outs), (ins tGPR:$Rn, imm0_255:$imm8), IIC_iCMPi,
 953                   "cmp", "\t$Rn, $imm8",
 954                   [(ARMcmp tGPR:$Rn, imm0_255:$imm8)]>,
 955              T1General<{1,0,1,?,?}> {
 956   // A8.6.35
 957   bits<3> Rn;
 958   bits<8> imm8;
 959   let Inst{10-8} = Rn;
 960   let Inst{7-0}  = imm8;
 961 }
 962
 963 // CMP register
 964 def tCMPr :                     // A8.6.36 T1
 965   T1pIDPEncode<0b1010, (outs), (ins tGPR:$Rn, tGPR:$Rm),
 966                IIC_iCMPr,
 967                "cmp", "\t$Rn, $Rm",
 968                [(ARMcmp tGPR:$Rn, tGPR:$Rm)]>;
 969
 970 def tCMPhir : T1pI<(outs), (ins GPR:$Rn, GPR:$Rm), IIC_iCMPr,
 971                    "cmp", "\t$Rn, $Rm", []>,
 972               T1Special<{0,1,?,?}> {
 973   // A8.6.36 T2
 974   bits<4> Rm;
 975   bits<4> Rn;
 976   let Inst{7}   = Rn{3};
 977   let Inst{6-3} = Rm;
 978   let Inst{2-0} = Rn{2-0};
 979 }
 980 } // isCompare = 1, Defs = [CPSR]
 981
 982
 983 // XOR register
 984 let isCommutable = 1 in
 985 def tEOR :                      // A8.6.45
 986   T1sItDPEncode<0b0001, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 987                 IIC_iBITr,
 988                 "eor", "\t$Rdn, $Rm",
 989                 [(set tGPR:$Rdn, (xor tGPR:$Rn, tGPR:$Rm))]>;
 990
 991 // LSL immediate
 992 def tLSLri :                    // A8.6.88
 993   T1sIGenEncodeImm<{0,0,0,?,?}, (outs tGPR:$Rd), (ins tGPR:$Rm, imm0_31:$imm5),
 994                    IIC_iMOVsi,
 995                    "lsl", "\t$Rd, $Rm, $imm5",
 996                    [(set tGPR:$Rd, (shl tGPR:$Rm, (i32 imm:$imm5)))]> {
 997   bits<5> imm5;
 998   let Inst{10-6} = imm5;
 999 }
1000
1001 // LSL register
1002 def tLSLrr :                    // A8.6.89
1003   T1sItDPEncode<0b0010, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1004                 IIC_iMOVsr,
1005                 "lsl", "\t$Rdn, $Rm",
1006                 [(set tGPR:$Rdn, (shl tGPR:$Rn, tGPR:$Rm))]>;
1007
1008 // LSR immediate
1009 def tLSRri :                    // A8.6.90
1010   T1sIGenEncodeImm<{0,0,1,?,?}, (outs tGPR:$Rd), (ins tGPR:$Rm, imm_sr:$imm5),
1011                    IIC_iMOVsi,
1012                    "lsr", "\t$Rd, $Rm, $imm5",
1013                    [(set tGPR:$Rd, (srl tGPR:$Rm, (i32 imm_sr:$imm5)))]> {
1014   bits<5> imm5;
1015   let Inst{10-6} = imm5;
1016 }
1017
1018 // LSR register
1019 def tLSRrr :                    // A8.6.91
1020   T1sItDPEncode<0b0011, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1021                 IIC_iMOVsr,
1022                 "lsr", "\t$Rdn, $Rm",
1023                 [(set tGPR:$Rdn, (srl tGPR:$Rn, tGPR:$Rm))]>;
1024
1025 // Move register
1026 let isMoveImm = 1 in
1027 def tMOVi8 : T1sI<(outs tGPR:$Rd), (ins imm0_255:$imm8), IIC_iMOVi,
1028                   "mov", "\t$Rd, $imm8",
1029                   [(set tGPR:$Rd, imm0_255:$imm8)]>,
1030              T1General<{1,0,0,?,?}> {
1031   // A8.6.96
1032   bits<3> Rd;
1033   bits<8> imm8;
1034   let Inst{10-8} = Rd;
1035   let Inst{7-0}  = imm8;
1036 }
1037 // Because we have an explicit tMOVSr below, we need an alias to handle
1038 // the immediate "movs" form here. Blech.
1039 def : tInstAlias <"movs $Rdn, $imm",
1040                  (tMOVi8 tGPR:$Rdn, CPSR, imm0_255:$imm, 14, 0)>;
1041
1042 // A7-73: MOV(2) - mov setting flag.
1043
1044 let neverHasSideEffects = 1 in {
1045 def tMOVr : Thumb1pI<(outs GPR:$Rd), (ins GPR:$Rm), AddrModeNone,
1046                       2, IIC_iMOVr,
1047                       "mov", "\t$Rd, $Rm", "", []>,
1048                   T1Special<{1,0,?,?}> {
1049   // A8.6.97
1050   bits<4> Rd;
1051   bits<4> Rm;
1052   let Inst{7}   = Rd{3};
1053   let Inst{6-3} = Rm;
1054   let Inst{2-0} = Rd{2-0};
1055 }
1056 let Defs = [CPSR] in
1057 def tMOVSr      : T1I<(outs tGPR:$Rd), (ins tGPR:$Rm), IIC_iMOVr,
1058                       "movs\t$Rd, $Rm", []>, Encoding16 {
1059   // A8.6.97
1060   bits<3> Rd;
1061   bits<3> Rm;
1062   let Inst{15-6} = 0b0000000000;
1063   let Inst{5-3}  = Rm;
1064   let Inst{2-0}  = Rd;
1065 }
1066 } // neverHasSideEffects
1067
1068 // Multiply register
1069 let isCommutable = 1 in
1070 def tMUL :                      // A8.6.105 T1
1071   Thumb1sI<(outs tGPR:$Rd), (ins tGPR:$Rn, tGPR:$Rm), AddrModeNone, 2,
1072            IIC_iMUL32, "mul", "\t$Rd, $Rn, $Rm", "$Rm = $Rd",
1073            [(set tGPR:$Rd, (mul tGPR:$Rn, tGPR:$Rm))]>,
1074       T1DataProcessing<0b1101> {
1075   bits<3> Rd;
1076   bits<3> Rn;
1077   let Inst{5-3} = Rn;
1078   let Inst{2-0} = Rd;
1079   let AsmMatchConverter = "cvtThumbMultiply";
1080 }
1081
1082 def :tInstAlias<"mul${s}${p} $Rdm, $Rn", (tMUL tGPR:$Rdm, s_cc_out:$s, tGPR:$Rn,
1083                                                pred:$p)>;
1084
1085 // Move inverse register
1086 def tMVN :                      // A8.6.107
1087   T1sIDPEncode<0b1111, (outs tGPR:$Rd), (ins tGPR:$Rn), IIC_iMVNr,
1088                "mvn", "\t$Rd, $Rn",
1089                [(set tGPR:$Rd, (not tGPR:$Rn))]>;
1090
1091 // Bitwise or register
1092 let isCommutable = 1 in
1093 def tORR :                      // A8.6.114
1094   T1sItDPEncode<0b1100, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1095                 IIC_iBITr,
1096                 "orr", "\t$Rdn, $Rm",
1097                 [(set tGPR:$Rdn, (or tGPR:$Rn, tGPR:$Rm))]>;
1098
1099 // Swaps
1100 def tREV :                      // A8.6.134
1101   T1pIMiscEncode<{1,0,1,0,0,0,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1102                  IIC_iUNAr,
1103                  "rev", "\t$Rd, $Rm",
1104                  [(set tGPR:$Rd, (bswap tGPR:$Rm))]>,
1105                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1106
1107 def tREV16 :                    // A8.6.135
1108   T1pIMiscEncode<{1,0,1,0,0,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1109                  IIC_iUNAr,
1110                  "rev16", "\t$Rd, $Rm",
1111              [(set tGPR:$Rd, (rotr (bswap tGPR:$Rm), (i32 16)))]>,
1112                 Requires<[IsThumb, IsThumb1Only, HasV6]>;
1113
1114 def tREVSH :                    // A8.6.136
1115   T1pIMiscEncode<{1,0,1,0,1,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1116                  IIC_iUNAr,
1117                  "revsh", "\t$Rd, $Rm",
1118                  [(set tGPR:$Rd, (sra (bswap tGPR:$Rm), (i32 16)))]>,
1119                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1120
1121 // Rotate right register
1122 def tROR :                      // A8.6.139
1123   T1sItDPEncode<0b0111, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1124                 IIC_iMOVsr,
1125                 "ror", "\t$Rdn, $Rm",
1126                 [(set tGPR:$Rdn, (rotr tGPR:$Rn, tGPR:$Rm))]>;
1127
1128 // Negate register
1129 def tRSB :                      // A8.6.141
1130   T1sIDPEncode<0b1001, (outs tGPR:$Rd), (ins tGPR:$Rn),
1131                IIC_iALUi,
1132                "rsb", "\t$Rd, $Rn, #0",
1133                [(set tGPR:$Rd, (ineg tGPR:$Rn))]>;
1134
1135 def : tInstAlias<"neg${s}${p} $Rd, $Rm",
1136                  (tRSB tGPR:$Rd, s_cc_out:$s, tGPR:$Rm, pred:$p)>;
1137
1138 // Subtract with carry register
1139 let Uses = [CPSR] in
1140 def tSBC :                      // A8.6.151
1141   T1sItDPEncode<0b0110, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1142                 IIC_iALUr,
1143                 "sbc", "\t$Rdn, $Rm",
1144                 [(set tGPR:$Rdn, (sube tGPR:$Rn, tGPR:$Rm))]>;
1145
1146 // Subtract immediate
1147 def tSUBi3 :                    // A8.6.210 T1
1148   T1sIGenEncodeImm<0b01111, (outs tGPR:$Rd), (ins tGPR:$Rm, i32imm:$imm3),
1149                    IIC_iALUi,
1150                    "sub", "\t$Rd, $Rm, $imm3",
1151                    [(set tGPR:$Rd, (add tGPR:$Rm, imm0_7_neg:$imm3))]> {
1152   bits<3> imm3;
1153   let Inst{8-6} = imm3;
1154 }
1155
1156 def tSUBi8 :                    // A8.6.210 T2
1157   T1sItGenEncodeImm<{1,1,1,?,?}, (outs tGPR:$Rdn), (ins tGPR:$Rn, i32imm:$imm8),
1158                     IIC_iALUi,
1159                     "sub", "\t$Rdn, $imm8",
1160                     [(set tGPR:$Rdn, (add tGPR:$Rn, imm8_255_neg:$imm8))]>;
1161
1162 // Subtract register
1163 def tSUBrr :                    // A8.6.212
1164   T1sIGenEncode<0b01101, (outs tGPR:$Rd), (ins tGPR:$Rn, tGPR:$Rm),
1165                 IIC_iALUr,
1166                 "sub", "\t$Rd, $Rn, $Rm",
1167                 [(set tGPR:$Rd, (sub tGPR:$Rn, tGPR:$Rm))]>;
1168
1169 // Sign-extend byte
1170 def tSXTB :                     // A8.6.222
1171   T1pIMiscEncode<{0,0,1,0,0,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1172                  IIC_iUNAr,
1173                  "sxtb", "\t$Rd, $Rm",
1174                  [(set tGPR:$Rd, (sext_inreg tGPR:$Rm, i8))]>,
1175                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1176
1177 // Sign-extend short
1178 def tSXTH :                     // A8.6.224
1179   T1pIMiscEncode<{0,0,1,0,0,0,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1180                  IIC_iUNAr,
1181                  "sxth", "\t$Rd, $Rm",
1182                  [(set tGPR:$Rd, (sext_inreg tGPR:$Rm, i16))]>,
1183                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1184
1185 // Test
1186 let isCompare = 1, isCommutable = 1, Defs = [CPSR] in
1187 def tTST :                      // A8.6.230
1188   T1pIDPEncode<0b1000, (outs), (ins tGPR:$Rn, tGPR:$Rm), IIC_iTSTr,
1189                "tst", "\t$Rn, $Rm",
1190                [(ARMcmpZ (and_su tGPR:$Rn, tGPR:$Rm), 0)]>;
1191
1192 // Zero-extend byte
1193 def tUXTB :                     // A8.6.262
1194   T1pIMiscEncode<{0,0,1,0,1,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1195                  IIC_iUNAr,
1196                  "uxtb", "\t$Rd, $Rm",
1197                  [(set tGPR:$Rd, (and tGPR:$Rm, 0xFF))]>,
1198                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1199
1200 // Zero-extend short
1201 def tUXTH :                     // A8.6.264
1202   T1pIMiscEncode<{0,0,1,0,1,0,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1203                  IIC_iUNAr,
1204                  "uxth", "\t$Rd, $Rm",
1205                  [(set tGPR:$Rd, (and tGPR:$Rm, 0xFFFF))]>,
1206                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1207
1208 // Conditional move tMOVCCr - Used to implement the Thumb SELECT_CC operation.
1209 // Expanded after instruction selection into a branch sequence.
1210 let usesCustomInserter = 1 in  // Expanded after instruction selection.
1211   def tMOVCCr_pseudo :
1212   PseudoInst<(outs tGPR:$dst), (ins tGPR:$false, tGPR:$true, pred:$cc),
1213               NoItinerary,
1214              [/*(set tGPR:$dst, (ARMcmov tGPR:$false, tGPR:$true, imm:$cc))*/]>;
1215
1216 // tLEApcrel - Load a pc-relative address into a register without offending the
1217 // assembler.
1218
1219 def tADR : T1I<(outs tGPR:$Rd), (ins t_adrlabel:$addr, pred:$p),
1220                IIC_iALUi, "adr{$p}\t$Rd, $addr", []>,
1221                T1Encoding<{1,0,1,0,0,?}> {
1222   bits<3> Rd;
1223   bits<8> addr;
1224   let Inst{10-8} = Rd;
1225   let Inst{7-0} = addr;
1226   let DecoderMethod = "DecodeThumbAddSpecialReg";
1227 }
1228
1229 let neverHasSideEffects = 1, isReMaterializable = 1 in
1230 def tLEApcrel   : tPseudoInst<(outs tGPR:$Rd), (ins i32imm:$label, pred:$p),
1231                               2, IIC_iALUi, []>;
1232
1233 def tLEApcrelJT : tPseudoInst<(outs tGPR:$Rd),
1234                               (ins i32imm:$label, nohash_imm:$id, pred:$p),
1235                               2, IIC_iALUi, []>;
1236
1237 //===----------------------------------------------------------------------===//
1238 // TLS Instructions
1239 //
1240
1241 // __aeabi_read_tp preserves the registers r1-r3.
1242 // This is a pseudo inst so that we can get the encoding right,
1243 // complete with fixup for the aeabi_read_tp function.
1244 let isCall = 1, Defs = [R0, R12, LR, CPSR], Uses = [SP] in
1245 def tTPsoft : tPseudoInst<(outs), (ins), 4, IIC_Br,
1246                           [(set R0, ARMthread_pointer)]>;
1247
1248 //===----------------------------------------------------------------------===//
1249 // SJLJ Exception handling intrinsics
1250 //
1251
1252 // eh_sjlj_setjmp() is an instruction sequence to store the return address and
1253 // save #0 in R0 for the non-longjmp case.  Since by its nature we may be coming
1254 // from some other function to get here, and we're using the stack frame for the
1255 // containing function to save/restore registers, we can't keep anything live in
1256 // regs across the eh_sjlj_setjmp(), else it will almost certainly have been
1257 // tromped upon when we get here from a longjmp(). We force everything out of
1258 // registers except for our own input by listing the relevant registers in
1259 // Defs. By doing so, we also cause the prologue/epilogue code to actively
1260 // preserve all of the callee-saved resgisters, which is exactly what we want.
1261 // $val is a scratch register for our use.
1262 let Defs = [ R0,  R1,  R2,  R3,  R4,  R5,  R6,  R7, R12, CPSR ],
1263     hasSideEffects = 1, isBarrier = 1, isCodeGenOnly = 1 in
1264 def tInt_eh_sjlj_setjmp : ThumbXI<(outs),(ins tGPR:$src, tGPR:$val),
1265                                   AddrModeNone, 0, NoItinerary, "","",
1266                           [(set R0, (ARMeh_sjlj_setjmp tGPR:$src, tGPR:$val))]>;
1267
1268 // FIXME: Non-Darwin version(s)
1269 let isBarrier = 1, hasSideEffects = 1, isTerminator = 1, isCodeGenOnly = 1,
1270     Defs = [ R7, LR, SP ] in
1271 def tInt_eh_sjlj_longjmp : XI<(outs), (ins GPR:$src, GPR:$scratch),
1272                               AddrModeNone, 0, IndexModeNone,
1273                               Pseudo, NoItinerary, "", "",
1274                               [(ARMeh_sjlj_longjmp GPR:$src, GPR:$scratch)]>,
1275                              Requires<[IsThumb, IsDarwin]>;
1276
1277 //===----------------------------------------------------------------------===//
1278 // Non-Instruction Patterns
1279 //
1280
1281 // Comparisons
1282 def : T1Pat<(ARMcmpZ tGPR:$Rn, imm0_255:$imm8),
1283             (tCMPi8  tGPR:$Rn, imm0_255:$imm8)>;
1284 def : T1Pat<(ARMcmpZ tGPR:$Rn, tGPR:$Rm),
1285             (tCMPr   tGPR:$Rn, tGPR:$Rm)>;
1286
1287 // Add with carry
1288 def : T1Pat<(addc   tGPR:$lhs, imm0_7:$rhs),
1289             (tADDi3 tGPR:$lhs, imm0_7:$rhs)>;
1290 def : T1Pat<(addc   tGPR:$lhs, imm8_255:$rhs),
1291             (tADDi8 tGPR:$lhs, imm8_255:$rhs)>;
1292 def : T1Pat<(addc   tGPR:$lhs, tGPR:$rhs),
1293             (tADDrr tGPR:$lhs, tGPR:$rhs)>;
1294
1295 // Subtract with carry
1296 def : T1Pat<(addc   tGPR:$lhs, imm0_7_neg:$rhs),
1297             (tSUBi3 tGPR:$lhs, imm0_7_neg:$rhs)>;
1298 def : T1Pat<(addc   tGPR:$lhs, imm8_255_neg:$rhs),
1299             (tSUBi8 tGPR:$lhs, imm8_255_neg:$rhs)>;
1300 def : T1Pat<(subc   tGPR:$lhs, tGPR:$rhs),
1301             (tSUBrr tGPR:$lhs, tGPR:$rhs)>;
1302
1303 // ConstantPool, GlobalAddress
1304 def : T1Pat<(ARMWrapper  tglobaladdr :$dst), (tLEApcrel tglobaladdr :$dst)>;
1305 def : T1Pat<(ARMWrapper  tconstpool  :$dst), (tLEApcrel tconstpool  :$dst)>;
1306
1307 // JumpTable
1308 def : T1Pat<(ARMWrapperJT tjumptable:$dst, imm:$id),
1309             (tLEApcrelJT tjumptable:$dst, imm:$id)>;
1310
1311 // Direct calls
1312 def : T1Pat<(ARMtcall texternalsym:$func), (tBL texternalsym:$func)>,
1313       Requires<[IsThumb, IsNotDarwin]>;
1314 def : T1Pat<(ARMtcall texternalsym:$func), (tBLr9 texternalsym:$func)>,
1315       Requires<[IsThumb, IsDarwin]>;
1316
1317 def : Tv5Pat<(ARMcall texternalsym:$func), (tBLXi texternalsym:$func)>,
1318       Requires<[IsThumb, HasV5T, IsNotDarwin]>;
1319 def : Tv5Pat<(ARMcall texternalsym:$func), (tBLXi_r9 texternalsym:$func)>,
1320       Requires<[IsThumb, HasV5T, IsDarwin]>;
1321
1322 // Indirect calls to ARM routines
1323 def : Tv5Pat<(ARMcall GPR:$dst), (tBLXr GPR:$dst)>,
1324       Requires<[IsThumb, HasV5T, IsNotDarwin]>;
1325 def : Tv5Pat<(ARMcall GPR:$dst), (tBLXr_r9 GPR:$dst)>,
1326       Requires<[IsThumb, HasV5T, IsDarwin]>;
1327
1328 // zextload i1 -> zextload i8
1329 def : T1Pat<(zextloadi1 t_addrmode_rrs1:$addr),
1330             (tLDRBr t_addrmode_rrs1:$addr)>;
1331 def : T1Pat<(zextloadi1 t_addrmode_is1:$addr),
1332             (tLDRBi t_addrmode_is1:$addr)>;
1333
1334 // extload -> zextload
1335 def : T1Pat<(extloadi1  t_addrmode_rrs1:$addr), (tLDRBr t_addrmode_rrs1:$addr)>;
1336 def : T1Pat<(extloadi1  t_addrmode_is1:$addr),  (tLDRBi t_addrmode_is1:$addr)>;
1337 def : T1Pat<(extloadi8  t_addrmode_rrs1:$addr), (tLDRBr t_addrmode_rrs1:$addr)>;
1338 def : T1Pat<(extloadi8  t_addrmode_is1:$addr),  (tLDRBi t_addrmode_is1:$addr)>;
1339 def : T1Pat<(extloadi16 t_addrmode_rrs2:$addr), (tLDRHr t_addrmode_rrs2:$addr)>;
1340 def : T1Pat<(extloadi16 t_addrmode_is2:$addr),  (tLDRHi t_addrmode_is2:$addr)>;
1341
1342 // If it's impossible to use [r,r] address mode for sextload, select to
1343 // ldr{b|h} + sxt{b|h} instead.
1344 def : T1Pat<(sextloadi8 t_addrmode_is1:$addr),
1345             (tSXTB (tLDRBi t_addrmode_is1:$addr))>,
1346       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1347 def : T1Pat<(sextloadi8 t_addrmode_rrs1:$addr),
1348             (tSXTB (tLDRBr t_addrmode_rrs1:$addr))>,
1349       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1350 def : T1Pat<(sextloadi16 t_addrmode_is2:$addr),
1351             (tSXTH (tLDRHi t_addrmode_is2:$addr))>,
1352       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1353 def : T1Pat<(sextloadi16 t_addrmode_rrs2:$addr),
1354             (tSXTH (tLDRHr t_addrmode_rrs2:$addr))>,
1355       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1356
1357 def : T1Pat<(sextloadi8 t_addrmode_rrs1:$addr),
1358             (tASRri (tLSLri (tLDRBr t_addrmode_rrs1:$addr), 24), 24)>;
1359 def : T1Pat<(sextloadi8 t_addrmode_is1:$addr),
1360             (tASRri (tLSLri (tLDRBi t_addrmode_is1:$addr), 24), 24)>;
1361 def : T1Pat<(sextloadi16 t_addrmode_rrs2:$addr),
1362             (tASRri (tLSLri (tLDRHr t_addrmode_rrs2:$addr), 16), 16)>;
1363 def : T1Pat<(sextloadi16 t_addrmode_is2:$addr),
1364             (tASRri (tLSLri (tLDRHi t_addrmode_is2:$addr), 16), 16)>;
1365
1366 def : T1Pat<(atomic_load_8 t_addrmode_is1:$src),
1367              (tLDRBi t_addrmode_is1:$src)>;
1368 def : T1Pat<(atomic_load_8 t_addrmode_rrs1:$src),
1369              (tLDRBr t_addrmode_rrs1:$src)>;
1370 def : T1Pat<(atomic_load_16 t_addrmode_is2:$src),
1371              (tLDRHi t_addrmode_is2:$src)>;
1372 def : T1Pat<(atomic_load_16 t_addrmode_rrs2:$src),
1373              (tLDRHr t_addrmode_rrs2:$src)>;
1374 def : T1Pat<(atomic_load_32 t_addrmode_is4:$src),
1375              (tLDRi t_addrmode_is4:$src)>;
1376 def : T1Pat<(atomic_load_32 t_addrmode_rrs4:$src),
1377              (tLDRr t_addrmode_rrs4:$src)>;
1378 def : T1Pat<(atomic_store_8 t_addrmode_is1:$ptr, tGPR:$val),
1379              (tSTRBi tGPR:$val, t_addrmode_is1:$ptr)>;
1380 def : T1Pat<(atomic_store_8 t_addrmode_rrs1:$ptr, tGPR:$val),
1381              (tSTRBr tGPR:$val, t_addrmode_rrs1:$ptr)>;
1382 def : T1Pat<(atomic_store_16 t_addrmode_is2:$ptr, tGPR:$val),
1383              (tSTRHi tGPR:$val, t_addrmode_is2:$ptr)>;
1384 def : T1Pat<(atomic_store_16 t_addrmode_rrs2:$ptr, tGPR:$val),
1385              (tSTRHr tGPR:$val, t_addrmode_rrs2:$ptr)>;
1386 def : T1Pat<(atomic_store_32 t_addrmode_is4:$ptr, tGPR:$val),
1387              (tSTRi tGPR:$val, t_addrmode_is4:$ptr)>;
1388 def : T1Pat<(atomic_store_32 t_addrmode_rrs4:$ptr, tGPR:$val),
1389              (tSTRr tGPR:$val, t_addrmode_rrs4:$ptr)>;
1390
1391 // Large immediate handling.
1392
1393 // Two piece imms.
1394 def : T1Pat<(i32 thumb_immshifted:$src),
1395             (tLSLri (tMOVi8 (thumb_immshifted_val imm:$src)),
1396                     (thumb_immshifted_shamt imm:$src))>;
1397
1398 def : T1Pat<(i32 imm0_255_comp:$src),
1399             (tMVN (tMOVi8 (imm_comp_XFORM imm:$src)))>;
1400
1401 // Pseudo instruction that combines ldr from constpool and add pc. This should
1402 // be expanded into two instructions late to allow if-conversion and
1403 // scheduling.
1404 let isReMaterializable = 1 in
1405 def tLDRpci_pic : PseudoInst<(outs GPR:$dst), (ins i32imm:$addr, pclabel:$cp),
1406                              NoItinerary,
1407                [(set GPR:$dst, (ARMpic_add (load (ARMWrapper tconstpool:$addr)),
1408                                            imm:$cp))]>,
1409                Requires<[IsThumb, IsThumb1Only]>;
1410
1411 // Pseudo-instruction for merged POP and return.
1412 // FIXME: remove when we have a way to marking a MI with these properties.
1413 let isReturn = 1, isTerminator = 1, isBarrier = 1, mayLoad = 1,
1414     hasExtraDefRegAllocReq = 1 in
1415 def tPOP_RET : tPseudoExpand<(outs), (ins pred:$p, reglist:$regs, variable_ops),
1416                            2, IIC_iPop_Br, [],
1417                            (tPOP pred:$p, reglist:$regs)>;
1418
1419 // Indirect branch using "mov pc, $Rm"
1420 let isBranch = 1, isTerminator = 1, isBarrier = 1, isIndirectBranch = 1 in {
1421   def tBRIND : tPseudoExpand<(outs), (ins GPR:$Rm, pred:$p),
1422                   2, IIC_Br, [(brind GPR:$Rm)],
1423                   (tMOVr PC, GPR:$Rm, pred:$p)>;
1424 }
1425
1426
1427 // In Thumb1, "nop" is encoded as a "mov r8, r8". Technically, the bf00
1428 // encoding is available on ARMv6K, but we don't differentiate that finely.
1429 def : InstAlias<"nop", (tMOVr R8, R8, 14, 0)>,Requires<[IsThumb, IsThumb1Only]>;