include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  51 class NoCapture<int argNo> : IntrinsicProperty {
  52   int ArgNo = argNo;
  53 }
  54
  55 //===----------------------------------------------------------------------===//
  56 // Types used by intrinsics.
  57 //===----------------------------------------------------------------------===//
  58
  59 class LLVMType<ValueType vt> {
  60   ValueType VT = vt;
  61 }
  62
  63 class LLVMPointerType<LLVMType elty>
  64   : LLVMType<iPTR>{
  65   LLVMType ElTy = elty;
  66 }
  67
  68 class LLVMAnyPointerType<LLVMType elty>
  69   : LLVMType<iPTRAny>{
  70   LLVMType ElTy = elty;
  71 }
  72
  73 // Match the type of another intrinsic parameter.  Number is an index into the
  74 // list of overloaded types for the intrinsic, excluding all the fixed types.
  75 // The Number value must refer to a previously listed type.  For example:
  76 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  77 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  78 // refers to the first overloaded type, which is the 2nd argument.
  79 class LLVMMatchType<int num>
  80   : LLVMType<OtherVT>{
  81   int Number = num;
  82 }
  83
  84 // Match the type of another intrinsic parameter that is expected to be
  85 // an integral vector type, but change the element size to be twice as wide
  86 // or half as wide as the other type.  This is only useful when the intrinsic
  87 // is overloaded, so the matched type should be declared as iAny.
  88 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  89 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  90
  91 def llvm_void_ty       : LLVMType<isVoid>;
  92 def llvm_anyint_ty     : LLVMType<iAny>;
  93 def llvm_anyfloat_ty   : LLVMType<fAny>;
  94 def llvm_anyvector_ty  : LLVMType<vAny>;
  95 def llvm_i1_ty         : LLVMType<i1>;
  96 def llvm_i8_ty         : LLVMType<i8>;
  97 def llvm_i16_ty        : LLVMType<i16>;
  98 def llvm_i32_ty        : LLVMType<i32>;
  99 def llvm_i64_ty        : LLVMType<i64>;
 100 def llvm_float_ty      : LLVMType<f32>;
 101 def llvm_double_ty     : LLVMType<f64>;
 102 def llvm_f80_ty        : LLVMType<f80>;
 103 def llvm_f128_ty       : LLVMType<f128>;
 104 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 105 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 106 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 107 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 108 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 109 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 110 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 111
 112 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 113 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 114
 115 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 116 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 117 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 118 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 119 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 120 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 121 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 122 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 123 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 124 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 125 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 126 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 127 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 128 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 129 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 130
 131 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 132 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 133 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 134 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 135 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 136
 137 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 138
 139
 140 //===----------------------------------------------------------------------===//
 141 // Intrinsic Definitions.
 142 //===----------------------------------------------------------------------===//
 143
 144 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 145 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 146 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 147 // example, llvm.bswap.i16 -> int_bswap_i16.
 148 //
 149 //  * RetTypes is a list containing the return types expected for the
 150 //    intrinsic.
 151 //  * ParamTypes is a list containing the parameter types expected for the
 152 //    intrinsic.
 153 //  * Properties can be set to describe the behavior of the intrinsic.
 154 //
 155 class Intrinsic<list<LLVMType> ret_types,
 156                 list<LLVMType> param_types = [],
 157                 list<IntrinsicProperty> properties = [],
 158                 string name = ""> {
 159   string LLVMName = name;
 160   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 161   list<LLVMType> RetTypes = ret_types;
 162   list<LLVMType> ParamTypes = param_types;
 163   list<IntrinsicProperty> Properties = properties;
 164
 165   bit isTarget = 0;
 166 }
 167
 168 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 169 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 170 /// support.
 171 class GCCBuiltin<string name> {
 172   string GCCBuiltinName = name;
 173 }
 174
 175
 176 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 177 //
 178
 179 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 180 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 181                             "llvm.va_copy">;
 182 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 183
 184 //===------------------- Garbage Collection Intrinsics --------------------===//
 185 //
 186 def int_gcroot  : Intrinsic<[],
 187                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 188 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 189                             [llvm_ptr_ty, llvm_ptrptr_ty],
 190                             [IntrReadArgMem]>;
 191 def int_gcwrite : Intrinsic<[],
 192                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 193                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 194
 195 //===--------------------- Code Generator Intrinsics ----------------------===//
 196 //
 197 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 198 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 199
 200 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 201 // model their dependencies on allocas.
 202 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 203                         GCCBuiltin<"__builtin_stack_save">;
 204 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 205                         GCCBuiltin<"__builtin_stack_restore">;
 206
 207 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 208 // however it does conveniently prevent the prefetch from being reordered
 209 // with respect to nearby accesses to the same memory.
 210 def int_prefetch      : Intrinsic<[],
 211                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 212                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 213 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 214
 215 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 216
 217 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 218 // guard to the correct place on the stack frame.
 219 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 220
 221 //===------------------- Standard C Library Intrinsics --------------------===//
 222 //
 223
 224 def int_memcpy  : Intrinsic<[],
 225                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 226                               llvm_i32_ty, llvm_i1_ty],
 227                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 228 def int_memmove : Intrinsic<[],
 229                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 230                              llvm_i32_ty, llvm_i1_ty],
 231                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 232 def int_memset  : Intrinsic<[],
 233                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 234                              llvm_i32_ty, llvm_i1_ty],
 235                             [IntrReadWriteArgMem, NoCapture<0>]>;
 236
 237 // These functions do not actually read memory, but they are sensitive to the
 238 // rounding mode.  This needs to be modelled separately; in the meantime
 239 // declaring them as reading memory is conservatively correct.
 240 let Properties = [IntrReadMem] in {
 241   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 242   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 243   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 244   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 245   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 246                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 247   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 248   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 249   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 250   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 251   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 252 }
 253
 254 // NOTE: these are internal interfaces.
 255 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 256 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 257 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 258 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 259
 260 // Internal interface for object size checking
 261 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 262                                [IntrReadArgMem]>,
 263                                GCCBuiltin<"__builtin_object_size">;
 264
 265 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 266 //
 267
 268 // None of these intrinsics accesses memory at all.
 269 let Properties = [IntrNoMem] in {
 270   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 271   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 272   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 273   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 274 }
 275
 276 //===------------------------ Debugger Intrinsics -------------------------===//
 277 //
 278
 279 // None of these intrinsics accesses memory at all...but that doesn't mean the
 280 // optimizers can change them aggressively.  Special handling needed in a few
 281 // places.
 282 let Properties = [IntrNoMem] in {
 283   def int_dbg_declare      : Intrinsic<[],
 284                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 285   def int_dbg_value        : Intrinsic<[],
 286                                        [llvm_metadata_ty, llvm_i64_ty,
 287                                         llvm_metadata_ty]>;
 288 }
 289
 290 //===------------------ Exception Handling Intrinsics----------------------===//
 291 //
 292 def int_eh_exception : Intrinsic<[llvm_ptr_ty], [], [IntrReadMem]>;
 293 def int_eh_selector  : Intrinsic<[llvm_i32_ty],
 294                                  [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 295
 296 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 297
 298 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 299 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 300
 301 def int_eh_unwind_init: Intrinsic<[]>,
 302                         GCCBuiltin<"__builtin_unwind_init">;
 303
 304 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 305
 306 let Properties = [IntrNoMem] in {
 307   def int_eh_sjlj_lsda    : Intrinsic<[llvm_ptr_ty]>;
 308   def int_eh_sjlj_callsite: Intrinsic<[], [llvm_i32_ty]>;
 309 }
 310 def int_eh_sjlj_setjmp  : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 311 def int_eh_sjlj_longjmp : Intrinsic<[], [llvm_ptr_ty]>;
 312
 313 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 314 //
 315 def int_var_annotation : Intrinsic<[],
 316                                    [llvm_ptr_ty, llvm_ptr_ty,
 317                                     llvm_ptr_ty, llvm_i32_ty],
 318                                    [], "llvm.var.annotation">;
 319 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 320                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 321                                     llvm_i32_ty],
 322                                    [], "llvm.ptr.annotation">;
 323 def int_annotation : Intrinsic<[llvm_anyint_ty],
 324                                [LLVMMatchType<0>, llvm_ptr_ty,
 325                                 llvm_ptr_ty, llvm_i32_ty],
 326                                [], "llvm.annotation">;
 327
 328 //===------------------------ Trampoline Intrinsics -----------------------===//
 329 //
 330 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 331                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 332                                     [IntrReadWriteArgMem]>,
 333                           GCCBuiltin<"__builtin_init_trampoline">;
 334
 335 //===------------------------ Overflow Intrinsics -------------------------===//
 336 //
 337
 338 // Expose the carry flag from add operations on two integrals.
 339 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 340                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 341                                        [IntrNoMem]>;
 342 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 343                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 344                                        [IntrNoMem]>;
 345
 346 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 347                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 348                                        [IntrNoMem]>;
 349 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 350                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 351                                        [IntrNoMem]>;
 352
 353 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 354                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 355                                        [IntrNoMem]>;
 356 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 357                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 358                                        [IntrNoMem]>;
 359
 360 //===------------------------- Atomic Intrinsics --------------------------===//
 361 //
 362 def int_memory_barrier : Intrinsic<[],
 363                                    [llvm_i1_ty, llvm_i1_ty,
 364                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 365                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 366
 367 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 368                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 369                                      LLVMMatchType<0>, LLVMMatchType<0>],
 370                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 371                            GCCBuiltin<"__sync_val_compare_and_swap">;
 372 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 373                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 374                                      LLVMMatchType<0>],
 375                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 376                            GCCBuiltin<"__sync_fetch_and_add">;
 377 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 378                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 379                                      LLVMMatchType<0>],
 380                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 381                            GCCBuiltin<"__sync_lock_test_and_set">;
 382 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 383                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 384                                      LLVMMatchType<0>],
 385                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 386                            GCCBuiltin<"__sync_fetch_and_sub">;
 387 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 388                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 389                                      LLVMMatchType<0>],
 390                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 391                            GCCBuiltin<"__sync_fetch_and_and">;
 392 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 393                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 394                                       LLVMMatchType<0>],
 395                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 396                            GCCBuiltin<"__sync_fetch_and_or">;
 397 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 398                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 399                                      LLVMMatchType<0>],
 400                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 401                            GCCBuiltin<"__sync_fetch_and_xor">;
 402 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 403                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 404                                       LLVMMatchType<0>],
 405                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 406                            GCCBuiltin<"__sync_fetch_and_nand">;
 407 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 408                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 409                                       LLVMMatchType<0>],
 410                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 411                            GCCBuiltin<"__sync_fetch_and_min">;
 412 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 413                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 414                                       LLVMMatchType<0>],
 415                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 416                            GCCBuiltin<"__sync_fetch_and_max">;
 417 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 418                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 419                                       LLVMMatchType<0>],
 420                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 421                            GCCBuiltin<"__sync_fetch_and_umin">;
 422 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 423                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 424                                       LLVMMatchType<0>],
 425                                      [IntrReadWriteArgMem, NoCapture<0>]>,
 426                            GCCBuiltin<"__sync_fetch_and_umax">;
 427
 428 //===------------------------- Memory Use Markers -------------------------===//
 429 //
 430 def int_lifetime_start  : Intrinsic<[],
 431                                     [llvm_i64_ty, llvm_ptr_ty],
 432                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 433 def int_lifetime_end    : Intrinsic<[],
 434                                     [llvm_i64_ty, llvm_ptr_ty],
 435                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 436 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 437                                     [llvm_i64_ty, llvm_ptr_ty],
 438                                     [IntrReadArgMem, NoCapture<1>]>;
 439 def int_invariant_end   : Intrinsic<[],
 440                                     [llvm_descriptor_ty, llvm_i64_ty,
 441                                      llvm_ptr_ty],
 442                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 443
 444 //===-------------------------- Other Intrinsics --------------------------===//
 445 //
 446 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 447                      GCCBuiltin<"__builtin_flt_rounds">;
 448 def int_trap : Intrinsic<[]>,
 449                GCCBuiltin<"__builtin_trap">;
 450
 451 // Intrisics to support half precision floating point format
 452 let Properties = [IntrNoMem] in {
 453 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 454                             GCCBuiltin<"__gnu_f2h_ieee">;
 455 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 456                             GCCBuiltin<"__gnu_h2f_ieee">;
 457 }
 458
 459 // These convert intrinsics are to support various conversions between
 460 // various types with rounding and saturation. NOTE: avoid using these
 461 // intrinsics as they might be removed sometime in the future and
 462 // most targets don't support them.
 463 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 464                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 465 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 466                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 467 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 468                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 469 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 470                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 471 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 472                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 473 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 474                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 475 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 476                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 477 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 478                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 479 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 480                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 481
 482 //===----------------------------------------------------------------------===//
 483 // Target-specific intrinsics
 484 //===----------------------------------------------------------------------===//
 485
 486 include "llvm/IntrinsicsPowerPC.td"
 487 include "llvm/IntrinsicsX86.td"
 488 include "llvm/IntrinsicsARM.td"
 489 include "llvm/IntrinsicsCellSPU.td"
 490 include "llvm/IntrinsicsAlpha.td"
 491 include "llvm/IntrinsicsXCore.td"