include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 //===----------------------------------------------------------------------===//
  73 // Types used by intrinsics.
  74 //===----------------------------------------------------------------------===//
  75
  76 class LLVMType<ValueType vt> {
  77   ValueType VT = vt;
  78 }
  79
  80 class LLVMQualPointerType<LLVMType elty, int addrspace>
  81   : LLVMType<iPTR>{
  82   LLVMType ElTy = elty;
  83   int AddrSpace = addrspace;
  84 }
  85
  86 class LLVMPointerType<LLVMType elty>
  87   : LLVMQualPointerType<elty, 0>;
  88
  89 class LLVMAnyPointerType<LLVMType elty>
  90   : LLVMType<iPTRAny>{
  91   LLVMType ElTy = elty;
  92 }
  93
  94 // Match the type of another intrinsic parameter.  Number is an index into the
  95 // list of overloaded types for the intrinsic, excluding all the fixed types.
  96 // The Number value must refer to a previously listed type.  For example:
  97 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  98 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  99 // refers to the first overloaded type, which is the 2nd argument.
 100 class LLVMMatchType<int num>
 101   : LLVMType<OtherVT>{
 102   int Number = num;
 103 }
 104
 105 // Match the type of another intrinsic parameter that is expected to be
 106 // an integral vector type, but change the element size to be twice as wide
 107 // or half as wide as the other type.  This is only useful when the intrinsic
 108 // is overloaded, so the matched type should be declared as iAny.
 109 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
 110 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
 111
 112 def llvm_void_ty       : LLVMType<isVoid>;
 113 def llvm_anyint_ty     : LLVMType<iAny>;
 114 def llvm_anyfloat_ty   : LLVMType<fAny>;
 115 def llvm_anyvector_ty  : LLVMType<vAny>;
 116 def llvm_i1_ty         : LLVMType<i1>;
 117 def llvm_i8_ty         : LLVMType<i8>;
 118 def llvm_i16_ty        : LLVMType<i16>;
 119 def llvm_i32_ty        : LLVMType<i32>;
 120 def llvm_i64_ty        : LLVMType<i64>;
 121 def llvm_half_ty       : LLVMType<f16>;
 122 def llvm_float_ty      : LLVMType<f32>;
 123 def llvm_double_ty     : LLVMType<f64>;
 124 def llvm_f80_ty        : LLVMType<f80>;
 125 def llvm_f128_ty       : LLVMType<f128>;
 126 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 127 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 128 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 129 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 130 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 131 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 132 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 133
 134 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 135 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 136
 137 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 138 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 139 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 140 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 141 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 142 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 143 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 144 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 145 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 146 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 147 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 148 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 149 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 150
 151 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 152 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 153 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 154 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 155 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 156 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 157
 158 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 159 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 160 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 161 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 162 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 163 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 164 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 165 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 166 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 167 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 168
 169 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 170 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 171 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 172 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 173 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 174 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 175 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 176 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 177 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 178 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 179 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 180 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 181
 182 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 183
 184
 185 //===----------------------------------------------------------------------===//
 186 // Intrinsic Definitions.
 187 //===----------------------------------------------------------------------===//
 188
 189 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 190 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 191 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 192 // example, llvm.bswap.i16 -> int_bswap_i16.
 193 //
 194 //  * RetTypes is a list containing the return types expected for the
 195 //    intrinsic.
 196 //  * ParamTypes is a list containing the parameter types expected for the
 197 //    intrinsic.
 198 //  * Properties can be set to describe the behavior of the intrinsic.
 199 //
 200 class SDPatternOperator;
 201 class Intrinsic<list<LLVMType> ret_types,
 202                 list<LLVMType> param_types = [],
 203                 list<IntrinsicProperty> properties = [],
 204                 string name = ""> : SDPatternOperator {
 205   string LLVMName = name;
 206   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 207   list<LLVMType> RetTypes = ret_types;
 208   list<LLVMType> ParamTypes = param_types;
 209   list<IntrinsicProperty> Properties = properties;
 210
 211   bit isTarget = 0;
 212 }
 213
 214 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 215 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 216 /// support.
 217 class GCCBuiltin<string name> {
 218   string GCCBuiltinName = name;
 219 }
 220
 221
 222 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 223 //
 224
 225 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 226 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 227                             "llvm.va_copy">;
 228 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 229
 230 //===------------------- Garbage Collection Intrinsics --------------------===//
 231 //
 232 def int_gcroot  : Intrinsic<[],
 233                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 234 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 235                             [llvm_ptr_ty, llvm_ptrptr_ty],
 236                             [IntrReadArgMem]>;
 237 def int_gcwrite : Intrinsic<[],
 238                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 239                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 240
 241 //===--------------------- Code Generator Intrinsics ----------------------===//
 242 //
 243 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 244 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 245
 246 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 247 // model their dependencies on allocas.
 248 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 249                         GCCBuiltin<"__builtin_stack_save">;
 250 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 251                         GCCBuiltin<"__builtin_stack_restore">;
 252
 253 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 254 // however it does conveniently prevent the prefetch from being reordered
 255 // with respect to nearby accesses to the same memory.
 256 def int_prefetch      : Intrinsic<[],
 257                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 258                                    llvm_i32_ty],
 259                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 260 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 261
 262 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 263
 264 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 265 // guard to the correct place on the stack frame.
 266 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 267 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 268                                         [IntrReadWriteArgMem]>;
 269
 270 //===------------------- Standard C Library Intrinsics --------------------===//
 271 //
 272
 273 def int_memcpy  : Intrinsic<[],
 274                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 275                               llvm_i32_ty, llvm_i1_ty],
 276                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 277                              ReadOnly<1>]>;
 278 def int_memmove : Intrinsic<[],
 279                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 280                              llvm_i32_ty, llvm_i1_ty],
 281                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 282                              ReadOnly<1>]>;
 283 def int_memset  : Intrinsic<[],
 284                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 285                              llvm_i32_ty, llvm_i1_ty],
 286                             [IntrReadWriteArgMem, NoCapture<0>]>;
 287
 288 // These functions do not actually read memory, but they are sensitive to the
 289 // rounding mode.  This needs to be modelled separately; in the meantime
 290 // declaring them as reading memory is conservatively correct.
 291 let Properties = [IntrReadMem] in {
 292   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 293   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 294   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 295   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 296   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 297                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 298   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 299   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 300   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 301   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 302   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 303   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 304   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 305                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 306   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 307   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 308   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 309   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 310   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 311   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 312 }
 313
 314 let Properties = [IntrNoMem] in {
 315   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 316                          [LLVMMatchType<0>, LLVMMatchType<0>,
 317                           LLVMMatchType<0>]>;
 318
 319   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 320                               [LLVMMatchType<0>, LLVMMatchType<0>,
 321                                LLVMMatchType<0>]>;
 322 }
 323
 324 // NOTE: these are internal interfaces.
 325 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 326 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 327 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 328 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 329
 330 // Internal interface for object size checking
 331 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 332                                [IntrNoMem]>,
 333                                GCCBuiltin<"__builtin_object_size">;
 334
 335 //===------------------------- Expect Intrinsics --------------------------===//
 336 //
 337 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 338                                               LLVMMatchType<0>], [IntrNoMem]>;
 339
 340 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 341 //
 342
 343 // None of these intrinsics accesses memory at all.
 344 let Properties = [IntrNoMem] in {
 345   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 346   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 347   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 348   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 349 }
 350
 351 //===------------------------ Debugger Intrinsics -------------------------===//
 352 //
 353
 354 // None of these intrinsics accesses memory at all...but that doesn't mean the
 355 // optimizers can change them aggressively.  Special handling needed in a few
 356 // places.
 357 let Properties = [IntrNoMem] in {
 358   def int_dbg_declare      : Intrinsic<[],
 359                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 360   def int_dbg_value        : Intrinsic<[],
 361                                        [llvm_metadata_ty, llvm_i64_ty,
 362                                         llvm_metadata_ty]>;
 363 }
 364
 365 //===------------------ Exception Handling Intrinsics----------------------===//
 366 //
 367
 368 // The result of eh.typeid.for depends on the enclosing function, but inside a
 369 // given function it is 'const' and may be CSE'd etc.
 370 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 371
 372 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 373 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 374
 375 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 376 // callee-saved registers to be saved and restored (regardless of whether they
 377 // are used) in the calling function. It is used by libgcc_eh.
 378 def int_eh_unwind_init: Intrinsic<[]>,
 379                         GCCBuiltin<"__builtin_unwind_init">;
 380
 381 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 382
 383 let Properties = [IntrNoMem] in {
 384   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 385   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 386 }
 387 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 388 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 389 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 390
 391 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 392 //
 393 def int_var_annotation : Intrinsic<[],
 394                                    [llvm_ptr_ty, llvm_ptr_ty,
 395                                     llvm_ptr_ty, llvm_i32_ty],
 396                                    [], "llvm.var.annotation">;
 397 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 398                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 399                                     llvm_i32_ty],
 400                                    [], "llvm.ptr.annotation">;
 401 def int_annotation : Intrinsic<[llvm_anyint_ty],
 402                                [LLVMMatchType<0>, llvm_ptr_ty,
 403                                 llvm_ptr_ty, llvm_i32_ty],
 404                                [], "llvm.annotation">;
 405
 406 //===------------------------ Trampoline Intrinsics -----------------------===//
 407 //
 408 def int_init_trampoline : Intrinsic<[],
 409                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 410                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 411                                    GCCBuiltin<"__builtin_init_trampoline">;
 412
 413 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 414                                       [IntrReadArgMem]>,
 415                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 416
 417 //===------------------------ Overflow Intrinsics -------------------------===//
 418 //
 419
 420 // Expose the carry flag from add operations on two integrals.
 421 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 422                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 423                                        [IntrNoMem]>;
 424 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 425                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 426                                        [IntrNoMem]>;
 427
 428 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 429                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 430                                        [IntrNoMem]>;
 431 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 432                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 433                                        [IntrNoMem]>;
 434
 435 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 436                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 437                                        [IntrNoMem]>;
 438 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 439                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 440                                        [IntrNoMem]>;
 441
 442 //===------------------------- Memory Use Markers -------------------------===//
 443 //
 444 def int_lifetime_start  : Intrinsic<[],
 445                                     [llvm_i64_ty, llvm_ptr_ty],
 446                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 447 def int_lifetime_end    : Intrinsic<[],
 448                                     [llvm_i64_ty, llvm_ptr_ty],
 449                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 450 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 451                                     [llvm_i64_ty, llvm_ptr_ty],
 452                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 453 def int_invariant_end   : Intrinsic<[],
 454                                     [llvm_descriptor_ty, llvm_i64_ty,
 455                                      llvm_ptr_ty],
 456                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 457
 458 //===------------------------ Stackmap Intrinsics -------------------------===//
 459 //
 460 def int_experimental_stackmap : Intrinsic<[],
 461                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty]>;
 462 def int_experimental_patchpoint_void : Intrinsic<[],
 463                                                  [llvm_i64_ty, llvm_i32_ty,
 464                                                   llvm_ptr_ty, llvm_i32_ty,
 465                                                   llvm_vararg_ty]>;
 466 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 467                                                 [llvm_i64_ty, llvm_i32_ty,
 468                                                  llvm_ptr_ty, llvm_i32_ty,
 469                                                  llvm_vararg_ty]>;
 470
 471 //===-------------------------- Other Intrinsics --------------------------===//
 472 //
 473 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 474                      GCCBuiltin<"__builtin_flt_rounds">;
 475 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 476                GCCBuiltin<"__builtin_trap">;
 477 def int_debugtrap : Intrinsic<[]>,
 478                     GCCBuiltin<"__builtin_debugtrap">;
 479
 480 // NOP: calls/invokes to this intrinsic are removed by codegen
 481 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 482
 483 // Intrisics to support half precision floating point format
 484 let Properties = [IntrNoMem] in {
 485 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 486                             GCCBuiltin<"__gnu_f2h_ieee">;
 487 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 488                             GCCBuiltin<"__gnu_h2f_ieee">;
 489 }
 490
 491 // These convert intrinsics are to support various conversions between
 492 // various types with rounding and saturation. NOTE: avoid using these
 493 // intrinsics as they might be removed sometime in the future and
 494 // most targets don't support them.
 495 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 496                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 497 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 498                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 499 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 500                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 501 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 502                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 503 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 504                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 505 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 506                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 507 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 508                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 509 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 510                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 511 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 512                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 513
 514 //===----------------------------------------------------------------------===//
 515 // Target-specific intrinsics
 516 //===----------------------------------------------------------------------===//
 517
 518 include "llvm/IR/IntrinsicsPowerPC.td"
 519 include "llvm/IR/IntrinsicsX86.td"
 520 include "llvm/IR/IntrinsicsARM.td"
 521 include "llvm/IR/IntrinsicsAArch64.td"
 522 include "llvm/IR/IntrinsicsXCore.td"
 523 include "llvm/IR/IntrinsicsHexagon.td"
 524 include "llvm/IR/IntrinsicsNVVM.td"
 525 include "llvm/IR/IntrinsicsMips.td"
 526 include "llvm/IR/IntrinsicsR600.td"