include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 //===----------------------------------------------------------------------===//
  73 // Types used by intrinsics.
  74 //===----------------------------------------------------------------------===//
  75
  76 class LLVMType<ValueType vt> {
  77   ValueType VT = vt;
  78 }
  79
  80 class LLVMQualPointerType<LLVMType elty, int addrspace>
  81   : LLVMType<iPTR>{
  82   LLVMType ElTy = elty;
  83   int AddrSpace = addrspace;
  84 }
  85
  86 class LLVMPointerType<LLVMType elty>
  87   : LLVMQualPointerType<elty, 0>;
  88
  89 class LLVMAnyPointerType<LLVMType elty>
  90   : LLVMType<iPTRAny>{
  91   LLVMType ElTy = elty;
  92 }
  93
  94 // Match the type of another intrinsic parameter.  Number is an index into the
  95 // list of overloaded types for the intrinsic, excluding all the fixed types.
  96 // The Number value must refer to a previously listed type.  For example:
  97 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  98 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  99 // refers to the first overloaded type, which is the 2nd argument.
 100 class LLVMMatchType<int num>
 101   : LLVMType<OtherVT>{
 102   int Number = num;
 103 }
 104
 105 // Match the type of another intrinsic parameter that is expected to be
 106 // an integral vector type, but change the element size to be twice as wide
 107 // or half as wide as the other type.  This is only useful when the intrinsic
 108 // is overloaded, so the matched type should be declared as iAny.
 109 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
 110 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
 111
 112 def llvm_void_ty       : LLVMType<isVoid>;
 113 def llvm_anyint_ty     : LLVMType<iAny>;
 114 def llvm_anyfloat_ty   : LLVMType<fAny>;
 115 def llvm_anyvector_ty  : LLVMType<vAny>;
 116 def llvm_i1_ty         : LLVMType<i1>;
 117 def llvm_i8_ty         : LLVMType<i8>;
 118 def llvm_i16_ty        : LLVMType<i16>;
 119 def llvm_i32_ty        : LLVMType<i32>;
 120 def llvm_i64_ty        : LLVMType<i64>;
 121 def llvm_half_ty       : LLVMType<f16>;
 122 def llvm_float_ty      : LLVMType<f32>;
 123 def llvm_double_ty     : LLVMType<f64>;
 124 def llvm_f80_ty        : LLVMType<f80>;
 125 def llvm_f128_ty       : LLVMType<f128>;
 126 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 127 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 128 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 129 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 130 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 131 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 132 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 133
 134 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 135 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 136
 137 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 138 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 139 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 140 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 141 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 142 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 143 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 144 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 145 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 146 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 147 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 148 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 149 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 150
 151 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 152 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 153 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 154 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 155 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 156 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 157
 158 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 159 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 160 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 161 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 162 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 163 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 164 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 165 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 166 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 167 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 168
 169 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 170 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 171 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 172 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 173 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 174 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 175 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 176 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 177 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 178 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 179
 180 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 181
 182
 183 //===----------------------------------------------------------------------===//
 184 // Intrinsic Definitions.
 185 //===----------------------------------------------------------------------===//
 186
 187 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 188 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 189 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 190 // example, llvm.bswap.i16 -> int_bswap_i16.
 191 //
 192 //  * RetTypes is a list containing the return types expected for the
 193 //    intrinsic.
 194 //  * ParamTypes is a list containing the parameter types expected for the
 195 //    intrinsic.
 196 //  * Properties can be set to describe the behavior of the intrinsic.
 197 //
 198 class SDPatternOperator;
 199 class Intrinsic<list<LLVMType> ret_types,
 200                 list<LLVMType> param_types = [],
 201                 list<IntrinsicProperty> properties = [],
 202                 string name = ""> : SDPatternOperator {
 203   string LLVMName = name;
 204   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 205   list<LLVMType> RetTypes = ret_types;
 206   list<LLVMType> ParamTypes = param_types;
 207   list<IntrinsicProperty> Properties = properties;
 208
 209   bit isTarget = 0;
 210 }
 211
 212 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 213 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 214 /// support.
 215 class GCCBuiltin<string name> {
 216   string GCCBuiltinName = name;
 217 }
 218
 219
 220 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 221 //
 222
 223 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 224 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 225                             "llvm.va_copy">;
 226 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 227
 228 //===------------------- Garbage Collection Intrinsics --------------------===//
 229 //
 230 def int_gcroot  : Intrinsic<[],
 231                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 232 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 233                             [llvm_ptr_ty, llvm_ptrptr_ty],
 234                             [IntrReadArgMem]>;
 235 def int_gcwrite : Intrinsic<[],
 236                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 237                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 238
 239 //===--------------------- Code Generator Intrinsics ----------------------===//
 240 //
 241 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 242 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 243
 244 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 245 // model their dependencies on allocas.
 246 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 247                         GCCBuiltin<"__builtin_stack_save">;
 248 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 249                         GCCBuiltin<"__builtin_stack_restore">;
 250
 251 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 252 // however it does conveniently prevent the prefetch from being reordered
 253 // with respect to nearby accesses to the same memory.
 254 def int_prefetch      : Intrinsic<[],
 255                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 256                                    llvm_i32_ty],
 257                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 258 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 259
 260 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 261
 262 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 263 // guard to the correct place on the stack frame.
 264 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 265 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 266                                         [IntrReadWriteArgMem]>;
 267
 268 //===------------------- Standard C Library Intrinsics --------------------===//
 269 //
 270
 271 def int_memcpy  : Intrinsic<[],
 272                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 273                               llvm_i32_ty, llvm_i1_ty],
 274                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 275                              ReadOnly<1>]>;
 276 def int_memmove : Intrinsic<[],
 277                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 278                              llvm_i32_ty, llvm_i1_ty],
 279                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 280                              ReadOnly<1>]>;
 281 def int_memset  : Intrinsic<[],
 282                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 283                              llvm_i32_ty, llvm_i1_ty],
 284                             [IntrReadWriteArgMem, NoCapture<0>]>;
 285
 286 // These functions do not actually read memory, but they are sensitive to the
 287 // rounding mode.  This needs to be modelled separately; in the meantime
 288 // declaring them as reading memory is conservatively correct.
 289 let Properties = [IntrReadMem] in {
 290   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 291   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 292   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 293   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 294   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 295                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 296   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 297   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 298   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 299   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 300   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 301   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 302   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 303                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 304   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 305   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 306   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 307   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 308   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 309   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 310 }
 311
 312 let Properties = [IntrNoMem] in {
 313   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 314                          [LLVMMatchType<0>, LLVMMatchType<0>,
 315                           LLVMMatchType<0>]>;
 316
 317   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 318                               [LLVMMatchType<0>, LLVMMatchType<0>,
 319                                LLVMMatchType<0>]>;
 320 }
 321
 322 // NOTE: these are internal interfaces.
 323 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 324 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 325 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 326 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 327
 328 // Internal interface for object size checking
 329 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 330                                [IntrNoMem]>,
 331                                GCCBuiltin<"__builtin_object_size">;
 332
 333 //===------------------------- Expect Intrinsics --------------------------===//
 334 //
 335 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 336                                               LLVMMatchType<0>], [IntrNoMem]>;
 337
 338 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 339 //
 340
 341 // None of these intrinsics accesses memory at all.
 342 let Properties = [IntrNoMem] in {
 343   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 344   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 345   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 346   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 347 }
 348
 349 //===------------------------ Debugger Intrinsics -------------------------===//
 350 //
 351
 352 // None of these intrinsics accesses memory at all...but that doesn't mean the
 353 // optimizers can change them aggressively.  Special handling needed in a few
 354 // places.
 355 let Properties = [IntrNoMem] in {
 356   def int_dbg_declare      : Intrinsic<[],
 357                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 358   def int_dbg_value        : Intrinsic<[],
 359                                        [llvm_metadata_ty, llvm_i64_ty,
 360                                         llvm_metadata_ty]>;
 361 }
 362
 363 //===------------------ Exception Handling Intrinsics----------------------===//
 364 //
 365
 366 // The result of eh.typeid.for depends on the enclosing function, but inside a
 367 // given function it is 'const' and may be CSE'd etc.
 368 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 369
 370 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 371 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 372
 373 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 374 // callee-saved registers to be saved and restored (regardless of whether they
 375 // are used) in the calling function. It is used by libgcc_eh.
 376 def int_eh_unwind_init: Intrinsic<[]>,
 377                         GCCBuiltin<"__builtin_unwind_init">;
 378
 379 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 380
 381 let Properties = [IntrNoMem] in {
 382   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 383   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 384 }
 385 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 386 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 387 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 388
 389 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 390 //
 391 def int_var_annotation : Intrinsic<[],
 392                                    [llvm_ptr_ty, llvm_ptr_ty,
 393                                     llvm_ptr_ty, llvm_i32_ty],
 394                                    [], "llvm.var.annotation">;
 395 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 396                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 397                                     llvm_i32_ty],
 398                                    [], "llvm.ptr.annotation">;
 399 def int_annotation : Intrinsic<[llvm_anyint_ty],
 400                                [LLVMMatchType<0>, llvm_ptr_ty,
 401                                 llvm_ptr_ty, llvm_i32_ty],
 402                                [], "llvm.annotation">;
 403
 404 //===------------------------ Trampoline Intrinsics -----------------------===//
 405 //
 406 def int_init_trampoline : Intrinsic<[],
 407                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 408                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 409                                    GCCBuiltin<"__builtin_init_trampoline">;
 410
 411 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 412                                       [IntrReadArgMem]>,
 413                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 414
 415 //===------------------------ Overflow Intrinsics -------------------------===//
 416 //
 417
 418 // Expose the carry flag from add operations on two integrals.
 419 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 420                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 421                                        [IntrNoMem]>;
 422 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 423                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 424                                        [IntrNoMem]>;
 425
 426 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 427                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 428                                        [IntrNoMem]>;
 429 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 430                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 431                                        [IntrNoMem]>;
 432
 433 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 434                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 435                                        [IntrNoMem]>;
 436 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 437                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 438                                        [IntrNoMem]>;
 439
 440 //===------------------------- Memory Use Markers -------------------------===//
 441 //
 442 def int_lifetime_start  : Intrinsic<[],
 443                                     [llvm_i64_ty, llvm_ptr_ty],
 444                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 445 def int_lifetime_end    : Intrinsic<[],
 446                                     [llvm_i64_ty, llvm_ptr_ty],
 447                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 448 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 449                                     [llvm_i64_ty, llvm_ptr_ty],
 450                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 451 def int_invariant_end   : Intrinsic<[],
 452                                     [llvm_descriptor_ty, llvm_i64_ty,
 453                                      llvm_ptr_ty],
 454                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 455
 456 //===-------------------------- Other Intrinsics --------------------------===//
 457 //
 458 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 459                      GCCBuiltin<"__builtin_flt_rounds">;
 460 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 461                GCCBuiltin<"__builtin_trap">;
 462 def int_debugtrap : Intrinsic<[]>,
 463                     GCCBuiltin<"__builtin_debugtrap">;
 464
 465 // NOP: calls/invokes to this intrinsic are removed by codegen
 466 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 467
 468 // Intrisics to support half precision floating point format
 469 let Properties = [IntrNoMem] in {
 470 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 471                             GCCBuiltin<"__gnu_f2h_ieee">;
 472 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 473                             GCCBuiltin<"__gnu_h2f_ieee">;
 474 }
 475
 476 // These convert intrinsics are to support various conversions between
 477 // various types with rounding and saturation. NOTE: avoid using these
 478 // intrinsics as they might be removed sometime in the future and
 479 // most targets don't support them.
 480 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 481                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 482 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 483                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 484 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 485                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 486 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 487                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 488 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 489                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 490 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 491                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 492 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 493                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 494 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 495                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 496 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 497                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 498
 499 //===----------------------------------------------------------------------===//
 500 // Target-specific intrinsics
 501 //===----------------------------------------------------------------------===//
 502
 503 include "llvm/IR/IntrinsicsPowerPC.td"
 504 include "llvm/IR/IntrinsicsX86.td"
 505 include "llvm/IR/IntrinsicsARM.td"
 506 include "llvm/IR/IntrinsicsAArch64.td"
 507 include "llvm/IR/IntrinsicsXCore.td"
 508 include "llvm/IR/IntrinsicsHexagon.td"
 509 include "llvm/IR/IntrinsicsNVVM.td"
 510 include "llvm/IR/IntrinsicsMips.td"
 511 include "llvm/IR/IntrinsicsR600.td"