lib/Target/ARM/ARM.td

   1 //===-- ARM.td - Describe the ARM Target Machine -----------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //
  11 //===----------------------------------------------------------------------===//
  12
  13 //===----------------------------------------------------------------------===//
  14 // Target-independent interfaces which we are implementing
  15 //===----------------------------------------------------------------------===//
  16
  17 include "llvm/Target/Target.td"
  18
  19 //===----------------------------------------------------------------------===//
  20 // ARM Subtarget state.
  21 //
  22
  23 def ModeThumb  : SubtargetFeature<"thumb-mode", "InThumbMode", "true",
  24                                   "Thumb mode">;
  25
  26 //===----------------------------------------------------------------------===//
  27 // ARM Subtarget features.
  28 //
  29
  30 def FeatureVFP2 : SubtargetFeature<"vfp2", "HasVFPv2", "true",
  31                                    "Enable VFP2 instructions">;
  32 def FeatureVFP3 : SubtargetFeature<"vfp3", "HasVFPv3", "true",
  33                                    "Enable VFP3 instructions",
  34                                    [FeatureVFP2]>;
  35 def FeatureNEON : SubtargetFeature<"neon", "HasNEON", "true",
  36                                    "Enable NEON instructions",
  37                                    [FeatureVFP3]>;
  38 def FeatureThumb2 : SubtargetFeature<"thumb2", "HasThumb2", "true",
  39                                      "Enable Thumb2 instructions">;
  40 def FeatureNoARM  : SubtargetFeature<"noarm", "NoARM", "true",
  41                                      "Does not support ARM mode execution",
  42                                      [ModeThumb]>;
  43 def FeatureFP16   : SubtargetFeature<"fp16", "HasFP16", "true",
  44                                      "Enable half-precision floating point">;
  45 def FeatureVFP4   : SubtargetFeature<"vfp4", "HasVFPv4", "true",
  46                                      "Enable VFP4 instructions",
  47                                      [FeatureVFP3, FeatureFP16]>;
  48 def FeatureFPARMv8 : SubtargetFeature<"fp-armv8", "HasFPARMv8",
  49                                    "true", "Enable ARMv8 FP",
  50                                    [FeatureVFP4]>;
  51 def FeatureD16    : SubtargetFeature<"d16", "HasD16", "true",
  52                                      "Restrict VFP3 to 16 double registers">;
  53 def FeatureHWDiv  : SubtargetFeature<"hwdiv", "HasHardwareDivide", "true",
  54                                      "Enable divide instructions">;
  55 def FeatureHWDivARM  : SubtargetFeature<"hwdiv-arm",
  56                                         "HasHardwareDivideInARM", "true",
  57                                       "Enable divide instructions in ARM mode">;
  58 def FeatureT2XtPk : SubtargetFeature<"t2xtpk", "HasT2ExtractPack", "true",
  59                                  "Enable Thumb2 extract and pack instructions">;
  60 def FeatureDB     : SubtargetFeature<"db", "HasDataBarrier", "true",
  61                                    "Has data barrier (dmb / dsb) instructions">;
  62 def FeatureSlowFPBrcc : SubtargetFeature<"slow-fp-brcc", "SlowFPBrcc", "true",
  63                                          "FP compare + branch is slow">;
  64 def FeatureVFPOnlySP : SubtargetFeature<"fp-only-sp", "FPOnlySP", "true",
  65                           "Floating point unit supports single precision only">;
  66 def FeaturePerfMon : SubtargetFeature<"perfmon", "HasPerfMon", "true",
  67                            "Enable support for Performance Monitor extensions">;
  68 def FeatureTrustZone : SubtargetFeature<"trustzone", "HasTrustZone", "true",
  69                           "Enable support for TrustZone security extensions">;
  70 def FeatureCrypto : SubtargetFeature<"crypto", "HasCrypto", "true",
  71                           "Enable support for Cryptography extensions",
  72                           [FeatureNEON]>;
  73 def FeatureCRC : SubtargetFeature<"crc", "HasCRC", "true",
  74                           "Enable support for CRC instructions">;
  75
  76 // Some processors have FP multiply-accumulate instructions that don't
  77 // play nicely with other VFP / NEON instructions, and it's generally better
  78 // to just not use them.
  79 def FeatureHasSlowFPVMLx : SubtargetFeature<"slowfpvmlx", "SlowFPVMLx", "true",
  80                                          "Disable VFP / NEON MAC instructions">;
  81
  82 // Cortex-A8 / A9 Advanced SIMD has multiplier accumulator forwarding.
  83 def FeatureVMLxForwarding : SubtargetFeature<"vmlx-forwarding",
  84                                        "HasVMLxForwarding", "true",
  85                                        "Has multiplier accumulator forwarding">;
  86
  87 // Some processors benefit from using NEON instructions for scalar
  88 // single-precision FP operations.
  89 def FeatureNEONForFP : SubtargetFeature<"neonfp", "UseNEONForSinglePrecisionFP",
  90                                         "true",
  91                                         "Use NEON for single precision FP">;
  92
  93 // Disable 32-bit to 16-bit narrowing for experimentation.
  94 def FeaturePref32BitThumb : SubtargetFeature<"32bit", "Pref32BitThumb", "true",
  95                                              "Prefer 32-bit Thumb instrs">;
  96
  97 /// Some instructions update CPSR partially, which can add false dependency for
  98 /// out-of-order implementation, e.g. Cortex-A9, unless each individual bit is
  99 /// mapped to a separate physical register. Avoid partial CPSR update for these
 100 /// processors.
 101 def FeatureAvoidPartialCPSR : SubtargetFeature<"avoid-partial-cpsr",
 102                                                "AvoidCPSRPartialUpdate", "true",
 103                                  "Avoid CPSR partial update for OOO execution">;
 104
 105 def FeatureAvoidMOVsShOp : SubtargetFeature<"avoid-movs-shop",
 106                                             "AvoidMOVsShifterOperand", "true",
 107                                 "Avoid movs instructions with shifter operand">;
 108
 109 // Some processors perform return stack prediction. CodeGen should avoid issue
 110 // "normal" call instructions to callees which do not return.
 111 def FeatureHasRAS : SubtargetFeature<"ras", "HasRAS", "true",
 112                                      "Has return address stack">;
 113
 114 /// Some M architectures don't have the DSP extension (v7E-M vs. v7M)
 115 def FeatureDSPThumb2 : SubtargetFeature<"t2dsp", "Thumb2DSP", "true",
 116                                  "Supports v7 DSP instructions in Thumb2">;
 117
 118 // Multiprocessing extension.
 119 def FeatureMP : SubtargetFeature<"mp", "HasMPExtension", "true",
 120                                  "Supports Multiprocessing extension">;
 121
 122 // Virtualization extension - requires HW divide (ARMv7-AR ARMARM - 4.4.8).
 123 def FeatureVirtualization : SubtargetFeature<"virtualization",
 124                                  "HasVirtualization", "true",
 125                                  "Supports Virtualization extension",
 126                                  [FeatureHWDiv, FeatureHWDivARM]>;
 127
 128 // M-series ISA
 129 def FeatureMClass : SubtargetFeature<"mclass", "ARMProcClass", "MClass",
 130                                      "Is microcontroller profile ('M' series)">;
 131
 132 // R-series ISA
 133 def FeatureRClass : SubtargetFeature<"rclass", "ARMProcClass", "RClass",
 134                                      "Is realtime profile ('R' series)">;
 135
 136 // A-series ISA
 137 def FeatureAClass : SubtargetFeature<"aclass", "ARMProcClass", "AClass",
 138                                      "Is application profile ('A' series)">;
 139
 140 // Special TRAP encoding for NaCl, which looks like a TRAP in Thumb too.
 141 // See ARMInstrInfo.td for details.
 142 def FeatureNaClTrap : SubtargetFeature<"nacl-trap", "UseNaClTrap", "true",
 143                                        "NaCl trap">;
 144
 145 // ARM ISAs.
 146 def HasV4TOps   : SubtargetFeature<"v4t", "HasV4TOps", "true",
 147                                    "Support ARM v4T instructions">;
 148 def HasV5TOps   : SubtargetFeature<"v5t", "HasV5TOps", "true",
 149                                    "Support ARM v5T instructions",
 150                                    [HasV4TOps]>;
 151 def HasV5TEOps  : SubtargetFeature<"v5te", "HasV5TEOps", "true",
 152                              "Support ARM v5TE, v5TEj, and v5TExp instructions",
 153                                    [HasV5TOps]>;
 154 def HasV6Ops    : SubtargetFeature<"v6", "HasV6Ops", "true",
 155                                    "Support ARM v6 instructions",
 156                                    [HasV5TEOps]>;
 157 def HasV6MOps   : SubtargetFeature<"v6m", "HasV6MOps", "true",
 158                                    "Support ARM v6M instructions",
 159                                    [HasV6Ops]>;
 160 def HasV6T2Ops  : SubtargetFeature<"v6t2", "HasV6T2Ops", "true",
 161                                    "Support ARM v6t2 instructions",
 162                                    [HasV6MOps, FeatureThumb2]>;
 163 def HasV7Ops    : SubtargetFeature<"v7", "HasV7Ops", "true",
 164                                    "Support ARM v7 instructions",
 165                                    [HasV6T2Ops, FeaturePerfMon]>;
 166 def HasV8Ops    : SubtargetFeature<"v8", "HasV8Ops", "true",
 167                                    "Support ARM v8 instructions",
 168                                    [HasV7Ops, FeatureVirtualization,
 169                                     FeatureMP]>;
 170
 171 //===----------------------------------------------------------------------===//
 172 // ARM Processors supported.
 173 //
 174
 175 include "ARMSchedule.td"
 176
 177 // ARM processor families.
 178 def ProcA5      : SubtargetFeature<"a5", "ARMProcFamily", "CortexA5",
 179                                    "Cortex-A5 ARM processors",
 180                                    [FeatureSlowFPBrcc, FeatureHasSlowFPVMLx,
 181                                     FeatureVMLxForwarding, FeatureT2XtPk,
 182                                     FeatureTrustZone]>;
 183 def ProcA7      : SubtargetFeature<"a7", "ARMProcFamily", "CortexA7",
 184                                    "Cortex-A7 ARM processors",
 185                                    [FeatureSlowFPBrcc, FeatureHasSlowFPVMLx,
 186                                     FeatureVMLxForwarding, FeatureT2XtPk,
 187                                     FeatureVFP4, FeatureMP,
 188                                     FeatureHWDiv, FeatureHWDivARM,
 189                                     FeatureTrustZone, FeatureVirtualization]>;
 190 def ProcA8      : SubtargetFeature<"a8", "ARMProcFamily", "CortexA8",
 191                                    "Cortex-A8 ARM processors",
 192                                    [FeatureSlowFPBrcc, FeatureHasSlowFPVMLx,
 193                                     FeatureVMLxForwarding, FeatureT2XtPk,
 194                                     FeatureTrustZone]>;
 195 def ProcA9      : SubtargetFeature<"a9", "ARMProcFamily", "CortexA9",
 196                                    "Cortex-A9 ARM processors",
 197                                    [FeatureVMLxForwarding,
 198                                     FeatureT2XtPk, FeatureFP16,
 199                                     FeatureAvoidPartialCPSR,
 200                                     FeatureTrustZone]>;
 201 def ProcSwift   : SubtargetFeature<"swift", "ARMProcFamily", "Swift",
 202                                    "Swift ARM processors",
 203                                    [FeatureNEONForFP, FeatureT2XtPk,
 204                                     FeatureVFP4, FeatureMP, FeatureHWDiv,
 205                                     FeatureHWDivARM, FeatureAvoidPartialCPSR,
 206                                     FeatureAvoidMOVsShOp,
 207                                     FeatureHasSlowFPVMLx, FeatureTrustZone]>;
 208
 209 // FIXME: It has not been determined if A15 has these features.
 210 def ProcA15      : SubtargetFeature<"a15", "ARMProcFamily", "CortexA15",
 211                                    "Cortex-A15 ARM processors",
 212                                    [FeatureT2XtPk, FeatureVFP4,
 213                                     FeatureMP, FeatureHWDiv, FeatureHWDivARM,
 214                                     FeatureAvoidPartialCPSR,
 215                                     FeatureTrustZone, FeatureVirtualization]>;
 216
 217 def ProcA53     : SubtargetFeature<"a53", "ARMProcFamily", "CortexA53",
 218                                    "Cortex-A53 ARM processors",
 219                                    [FeatureHWDiv, FeatureHWDivARM,
 220                                     FeatureTrustZone, FeatureT2XtPk,
 221                                     FeatureCrypto, FeatureCRC]>;
 222
 223 def ProcA57     : SubtargetFeature<"a57", "ARMProcFamily", "CortexA57",
 224                                    "Cortex-A57 ARM processors",
 225                                    [FeatureHWDiv, FeatureHWDivARM,
 226                                     FeatureTrustZone, FeatureT2XtPk,
 227                                     FeatureCrypto, FeatureCRC]>;
 228
 229 def ProcR5      : SubtargetFeature<"r5", "ARMProcFamily", "CortexR5",
 230                                    "Cortex-R5 ARM processors",
 231                                    [FeatureSlowFPBrcc,
 232                                     FeatureHWDiv, FeatureHWDivARM,
 233                                     FeatureHasSlowFPVMLx,
 234                                     FeatureAvoidPartialCPSR,
 235                                     FeatureT2XtPk]>;
 236
 237 class ProcNoItin<string Name, list<SubtargetFeature> Features>
 238  : Processor<Name, NoItineraries, Features>;
 239
 240 // V4 Processors.
 241 def : ProcNoItin<"generic",         []>;
 242 def : ProcNoItin<"arm8",            []>;
 243 def : ProcNoItin<"arm810",          []>;
 244 def : ProcNoItin<"strongarm",       []>;
 245 def : ProcNoItin<"strongarm110",    []>;
 246 def : ProcNoItin<"strongarm1100",   []>;
 247 def : ProcNoItin<"strongarm1110",   []>;
 248
 249 // V4T Processors.
 250 def : ProcNoItin<"arm7tdmi",        [HasV4TOps]>;
 251 def : ProcNoItin<"arm7tdmi-s",      [HasV4TOps]>;
 252 def : ProcNoItin<"arm710t",         [HasV4TOps]>;
 253 def : ProcNoItin<"arm720t",         [HasV4TOps]>;
 254 def : ProcNoItin<"arm9",            [HasV4TOps]>;
 255 def : ProcNoItin<"arm9tdmi",        [HasV4TOps]>;
 256 def : ProcNoItin<"arm920",          [HasV4TOps]>;
 257 def : ProcNoItin<"arm920t",         [HasV4TOps]>;
 258 def : ProcNoItin<"arm922t",         [HasV4TOps]>;
 259 def : ProcNoItin<"arm940t",         [HasV4TOps]>;
 260 def : ProcNoItin<"ep9312",          [HasV4TOps]>;
 261
 262 // V5T Processors.
 263 def : ProcNoItin<"arm10tdmi",       [HasV5TOps]>;
 264 def : ProcNoItin<"arm1020t",        [HasV5TOps]>;
 265
 266 // V5TE Processors.
 267 def : ProcNoItin<"arm9e",           [HasV5TEOps]>;
 268 def : ProcNoItin<"arm926ej-s",      [HasV5TEOps]>;
 269 def : ProcNoItin<"arm946e-s",       [HasV5TEOps]>;
 270 def : ProcNoItin<"arm966e-s",       [HasV5TEOps]>;
 271 def : ProcNoItin<"arm968e-s",       [HasV5TEOps]>;
 272 def : ProcNoItin<"arm10e",          [HasV5TEOps]>;
 273 def : ProcNoItin<"arm1020e",        [HasV5TEOps]>;
 274 def : ProcNoItin<"arm1022e",        [HasV5TEOps]>;
 275 def : ProcNoItin<"xscale",          [HasV5TEOps]>;
 276 def : ProcNoItin<"iwmmxt",          [HasV5TEOps]>;
 277
 278 // V6 Processors.
 279 def : Processor<"arm1136j-s",       ARMV6Itineraries, [HasV6Ops]>;
 280 def : Processor<"arm1136jf-s",      ARMV6Itineraries, [HasV6Ops, FeatureVFP2,
 281                                                        FeatureHasSlowFPVMLx]>;
 282 def : Processor<"arm1176jz-s",      ARMV6Itineraries, [HasV6Ops]>;
 283 def : Processor<"arm1176jzf-s",     ARMV6Itineraries, [HasV6Ops, FeatureVFP2,
 284                                                        FeatureHasSlowFPVMLx]>;
 285 def : Processor<"mpcorenovfp",      ARMV6Itineraries, [HasV6Ops]>;
 286 def : Processor<"mpcore",           ARMV6Itineraries, [HasV6Ops, FeatureVFP2,
 287                                                        FeatureHasSlowFPVMLx]>;
 288
 289 // V6M Processors.
 290 def : Processor<"cortex-m0",        ARMV6Itineraries, [HasV6MOps, FeatureNoARM,
 291                                                        FeatureDB, FeatureMClass]>;
 292
 293 // V6T2 Processors.
 294 def : Processor<"arm1156t2-s",      ARMV6Itineraries, [HasV6T2Ops,
 295                                                        FeatureDSPThumb2]>;
 296 def : Processor<"arm1156t2f-s",     ARMV6Itineraries, [HasV6T2Ops, FeatureVFP2,
 297                                                        FeatureHasSlowFPVMLx,
 298                                                        FeatureDSPThumb2]>;
 299
 300 // V7a Processors.
 301 // FIXME: A5 has currently the same Schedule model as A8
 302 def : ProcessorModel<"cortex-a5",   CortexA8Model,
 303                                     [ProcA5, HasV7Ops, FeatureNEON, FeatureDB,
 304                                      FeatureVFP4, FeatureDSPThumb2,
 305                                      FeatureHasRAS, FeatureAClass]>;
 306 def : ProcessorModel<"cortex-a7",   CortexA8Model,
 307                                     [ProcA7, HasV7Ops, FeatureNEON, FeatureDB,
 308                                      FeatureDSPThumb2, FeatureHasRAS,
 309                                      FeatureAClass]>;
 310 def : ProcessorModel<"cortex-a8",   CortexA8Model,
 311                                     [ProcA8, HasV7Ops, FeatureNEON, FeatureDB,
 312                                      FeatureDSPThumb2, FeatureHasRAS,
 313                                      FeatureAClass]>;
 314 def : ProcessorModel<"cortex-a9",   CortexA9Model,
 315                                     [ProcA9, HasV7Ops, FeatureNEON, FeatureDB,
 316                                      FeatureDSPThumb2, FeatureHasRAS,
 317                                      FeatureAClass]>;
 318 def : ProcessorModel<"cortex-a9-mp", CortexA9Model,
 319                                     [ProcA9, HasV7Ops, FeatureNEON, FeatureDB,
 320                                      FeatureDSPThumb2, FeatureMP,
 321                                      FeatureHasRAS, FeatureAClass]>;
 322 // FIXME: A15 has currently the same ProcessorModel as A9.
 323 def : ProcessorModel<"cortex-a15",   CortexA9Model,
 324                                     [ProcA15, HasV7Ops, FeatureNEON, FeatureDB,
 325                                      FeatureDSPThumb2, FeatureHasRAS,
 326                                      FeatureAClass]>;
 327 // FIXME: R5 has currently the same ProcessorModel as A8.
 328 def : ProcessorModel<"cortex-r5",   CortexA8Model,
 329                                     [ProcR5, HasV7Ops, FeatureDB,
 330                                      FeatureVFP3, FeatureDSPThumb2,
 331                                      FeatureHasRAS, FeatureVFPOnlySP,
 332                                      FeatureD16, FeatureRClass]>;
 333
 334 // V7M Processors.
 335 def : ProcNoItin<"cortex-m3",       [HasV7Ops,
 336                                      FeatureThumb2, FeatureNoARM, FeatureDB,
 337                                      FeatureHWDiv, FeatureMClass]>;
 338
 339 // V7EM Processors.
 340 def : ProcNoItin<"cortex-m4",       [HasV7Ops,
 341                                      FeatureThumb2, FeatureNoARM, FeatureDB,
 342                                      FeatureHWDiv, FeatureDSPThumb2,
 343                                      FeatureT2XtPk, FeatureVFP4,
 344                                      FeatureVFPOnlySP, FeatureD16,
 345                                      FeatureMClass]>;
 346
 347 // Swift uArch Processors.
 348 def : ProcessorModel<"swift",       SwiftModel,
 349                                     [ProcSwift, HasV7Ops, FeatureNEON,
 350                                      FeatureDB, FeatureDSPThumb2,
 351                                      FeatureHasRAS, FeatureAClass]>;
 352
 353 // V8 Processors
 354 def : ProcNoItin<"cortex-a53",      [ProcA53, HasV8Ops, FeatureAClass,
 355                                     FeatureDB, FeatureFPARMv8,
 356                                     FeatureNEON, FeatureDSPThumb2]>;
 357 def : ProcNoItin<"cortex-a57",      [ProcA57, HasV8Ops, FeatureAClass,
 358                                     FeatureDB, FeatureFPARMv8,
 359                                     FeatureNEON, FeatureDSPThumb2]>;
 360
 361 //===----------------------------------------------------------------------===//
 362 // Register File Description
 363 //===----------------------------------------------------------------------===//
 364
 365 include "ARMRegisterInfo.td"
 366
 367 include "ARMCallingConv.td"
 368
 369 //===----------------------------------------------------------------------===//
 370 // Instruction Descriptions
 371 //===----------------------------------------------------------------------===//
 372
 373 include "ARMInstrInfo.td"
 374
 375 def ARMInstrInfo : InstrInfo;
 376
 377
 378 //===----------------------------------------------------------------------===//
 379 // Assembly printer
 380 //===----------------------------------------------------------------------===//
 381 // ARM Uses the MC printer for asm output, so make sure the TableGen
 382 // AsmWriter bits get associated with the correct class.
 383 def ARMAsmWriter : AsmWriter {
 384   string AsmWriterClassName  = "InstPrinter";
 385   bit isMCAsmWriter = 1;
 386 }
 387
 388 //===----------------------------------------------------------------------===//
 389 // Declare the target which we are implementing
 390 //===----------------------------------------------------------------------===//
 391
 392 def ARM : Target {
 393   // Pull in Instruction Info:
 394   let InstructionSet = ARMInstrInfo;
 395
 396   let AssemblyWriters = [ARMAsmWriter];
 397 }