include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  The reads
  42 // and writes may be volatile, but except for this it has no other side effects.
  43 def IntrWriteArgMem : IntrinsicProperty;
  44
  45 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  46 // other side effects.  It cannot be modified by the optimizer.  This is the
  47 // default if the intrinsic has no other Intr*Mem property.
  48 def IntrWriteMem : IntrinsicProperty;
  49
  50 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  51 def Commutative : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 //===----------------------------------------------------------------------===//
  59 // Types used by intrinsics.
  60 //===----------------------------------------------------------------------===//
  61
  62 class LLVMType<ValueType vt> {
  63   ValueType VT = vt;
  64 }
  65
  66 class LLVMPointerType<LLVMType elty>
  67   : LLVMType<iPTR>{
  68   LLVMType ElTy = elty;
  69 }
  70
  71 class LLVMAnyPointerType<LLVMType elty>
  72   : LLVMType<iPTRAny>{
  73   LLVMType ElTy = elty;
  74 }
  75
  76 // Match the type of another intrinsic parameter.  Number is an index into the
  77 // list of overloaded types for the intrinsic, excluding all the fixed types.
  78 // The Number value must refer to a previously listed type.  For example:
  79 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  80 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  81 // refers to the first overloaded type, which is the 2nd argument.
  82 class LLVMMatchType<int num>
  83   : LLVMType<OtherVT>{
  84   int Number = num;
  85 }
  86
  87 // Match the type of another intrinsic parameter that is expected to be
  88 // an integral vector type, but change the element size to be twice as wide
  89 // or half as wide as the other type.  This is only useful when the intrinsic
  90 // is overloaded, so the matched type should be declared as iAny.
  91 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  92 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  93
  94 def llvm_void_ty       : LLVMType<isVoid>;
  95 def llvm_anyint_ty     : LLVMType<iAny>;
  96 def llvm_anyfloat_ty   : LLVMType<fAny>;
  97 def llvm_anyvector_ty  : LLVMType<vAny>;
  98 def llvm_i1_ty         : LLVMType<i1>;
  99 def llvm_i8_ty         : LLVMType<i8>;
 100 def llvm_i16_ty        : LLVMType<i16>;
 101 def llvm_i32_ty        : LLVMType<i32>;
 102 def llvm_i64_ty        : LLVMType<i64>;
 103 def llvm_float_ty      : LLVMType<f32>;
 104 def llvm_double_ty     : LLVMType<f64>;
 105 def llvm_f80_ty        : LLVMType<f80>;
 106 def llvm_f128_ty       : LLVMType<f128>;
 107 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 108 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 109 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 110 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 111 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 112 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 113 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 114
 115 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 116 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 117 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 118 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 119 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 120 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  4 x i16
 121 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 122 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 123 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 124 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 125 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 126 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 127 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 128 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 129 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 130
 131 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 132 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 133 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 134 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 135 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 136
 137 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 138
 139
 140 //===----------------------------------------------------------------------===//
 141 // Intrinsic Definitions.
 142 //===----------------------------------------------------------------------===//
 143
 144 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 145 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 146 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 147 // example, llvm.bswap.i16 -> int_bswap_i16.
 148 //
 149 //  * RetTypes is a list containing the return types expected for the
 150 //    intrinsic.
 151 //  * ParamTypes is a list containing the parameter types expected for the
 152 //    intrinsic.
 153 //  * Properties can be set to describe the behavior of the intrinsic.
 154 //
 155 class Intrinsic<list<LLVMType> ret_types,
 156                 list<LLVMType> param_types = [],
 157                 list<IntrinsicProperty> properties = [],
 158                 string name = ""> {
 159   string LLVMName = name;
 160   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 161   list<LLVMType> RetTypes = ret_types;
 162   list<LLVMType> ParamTypes = param_types;
 163   list<IntrinsicProperty> Properties = properties;
 164
 165   bit isTarget = 0;
 166 }
 167
 168 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 169 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 170 /// support.
 171 class GCCBuiltin<string name> {
 172   string GCCBuiltinName = name;
 173 }
 174
 175
 176 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 177 //
 178
 179 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 180 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 181                             "llvm.va_copy">;
 182 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 183
 184 //===------------------- Garbage Collection Intrinsics --------------------===//
 185 //
 186 def int_gcroot  : Intrinsic<[llvm_void_ty],
 187                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 188 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 189                             [llvm_ptr_ty, llvm_ptrptr_ty],
 190                             [IntrReadArgMem]>;
 191 def int_gcwrite : Intrinsic<[llvm_void_ty],
 192                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 193                             [IntrWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 194
 195 //===--------------------- Code Generator Intrinsics ----------------------===//
 196 //
 197 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 198 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 199
 200 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 201 // model their dependencies on allocas.
 202 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 203                         GCCBuiltin<"__builtin_stack_save">;
 204 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 205                         GCCBuiltin<"__builtin_stack_restore">;
 206
 207 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 208 // however it does conveniently prevent the prefetch from being reordered
 209 // with respect to nearby accesses to the same memory.
 210 def int_prefetch      : Intrinsic<[llvm_void_ty],
 211                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 212                                   [IntrWriteArgMem, NoCapture<0>]>;
 213 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 214
 215 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 216
 217 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 218 // guard to the correct place on the stack frame.
 219 def int_stackprotector : Intrinsic<[llvm_void_ty],
 220                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 221                                    [IntrWriteMem]>;
 222
 223 //===------------------- Standard C Library Intrinsics --------------------===//
 224 //
 225
 226 def int_memcpy  : Intrinsic<[llvm_void_ty],
 227                              [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 228                               llvm_i32_ty],
 229                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 230 def int_memmove : Intrinsic<[llvm_void_ty],
 231                             [llvm_ptr_ty, llvm_ptr_ty, llvm_anyint_ty,
 232                              llvm_i32_ty],
 233                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 234 def int_memset  : Intrinsic<[llvm_void_ty],
 235                             [llvm_ptr_ty, llvm_i8_ty, llvm_anyint_ty,
 236                              llvm_i32_ty],
 237                             [IntrWriteArgMem, NoCapture<0>]>;
 238
 239 // These functions do not actually read memory, but they are sensitive to the
 240 // rounding mode.  This needs to be modelled separately; in the meantime
 241 // declaring them as reading memory is conservatively correct.
 242 let Properties = [IntrReadMem] in {
 243   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 244   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 245   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 246   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 247   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 248                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 249   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 250   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 251   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 252   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 253   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 254 }
 255
 256 // NOTE: these are internal interfaces.
 257 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 258 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 259 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 260 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 261
 262 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 263 //
 264
 265 // None of these intrinsics accesses memory at all.
 266 let Properties = [IntrNoMem] in {
 267   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 268   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 269   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 270   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 271 }
 272
 273 //===------------------------ Debugger Intrinsics -------------------------===//
 274 //
 275
 276 // None of these intrinsics accesses memory at all...but that doesn't mean the
 277 // optimizers can change them aggressively.  Special handling needed in a few
 278 // places.
 279 let Properties = [IntrNoMem] in {
 280   def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 281                                        [llvm_i32_ty, llvm_i32_ty,
 282                                         llvm_metadata_ty]>;
 283   def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_metadata_ty]>;
 284   def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_metadata_ty]>;
 285   def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_metadata_ty]>;
 286   def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 287                                        [llvm_descriptor_ty, llvm_metadata_ty]>;
 288 }
 289
 290 //===------------------ Exception Handling Intrinsics----------------------===//
 291 //
 292 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 293 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 294                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 295 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 296                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 297
 298 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 299 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 300
 301 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 302 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 303
 304 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 305                         GCCBuiltin<"__builtin_unwind_init">;
 306
 307 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 308
 309 let Properties = [IntrNoMem] in {
 310   def int_eh_sjlj_setjmp  : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 311   def int_eh_sjlj_longjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>;
 312   def int_eh_sjlj_lsda    : Intrinsic<[llvm_ptr_ty]>;
 313 }
 314
 315 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 316 //
 317 def int_var_annotation : Intrinsic<[llvm_void_ty],
 318                                    [llvm_ptr_ty, llvm_ptr_ty,
 319                                     llvm_ptr_ty, llvm_i32_ty],
 320                                    [], "llvm.var.annotation">;
 321 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 322                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 323                                     llvm_i32_ty],
 324                                    [], "llvm.ptr.annotation">;
 325 def int_annotation : Intrinsic<[llvm_anyint_ty],
 326                                [LLVMMatchType<0>, llvm_ptr_ty,
 327                                 llvm_ptr_ty, llvm_i32_ty],
 328                                [], "llvm.annotation">;
 329
 330 //===------------------------ Trampoline Intrinsics -----------------------===//
 331 //
 332 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 333                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 334                                     [IntrWriteArgMem]>,
 335                           GCCBuiltin<"__builtin_init_trampoline">;
 336
 337 //===------------------------ Overflow Intrinsics -------------------------===//
 338 //
 339
 340 // Expose the carry flag from add operations on two integrals.
 341 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 342                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 343 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 344                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 345
 346 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 347                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 348 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 349                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 350
 351 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 352                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 353 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 354                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 355
 356 //===------------------------- Atomic Intrinsics --------------------------===//
 357 //
 358 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 359                                    [llvm_i1_ty, llvm_i1_ty,
 360                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 361                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 362
 363 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 364                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 365                                      LLVMMatchType<0>, LLVMMatchType<0>],
 366                                     [IntrWriteArgMem, NoCapture<0>]>,
 367                            GCCBuiltin<"__sync_val_compare_and_swap">;
 368 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 369                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 370                                      LLVMMatchType<0>],
 371                                     [IntrWriteArgMem, NoCapture<0>]>,
 372                            GCCBuiltin<"__sync_fetch_and_add">;
 373 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 374                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 375                                      LLVMMatchType<0>],
 376                                     [IntrWriteArgMem, NoCapture<0>]>,
 377                            GCCBuiltin<"__sync_lock_test_and_set">;
 378 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 379                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 380                                      LLVMMatchType<0>],
 381                                     [IntrWriteArgMem, NoCapture<0>]>,
 382                            GCCBuiltin<"__sync_fetch_and_sub">;
 383 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 384                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 385                                      LLVMMatchType<0>],
 386                                     [IntrWriteArgMem, NoCapture<0>]>,
 387                            GCCBuiltin<"__sync_fetch_and_and">;
 388 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 389                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 390                                       LLVMMatchType<0>],
 391                                      [IntrWriteArgMem, NoCapture<0>]>,
 392                            GCCBuiltin<"__sync_fetch_and_or">;
 393 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 394                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 395                                      LLVMMatchType<0>],
 396                                     [IntrWriteArgMem, NoCapture<0>]>,
 397                            GCCBuiltin<"__sync_fetch_and_xor">;
 398 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 399                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 400                                       LLVMMatchType<0>],
 401                                      [IntrWriteArgMem, NoCapture<0>]>,
 402                            GCCBuiltin<"__sync_fetch_and_nand">;
 403 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 404                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 405                                       LLVMMatchType<0>],
 406                                      [IntrWriteArgMem, NoCapture<0>]>,
 407                            GCCBuiltin<"__sync_fetch_and_min">;
 408 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 409                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 410                                       LLVMMatchType<0>],
 411                                      [IntrWriteArgMem, NoCapture<0>]>,
 412                            GCCBuiltin<"__sync_fetch_and_max">;
 413 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 414                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 415                                       LLVMMatchType<0>],
 416                                      [IntrWriteArgMem, NoCapture<0>]>,
 417                            GCCBuiltin<"__sync_fetch_and_umin">;
 418 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 419                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 420                                       LLVMMatchType<0>],
 421                                      [IntrWriteArgMem, NoCapture<0>]>,
 422                            GCCBuiltin<"__sync_fetch_and_umax">;
 423
 424 //===-------------------------- Other Intrinsics --------------------------===//
 425 //
 426 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 427                      GCCBuiltin<"__builtin_flt_rounds">;
 428 def int_trap : Intrinsic<[llvm_void_ty]>,
 429                GCCBuiltin<"__builtin_trap">;
 430
 431 // These convert intrinsics are to support various conversions between
 432 // various types with rounding and saturation. NOTE: avoid using these
 433 // intrinsics as they might be removed sometime in the future and
 434 // most targets don't support them.
 435 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 436                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 437 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 438                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 439 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 440                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 441 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 442                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 443 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 444                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 445 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 446                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 447 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 448                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 449 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 450                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 451 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 452                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 453
 454 //===----------------------------------------------------------------------===//
 455 // Target-specific intrinsics
 456 //===----------------------------------------------------------------------===//
 457
 458 include "llvm/IntrinsicsPowerPC.td"
 459 include "llvm/IntrinsicsX86.td"
 460 include "llvm/IntrinsicsARM.td"
 461 include "llvm/IntrinsicsCellSPU.td"
 462 include "llvm/IntrinsicsAlpha.td"
 463 include "llvm/IntrinsicsXCore.td"
 464 include "llvm/IntrinsicsBlackfin.td"