lib/AsmParser/Lexer.l.cvs

   1 /*===-- Lexer.l - Scanner for llvm assembly files --------------*- C++ -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file implements the flex scanner for LLVM assembly languages files.
  11 //
  12 //===----------------------------------------------------------------------===*/
  13
  14 %option prefix="llvmAsm"
  15 %option yylineno
  16 %option nostdinit
  17 %option never-interactive
  18 %option batch
  19 %option noyywrap
  20 %option nodefault
  21 %option 8bit
  22 %option outfile="Lexer.cpp"
  23 %option ecs
  24 %option noreject
  25 %option noyymore
  26
  27 %{
  28 #include "ParserInternals.h"
  29 #include "llvm/Module.h"
  30 #include <list>
  31 #include "llvmAsmParser.h"
  32 #include <cctype>
  33 #include <cstdlib>
  34
  35 void set_scan_file(FILE * F){
  36   yy_switch_to_buffer(yy_create_buffer( F, YY_BUF_SIZE ) );
  37 }
  38 void set_scan_string (const char * str) {
  39   yy_scan_string (str);
  40 }
  41
  42 #define RET_TOK(type, Enum, sym) \
  43   llvmAsmlval.type = Instruction::Enum; return sym
  44
  45 namespace llvm {
  46
  47 // TODO: All of the static identifiers are figured out by the lexer,
  48 // these should be hashed to reduce the lexer size
  49
  50
  51 // atoull - Convert an ascii string of decimal digits into the unsigned long
  52 // long representation... this does not have to do input error checking,
  53 // because we know that the input will be matched by a suitable regex...
  54 //
  55 static uint64_t atoull(const char *Buffer) {
  56   uint64_t Result = 0;
  57   for (; *Buffer; Buffer++) {
  58     uint64_t OldRes = Result;
  59     Result *= 10;
  60     Result += *Buffer-'0';
  61     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  62       GenerateError("constant bigger than 64 bits detected!");
  63   }
  64   return Result;
  65 }
  66
  67 static uint64_t HexIntToVal(const char *Buffer) {
  68   uint64_t Result = 0;
  69   for (; *Buffer; ++Buffer) {
  70     uint64_t OldRes = Result;
  71     Result *= 16;
  72     char C = *Buffer;
  73     if (C >= '0' && C <= '9')
  74       Result += C-'0';
  75     else if (C >= 'A' && C <= 'F')
  76       Result += C-'A'+10;
  77     else if (C >= 'a' && C <= 'f')
  78       Result += C-'a'+10;
  79
  80     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  81       GenerateError("constant bigger than 64 bits detected!");
  82   }
  83   return Result;
  84 }
  85
  86
  87 // HexToFP - Convert the ascii string in hexidecimal format to the floating
  88 // point representation of it.
  89 //
  90 static double HexToFP(const char *Buffer) {
  91   // Behave nicely in the face of C TBAA rules... see:
  92   // http://www.nullstone.com/htmls/category/aliastyp.htm
  93   union {
  94     uint64_t UI;
  95     double FP;
  96   } UIntToFP;
  97   UIntToFP.UI = HexIntToVal(Buffer);
  98
  99   assert(sizeof(double) == sizeof(uint64_t) &&
 100          "Data sizes incompatible on this target!");
 101   return UIntToFP.FP;   // Cast Hex constant to double
 102 }
 103
 104
 105 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
 106 // appropriate character.  If AllowNull is set to false, a \00 value will cause
 107 // an exception to be thrown.
 108 //
 109 // If AllowNull is set to true, the return value of the function points to the
 110 // last character of the string in memory.
 111 //
 112 char *UnEscapeLexed(char *Buffer, bool AllowNull) {
 113   char *BOut = Buffer;
 114   for (char *BIn = Buffer; *BIn; ) {
 115     if (BIn[0] == '\\' && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
 116       char Tmp = BIn[3]; BIn[3] = 0;     // Terminate string
 117       *BOut = (char)strtol(BIn+1, 0, 16);  // Convert to number
 118       if (!AllowNull && !*BOut)
 119         GenerateError("String literal cannot accept \\00 escape!");
 120
 121       BIn[3] = Tmp;                  // Restore character
 122       BIn += 3;                      // Skip over handled chars
 123       ++BOut;
 124     } else {
 125       *BOut++ = *BIn++;
 126     }
 127   }
 128
 129   return BOut;
 130 }
 131
 132 } // End llvm namespace
 133
 134 using namespace llvm;
 135
 136 #define YY_NEVER_INTERACTIVE 1
 137 %}
 138
 139
 140
 141 /* Comments start with a ; and go till end of line */
 142 Comment    ;.*
 143
 144 /* Variable(Value) identifiers start with a % sign */
 145 VarID       %[-a-zA-Z$._][-a-zA-Z$._0-9]*
 146
 147 /* Label identifiers end with a colon */
 148 Label       [-a-zA-Z$._0-9]+:
 149 QuoteLabel \"[^\"]+\":
 150
 151 /* Quoted names can contain any character except " and \ */
 152 StringConstant \"[^\"]*\"
 153
 154
 155 /* [PN]Integer: match positive and negative literal integer values that
 156  * are preceeded by a '%' character.  These represent unnamed variable slots.
 157  */
 158 EPInteger     %[0-9]+
 159 ENInteger    %-[0-9]+
 160
 161
 162 /* E[PN]Integer: match positive and negative literal integer values */
 163 PInteger   [0-9]+
 164 NInteger  -[0-9]+
 165
 166 /* FPConstant - A Floating point constant.
 167  */
 168 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 169
 170 /* HexFPConstant - Floating point constant represented in IEEE format as a
 171  *  hexadecimal number for when exponential notation is not precise enough.
 172  */
 173 HexFPConstant 0x[0-9A-Fa-f]+
 174
 175 /* HexIntConstant - Hexadecimal constant generated by the CFE to avoid forcing
 176  * it to deal with 64 bit numbers.
 177  */
 178 HexIntConstant [us]0x[0-9A-Fa-f]+
 179 %%
 180
 181 {Comment}       { /* Ignore comments for now */ }
 182
 183 begin           { return BEGINTOK; }
 184 end             { return ENDTOK; }
 185 true            { return TRUETOK;  }
 186 false           { return FALSETOK; }
 187 declare         { return DECLARE; }
 188 global          { return GLOBAL; }
 189 constant        { return CONSTANT; }
 190 internal        { return INTERNAL; }
 191 linkonce        { return LINKONCE; }
 192 weak            { return WEAK; }
 193 appending       { return APPENDING; }
 194 dllimport       { return DLLIMPORT; }
 195 dllexport       { return DLLEXPORT; }
 196 extern_weak     { return EXTERN_WEAK; }
 197 uninitialized   { return EXTERNAL; }    /* Deprecated, turn into external */
 198 external        { return EXTERNAL; }
 199 implementation  { return IMPLEMENTATION; }
 200 zeroinitializer { return ZEROINITIALIZER; }
 201 \.\.\.          { return DOTDOTDOT; }
 202 undef           { return UNDEF; }
 203 null            { return NULL_TOK; }
 204 to              { return TO; }
 205 except          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 206 not             { return NOT; }  /* Deprecated, turned into XOR */
 207 tail            { return TAIL; }
 208 target          { return TARGET; }
 209 triple          { return TRIPLE; }
 210 deplibs         { return DEPLIBS; }
 211 endian          { return ENDIAN; }
 212 pointersize     { return POINTERSIZE; }
 213 little          { return LITTLE; }
 214 big             { return BIG; }
 215 volatile        { return VOLATILE; }
 216 align           { return ALIGN;  }
 217 section         { return SECTION; }
 218 module          { return MODULE; }
 219 asm             { return ASM_TOK; }
 220 sideeffect      { return SIDEEFFECT; }
 221
 222 cc              { return CC_TOK; }
 223 ccc             { return CCC_TOK; }
 224 csretcc         { return CSRETCC_TOK; }
 225 fastcc          { return FASTCC_TOK; }
 226 coldcc          { return COLDCC_TOK; }
 227
 228 void            { llvmAsmlval.PrimType = Type::VoidTy  ; return VOID;   }
 229 bool            { llvmAsmlval.PrimType = Type::BoolTy  ; return BOOL;   }
 230 sbyte           { llvmAsmlval.PrimType = Type::SByteTy ; return SBYTE;  }
 231 ubyte           { llvmAsmlval.PrimType = Type::UByteTy ; return UBYTE;  }
 232 short           { llvmAsmlval.PrimType = Type::ShortTy ; return SHORT;  }
 233 ushort          { llvmAsmlval.PrimType = Type::UShortTy; return USHORT; }
 234 int             { llvmAsmlval.PrimType = Type::IntTy   ; return INT;    }
 235 uint            { llvmAsmlval.PrimType = Type::UIntTy  ; return UINT;   }
 236 long            { llvmAsmlval.PrimType = Type::LongTy  ; return LONG;   }
 237 ulong           { llvmAsmlval.PrimType = Type::ULongTy ; return ULONG;  }
 238 float           { llvmAsmlval.PrimType = Type::FloatTy ; return FLOAT;  }
 239 double          { llvmAsmlval.PrimType = Type::DoubleTy; return DOUBLE; }
 240 label           { llvmAsmlval.PrimType = Type::LabelTy ; return LABEL;  }
 241 type            { return TYPE;   }
 242 opaque          { return OPAQUE; }
 243
 244 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 245 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 246 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 247 div             { RET_TOK(BinaryOpVal, Div, DIV); }
 248 rem             { RET_TOK(BinaryOpVal, Rem, REM); }
 249 and             { RET_TOK(BinaryOpVal, And, AND); }
 250 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 251 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 252 setne           { RET_TOK(BinaryOpVal, SetNE, SETNE); }
 253 seteq           { RET_TOK(BinaryOpVal, SetEQ, SETEQ); }
 254 setlt           { RET_TOK(BinaryOpVal, SetLT, SETLT); }
 255 setgt           { RET_TOK(BinaryOpVal, SetGT, SETGT); }
 256 setle           { RET_TOK(BinaryOpVal, SetLE, SETLE); }
 257 setge           { RET_TOK(BinaryOpVal, SetGE, SETGE); }
 258
 259 phi             { RET_TOK(OtherOpVal, PHI, PHI_TOK); }
 260 call            { RET_TOK(OtherOpVal, Call, CALL); }
 261 cast            { RET_TOK(OtherOpVal, Cast, CAST); }
 262 select          { RET_TOK(OtherOpVal, Select, SELECT); }
 263 shl             { RET_TOK(OtherOpVal, Shl, SHL); }
 264 shr             { RET_TOK(OtherOpVal, Shr, SHR); }
 265 vanext          { return VANEXT_old; }
 266 vaarg           { return VAARG_old; }
 267 va_arg          { RET_TOK(OtherOpVal, VAArg , VAARG); }
 268 ret             { RET_TOK(TermOpVal, Ret, RET); }
 269 br              { RET_TOK(TermOpVal, Br, BR); }
 270 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 271 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 272 unwind          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 273 unreachable     { RET_TOK(TermOpVal, Unreachable, UNREACHABLE); }
 274
 275 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 276 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 277 free            { RET_TOK(MemOpVal, Free, FREE); }
 278 load            { RET_TOK(MemOpVal, Load, LOAD); }
 279 store           { RET_TOK(MemOpVal, Store, STORE); }
 280 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 281
 282 extractelement  { RET_TOK(OtherOpVal, ExtractElement, EXTRACTELEMENT); }
 283 insertelement   { RET_TOK(OtherOpVal, InsertElement, INSERTELEMENT); }
 284 shufflevector   { RET_TOK(OtherOpVal, ShuffleVector, SHUFFLEVECTOR); }
 285
 286
 287 {VarID}         {
 288                   UnEscapeLexed(yytext+1);
 289                   llvmAsmlval.StrVal = strdup(yytext+1);             // Skip %
 290                   return VAR_ID;
 291                 }
 292 {Label}         {
 293                   yytext[strlen(yytext)-1] = 0;  // nuke colon
 294                   UnEscapeLexed(yytext);
 295                   llvmAsmlval.StrVal = strdup(yytext);
 296                   return LABELSTR;
 297                 }
 298 {QuoteLabel}    {
 299                   yytext[strlen(yytext)-2] = 0;  // nuke colon, end quote
 300                   UnEscapeLexed(yytext+1);
 301                   llvmAsmlval.StrVal = strdup(yytext+1);
 302                   return LABELSTR;
 303                 }
 304
 305 {StringConstant} { // Note that we cannot unescape a string constant here!  The
 306                    // string constant might contain a \00 which would not be
 307                    // understood by the string stuff.  It is valid to make a
 308                    // [sbyte] c"Hello World\00" constant, for example.
 309                    //
 310                    yytext[strlen(yytext)-1] = 0;           // nuke end quote
 311                    llvmAsmlval.StrVal = strdup(yytext+1);  // Nuke start quote
 312                    return STRINGCONSTANT;
 313                  }
 314
 315
 316 {PInteger}      { llvmAsmlval.UInt64Val = atoull(yytext); return EUINT64VAL; }
 317 {NInteger}      {
 318                   uint64_t Val = atoull(yytext+1);
 319                   // +1:  we have bigger negative range
 320                   if (Val > (uint64_t)INT64_MAX+1)
 321                     GenerateError("Constant too large for signed 64 bits!");
 322                   llvmAsmlval.SInt64Val = -Val;
 323                   return ESINT64VAL;
 324                 }
 325 {HexIntConstant} {
 326                    llvmAsmlval.UInt64Val = HexIntToVal(yytext+3);
 327                    return yytext[0] == 's' ? ESINT64VAL : EUINT64VAL;
 328                  }
 329
 330 {EPInteger}     {
 331                   uint64_t Val = atoull(yytext+1);
 332                   if ((unsigned)Val != Val)
 333                     GenerateError("Invalid value number (too large)!");
 334                   llvmAsmlval.UIntVal = unsigned(Val);
 335                   return UINTVAL;
 336                 }
 337 {ENInteger}     {
 338                   uint64_t Val = atoull(yytext+2);
 339                   // +1:  we have bigger negative range
 340                   if (Val > (uint64_t)INT32_MAX+1)
 341                     GenerateError("Constant too large for signed 32 bits!");
 342                   llvmAsmlval.SIntVal = (int)-Val;
 343                   return SINTVAL;
 344                 }
 345
 346 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 347 {HexFPConstant} { llvmAsmlval.FPVal = HexToFP(yytext); return FPVAL; }
 348
 349 <<EOF>>         {
 350                   /* Make sure to free the internal buffers for flex when we are
 351                    * done reading our input!
 352                    */
 353                   yy_delete_buffer(YY_CURRENT_BUFFER);
 354                   return EOF;
 355                 }
 356
 357 [ \r\t\n]       { /* Ignore whitespace */ }
 358 .               { return yytext[0]; }
 359
 360 %%