include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 // IntrNoduplicate - Calls to this intrinsic cannot be duplicated.
  73 // Parallels the noduplicate attribute on LLVM IR functions.
  74 def IntrNoDuplicate : IntrinsicProperty;
  75
  76 // IntrConvergent - Calls to this intrinsic are convergent and may only be
  77 // moved to control equivalent blocks.
  78 // Parallels the convergent attribute on LLVM IR functions.
  79 def IntrConvergent : IntrinsicProperty;
  80
  81 //===----------------------------------------------------------------------===//
  82 // Types used by intrinsics.
  83 //===----------------------------------------------------------------------===//
  84
  85 class LLVMType<ValueType vt> {
  86   ValueType VT = vt;
  87 }
  88
  89 class LLVMQualPointerType<LLVMType elty, int addrspace>
  90   : LLVMType<iPTR>{
  91   LLVMType ElTy = elty;
  92   int AddrSpace = addrspace;
  93 }
  94
  95 class LLVMPointerType<LLVMType elty>
  96   : LLVMQualPointerType<elty, 0>;
  97
  98 class LLVMAnyPointerType<LLVMType elty>
  99   : LLVMType<iPTRAny>{
 100   LLVMType ElTy = elty;
 101 }
 102
 103 // Match the type of another intrinsic parameter.  Number is an index into the
 104 // list of overloaded types for the intrinsic, excluding all the fixed types.
 105 // The Number value must refer to a previously listed type.  For example:
 106 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
 107 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
 108 // refers to the first overloaded type, which is the 2nd argument.
 109 class LLVMMatchType<int num>
 110   : LLVMType<OtherVT>{
 111   int Number = num;
 112 }
 113
 114 // Match the type of another intrinsic parameter that is expected to be based on
 115 // an integral type (i.e. either iN or <N x iM>), but change the scalar size to
 116 // be twice as wide or half as wide as the other type.  This is only useful when
 117 // the intrinsic is overloaded, so the matched type should be declared as iAny.
 118 class LLVMExtendedType<int num> : LLVMMatchType<num>;
 119 class LLVMTruncatedType<int num> : LLVMMatchType<num>;
 120 class LLVMVectorSameWidth<int num, LLVMType elty>
 121   : LLVMMatchType<num> {
 122   ValueType ElTy = elty.VT;
 123 }
 124 class LLVMPointerTo<int num> : LLVMMatchType<num>;
 125 class LLVMVectorOfPointersToElt<int num> : LLVMMatchType<num>;
 126
 127 // Match the type of another intrinsic parameter that is expected to be a
 128 // vector type, but change the element count to be half as many
 129 class LLVMHalfElementsVectorType<int num> : LLVMMatchType<num>;
 130
 131 def llvm_void_ty       : LLVMType<isVoid>;
 132 def llvm_any_ty        : LLVMType<Any>;
 133 def llvm_anyint_ty     : LLVMType<iAny>;
 134 def llvm_anyfloat_ty   : LLVMType<fAny>;
 135 def llvm_anyvector_ty  : LLVMType<vAny>;
 136 def llvm_i1_ty         : LLVMType<i1>;
 137 def llvm_i8_ty         : LLVMType<i8>;
 138 def llvm_i16_ty        : LLVMType<i16>;
 139 def llvm_i32_ty        : LLVMType<i32>;
 140 def llvm_i64_ty        : LLVMType<i64>;
 141 def llvm_half_ty       : LLVMType<f16>;
 142 def llvm_float_ty      : LLVMType<f32>;
 143 def llvm_double_ty     : LLVMType<f64>;
 144 def llvm_f80_ty        : LLVMType<f80>;
 145 def llvm_f128_ty       : LLVMType<f128>;
 146 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 147 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 148 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 149 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 150 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 151 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 152 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 153
 154 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 155 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 156
 157 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 158 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 159 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 160 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 161 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 162 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 163 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 164 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 165 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 166 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 167 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 168 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 169 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 170
 171 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 172 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 173 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 174 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 175 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 176 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 177
 178 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 179 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 180 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 181 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 182 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 183 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 184 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 185 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 186 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 187 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 188
 189 def llvm_v1i128_ty     : LLVMType<v1i128>;   //  1 x i128
 190
 191 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 192 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 193 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 194 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 195 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 196 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 197 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 198 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 199 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 200 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 201 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 202 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 203
 204 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 205
 206
 207 //===----------------------------------------------------------------------===//
 208 // Intrinsic Definitions.
 209 //===----------------------------------------------------------------------===//
 210
 211 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 212 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 213 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 214 // example, llvm.bswap.i16 -> int_bswap_i16.
 215 //
 216 //  * RetTypes is a list containing the return types expected for the
 217 //    intrinsic.
 218 //  * ParamTypes is a list containing the parameter types expected for the
 219 //    intrinsic.
 220 //  * Properties can be set to describe the behavior of the intrinsic.
 221 //
 222 class SDPatternOperator;
 223 class Intrinsic<list<LLVMType> ret_types,
 224                 list<LLVMType> param_types = [],
 225                 list<IntrinsicProperty> properties = [],
 226                 string name = ""> : SDPatternOperator {
 227   string LLVMName = name;
 228   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 229   list<LLVMType> RetTypes = ret_types;
 230   list<LLVMType> ParamTypes = param_types;
 231   list<IntrinsicProperty> Properties = properties;
 232
 233   bit isTarget = 0;
 234 }
 235
 236 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 237 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 238 /// support.
 239 class GCCBuiltin<string name> {
 240   string GCCBuiltinName = name;
 241 }
 242
 243 class MSBuiltin<string name> {
 244   string MSBuiltinName = name;
 245 }
 246
 247
 248 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 249 //
 250
 251 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 252 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 253                             "llvm.va_copy">;
 254 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 255
 256 //===------------------- Garbage Collection Intrinsics --------------------===//
 257 //
 258 def int_gcroot  : Intrinsic<[],
 259                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 260 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 261                             [llvm_ptr_ty, llvm_ptrptr_ty],
 262                             [IntrReadArgMem]>;
 263 def int_gcwrite : Intrinsic<[],
 264                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 265                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 266
 267 //===--------------------- Code Generator Intrinsics ----------------------===//
 268 //
 269 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 270 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 271 def int_frameescape : Intrinsic<[], [llvm_vararg_ty]>;
 272 def int_framerecover : Intrinsic<[llvm_ptr_ty],
 273                                  [llvm_ptr_ty, llvm_ptr_ty, llvm_i32_ty],
 274                                  [IntrNoMem]>;
 275 def int_read_register  : Intrinsic<[llvm_anyint_ty], [llvm_metadata_ty],
 276                                    [IntrReadMem], "llvm.read_register">;
 277 def int_write_register : Intrinsic<[], [llvm_metadata_ty, llvm_anyint_ty],
 278                                    [], "llvm.write_register">;
 279
 280 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 281 // model their dependencies on allocas.
 282 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 283                         GCCBuiltin<"__builtin_stack_save">;
 284 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 285                         GCCBuiltin<"__builtin_stack_restore">;
 286
 287 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 288 // however it does conveniently prevent the prefetch from being reordered
 289 // with respect to nearby accesses to the same memory.
 290 def int_prefetch      : Intrinsic<[],
 291                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 292                                    llvm_i32_ty],
 293                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 294 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 295
 296 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 297
 298 // The assume intrinsic is marked as arbitrarily writing so that proper
 299 // control dependencies will be maintained.
 300 def int_assume        : Intrinsic<[], [llvm_i1_ty], []>;
 301
 302 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 303 // guard to the correct place on the stack frame.
 304 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 305 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 306                                         [IntrReadWriteArgMem]>;
 307
 308 // A counter increment for instrumentation based profiling.
 309 def int_instrprof_increment : Intrinsic<[],
 310                                         [llvm_ptr_ty, llvm_i64_ty,
 311                                          llvm_i32_ty, llvm_i32_ty],
 312                                         []>;
 313
 314 //===------------------- Standard C Library Intrinsics --------------------===//
 315 //
 316
 317 def int_memcpy  : Intrinsic<[],
 318                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 319                               llvm_i32_ty, llvm_i1_ty],
 320                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 321                              ReadOnly<1>]>;
 322 def int_memmove : Intrinsic<[],
 323                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 324                              llvm_i32_ty, llvm_i1_ty],
 325                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 326                              ReadOnly<1>]>;
 327 def int_memset  : Intrinsic<[],
 328                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 329                              llvm_i32_ty, llvm_i1_ty],
 330                             [IntrReadWriteArgMem, NoCapture<0>]>;
 331
 332 let Properties = [IntrNoMem] in {
 333   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 334                            [LLVMMatchType<0>, LLVMMatchType<0>,
 335                             LLVMMatchType<0>]>;
 336   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 337                               [LLVMMatchType<0>, LLVMMatchType<0>,
 338                                LLVMMatchType<0>]>;
 339
 340   // These functions do not read memory, but are sensitive to the
 341   // rounding mode. LLVM purposely does not model changes to the FP
 342   // environment so they can be treated as readnone.
 343   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 344   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 345   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 346   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 347   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 348                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 349   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 350   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 351   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 352   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 353   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 354   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 355   def int_minnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 356   def int_maxnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 357   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 358                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 359   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 360   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 361   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 362   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 363   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 364   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 365 }
 366
 367 // NOTE: these are internal interfaces.
 368 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 369 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 370 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 371 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 372
 373 // Internal interface for object size checking
 374 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 375                                [IntrNoMem]>,
 376                                GCCBuiltin<"__builtin_object_size">;
 377
 378 //===------------------------- Expect Intrinsics --------------------------===//
 379 //
 380 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 381                                               LLVMMatchType<0>], [IntrNoMem]>;
 382
 383 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 384 //
 385
 386 // None of these intrinsics accesses memory at all.
 387 let Properties = [IntrNoMem] in {
 388   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 389   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 390   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 391   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 392 }
 393
 394 //===------------------------ Debugger Intrinsics -------------------------===//
 395 //
 396
 397 // None of these intrinsics accesses memory at all...but that doesn't mean the
 398 // optimizers can change them aggressively.  Special handling needed in a few
 399 // places.
 400 let Properties = [IntrNoMem] in {
 401   def int_dbg_declare      : Intrinsic<[],
 402                                        [llvm_metadata_ty,
 403                                        llvm_metadata_ty,
 404                                        llvm_metadata_ty]>;
 405   def int_dbg_value        : Intrinsic<[],
 406                                        [llvm_metadata_ty, llvm_i64_ty,
 407                                         llvm_metadata_ty,
 408                                         llvm_metadata_ty]>;
 409 }
 410
 411 //===------------------ Exception Handling Intrinsics----------------------===//
 412 //
 413
 414 // The result of eh.typeid.for depends on the enclosing function, but inside a
 415 // given function it is 'const' and may be CSE'd etc.
 416 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 417
 418 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 419 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 420
 421 // eh.begincatch takes a pointer returned by a landingpad instruction and
 422 // copies the exception object into the memory pointed to by the second
 423 // parameter. If the second parameter is null, no copy occurs.
 424 def int_eh_begincatch : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 425                                   [NoCapture<0>, NoCapture<1>]>;
 426 def int_eh_endcatch : Intrinsic<[], []>;
 427
 428 // Represents the list of actions to take when an exception is thrown.
 429 def int_eh_actions : Intrinsic<[llvm_ptr_ty], [llvm_vararg_ty], []>;
 430
 431 def int_eh_exceptioncode : Intrinsic<[llvm_i32_ty], [], [IntrReadMem]>;
 432 def int_eh_exceptioninfo : Intrinsic<[llvm_ptr_ty], [], [IntrReadMem]>;
 433
 434 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 435 // callee-saved registers to be saved and restored (regardless of whether they
 436 // are used) in the calling function. It is used by libgcc_eh.
 437 def int_eh_unwind_init: Intrinsic<[]>,
 438                         GCCBuiltin<"__builtin_unwind_init">;
 439
 440 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 441
 442 let Properties = [IntrNoMem] in {
 443   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 444   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 445 }
 446 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 447 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 448 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 449
 450 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 451 //
 452 def int_var_annotation : Intrinsic<[],
 453                                    [llvm_ptr_ty, llvm_ptr_ty,
 454                                     llvm_ptr_ty, llvm_i32_ty],
 455                                    [], "llvm.var.annotation">;
 456 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 457                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 458                                     llvm_i32_ty],
 459                                    [], "llvm.ptr.annotation">;
 460 def int_annotation : Intrinsic<[llvm_anyint_ty],
 461                                [LLVMMatchType<0>, llvm_ptr_ty,
 462                                 llvm_ptr_ty, llvm_i32_ty],
 463                                [], "llvm.annotation">;
 464
 465 //===------------------------ Trampoline Intrinsics -----------------------===//
 466 //
 467 def int_init_trampoline : Intrinsic<[],
 468                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 469                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 470                                    GCCBuiltin<"__builtin_init_trampoline">;
 471
 472 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 473                                       [IntrReadArgMem]>,
 474                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 475
 476 //===------------------------ Overflow Intrinsics -------------------------===//
 477 //
 478
 479 // Expose the carry flag from add operations on two integrals.
 480 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 481                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 482                                        [IntrNoMem]>;
 483 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 484                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 485                                        [IntrNoMem]>;
 486
 487 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 488                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 489                                        [IntrNoMem]>;
 490 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 491                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 492                                        [IntrNoMem]>;
 493
 494 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 495                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 496                                        [IntrNoMem]>;
 497 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 498                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 499                                        [IntrNoMem]>;
 500
 501 //===------------------------- Memory Use Markers -------------------------===//
 502 //
 503 def int_lifetime_start  : Intrinsic<[],
 504                                     [llvm_i64_ty, llvm_ptr_ty],
 505                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 506 def int_lifetime_end    : Intrinsic<[],
 507                                     [llvm_i64_ty, llvm_ptr_ty],
 508                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 509 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 510                                     [llvm_i64_ty, llvm_ptr_ty],
 511                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 512 def int_invariant_end   : Intrinsic<[],
 513                                     [llvm_descriptor_ty, llvm_i64_ty,
 514                                      llvm_ptr_ty],
 515                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 516
 517 //===------------------------ Stackmap Intrinsics -------------------------===//
 518 //
 519 def int_experimental_stackmap : Intrinsic<[],
 520                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty],
 521                                   [Throws]>;
 522 def int_experimental_patchpoint_void : Intrinsic<[],
 523                                                  [llvm_i64_ty, llvm_i32_ty,
 524                                                   llvm_ptr_ty, llvm_i32_ty,
 525                                                   llvm_vararg_ty],
 526                                                   [Throws]>;
 527 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 528                                                 [llvm_i64_ty, llvm_i32_ty,
 529                                                  llvm_ptr_ty, llvm_i32_ty,
 530                                                  llvm_vararg_ty],
 531                                                  [Throws]>;
 532
 533
 534 //===------------------------ Garbage Collection Intrinsics ---------------===//
 535 // These are documented in docs/Statepoint.rst
 536
 537 def int_experimental_gc_statepoint : Intrinsic<[llvm_i32_ty],
 538                                [llvm_i64_ty, llvm_i32_ty,
 539                                 llvm_anyptr_ty, llvm_i32_ty,
 540                                 llvm_i32_ty, llvm_vararg_ty],
 541                                 [Throws]>;
 542
 543 def int_experimental_gc_result   : Intrinsic<[llvm_any_ty], [llvm_i32_ty]>;
 544 def int_experimental_gc_relocate : Intrinsic<[llvm_anyptr_ty],
 545                                 [llvm_i32_ty, llvm_i32_ty, llvm_i32_ty]>;
 546
 547 // Deprecated: will be removed in a couple of weeks
 548 def int_experimental_gc_result_int : Intrinsic<[llvm_anyint_ty], [llvm_i32_ty]>;
 549 def int_experimental_gc_result_float : Intrinsic<[llvm_anyfloat_ty],
 550                                                  [llvm_i32_ty]>;
 551 def int_experimental_gc_result_ptr : Intrinsic<[llvm_anyptr_ty], [llvm_i32_ty]>;
 552
 553 //===-------------------------- Other Intrinsics --------------------------===//
 554 //
 555 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 556                      GCCBuiltin<"__builtin_flt_rounds">;
 557 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 558                GCCBuiltin<"__builtin_trap">;
 559 def int_debugtrap : Intrinsic<[]>,
 560                     GCCBuiltin<"__builtin_debugtrap">;
 561
 562 // NOP: calls/invokes to this intrinsic are removed by codegen
 563 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 564
 565 // Intrisics to support half precision floating point format
 566 let Properties = [IntrNoMem] in {
 567 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_anyfloat_ty]>;
 568 def int_convert_from_fp16 : Intrinsic<[llvm_anyfloat_ty], [llvm_i16_ty]>;
 569 }
 570
 571 // These convert intrinsics are to support various conversions between
 572 // various types with rounding and saturation. NOTE: avoid using these
 573 // intrinsics as they might be removed sometime in the future and
 574 // most targets don't support them.
 575 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 576                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 577 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 578                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 579 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 580                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 581 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 582                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 583 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 584                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 585 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 586                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 587 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 588                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 589 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 590                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 591 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 592                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 593
 594 // Clear cache intrinsic, default to ignore (ie. emit nothing)
 595 // maps to void __clear_cache() on supporting platforms
 596 def int_clear_cache : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 597                                 [], "llvm.clear_cache">;
 598
 599 //===-------------------------- Masked Intrinsics -------------------------===//
 600 //
 601 def int_masked_store : Intrinsic<[], [llvm_anyvector_ty, LLVMPointerTo<0>,
 602                                       llvm_i32_ty,
 603                                       LLVMVectorSameWidth<0, llvm_i1_ty>],
 604                                  [IntrReadWriteArgMem]>;
 605
 606 def int_masked_load  : Intrinsic<[llvm_anyvector_ty],
 607                                  [LLVMPointerTo<0>, llvm_i32_ty,
 608                                   LLVMVectorSameWidth<0, llvm_i1_ty>, LLVMMatchType<0>],
 609                                  [IntrReadArgMem]>;
 610
 611 def int_masked_gather: Intrinsic<[llvm_anyvector_ty],
 612                                  [LLVMVectorOfPointersToElt<0>, llvm_i32_ty,
 613                                   LLVMVectorSameWidth<0, llvm_i1_ty>,
 614                                   LLVMMatchType<0>],
 615                                  [IntrReadArgMem]>;
 616
 617 def int_masked_scatter: Intrinsic<[],
 618                                   [llvm_anyvector_ty,
 619                                    LLVMVectorOfPointersToElt<0>, llvm_i32_ty,
 620                                    LLVMVectorSameWidth<0, llvm_i1_ty>],
 621                                   [IntrReadWriteArgMem]>;
 622
 623 // Intrinsics to support bit sets.
 624 def int_bitset_test : Intrinsic<[llvm_i1_ty], [llvm_ptr_ty, llvm_metadata_ty],
 625                                 [IntrNoMem]>;
 626
 627 //===----------------------------------------------------------------------===//
 628 // Target-specific intrinsics
 629 //===----------------------------------------------------------------------===//
 630
 631 include "llvm/IR/IntrinsicsPowerPC.td"
 632 include "llvm/IR/IntrinsicsX86.td"
 633 include "llvm/IR/IntrinsicsARM.td"
 634 include "llvm/IR/IntrinsicsAArch64.td"
 635 include "llvm/IR/IntrinsicsXCore.td"
 636 include "llvm/IR/IntrinsicsHexagon.td"
 637 include "llvm/IR/IntrinsicsNVVM.td"
 638 include "llvm/IR/IntrinsicsMips.td"
 639 include "llvm/IR/IntrinsicsR600.td"
 640 include "llvm/IR/IntrinsicsBPF.td"
 641 include "llvm/IR/IntrinsicsSystemZ.td"