lib/Target/AMDGPU/AMDGPU.td

   1 //===-- AMDGPU.td - AMDGPU Tablegen files ------------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 include "llvm/Target/Target.td"
  11
  12 //===----------------------------------------------------------------------===//
  13 // Subtarget Features
  14 //===----------------------------------------------------------------------===//
  15
  16 // Debugging Features
  17
  18 def FeatureDumpCode : SubtargetFeature <"DumpCode",
  19         "DumpCode",
  20         "true",
  21         "Dump MachineInstrs in the CodeEmitter">;
  22
  23 def FeatureDumpCodeLower : SubtargetFeature <"dumpcode",
  24         "DumpCode",
  25         "true",
  26         "Dump MachineInstrs in the CodeEmitter">;
  27
  28 def FeatureIRStructurizer : SubtargetFeature <"disable-irstructurizer",
  29         "EnableIRStructurizer",
  30         "false",
  31         "Disable IR Structurizer">;
  32
  33 def FeaturePromoteAlloca : SubtargetFeature <"promote-alloca",
  34         "EnablePromoteAlloca",
  35         "true",
  36         "Enable promote alloca pass">;
  37
  38 // Target features
  39
  40 def FeatureIfCvt : SubtargetFeature <"disable-ifcvt",
  41         "EnableIfCvt",
  42         "false",
  43         "Disable the if conversion pass">;
  44
  45 def FeatureFP64 : SubtargetFeature<"fp64",
  46         "FP64",
  47         "true",
  48         "Enable double precision operations">;
  49
  50 def FeatureFP64Denormals : SubtargetFeature<"fp64-denormals",
  51         "FP64Denormals",
  52         "true",
  53         "Enable double precision denormal handling",
  54         [FeatureFP64]>;
  55
  56 def FeatureFastFMAF32 : SubtargetFeature<"fast-fmaf",
  57         "FastFMAF32",
  58         "true",
  59         "Assuming f32 fma is at least as fast as mul + add",
  60         []>;
  61
  62 // Some instructions do not support denormals despite this flag. Using
  63 // fp32 denormals also causes instructions to run at the double
  64 // precision rate for the device.
  65 def FeatureFP32Denormals : SubtargetFeature<"fp32-denormals",
  66         "FP32Denormals",
  67         "true",
  68         "Enable single precision denormal handling">;
  69
  70 def Feature64BitPtr : SubtargetFeature<"64BitPtr",
  71         "Is64bit",
  72         "true",
  73         "Specify if 64-bit addressing should be used">;
  74
  75 def FeatureR600ALUInst : SubtargetFeature<"R600ALUInst",
  76         "R600ALUInst",
  77         "false",
  78         "Older version of ALU instructions encoding">;
  79
  80 def FeatureVertexCache : SubtargetFeature<"HasVertexCache",
  81         "HasVertexCache",
  82         "true",
  83         "Specify use of dedicated vertex cache">;
  84
  85 def FeatureCaymanISA : SubtargetFeature<"caymanISA",
  86         "CaymanISA",
  87         "true",
  88         "Use Cayman ISA">;
  89
  90 def FeatureCFALUBug : SubtargetFeature<"cfalubug",
  91         "CFALUBug",
  92         "true",
  93         "GPU has CF_ALU bug">;
  94
  95 // XXX - This should probably be removed once enabled by default
  96 def FeatureEnableLoadStoreOpt : SubtargetFeature <"load-store-opt",
  97         "EnableLoadStoreOpt",
  98         "true",
  99         "Enable SI load/store optimizer pass">;
 100
 101 def FeatureFlatAddressSpace : SubtargetFeature<"flat-address-space",
 102         "FlatAddressSpace",
 103         "true",
 104         "Support flat address space">;
 105
 106 def FeatureVGPRSpilling : SubtargetFeature<"vgpr-spilling",
 107         "EnableVGPRSpilling",
 108         "true",
 109         "Enable spilling of VGPRs to scratch memory">;
 110
 111 def FeatureSGPRInitBug : SubtargetFeature<"sgpr-init-bug",
 112         "SGPRInitBug",
 113         "true",
 114         "VI SGPR initilization bug requiring a fixed SGPR allocation size">;
 115
 116 class SubtargetFeatureFetchLimit <string Value> :
 117                           SubtargetFeature <"fetch"#Value,
 118         "TexVTXClauseSize",
 119         Value,
 120         "Limit the maximum number of fetches in a clause to "#Value>;
 121
 122 def FeatureFetchLimit8 : SubtargetFeatureFetchLimit <"8">;
 123 def FeatureFetchLimit16 : SubtargetFeatureFetchLimit <"16">;
 124
 125 class SubtargetFeatureWavefrontSize <int Value> : SubtargetFeature<
 126         "wavefrontsize"#Value,
 127         "WavefrontSize",
 128         !cast<string>(Value),
 129         "The number of threads per wavefront">;
 130
 131 def FeatureWavefrontSize16 : SubtargetFeatureWavefrontSize<16>;
 132 def FeatureWavefrontSize32 : SubtargetFeatureWavefrontSize<32>;
 133 def FeatureWavefrontSize64 : SubtargetFeatureWavefrontSize<64>;
 134
 135 class SubtargetFeatureLDSBankCount <int Value> : SubtargetFeature <
 136       "ldsbankcount"#Value,
 137       "LDSBankCount",
 138       !cast<string>(Value),
 139       "The number of LDS banks per compute unit.">;
 140
 141 def FeatureLDSBankCount16 : SubtargetFeatureLDSBankCount<16>;
 142 def FeatureLDSBankCount32 : SubtargetFeatureLDSBankCount<32>;
 143
 144 class SubtargetFeatureISAVersion <int Major, int Minor, int Stepping>
 145                                  : SubtargetFeature <
 146       "isaver"#Major#"."#Minor#"."#Stepping,
 147       "IsaVersion",
 148       "ISAVersion"#Major#"_"#Minor#"_"#Stepping,
 149       "Instruction set version number"
 150 >;
 151
 152 def FeatureISAVersion7_0_0 : SubtargetFeatureISAVersion <7,0,0>;
 153 def FeatureISAVersion7_0_1 : SubtargetFeatureISAVersion <7,0,1>;
 154 def FeatureISAVersion8_0_0 : SubtargetFeatureISAVersion <8,0,0>;
 155 def FeatureISAVersion8_0_1 : SubtargetFeatureISAVersion <8,0,1>;
 156
 157 class SubtargetFeatureLocalMemorySize <int Value> : SubtargetFeature<
 158         "localmemorysize"#Value,
 159         "LocalMemorySize",
 160         !cast<string>(Value),
 161         "The size of local memory in bytes">;
 162
 163 def FeatureGCN : SubtargetFeature<"gcn",
 164         "IsGCN",
 165         "true",
 166         "GCN or newer GPU">;
 167
 168 def FeatureGCN1Encoding : SubtargetFeature<"gcn1-encoding",
 169         "GCN1Encoding",
 170         "true",
 171         "Encoding format for SI and CI">;
 172
 173 def FeatureGCN3Encoding : SubtargetFeature<"gcn3-encoding",
 174         "GCN3Encoding",
 175         "true",
 176         "Encoding format for VI">;
 177
 178 def FeatureCIInsts : SubtargetFeature<"ci-insts",
 179         "CIInsts",
 180         "true",
 181         "Additional intstructions for CI+">;
 182
 183 // Dummy feature used to disable assembler instructions.
 184 def FeatureDisable : SubtargetFeature<"",
 185                                       "FeatureDisable","true",
 186                                       "Dummy feature to disable assembler"
 187                                       " instructions">;
 188
 189 class SubtargetFeatureGeneration <string Value,
 190                                   list<SubtargetFeature> Implies> :
 191         SubtargetFeature <Value, "Gen", "AMDGPUSubtarget::"#Value,
 192                           Value#" GPU generation", Implies>;
 193
 194 def FeatureLocalMemorySize0 : SubtargetFeatureLocalMemorySize<0>;
 195 def FeatureLocalMemorySize32768 : SubtargetFeatureLocalMemorySize<32768>;
 196 def FeatureLocalMemorySize65536 : SubtargetFeatureLocalMemorySize<65536>;
 197
 198 def FeatureR600 : SubtargetFeatureGeneration<"R600",
 199         [FeatureR600ALUInst, FeatureFetchLimit8, FeatureLocalMemorySize0]>;
 200
 201 def FeatureR700 : SubtargetFeatureGeneration<"R700",
 202         [FeatureFetchLimit16, FeatureLocalMemorySize0]>;
 203
 204 def FeatureEvergreen : SubtargetFeatureGeneration<"EVERGREEN",
 205         [FeatureFetchLimit16, FeatureLocalMemorySize32768]>;
 206
 207 def FeatureNorthernIslands : SubtargetFeatureGeneration<"NORTHERN_ISLANDS",
 208         [FeatureFetchLimit16, FeatureWavefrontSize64,
 209          FeatureLocalMemorySize32768]
 210 >;
 211
 212 def FeatureSouthernIslands : SubtargetFeatureGeneration<"SOUTHERN_ISLANDS",
 213         [Feature64BitPtr, FeatureFP64, FeatureLocalMemorySize32768,
 214          FeatureWavefrontSize64, FeatureGCN, FeatureGCN1Encoding,
 215          FeatureLDSBankCount32]>;
 216
 217 def FeatureSeaIslands : SubtargetFeatureGeneration<"SEA_ISLANDS",
 218         [Feature64BitPtr, FeatureFP64, FeatureLocalMemorySize65536,
 219          FeatureWavefrontSize64, FeatureGCN, FeatureFlatAddressSpace,
 220          FeatureGCN1Encoding, FeatureCIInsts]>;
 221
 222 def FeatureVolcanicIslands : SubtargetFeatureGeneration<"VOLCANIC_ISLANDS",
 223         [Feature64BitPtr, FeatureFP64, FeatureLocalMemorySize65536,
 224          FeatureWavefrontSize64, FeatureFlatAddressSpace, FeatureGCN,
 225          FeatureGCN3Encoding, FeatureCIInsts, FeatureLDSBankCount32]>;
 226
 227 //===----------------------------------------------------------------------===//
 228
 229 def AMDGPUInstrInfo : InstrInfo {
 230   let guessInstructionProperties = 1;
 231   let noNamedPositionallyEncodedOperands = 1;
 232 }
 233
 234 def AMDGPUAsmParser : AsmParser {
 235   // Some of the R600 registers have the same name, so this crashes.
 236   // For example T0_XYZW and T0_XY both have the asm name T0.
 237   let ShouldEmitMatchRegisterName = 0;
 238 }
 239
 240 def AMDGPU : Target {
 241   // Pull in Instruction Info:
 242   let InstructionSet = AMDGPUInstrInfo;
 243   let AssemblyParsers = [AMDGPUAsmParser];
 244 }
 245
 246 // Dummy Instruction itineraries for pseudo instructions
 247 def ALU_NULL : FuncUnit;
 248 def NullALU : InstrItinClass;
 249
 250 //===----------------------------------------------------------------------===//
 251 // Predicate helper class
 252 //===----------------------------------------------------------------------===//
 253
 254 def TruePredicate : Predicate<"true">;
 255 def isSICI : Predicate<
 256   "Subtarget->getGeneration() == AMDGPUSubtarget::SOUTHERN_ISLANDS ||"
 257   "Subtarget->getGeneration() == AMDGPUSubtarget::SEA_ISLANDS"
 258 >, AssemblerPredicate<"FeatureGCN1Encoding">;
 259
 260 class PredicateControl {
 261   Predicate SubtargetPredicate;
 262   Predicate SIAssemblerPredicate = isSICI;
 263   list<Predicate> AssemblerPredicates = [];
 264   Predicate AssemblerPredicate = TruePredicate;
 265   list<Predicate> OtherPredicates = [];
 266   list<Predicate> Predicates = !listconcat([SubtargetPredicate, AssemblerPredicate],
 267                                             AssemblerPredicates,
 268                                             OtherPredicates);
 269 }
 270
 271 // Include AMDGPU TD files
 272 include "R600Schedule.td"
 273 include "SISchedule.td"
 274 include "Processors.td"
 275 include "AMDGPUInstrInfo.td"
 276 include "AMDGPUIntrinsics.td"
 277 include "AMDGPURegisterInfo.td"
 278 include "AMDGPUInstructions.td"
 279 include "AMDGPUCallingConv.td"