include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 // IntrNoduplicate - Calls to this intrinsic cannot be duplicated.
  73 // Parallels the noduplicate attribute on LLVM IR functions.
  74 def IntrNoDuplicate : IntrinsicProperty;
  75
  76 //===----------------------------------------------------------------------===//
  77 // Types used by intrinsics.
  78 //===----------------------------------------------------------------------===//
  79
  80 class LLVMType<ValueType vt> {
  81   ValueType VT = vt;
  82 }
  83
  84 class LLVMQualPointerType<LLVMType elty, int addrspace>
  85   : LLVMType<iPTR>{
  86   LLVMType ElTy = elty;
  87   int AddrSpace = addrspace;
  88 }
  89
  90 class LLVMPointerType<LLVMType elty>
  91   : LLVMQualPointerType<elty, 0>;
  92
  93 class LLVMAnyPointerType<LLVMType elty>
  94   : LLVMType<iPTRAny>{
  95   LLVMType ElTy = elty;
  96 }
  97
  98 // Match the type of another intrinsic parameter.  Number is an index into the
  99 // list of overloaded types for the intrinsic, excluding all the fixed types.
 100 // The Number value must refer to a previously listed type.  For example:
 101 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
 102 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
 103 // refers to the first overloaded type, which is the 2nd argument.
 104 class LLVMMatchType<int num>
 105   : LLVMType<OtherVT>{
 106   int Number = num;
 107 }
 108
 109 // Match the type of another intrinsic parameter that is expected to be based on
 110 // an integral type (i.e. either iN or <N x iM>), but change the scalar size to
 111 // be twice as wide or half as wide as the other type.  This is only useful when
 112 // the intrinsic is overloaded, so the matched type should be declared as iAny.
 113 class LLVMExtendedType<int num> : LLVMMatchType<num>;
 114 class LLVMTruncatedType<int num> : LLVMMatchType<num>;
 115 class LLVMVectorSameWidth<int num, LLVMType elty>
 116   : LLVMMatchType<num> {
 117   ValueType ElTy = elty.VT;
 118 }
 119 class LLVMPointerTo<int num> : LLVMMatchType<num>;
 120
 121 // Match the type of another intrinsic parameter that is expected to be a
 122 // vector type, but change the element count to be half as many
 123 class LLVMHalfElementsVectorType<int num> : LLVMMatchType<num>;
 124
 125 def llvm_void_ty       : LLVMType<isVoid>;
 126 def llvm_any_ty        : LLVMType<Any>;
 127 def llvm_anyint_ty     : LLVMType<iAny>;
 128 def llvm_anyfloat_ty   : LLVMType<fAny>;
 129 def llvm_anyvector_ty  : LLVMType<vAny>;
 130 def llvm_i1_ty         : LLVMType<i1>;
 131 def llvm_i8_ty         : LLVMType<i8>;
 132 def llvm_i16_ty        : LLVMType<i16>;
 133 def llvm_i32_ty        : LLVMType<i32>;
 134 def llvm_i64_ty        : LLVMType<i64>;
 135 def llvm_half_ty       : LLVMType<f16>;
 136 def llvm_float_ty      : LLVMType<f32>;
 137 def llvm_double_ty     : LLVMType<f64>;
 138 def llvm_f80_ty        : LLVMType<f80>;
 139 def llvm_f128_ty       : LLVMType<f128>;
 140 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 141 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 142 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 143 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 144 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 145 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 146 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 147
 148 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 149 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 150
 151 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 152 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 153 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 154 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 155 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 156 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 157 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 158 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 159 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 160 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 161 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 162 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 163 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 164
 165 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 166 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 167 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 168 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 169 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 170 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 171
 172 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 173 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 174 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 175 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 176 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 177 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 178 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 179 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 180 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 181 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 182
 183 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 184 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 185 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 186 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 187 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 188 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 189 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 190 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 191 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 192 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 193 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 194 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 195
 196 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 197
 198
 199 //===----------------------------------------------------------------------===//
 200 // Intrinsic Definitions.
 201 //===----------------------------------------------------------------------===//
 202
 203 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 204 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 205 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 206 // example, llvm.bswap.i16 -> int_bswap_i16.
 207 //
 208 //  * RetTypes is a list containing the return types expected for the
 209 //    intrinsic.
 210 //  * ParamTypes is a list containing the parameter types expected for the
 211 //    intrinsic.
 212 //  * Properties can be set to describe the behavior of the intrinsic.
 213 //
 214 class SDPatternOperator;
 215 class Intrinsic<list<LLVMType> ret_types,
 216                 list<LLVMType> param_types = [],
 217                 list<IntrinsicProperty> properties = [],
 218                 string name = ""> : SDPatternOperator {
 219   string LLVMName = name;
 220   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 221   list<LLVMType> RetTypes = ret_types;
 222   list<LLVMType> ParamTypes = param_types;
 223   list<IntrinsicProperty> Properties = properties;
 224
 225   bit isTarget = 0;
 226 }
 227
 228 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 229 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 230 /// support.
 231 class GCCBuiltin<string name> {
 232   string GCCBuiltinName = name;
 233 }
 234
 235 class MSBuiltin<string name> {
 236   string MSBuiltinName = name;
 237 }
 238
 239
 240 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 241 //
 242
 243 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 244 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 245                             "llvm.va_copy">;
 246 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 247
 248 //===------------------- Garbage Collection Intrinsics --------------------===//
 249 //
 250 def int_gcroot  : Intrinsic<[],
 251                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 252 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 253                             [llvm_ptr_ty, llvm_ptrptr_ty],
 254                             [IntrReadArgMem]>;
 255 def int_gcwrite : Intrinsic<[],
 256                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 257                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 258
 259 //===--------------------- Code Generator Intrinsics ----------------------===//
 260 //
 261 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 262 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 263 def int_frameallocate : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 264 def int_framerecover : Intrinsic<[llvm_ptr_ty],
 265                                              [llvm_ptr_ty, llvm_ptr_ty],
 266                                              [IntrNoMem]>;
 267 def int_read_register  : Intrinsic<[llvm_anyint_ty], [llvm_metadata_ty],
 268                                    [IntrNoMem], "llvm.read_register">;
 269 def int_write_register : Intrinsic<[], [llvm_metadata_ty, llvm_anyint_ty],
 270                                    [], "llvm.write_register">;
 271
 272 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 273 // model their dependencies on allocas.
 274 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 275                         GCCBuiltin<"__builtin_stack_save">;
 276 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 277                         GCCBuiltin<"__builtin_stack_restore">;
 278
 279 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 280 // however it does conveniently prevent the prefetch from being reordered
 281 // with respect to nearby accesses to the same memory.
 282 def int_prefetch      : Intrinsic<[],
 283                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 284                                    llvm_i32_ty],
 285                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 286 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 287
 288 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 289
 290 // The assume intrinsic is marked as arbitrarily writing so that proper
 291 // control dependencies will be maintained.
 292 def int_assume        : Intrinsic<[], [llvm_i1_ty], []>;
 293
 294 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 295 // guard to the correct place on the stack frame.
 296 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 297 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 298                                         [IntrReadWriteArgMem]>;
 299
 300 // A counter increment for instrumentation based profiling.
 301 def int_instrprof_increment : Intrinsic<[],
 302                                         [llvm_ptr_ty, llvm_i64_ty,
 303                                          llvm_i32_ty, llvm_i32_ty],
 304                                         []>;
 305
 306 //===------------------- Standard C Library Intrinsics --------------------===//
 307 //
 308
 309 def int_memcpy  : Intrinsic<[],
 310                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 311                               llvm_i32_ty, llvm_i1_ty],
 312                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 313                              ReadOnly<1>]>;
 314 def int_memmove : Intrinsic<[],
 315                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 316                              llvm_i32_ty, llvm_i1_ty],
 317                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 318                              ReadOnly<1>]>;
 319 def int_memset  : Intrinsic<[],
 320                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 321                              llvm_i32_ty, llvm_i1_ty],
 322                             [IntrReadWriteArgMem, NoCapture<0>]>;
 323
 324 let Properties = [IntrNoMem] in {
 325   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 326                            [LLVMMatchType<0>, LLVMMatchType<0>,
 327                             LLVMMatchType<0>]>;
 328   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 329                               [LLVMMatchType<0>, LLVMMatchType<0>,
 330                                LLVMMatchType<0>]>;
 331
 332   // These functions do not read memory, but are sensitive to the
 333   // rounding mode. LLVM purposely does not model changes to the FP
 334   // environment so they can be treated as readnone.
 335   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 336   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 337   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 338   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 339   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 340                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 341   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 342   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 343   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 344   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 345   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 346   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 347   def int_minnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 348   def int_maxnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 349   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 350                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 351   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 352   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 353   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 354   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 355   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 356   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 357 }
 358
 359 // NOTE: these are internal interfaces.
 360 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 361 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 362 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 363 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 364
 365 // Internal interface for object size checking
 366 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 367                                [IntrNoMem]>,
 368                                GCCBuiltin<"__builtin_object_size">;
 369
 370 //===------------------------- Expect Intrinsics --------------------------===//
 371 //
 372 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 373                                               LLVMMatchType<0>], [IntrNoMem]>;
 374
 375 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 376 //
 377
 378 // None of these intrinsics accesses memory at all.
 379 let Properties = [IntrNoMem] in {
 380   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 381   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 382   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 383   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 384 }
 385
 386 //===------------------------ Debugger Intrinsics -------------------------===//
 387 //
 388
 389 // None of these intrinsics accesses memory at all...but that doesn't mean the
 390 // optimizers can change them aggressively.  Special handling needed in a few
 391 // places.
 392 let Properties = [IntrNoMem] in {
 393   def int_dbg_declare      : Intrinsic<[],
 394                                        [llvm_metadata_ty,
 395                                        llvm_metadata_ty,
 396                                        llvm_metadata_ty]>;
 397   def int_dbg_value        : Intrinsic<[],
 398                                        [llvm_metadata_ty, llvm_i64_ty,
 399                                         llvm_metadata_ty,
 400                                         llvm_metadata_ty]>;
 401 }
 402
 403 //===------------------ Exception Handling Intrinsics----------------------===//
 404 //
 405
 406 // The result of eh.typeid.for depends on the enclosing function, but inside a
 407 // given function it is 'const' and may be CSE'd etc.
 408 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 409
 410 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 411 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 412
 413 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 414 // callee-saved registers to be saved and restored (regardless of whether they
 415 // are used) in the calling function. It is used by libgcc_eh.
 416 def int_eh_unwind_init: Intrinsic<[]>,
 417                         GCCBuiltin<"__builtin_unwind_init">;
 418
 419 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 420
 421 let Properties = [IntrNoMem] in {
 422   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 423   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 424 }
 425 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 426 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 427 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 428
 429 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 430 //
 431 def int_var_annotation : Intrinsic<[],
 432                                    [llvm_ptr_ty, llvm_ptr_ty,
 433                                     llvm_ptr_ty, llvm_i32_ty],
 434                                    [], "llvm.var.annotation">;
 435 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 436                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 437                                     llvm_i32_ty],
 438                                    [], "llvm.ptr.annotation">;
 439 def int_annotation : Intrinsic<[llvm_anyint_ty],
 440                                [LLVMMatchType<0>, llvm_ptr_ty,
 441                                 llvm_ptr_ty, llvm_i32_ty],
 442                                [], "llvm.annotation">;
 443
 444 //===------------------------ Trampoline Intrinsics -----------------------===//
 445 //
 446 def int_init_trampoline : Intrinsic<[],
 447                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 448                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 449                                    GCCBuiltin<"__builtin_init_trampoline">;
 450
 451 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 452                                       [IntrReadArgMem]>,
 453                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 454
 455 //===------------------------ Overflow Intrinsics -------------------------===//
 456 //
 457
 458 // Expose the carry flag from add operations on two integrals.
 459 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 460                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 461                                        [IntrNoMem]>;
 462 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 463                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 464                                        [IntrNoMem]>;
 465
 466 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 467                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 468                                        [IntrNoMem]>;
 469 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 470                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 471                                        [IntrNoMem]>;
 472
 473 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 474                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 475                                        [IntrNoMem]>;
 476 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 477                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 478                                        [IntrNoMem]>;
 479
 480 //===------------------------- Memory Use Markers -------------------------===//
 481 //
 482 def int_lifetime_start  : Intrinsic<[],
 483                                     [llvm_i64_ty, llvm_ptr_ty],
 484                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 485 def int_lifetime_end    : Intrinsic<[],
 486                                     [llvm_i64_ty, llvm_ptr_ty],
 487                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 488 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 489                                     [llvm_i64_ty, llvm_ptr_ty],
 490                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 491 def int_invariant_end   : Intrinsic<[],
 492                                     [llvm_descriptor_ty, llvm_i64_ty,
 493                                      llvm_ptr_ty],
 494                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 495
 496 //===------------------------ Stackmap Intrinsics -------------------------===//
 497 //
 498 def int_experimental_stackmap : Intrinsic<[],
 499                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty],
 500                                   [Throws]>;
 501 def int_experimental_patchpoint_void : Intrinsic<[],
 502                                                  [llvm_i64_ty, llvm_i32_ty,
 503                                                   llvm_ptr_ty, llvm_i32_ty,
 504                                                   llvm_vararg_ty],
 505                                                   [Throws]>;
 506 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 507                                                 [llvm_i64_ty, llvm_i32_ty,
 508                                                  llvm_ptr_ty, llvm_i32_ty,
 509                                                  llvm_vararg_ty],
 510                                                  [Throws]>;
 511
 512
 513 //===------------------------ Garbage Collection Intrinsics ---------------===//
 514 // These are documented in docs/Statepoint.rst
 515
 516 def int_experimental_gc_statepoint : Intrinsic<[llvm_i32_ty],
 517                                [llvm_anyptr_ty, llvm_i32_ty,
 518                                 llvm_i32_ty, llvm_vararg_ty]>;
 519
 520 def int_experimental_gc_result   : Intrinsic<[llvm_any_ty], [llvm_i32_ty]>;
 521 def int_experimental_gc_relocate : Intrinsic<[llvm_anyptr_ty],
 522                                 [llvm_i32_ty, llvm_i32_ty, llvm_i32_ty]>;
 523
 524 // Deprecated: will be removed in a couple of weeks
 525 def int_experimental_gc_result_int : Intrinsic<[llvm_anyint_ty], [llvm_i32_ty]>;
 526 def int_experimental_gc_result_float : Intrinsic<[llvm_anyfloat_ty],
 527                                                  [llvm_i32_ty]>;
 528 def int_experimental_gc_result_ptr : Intrinsic<[llvm_anyptr_ty], [llvm_i32_ty]>;
 529
 530 //===-------------------------- Other Intrinsics --------------------------===//
 531 //
 532 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 533                      GCCBuiltin<"__builtin_flt_rounds">;
 534 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 535                GCCBuiltin<"__builtin_trap">;
 536 def int_debugtrap : Intrinsic<[]>,
 537                     GCCBuiltin<"__builtin_debugtrap">;
 538
 539 // NOP: calls/invokes to this intrinsic are removed by codegen
 540 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 541
 542 // Intrisics to support half precision floating point format
 543 let Properties = [IntrNoMem] in {
 544 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_anyfloat_ty]>;
 545 def int_convert_from_fp16 : Intrinsic<[llvm_anyfloat_ty], [llvm_i16_ty]>;
 546 }
 547
 548 // These convert intrinsics are to support various conversions between
 549 // various types with rounding and saturation. NOTE: avoid using these
 550 // intrinsics as they might be removed sometime in the future and
 551 // most targets don't support them.
 552 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 553                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 554 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 555                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 556 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 557                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 558 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 559                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 560 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 561                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 562 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 563                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 564 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 565                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 566 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 567                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 568 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 569                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 570
 571 // Clear cache intrinsic, default to ignore (ie. emit nothing)
 572 // maps to void __clear_cache() on supporting platforms
 573 def int_clear_cache : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 574                                 [], "llvm.clear_cache">;
 575
 576 //===-------------------------- Masked Intrinsics -------------------------===//
 577 //
 578 def int_masked_store : Intrinsic<[], [llvm_anyvector_ty, LLVMPointerTo<0>,
 579                                       llvm_i32_ty,
 580                                       LLVMVectorSameWidth<0, llvm_i1_ty>],
 581                                  [IntrReadWriteArgMem]>;
 582
 583 def int_masked_load  : Intrinsic<[llvm_anyvector_ty],
 584                                  [LLVMPointerTo<0>, llvm_i32_ty,
 585                                   LLVMVectorSameWidth<0, llvm_i1_ty>, LLVMMatchType<0>],
 586                                  [IntrReadArgMem]>;
 587 //===----------------------------------------------------------------------===//
 588 // Target-specific intrinsics
 589 //===----------------------------------------------------------------------===//
 590
 591 include "llvm/IR/IntrinsicsPowerPC.td"
 592 include "llvm/IR/IntrinsicsX86.td"
 593 include "llvm/IR/IntrinsicsARM.td"
 594 include "llvm/IR/IntrinsicsAArch64.td"
 595 include "llvm/IR/IntrinsicsXCore.td"
 596 include "llvm/IR/IntrinsicsHexagon.td"
 597 include "llvm/IR/IntrinsicsNVVM.td"
 598 include "llvm/IR/IntrinsicsMips.td"
 599 include "llvm/IR/IntrinsicsR600.td"