include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 // IntrNoduplicate - Calls to this intrinsic cannot be duplicated.
  73 // Parallels the noduplicate attribute on LLVM IR functions.
  74 def IntrNoDuplicate : IntrinsicProperty;
  75
  76 //===----------------------------------------------------------------------===//
  77 // Types used by intrinsics.
  78 //===----------------------------------------------------------------------===//
  79
  80 class LLVMType<ValueType vt> {
  81   ValueType VT = vt;
  82 }
  83
  84 class LLVMQualPointerType<LLVMType elty, int addrspace>
  85   : LLVMType<iPTR>{
  86   LLVMType ElTy = elty;
  87   int AddrSpace = addrspace;
  88 }
  89
  90 class LLVMPointerType<LLVMType elty>
  91   : LLVMQualPointerType<elty, 0>;
  92
  93 class LLVMAnyPointerType<LLVMType elty>
  94   : LLVMType<iPTRAny>{
  95   LLVMType ElTy = elty;
  96 }
  97
  98 // Match the type of another intrinsic parameter.  Number is an index into the
  99 // list of overloaded types for the intrinsic, excluding all the fixed types.
 100 // The Number value must refer to a previously listed type.  For example:
 101 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
 102 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
 103 // refers to the first overloaded type, which is the 2nd argument.
 104 class LLVMMatchType<int num>
 105   : LLVMType<OtherVT>{
 106   int Number = num;
 107 }
 108
 109 // Match the type of another intrinsic parameter that is expected to be based on
 110 // an integral type (i.e. either iN or <N x iM>), but change the scalar size to
 111 // be twice as wide or half as wide as the other type.  This is only useful when
 112 // the intrinsic is overloaded, so the matched type should be declared as iAny.
 113 class LLVMExtendedType<int num> : LLVMMatchType<num>;
 114 class LLVMTruncatedType<int num> : LLVMMatchType<num>;
 115 class LLVMVectorSameWidth<int num, LLVMType elty>
 116   : LLVMMatchType<num> {
 117   ValueType ElTy = elty.VT;
 118 }
 119 class LLVMPointerTo<int num> : LLVMMatchType<num>;
 120
 121 // Match the type of another intrinsic parameter that is expected to be a
 122 // vector type, but change the element count to be half as many
 123 class LLVMHalfElementsVectorType<int num> : LLVMMatchType<num>;
 124
 125 def llvm_void_ty       : LLVMType<isVoid>;
 126 def llvm_anyint_ty     : LLVMType<iAny>;
 127 def llvm_anyfloat_ty   : LLVMType<fAny>;
 128 def llvm_anyvector_ty  : LLVMType<vAny>;
 129 def llvm_i1_ty         : LLVMType<i1>;
 130 def llvm_i8_ty         : LLVMType<i8>;
 131 def llvm_i16_ty        : LLVMType<i16>;
 132 def llvm_i32_ty        : LLVMType<i32>;
 133 def llvm_i64_ty        : LLVMType<i64>;
 134 def llvm_half_ty       : LLVMType<f16>;
 135 def llvm_float_ty      : LLVMType<f32>;
 136 def llvm_double_ty     : LLVMType<f64>;
 137 def llvm_f80_ty        : LLVMType<f80>;
 138 def llvm_f128_ty       : LLVMType<f128>;
 139 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 140 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 141 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 142 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 143 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 144 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 145 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 146
 147 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 148 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 149
 150 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 151 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 152 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 153 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 154 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 155 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 156 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 157 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 158 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 159 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 160 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 161 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 162 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 163
 164 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 165 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 166 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 167 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 168 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 169 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 170
 171 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 172 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 173 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 174 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 175 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 176 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 177 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 178 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 179 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 180 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 181
 182 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 183 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 184 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 185 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 186 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 187 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 188 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 189 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 190 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 191 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 192 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 193 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 194
 195 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 196
 197
 198 //===----------------------------------------------------------------------===//
 199 // Intrinsic Definitions.
 200 //===----------------------------------------------------------------------===//
 201
 202 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 203 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 204 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 205 // example, llvm.bswap.i16 -> int_bswap_i16.
 206 //
 207 //  * RetTypes is a list containing the return types expected for the
 208 //    intrinsic.
 209 //  * ParamTypes is a list containing the parameter types expected for the
 210 //    intrinsic.
 211 //  * Properties can be set to describe the behavior of the intrinsic.
 212 //
 213 class SDPatternOperator;
 214 class Intrinsic<list<LLVMType> ret_types,
 215                 list<LLVMType> param_types = [],
 216                 list<IntrinsicProperty> properties = [],
 217                 string name = ""> : SDPatternOperator {
 218   string LLVMName = name;
 219   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 220   list<LLVMType> RetTypes = ret_types;
 221   list<LLVMType> ParamTypes = param_types;
 222   list<IntrinsicProperty> Properties = properties;
 223
 224   bit isTarget = 0;
 225 }
 226
 227 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 228 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 229 /// support.
 230 class GCCBuiltin<string name> {
 231   string GCCBuiltinName = name;
 232 }
 233
 234 class MSBuiltin<string name> {
 235   string MSBuiltinName = name;
 236 }
 237
 238
 239 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 240 //
 241
 242 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 243 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 244                             "llvm.va_copy">;
 245 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 246
 247 //===------------------- Garbage Collection Intrinsics --------------------===//
 248 //
 249 def int_gcroot  : Intrinsic<[],
 250                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 251 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 252                             [llvm_ptr_ty, llvm_ptrptr_ty],
 253                             [IntrReadArgMem]>;
 254 def int_gcwrite : Intrinsic<[],
 255                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 256                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 257
 258 //===--------------------- Code Generator Intrinsics ----------------------===//
 259 //
 260 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 261 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 262 def int_frameallocate : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 263 def int_recoverframeallocation : Intrinsic<[llvm_ptr_ty],
 264                                              [llvm_ptr_ty, llvm_ptr_ty],
 265                                              [IntrNoMem]>;
 266 def int_read_register  : Intrinsic<[llvm_anyint_ty], [llvm_metadata_ty],
 267                                    [IntrNoMem], "llvm.read_register">;
 268 def int_write_register : Intrinsic<[], [llvm_metadata_ty, llvm_anyint_ty],
 269                                    [], "llvm.write_register">;
 270
 271 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 272 // model their dependencies on allocas.
 273 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 274                         GCCBuiltin<"__builtin_stack_save">;
 275 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 276                         GCCBuiltin<"__builtin_stack_restore">;
 277
 278 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 279 // however it does conveniently prevent the prefetch from being reordered
 280 // with respect to nearby accesses to the same memory.
 281 def int_prefetch      : Intrinsic<[],
 282                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 283                                    llvm_i32_ty],
 284                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 285 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 286
 287 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 288
 289 // The assume intrinsic is marked as arbitrarily writing so that proper
 290 // control dependencies will be maintained.
 291 def int_assume        : Intrinsic<[], [llvm_i1_ty], []>;
 292
 293 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 294 // guard to the correct place on the stack frame.
 295 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 296 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 297                                         [IntrReadWriteArgMem]>;
 298
 299 // A counter increment for instrumentation based profiling.
 300 def int_instrprof_increment : Intrinsic<[],
 301                                         [llvm_ptr_ty, llvm_i64_ty,
 302                                          llvm_i32_ty, llvm_i32_ty],
 303                                         []>;
 304
 305 //===------------------- Standard C Library Intrinsics --------------------===//
 306 //
 307
 308 def int_memcpy  : Intrinsic<[],
 309                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 310                               llvm_i32_ty, llvm_i1_ty],
 311                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 312                              ReadOnly<1>]>;
 313 def int_memmove : Intrinsic<[],
 314                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 315                              llvm_i32_ty, llvm_i1_ty],
 316                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 317                              ReadOnly<1>]>;
 318 def int_memset  : Intrinsic<[],
 319                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 320                              llvm_i32_ty, llvm_i1_ty],
 321                             [IntrReadWriteArgMem, NoCapture<0>]>;
 322
 323 let Properties = [IntrNoMem] in {
 324   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 325                            [LLVMMatchType<0>, LLVMMatchType<0>,
 326                             LLVMMatchType<0>]>;
 327   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 328                               [LLVMMatchType<0>, LLVMMatchType<0>,
 329                                LLVMMatchType<0>]>;
 330
 331   // These functions do not read memory, but are sensitive to the
 332   // rounding mode. LLVM purposely does not model changes to the FP
 333   // environment so they can be treated as readnone.
 334   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 335   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 336   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 337   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 338   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 339                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 340   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 341   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 342   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 343   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 344   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 345   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 346   def int_minnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 347   def int_maxnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 348   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 349                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 350   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 351   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 352   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 353   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 354   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 355   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 356 }
 357
 358 // NOTE: these are internal interfaces.
 359 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 360 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 361 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 362 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 363
 364 // Internal interface for object size checking
 365 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 366                                [IntrNoMem]>,
 367                                GCCBuiltin<"__builtin_object_size">;
 368
 369 //===------------------------- Expect Intrinsics --------------------------===//
 370 //
 371 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 372                                               LLVMMatchType<0>], [IntrNoMem]>;
 373
 374 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 375 //
 376
 377 // None of these intrinsics accesses memory at all.
 378 let Properties = [IntrNoMem] in {
 379   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 380   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 381   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 382   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 383 }
 384
 385 //===------------------------ Debugger Intrinsics -------------------------===//
 386 //
 387
 388 // None of these intrinsics accesses memory at all...but that doesn't mean the
 389 // optimizers can change them aggressively.  Special handling needed in a few
 390 // places.
 391 let Properties = [IntrNoMem] in {
 392   def int_dbg_declare      : Intrinsic<[],
 393                                        [llvm_metadata_ty,
 394                                        llvm_metadata_ty,
 395                                        llvm_metadata_ty]>;
 396   def int_dbg_value        : Intrinsic<[],
 397                                        [llvm_metadata_ty, llvm_i64_ty,
 398                                         llvm_metadata_ty,
 399                                         llvm_metadata_ty]>;
 400 }
 401
 402 //===------------------ Exception Handling Intrinsics----------------------===//
 403 //
 404
 405 // The result of eh.typeid.for depends on the enclosing function, but inside a
 406 // given function it is 'const' and may be CSE'd etc.
 407 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 408
 409 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 410 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 411
 412 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 413 // callee-saved registers to be saved and restored (regardless of whether they
 414 // are used) in the calling function. It is used by libgcc_eh.
 415 def int_eh_unwind_init: Intrinsic<[]>,
 416                         GCCBuiltin<"__builtin_unwind_init">;
 417
 418 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 419
 420 let Properties = [IntrNoMem] in {
 421   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 422   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 423 }
 424 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 425 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 426 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 427
 428 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 429 //
 430 def int_var_annotation : Intrinsic<[],
 431                                    [llvm_ptr_ty, llvm_ptr_ty,
 432                                     llvm_ptr_ty, llvm_i32_ty],
 433                                    [], "llvm.var.annotation">;
 434 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 435                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 436                                     llvm_i32_ty],
 437                                    [], "llvm.ptr.annotation">;
 438 def int_annotation : Intrinsic<[llvm_anyint_ty],
 439                                [LLVMMatchType<0>, llvm_ptr_ty,
 440                                 llvm_ptr_ty, llvm_i32_ty],
 441                                [], "llvm.annotation">;
 442
 443 //===------------------------ Trampoline Intrinsics -----------------------===//
 444 //
 445 def int_init_trampoline : Intrinsic<[],
 446                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 447                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 448                                    GCCBuiltin<"__builtin_init_trampoline">;
 449
 450 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 451                                       [IntrReadArgMem]>,
 452                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 453
 454 //===------------------------ Overflow Intrinsics -------------------------===//
 455 //
 456
 457 // Expose the carry flag from add operations on two integrals.
 458 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 459                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 460                                        [IntrNoMem]>;
 461 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 462                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 463                                        [IntrNoMem]>;
 464
 465 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 466                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 467                                        [IntrNoMem]>;
 468 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 469                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 470                                        [IntrNoMem]>;
 471
 472 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 473                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 474                                        [IntrNoMem]>;
 475 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 476                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 477                                        [IntrNoMem]>;
 478
 479 //===------------------------- Memory Use Markers -------------------------===//
 480 //
 481 def int_lifetime_start  : Intrinsic<[],
 482                                     [llvm_i64_ty, llvm_ptr_ty],
 483                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 484 def int_lifetime_end    : Intrinsic<[],
 485                                     [llvm_i64_ty, llvm_ptr_ty],
 486                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 487 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 488                                     [llvm_i64_ty, llvm_ptr_ty],
 489                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 490 def int_invariant_end   : Intrinsic<[],
 491                                     [llvm_descriptor_ty, llvm_i64_ty,
 492                                      llvm_ptr_ty],
 493                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 494
 495 //===------------------------ Stackmap Intrinsics -------------------------===//
 496 //
 497 def int_experimental_stackmap : Intrinsic<[],
 498                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty],
 499                                   [Throws]>;
 500 def int_experimental_patchpoint_void : Intrinsic<[],
 501                                                  [llvm_i64_ty, llvm_i32_ty,
 502                                                   llvm_ptr_ty, llvm_i32_ty,
 503                                                   llvm_vararg_ty],
 504                                                   [Throws]>;
 505 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 506                                                 [llvm_i64_ty, llvm_i32_ty,
 507                                                  llvm_ptr_ty, llvm_i32_ty,
 508                                                  llvm_vararg_ty],
 509                                                  [Throws]>;
 510
 511
 512 //===------------------------ Garbage Collection Intrinsics ---------------===//
 513 // These are documented in docs/Statepoint.rst
 514
 515 def int_experimental_gc_statepoint : Intrinsic<[llvm_i32_ty],
 516                                [llvm_anyptr_ty, llvm_i32_ty,
 517                                 llvm_i32_ty, llvm_vararg_ty]>;
 518
 519 def int_experimental_gc_result_int : Intrinsic<[llvm_anyint_ty], [llvm_i32_ty]>;
 520 def int_experimental_gc_result_float : Intrinsic<[llvm_anyfloat_ty],
 521                                                  [llvm_i32_ty]>;
 522 def int_experimental_gc_result_ptr : Intrinsic<[llvm_anyptr_ty], [llvm_i32_ty]>;
 523
 524 def int_experimental_gc_relocate : Intrinsic<[llvm_anyptr_ty],
 525                                 [llvm_i32_ty, llvm_i32_ty, llvm_i32_ty]>;
 526
 527 //===-------------------------- Other Intrinsics --------------------------===//
 528 //
 529 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 530                      GCCBuiltin<"__builtin_flt_rounds">;
 531 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 532                GCCBuiltin<"__builtin_trap">;
 533 def int_debugtrap : Intrinsic<[]>,
 534                     GCCBuiltin<"__builtin_debugtrap">;
 535
 536 // NOP: calls/invokes to this intrinsic are removed by codegen
 537 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 538
 539 // Intrisics to support half precision floating point format
 540 let Properties = [IntrNoMem] in {
 541 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_anyfloat_ty]>;
 542 def int_convert_from_fp16 : Intrinsic<[llvm_anyfloat_ty], [llvm_i16_ty]>;
 543 }
 544
 545 // These convert intrinsics are to support various conversions between
 546 // various types with rounding and saturation. NOTE: avoid using these
 547 // intrinsics as they might be removed sometime in the future and
 548 // most targets don't support them.
 549 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 550                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 551 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 552                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 553 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 554                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 555 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 556                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 557 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 558                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 559 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 560                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 561 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 562                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 563 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 564                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 565 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 566                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 567
 568 // Clear cache intrinsic, default to ignore (ie. emit nothing)
 569 // maps to void __clear_cache() on supporting platforms
 570 def int_clear_cache : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 571                                 [], "llvm.clear_cache">;
 572
 573 //===-------------------------- Masked Intrinsics -------------------------===//
 574 //
 575 def int_masked_store : Intrinsic<[], [llvm_anyvector_ty, LLVMPointerTo<0>,
 576                                       llvm_i32_ty,
 577                                       LLVMVectorSameWidth<0, llvm_i1_ty>],
 578                                  [IntrReadWriteArgMem]>;
 579
 580 def int_masked_load  : Intrinsic<[llvm_anyvector_ty],
 581                                  [LLVMPointerTo<0>, llvm_i32_ty,
 582                                   LLVMVectorSameWidth<0, llvm_i1_ty>, LLVMMatchType<0>],
 583                                  [IntrReadArgMem]>;
 584 //===----------------------------------------------------------------------===//
 585 // Target-specific intrinsics
 586 //===----------------------------------------------------------------------===//
 587
 588 include "llvm/IR/IntrinsicsPowerPC.td"
 589 include "llvm/IR/IntrinsicsX86.td"
 590 include "llvm/IR/IntrinsicsARM.td"
 591 include "llvm/IR/IntrinsicsAArch64.td"
 592 include "llvm/IR/IntrinsicsXCore.td"
 593 include "llvm/IR/IntrinsicsHexagon.td"
 594 include "llvm/IR/IntrinsicsNVVM.td"
 595 include "llvm/IR/IntrinsicsMips.td"
 596 include "llvm/IR/IntrinsicsR600.td"