lib/AsmParser/Lexer.l

   1 /*===-- Lexer.l - Scanner for llvm assembly files --------------*- C++ -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file implements the flex scanner for LLVM assembly languages files.
  11 //
  12 //===----------------------------------------------------------------------===*/
  13
  14 %option prefix="llvmAsm"
  15 %option yylineno
  16 %option nostdinit
  17 %option never-interactive
  18 %option batch
  19 %option noyywrap
  20 %option nodefault
  21 %option 8bit
  22 %option outfile="Lexer.cpp"
  23 %option ecs
  24 %option noreject
  25 %option noyymore
  26
  27 %{
  28 #include "ParserInternals.h"
  29 #include "llvm/Module.h"
  30 #include "llvm/Support/MathExtras.h"
  31 #include <list>
  32 #include "llvmAsmParser.h"
  33 #include <cctype>
  34 #include <cstdlib>
  35
  36 void set_scan_file(FILE * F){
  37   yy_switch_to_buffer(yy_create_buffer( F, YY_BUF_SIZE ) );
  38 }
  39 void set_scan_string (const char * str) {
  40   yy_scan_string (str);
  41 }
  42
  43 // Construct a token value for a non-obsolete token
  44 #define RET_TOK(type, Enum, sym) \
  45   llvmAsmlval.type = Instruction::Enum; \
  46   return sym
  47
  48 // Construct a token value for an obsolete token
  49 #define RET_TY(CTYPE, SYM) \
  50   llvmAsmlval.PrimType = CTYPE;\
  51   return SYM
  52
  53 namespace llvm {
  54
  55 // TODO: All of the static identifiers are figured out by the lexer,
  56 // these should be hashed to reduce the lexer size
  57
  58
  59 // atoull - Convert an ascii string of decimal digits into the unsigned long
  60 // long representation... this does not have to do input error checking,
  61 // because we know that the input will be matched by a suitable regex...
  62 //
  63 static uint64_t atoull(const char *Buffer) {
  64   uint64_t Result = 0;
  65   for (; *Buffer; Buffer++) {
  66     uint64_t OldRes = Result;
  67     Result *= 10;
  68     Result += *Buffer-'0';
  69     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  70       GenerateError("constant bigger than 64 bits detected!");
  71   }
  72   return Result;
  73 }
  74
  75 static uint64_t HexIntToVal(const char *Buffer) {
  76   uint64_t Result = 0;
  77   for (; *Buffer; ++Buffer) {
  78     uint64_t OldRes = Result;
  79     Result *= 16;
  80     char C = *Buffer;
  81     if (C >= '0' && C <= '9')
  82       Result += C-'0';
  83     else if (C >= 'A' && C <= 'F')
  84       Result += C-'A'+10;
  85     else if (C >= 'a' && C <= 'f')
  86       Result += C-'a'+10;
  87
  88     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  89       GenerateError("constant bigger than 64 bits detected!");
  90   }
  91   return Result;
  92 }
  93
  94
  95 // HexToFP - Convert the ascii string in hexidecimal format to the floating
  96 // point representation of it.
  97 //
  98 static double HexToFP(const char *Buffer) {
  99   return BitsToDouble(HexIntToVal(Buffer));   // Cast Hex constant to double
 100 }
 101
 102
 103 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
 104 // appropriate character.
 105 char *UnEscapeLexed(char *Buffer, char* EndBuffer) {
 106   char *BOut = Buffer;
 107   for (char *BIn = Buffer; *BIn; ) {
 108     if (BIn[0] == '\\') {
 109       if (BIn < EndBuffer-1 && BIn[1] == '\\') {
 110         *BOut++ = '\\'; // Two \ becomes one
 111         BIn += 2;
 112       } else if (BIn < EndBuffer-2 && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
 113         char Tmp = BIn[3]; BIn[3] = 0;      // Terminate string
 114         *BOut = (char)strtol(BIn+1, 0, 16); // Convert to number
 115         BIn[3] = Tmp;                       // Restore character
 116         BIn += 3;                           // Skip over handled chars
 117         ++BOut;
 118       } else {
 119         *BOut++ = *BIn++;
 120       }
 121     } else {
 122       *BOut++ = *BIn++;
 123     }
 124   }
 125   return BOut;
 126 }
 127
 128 } // End llvm namespace
 129
 130 using namespace llvm;
 131
 132 #define YY_NEVER_INTERACTIVE 1
 133 %}
 134
 135
 136
 137 /* Comments start with a ; and go till end of line */
 138 Comment    ;.*
 139
 140 /* Local Values and Type identifiers start with a % sign */
 141 LocalVarName       %[-a-zA-Z$._][-a-zA-Z$._0-9]*
 142
 143 /* Global Value identifiers start with an @ sign */
 144 GlobalVarName       @[-a-zA-Z$._][-a-zA-Z$._0-9]*
 145
 146 /* Label identifiers end with a colon */
 147 Label       [-a-zA-Z$._0-9]+:
 148 QuoteLabel \"[^\"]+\":
 149
 150 /* Quoted names can contain any character except " and \ */
 151 StringConstant \"[^\"]*\"
 152 AtStringConstant @\"[^\"]*\"
 153 PctStringConstant %\"[^\"]*\"
 154
 155 /* LocalVarID/GlobalVarID: match an unnamed local variable slot ID. */
 156 LocalVarID     %[0-9]+
 157 GlobalVarID    @[0-9]+
 158
 159 /* Integer types are specified with i and a bitwidth */
 160 IntegerType i[0-9]+
 161
 162 /* E[PN]Integer: match positive and negative literal integer values. */
 163 PInteger   [0-9]+
 164 NInteger  -[0-9]+
 165
 166 /* FPConstant - A Floating point constant.
 167  */
 168 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 169
 170 /* HexFPConstant - Floating point constant represented in IEEE format as a
 171  *  hexadecimal number for when exponential notation is not precise enough.
 172  */
 173 HexFPConstant 0x[0-9A-Fa-f]+
 174
 175 /* HexIntConstant - Hexadecimal constant generated by the CFE to avoid forcing
 176  * it to deal with 64 bit numbers.
 177  */
 178 HexIntConstant [us]0x[0-9A-Fa-f]+
 179
 180 /* WSNL - shorthand for newline followed by whitespace */
 181 WSNL [ \r\t\n]*$
 182 %%
 183
 184 {Comment}       { /* Ignore comments for now */ }
 185
 186 begin           { return BEGINTOK; }
 187 end             { return ENDTOK; }
 188 true            { return TRUETOK;  }
 189 false           { return FALSETOK; }
 190 declare         { return DECLARE; }
 191 define          { return DEFINE; }
 192 global          { return GLOBAL; }
 193 constant        { return CONSTANT; }
 194 internal        { return INTERNAL; }
 195 linkonce        { return LINKONCE; }
 196 weak            { return WEAK; }
 197 appending       { return APPENDING; }
 198 dllimport       { return DLLIMPORT; }
 199 dllexport       { return DLLEXPORT; }
 200 hidden          { return HIDDEN; }
 201 protected       { return PROTECTED; }
 202 extern_weak     { return EXTERN_WEAK; }
 203 external        { return EXTERNAL; }
 204 thread_local    { return THREAD_LOCAL; }
 205 zeroinitializer { return ZEROINITIALIZER; }
 206 \.\.\.          { return DOTDOTDOT; }
 207 undef           { return UNDEF; }
 208 null            { return NULL_TOK; }
 209 to              { return TO; }
 210 tail            { return TAIL; }
 211 target          { return TARGET; }
 212 triple          { return TRIPLE; }
 213 deplibs         { return DEPLIBS; }
 214 datalayout      { return DATALAYOUT; }
 215 volatile        { return VOLATILE; }
 216 align           { return ALIGN;  }
 217 section         { return SECTION; }
 218 alias           { return ALIAS; }
 219 module          { return MODULE; }
 220 asm             { return ASM_TOK; }
 221 sideeffect      { return SIDEEFFECT; }
 222
 223 cc              { return CC_TOK; }
 224 ccc             { return CCC_TOK; }
 225 fastcc          { return FASTCC_TOK; }
 226 coldcc          { return COLDCC_TOK; }
 227 x86_stdcallcc   { return X86_STDCALLCC_TOK; }
 228 x86_fastcallcc  { return X86_FASTCALLCC_TOK; }
 229
 230 signext         { return SIGNEXT; }
 231 zeroext         { return ZEROEXT; }
 232 inreg           { return INREG; }
 233 sret            { return SRET;  }
 234 nounwind        { return NOUNWIND; }
 235 noreturn        { return NORETURN; }
 236 noalias         { return NOALIAS; }
 237 byval           { return BYVAL; }
 238 nest            { return NEST; }
 239 sext{WSNL}      { // For auto-upgrade only, drop in LLVM 3.0
 240                   return SIGNEXT; }
 241 zext{WSNL}      { // For auto-upgrade only, drop in LLVM 3.0
 242                   return ZEROEXT; }
 243
 244 void            { RET_TY(Type::VoidTy,  VOID);  }
 245 float           { RET_TY(Type::FloatTy, FLOAT); }
 246 double          { RET_TY(Type::DoubleTy,DOUBLE);}
 247 label           { RET_TY(Type::LabelTy, LABEL); }
 248 type            { return TYPE;   }
 249 opaque          { return OPAQUE; }
 250 {IntegerType}   { uint64_t NumBits = atoull(yytext+1);
 251                   if (NumBits < IntegerType::MIN_INT_BITS ||
 252                       NumBits > IntegerType::MAX_INT_BITS)
 253                     GenerateError("Bitwidth for integer type out of range!");
 254                   const Type* Ty = IntegerType::get(NumBits);
 255                   RET_TY(Ty, INTTYPE);
 256                 }
 257
 258 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 259 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 260 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 261 udiv            { RET_TOK(BinaryOpVal, UDiv, UDIV); }
 262 sdiv            { RET_TOK(BinaryOpVal, SDiv, SDIV); }
 263 fdiv            { RET_TOK(BinaryOpVal, FDiv, FDIV); }
 264 urem            { RET_TOK(BinaryOpVal, URem, UREM); }
 265 srem            { RET_TOK(BinaryOpVal, SRem, SREM); }
 266 frem            { RET_TOK(BinaryOpVal, FRem, FREM); }
 267 shl             { RET_TOK(BinaryOpVal, Shl, SHL); }
 268 lshr            { RET_TOK(BinaryOpVal, LShr, LSHR); }
 269 ashr            { RET_TOK(BinaryOpVal, AShr, ASHR); }
 270 and             { RET_TOK(BinaryOpVal, And, AND); }
 271 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 272 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 273 icmp            { RET_TOK(OtherOpVal,  ICmp,  ICMP); }
 274 fcmp            { RET_TOK(OtherOpVal,  FCmp,  FCMP); }
 275
 276 eq              { return EQ;  }
 277 ne              { return NE;  }
 278 slt             { return SLT; }
 279 sgt             { return SGT; }
 280 sle             { return SLE; }
 281 sge             { return SGE; }
 282 ult             { return ULT; }
 283 ugt             { return UGT; }
 284 ule             { return ULE; }
 285 uge             { return UGE; }
 286 oeq             { return OEQ; }
 287 one             { return ONE; }
 288 olt             { return OLT; }
 289 ogt             { return OGT; }
 290 ole             { return OLE; }
 291 oge             { return OGE; }
 292 ord             { return ORD; }
 293 uno             { return UNO; }
 294 ueq             { return UEQ; }
 295 une             { return UNE; }
 296
 297 phi             { RET_TOK(OtherOpVal, PHI, PHI_TOK); }
 298 call            { RET_TOK(OtherOpVal, Call, CALL); }
 299 trunc           { RET_TOK(CastOpVal, Trunc, TRUNC); }
 300 zext            { RET_TOK(CastOpVal, ZExt, ZEXT); }
 301 sext            { RET_TOK(CastOpVal, SExt, SEXT); }
 302 fptrunc         { RET_TOK(CastOpVal, FPTrunc, FPTRUNC); }
 303 fpext           { RET_TOK(CastOpVal, FPExt, FPEXT); }
 304 uitofp          { RET_TOK(CastOpVal, UIToFP, UITOFP); }
 305 sitofp          { RET_TOK(CastOpVal, SIToFP, SITOFP); }
 306 fptoui          { RET_TOK(CastOpVal, FPToUI, FPTOUI); }
 307 fptosi          { RET_TOK(CastOpVal, FPToSI, FPTOSI); }
 308 inttoptr        { RET_TOK(CastOpVal, IntToPtr, INTTOPTR); }
 309 ptrtoint        { RET_TOK(CastOpVal, PtrToInt, PTRTOINT); }
 310 bitcast         { RET_TOK(CastOpVal, BitCast, BITCAST); }
 311 select          { RET_TOK(OtherOpVal, Select, SELECT); }
 312 va_arg          { RET_TOK(OtherOpVal, VAArg , VAARG); }
 313 ret             { RET_TOK(TermOpVal, Ret, RET); }
 314 br              { RET_TOK(TermOpVal, Br, BR); }
 315 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 316 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 317 unwind          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 318 unreachable     { RET_TOK(TermOpVal, Unreachable, UNREACHABLE); }
 319
 320 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 321 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 322 free            { RET_TOK(MemOpVal, Free, FREE); }
 323 load            { RET_TOK(MemOpVal, Load, LOAD); }
 324 store           { RET_TOK(MemOpVal, Store, STORE); }
 325 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 326
 327 extractelement  { RET_TOK(OtherOpVal, ExtractElement, EXTRACTELEMENT); }
 328 insertelement   { RET_TOK(OtherOpVal, InsertElement, INSERTELEMENT); }
 329 shufflevector   { RET_TOK(OtherOpVal, ShuffleVector, SHUFFLEVECTOR); }
 330
 331
 332 {LocalVarName}  {
 333                   llvmAsmlval.StrVal = new std::string(yytext+1);   // Skip %
 334                   return LOCALVAR;
 335                 }
 336 {GlobalVarName} {
 337                   llvmAsmlval.StrVal = new std::string(yytext+1);   // Skip @
 338                   return GLOBALVAR;
 339                 }
 340 {Label}         {
 341                   yytext[yyleng-1] = 0;            // nuke colon
 342                   llvmAsmlval.StrVal = new std::string(yytext);
 343                   return LABELSTR;
 344                 }
 345 {QuoteLabel}    {
 346                   yytext[yyleng-2] = 0;  // nuke colon, end quote
 347                   const char* EndChar = UnEscapeLexed(yytext+1, yytext+yyleng);
 348                   llvmAsmlval.StrVal =
 349                     new std::string(yytext+1, EndChar - yytext - 1);
 350                   return LABELSTR;
 351                 }
 352
 353 {StringConstant} { yytext[yyleng-1] = 0;           // nuke end quote
 354                    const char* EndChar = UnEscapeLexed(yytext+1, yytext+yyleng);
 355                    llvmAsmlval.StrVal =
 356                      new std::string(yytext+1, EndChar - yytext - 1);
 357                    return STRINGCONSTANT;
 358                  }
 359 {AtStringConstant} {
 360                      yytext[yyleng-1] = 0;         // nuke end quote
 361                      const char* EndChar =
 362                        UnEscapeLexed(yytext+2, yytext+yyleng);
 363                      llvmAsmlval.StrVal =
 364                        new std::string(yytext+2, EndChar - yytext - 2);
 365                      return ATSTRINGCONSTANT;
 366                    }
 367 {PctStringConstant} {
 368                      yytext[yyleng-1] = 0;           // nuke end quote
 369                      const char* EndChar =
 370                        UnEscapeLexed(yytext+2, yytext+yyleng);
 371                      llvmAsmlval.StrVal =
 372                        new std::string(yytext+2, EndChar - yytext - 2);
 373                      return PCTSTRINGCONSTANT;
 374                    }
 375 {PInteger}      {
 376                   uint32_t numBits = ((yyleng * 64) / 19) + 1;
 377                   APInt Tmp(numBits, yytext, yyleng, 10);
 378                   uint32_t activeBits = Tmp.getActiveBits();
 379                   if (activeBits > 0 && activeBits < numBits)
 380                     Tmp.trunc(activeBits);
 381                   if (Tmp.getBitWidth() > 64) {
 382                     llvmAsmlval.APIntVal = new APInt(Tmp);
 383                     return EUAPINTVAL;
 384                   } else {
 385                     llvmAsmlval.UInt64Val = Tmp.getZExtValue();
 386                     return EUINT64VAL;
 387                   }
 388                 }
 389 {NInteger}      {
 390                   uint32_t numBits = (((yyleng-1) * 64) / 19) + 2;
 391                   APInt Tmp(numBits, yytext, yyleng, 10);
 392                   uint32_t minBits = Tmp.getMinSignedBits();
 393                   if (minBits > 0 && minBits < numBits)
 394                     Tmp.trunc(minBits);
 395                   if (Tmp.getBitWidth() > 64) {
 396                     llvmAsmlval.APIntVal = new APInt(Tmp);
 397                     return ESAPINTVAL;
 398                   } else {
 399                     llvmAsmlval.SInt64Val = Tmp.getSExtValue();
 400                     return ESINT64VAL;
 401                   }
 402                 }
 403
 404 {HexIntConstant} { int len = yyleng - 3;
 405                    uint32_t bits = len * 4;
 406                    APInt Tmp(bits, yytext+3, len, 16);
 407                    uint32_t activeBits = Tmp.getActiveBits();
 408                    if (activeBits > 0 && activeBits < bits)
 409                      Tmp.trunc(activeBits);
 410                    if (Tmp.getBitWidth() > 64) {
 411                      llvmAsmlval.APIntVal = new APInt(Tmp);
 412                      return yytext[0] == 's' ? ESAPINTVAL : EUAPINTVAL;
 413                    } else if (yytext[0] == 's') {
 414                      llvmAsmlval.SInt64Val = Tmp.getSExtValue();
 415                      return ESINT64VAL;
 416                    } else {
 417                      llvmAsmlval.UInt64Val = Tmp.getZExtValue();
 418                      return EUINT64VAL;
 419                    }
 420                  }
 421
 422 {LocalVarID}     {
 423                   uint64_t Val = atoull(yytext+1);
 424                   if ((unsigned)Val != Val)
 425                     GenerateError("Invalid value number (too large)!");
 426                   llvmAsmlval.UIntVal = unsigned(Val);
 427                   return LOCALVAL_ID;
 428                 }
 429 {GlobalVarID}   {
 430                   uint64_t Val = atoull(yytext+1);
 431                   if ((unsigned)Val != Val)
 432                     GenerateError("Invalid value number (too large)!");
 433                   llvmAsmlval.UIntVal = unsigned(Val);
 434                   return GLOBALVAL_ID;
 435                 }
 436
 437 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 438 {HexFPConstant} { llvmAsmlval.FPVal = HexToFP(yytext); return FPVAL; }
 439
 440 <<EOF>>         {
 441                   /* Make sure to free the internal buffers for flex when we are
 442                    * done reading our input!
 443                    */
 444                   yy_delete_buffer(YY_CURRENT_BUFFER);
 445                   return EOF;
 446                 }
 447
 448 [ \r\t\n]       { /* Ignore whitespace */ }
 449 .               { return yytext[0]; }
 450
 451 %%