include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 // ReadOnly - The specified argument pointer is not written to through the
  59 // pointer by the intrinsic.
  60 class ReadOnly<int argNo> : IntrinsicProperty {
  61   int ArgNo = argNo;
  62 }
  63
  64 // ReadNone - The specified argument pointer is not dereferenced by the
  65 // intrinsic.
  66 class ReadNone<int argNo> : IntrinsicProperty {
  67   int ArgNo = argNo;
  68 }
  69
  70 def IntrNoReturn : IntrinsicProperty;
  71
  72 // IntrNoduplicate - Calls to this intrinsic cannot be duplicated.
  73 // Parallels the noduplicate attribute on LLVM IR functions.
  74 def IntrNoDuplicate : IntrinsicProperty;
  75
  76 //===----------------------------------------------------------------------===//
  77 // Types used by intrinsics.
  78 //===----------------------------------------------------------------------===//
  79
  80 class LLVMType<ValueType vt> {
  81   ValueType VT = vt;
  82 }
  83
  84 class LLVMQualPointerType<LLVMType elty, int addrspace>
  85   : LLVMType<iPTR>{
  86   LLVMType ElTy = elty;
  87   int AddrSpace = addrspace;
  88 }
  89
  90 class LLVMPointerType<LLVMType elty>
  91   : LLVMQualPointerType<elty, 0>;
  92
  93 class LLVMAnyPointerType<LLVMType elty>
  94   : LLVMType<iPTRAny>{
  95   LLVMType ElTy = elty;
  96 }
  97
  98 // Match the type of another intrinsic parameter.  Number is an index into the
  99 // list of overloaded types for the intrinsic, excluding all the fixed types.
 100 // The Number value must refer to a previously listed type.  For example:
 101 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
 102 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
 103 // refers to the first overloaded type, which is the 2nd argument.
 104 class LLVMMatchType<int num>
 105   : LLVMType<OtherVT>{
 106   int Number = num;
 107 }
 108
 109 // Match the type of another intrinsic parameter that is expected to be based on
 110 // an integral type (i.e. either iN or <N x iM>), but change the scalar size to
 111 // be twice as wide or half as wide as the other type.  This is only useful when
 112 // the intrinsic is overloaded, so the matched type should be declared as iAny.
 113 class LLVMExtendedType<int num> : LLVMMatchType<num>;
 114 class LLVMTruncatedType<int num> : LLVMMatchType<num>;
 115 class LLVMVectorSameWidth<int num, LLVMType elty>
 116   : LLVMMatchType<num> {
 117   ValueType ElTy = elty.VT;
 118 }
 119
 120 // Match the type of another intrinsic parameter that is expected to be a
 121 // vector type, but change the element count to be half as many
 122 class LLVMHalfElementsVectorType<int num> : LLVMMatchType<num>;
 123
 124 def llvm_void_ty       : LLVMType<isVoid>;
 125 def llvm_anyint_ty     : LLVMType<iAny>;
 126 def llvm_anyfloat_ty   : LLVMType<fAny>;
 127 def llvm_anyvector_ty  : LLVMType<vAny>;
 128 def llvm_i1_ty         : LLVMType<i1>;
 129 def llvm_i8_ty         : LLVMType<i8>;
 130 def llvm_i16_ty        : LLVMType<i16>;
 131 def llvm_i32_ty        : LLVMType<i32>;
 132 def llvm_i64_ty        : LLVMType<i64>;
 133 def llvm_half_ty       : LLVMType<f16>;
 134 def llvm_float_ty      : LLVMType<f32>;
 135 def llvm_double_ty     : LLVMType<f64>;
 136 def llvm_f80_ty        : LLVMType<f80>;
 137 def llvm_f128_ty       : LLVMType<f128>;
 138 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 139 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 140 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 141 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 142 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 143 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 144 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 145
 146 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 147 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 148
 149 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 150 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 151 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 152 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 153 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 154 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 155 def llvm_v1i8_ty       : LLVMType<v1i8>;     //  1 x i8
 156 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 157 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 158 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 159 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 160 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 161 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 162
 163 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 164 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 165 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 166 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 167 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 168 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 169
 170 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 171 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 172 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 173 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 174 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 175 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 176 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 177 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 178 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 179 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 180
 181 def llvm_v2f16_ty      : LLVMType<v2f16>;    //  2 x half (__fp16)
 182 def llvm_v4f16_ty      : LLVMType<v4f16>;    //  4 x half (__fp16)
 183 def llvm_v8f16_ty      : LLVMType<v8f16>;    //  8 x half (__fp16)
 184 def llvm_v1f32_ty      : LLVMType<v1f32>;    //  1 x float
 185 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 186 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 187 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 188 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 189 def llvm_v1f64_ty      : LLVMType<v1f64>;    //  1 x double
 190 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 191 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 192 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 193
 194 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 195
 196
 197 //===----------------------------------------------------------------------===//
 198 // Intrinsic Definitions.
 199 //===----------------------------------------------------------------------===//
 200
 201 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 202 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 203 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 204 // example, llvm.bswap.i16 -> int_bswap_i16.
 205 //
 206 //  * RetTypes is a list containing the return types expected for the
 207 //    intrinsic.
 208 //  * ParamTypes is a list containing the parameter types expected for the
 209 //    intrinsic.
 210 //  * Properties can be set to describe the behavior of the intrinsic.
 211 //
 212 class SDPatternOperator;
 213 class Intrinsic<list<LLVMType> ret_types,
 214                 list<LLVMType> param_types = [],
 215                 list<IntrinsicProperty> properties = [],
 216                 string name = ""> : SDPatternOperator {
 217   string LLVMName = name;
 218   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 219   list<LLVMType> RetTypes = ret_types;
 220   list<LLVMType> ParamTypes = param_types;
 221   list<IntrinsicProperty> Properties = properties;
 222
 223   bit isTarget = 0;
 224 }
 225
 226 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 227 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 228 /// support.
 229 class GCCBuiltin<string name> {
 230   string GCCBuiltinName = name;
 231 }
 232
 233 class MSBuiltin<string name> {
 234   string MSBuiltinName = name;
 235 }
 236
 237
 238 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 239 //
 240
 241 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 242 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 243                             "llvm.va_copy">;
 244 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 245
 246 //===------------------- Garbage Collection Intrinsics --------------------===//
 247 //
 248 def int_gcroot  : Intrinsic<[],
 249                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 250 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 251                             [llvm_ptr_ty, llvm_ptrptr_ty],
 252                             [IntrReadArgMem]>;
 253 def int_gcwrite : Intrinsic<[],
 254                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 255                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 256
 257 //===--------------------- Code Generator Intrinsics ----------------------===//
 258 //
 259 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 260 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 261 def int_read_register  : Intrinsic<[llvm_anyint_ty], [llvm_metadata_ty],
 262                                    [IntrNoMem], "llvm.read_register">;
 263 def int_write_register : Intrinsic<[], [llvm_metadata_ty, llvm_anyint_ty],
 264                                    [], "llvm.write_register">;
 265
 266 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 267 // model their dependencies on allocas.
 268 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 269                         GCCBuiltin<"__builtin_stack_save">;
 270 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 271                         GCCBuiltin<"__builtin_stack_restore">;
 272
 273 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 274 // however it does conveniently prevent the prefetch from being reordered
 275 // with respect to nearby accesses to the same memory.
 276 def int_prefetch      : Intrinsic<[],
 277                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 278                                    llvm_i32_ty],
 279                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 280 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 281
 282 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 283
 284 // The assume intrinsic is marked as arbitrarily writing so that proper
 285 // control dependencies will be maintained.
 286 def int_assume        : Intrinsic<[], [llvm_i1_ty], []>;
 287
 288 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 289 // guard to the correct place on the stack frame.
 290 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 291 def int_stackprotectorcheck : Intrinsic<[], [llvm_ptrptr_ty],
 292                                         [IntrReadWriteArgMem]>;
 293
 294 //===------------------- Standard C Library Intrinsics --------------------===//
 295 //
 296
 297 def int_memcpy  : Intrinsic<[],
 298                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 299                               llvm_i32_ty, llvm_i1_ty],
 300                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 301                              ReadOnly<1>]>;
 302 def int_memmove : Intrinsic<[],
 303                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 304                              llvm_i32_ty, llvm_i1_ty],
 305                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>,
 306                              ReadOnly<1>]>;
 307 def int_memset  : Intrinsic<[],
 308                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 309                              llvm_i32_ty, llvm_i1_ty],
 310                             [IntrReadWriteArgMem, NoCapture<0>]>;
 311
 312 let Properties = [IntrNoMem] in {
 313   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 314                            [LLVMMatchType<0>, LLVMMatchType<0>,
 315                             LLVMMatchType<0>]>;
 316   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 317                               [LLVMMatchType<0>, LLVMMatchType<0>,
 318                                LLVMMatchType<0>]>;
 319
 320   // These functions do not read memory, but are sensitive to the
 321   // rounding mode. LLVM purposely does not model changes to the FP
 322   // environment so they can be treated as readnone.
 323   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 324   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 325   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 326   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 327   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 328                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 329   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 330   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 331   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 332   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 333   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 334   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 335   def int_minnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 336   def int_maxnum : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, LLVMMatchType<0>]>;
 337   def int_copysign : Intrinsic<[llvm_anyfloat_ty],
 338                                [LLVMMatchType<0>, LLVMMatchType<0>]>;
 339   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 340   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 341   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 342   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 343   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 344   def int_round : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 345 }
 346
 347 // NOTE: these are internal interfaces.
 348 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 349 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 350 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 351 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 352
 353 // Internal interface for object size checking
 354 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_anyptr_ty, llvm_i1_ty],
 355                                [IntrNoMem]>,
 356                                GCCBuiltin<"__builtin_object_size">;
 357
 358 //===------------------------- Expect Intrinsics --------------------------===//
 359 //
 360 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 361                                               LLVMMatchType<0>], [IntrNoMem]>;
 362
 363 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 364 //
 365
 366 // None of these intrinsics accesses memory at all.
 367 let Properties = [IntrNoMem] in {
 368   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 369   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 370   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 371   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 372 }
 373
 374 //===------------------------ Debugger Intrinsics -------------------------===//
 375 //
 376
 377 // None of these intrinsics accesses memory at all...but that doesn't mean the
 378 // optimizers can change them aggressively.  Special handling needed in a few
 379 // places.
 380 let Properties = [IntrNoMem] in {
 381   def int_dbg_declare      : Intrinsic<[],
 382                                        [llvm_metadata_ty,
 383                                        llvm_metadata_ty,
 384                                        llvm_metadata_ty]>;
 385   def int_dbg_value        : Intrinsic<[],
 386                                        [llvm_metadata_ty, llvm_i64_ty,
 387                                         llvm_metadata_ty,
 388                                         llvm_metadata_ty]>;
 389 }
 390
 391 //===------------------ Exception Handling Intrinsics----------------------===//
 392 //
 393
 394 // The result of eh.typeid.for depends on the enclosing function, but inside a
 395 // given function it is 'const' and may be CSE'd etc.
 396 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 397
 398 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 399 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 400
 401 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 402 // callee-saved registers to be saved and restored (regardless of whether they
 403 // are used) in the calling function. It is used by libgcc_eh.
 404 def int_eh_unwind_init: Intrinsic<[]>,
 405                         GCCBuiltin<"__builtin_unwind_init">;
 406
 407 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 408
 409 let Properties = [IntrNoMem] in {
 410   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 411   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 412 }
 413 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 414 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 415 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 416
 417 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 418 //
 419 def int_var_annotation : Intrinsic<[],
 420                                    [llvm_ptr_ty, llvm_ptr_ty,
 421                                     llvm_ptr_ty, llvm_i32_ty],
 422                                    [], "llvm.var.annotation">;
 423 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 424                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 425                                     llvm_i32_ty],
 426                                    [], "llvm.ptr.annotation">;
 427 def int_annotation : Intrinsic<[llvm_anyint_ty],
 428                                [LLVMMatchType<0>, llvm_ptr_ty,
 429                                 llvm_ptr_ty, llvm_i32_ty],
 430                                [], "llvm.annotation">;
 431
 432 //===------------------------ Trampoline Intrinsics -----------------------===//
 433 //
 434 def int_init_trampoline : Intrinsic<[],
 435                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 436                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 437                                    GCCBuiltin<"__builtin_init_trampoline">;
 438
 439 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 440                                       [IntrReadArgMem]>,
 441                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 442
 443 //===------------------------ Overflow Intrinsics -------------------------===//
 444 //
 445
 446 // Expose the carry flag from add operations on two integrals.
 447 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 448                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 449                                        [IntrNoMem]>;
 450 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 451                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 452                                        [IntrNoMem]>;
 453
 454 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 455                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 456                                        [IntrNoMem]>;
 457 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 458                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 459                                        [IntrNoMem]>;
 460
 461 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 462                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 463                                        [IntrNoMem]>;
 464 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 465                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 466                                        [IntrNoMem]>;
 467
 468 //===------------------------- Memory Use Markers -------------------------===//
 469 //
 470 def int_lifetime_start  : Intrinsic<[],
 471                                     [llvm_i64_ty, llvm_ptr_ty],
 472                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 473 def int_lifetime_end    : Intrinsic<[],
 474                                     [llvm_i64_ty, llvm_ptr_ty],
 475                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 476 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 477                                     [llvm_i64_ty, llvm_ptr_ty],
 478                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 479 def int_invariant_end   : Intrinsic<[],
 480                                     [llvm_descriptor_ty, llvm_i64_ty,
 481                                      llvm_ptr_ty],
 482                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 483
 484 //===------------------------ Stackmap Intrinsics -------------------------===//
 485 //
 486 def int_experimental_stackmap : Intrinsic<[],
 487                                   [llvm_i64_ty, llvm_i32_ty, llvm_vararg_ty],
 488                                   [Throws]>;
 489 def int_experimental_patchpoint_void : Intrinsic<[],
 490                                                  [llvm_i64_ty, llvm_i32_ty,
 491                                                   llvm_ptr_ty, llvm_i32_ty,
 492                                                   llvm_vararg_ty],
 493                                                   [Throws]>;
 494 def int_experimental_patchpoint_i64 : Intrinsic<[llvm_i64_ty],
 495                                                 [llvm_i64_ty, llvm_i32_ty,
 496                                                  llvm_ptr_ty, llvm_i32_ty,
 497                                                  llvm_vararg_ty],
 498                                                  [Throws]>;
 499
 500
 501 //===------------------------ Garbage Collection Intrinsics ---------------===//
 502 // These are documented in docs/Statepoint.rst
 503
 504 def int_experimental_gc_statepoint : Intrinsic<[llvm_i32_ty],
 505                                [llvm_anyptr_ty, llvm_i32_ty,
 506                                 llvm_i32_ty, llvm_vararg_ty]>;
 507
 508 def int_experimental_gc_result_int : Intrinsic<[llvm_anyint_ty], [llvm_i32_ty]>;
 509 def int_experimental_gc_result_float : Intrinsic<[llvm_anyfloat_ty],
 510                                                  [llvm_i32_ty]>;
 511 def int_experimental_gc_result_ptr : Intrinsic<[llvm_anyptr_ty], [llvm_i32_ty]>;
 512
 513 def int_experimental_gc_relocate : Intrinsic<[llvm_anyptr_ty],
 514                                 [llvm_i32_ty, llvm_i32_ty, llvm_i32_ty]>;
 515
 516 //===-------------------------- Other Intrinsics --------------------------===//
 517 //
 518 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 519                      GCCBuiltin<"__builtin_flt_rounds">;
 520 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 521                GCCBuiltin<"__builtin_trap">;
 522 def int_debugtrap : Intrinsic<[]>,
 523                     GCCBuiltin<"__builtin_debugtrap">;
 524
 525 // NOP: calls/invokes to this intrinsic are removed by codegen
 526 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 527
 528 // Intrisics to support half precision floating point format
 529 let Properties = [IntrNoMem] in {
 530 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_anyfloat_ty]>;
 531 def int_convert_from_fp16 : Intrinsic<[llvm_anyfloat_ty], [llvm_i16_ty]>;
 532 }
 533
 534 // These convert intrinsics are to support various conversions between
 535 // various types with rounding and saturation. NOTE: avoid using these
 536 // intrinsics as they might be removed sometime in the future and
 537 // most targets don't support them.
 538 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 539                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 540 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 541                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 542 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 543                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 544 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 545                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 546 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 547                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 548 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 549                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 550 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 551                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 552 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 553                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 554 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 555                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 556
 557 // Clear cache intrinsic, default to ignore (ie. emit nothing)
 558 // maps to void __clear_cache() on supporting platforms
 559 def int_clear_cache : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty],
 560                                 [], "llvm.clear_cache">;
 561
 562 //===-------------------------- Masked Intrinsics -------------------------===//
 563 //
 564 def int_masked_store : Intrinsic<[], [llvm_ptr_ty, llvm_anyvector_ty,
 565                                       llvm_i32_ty,
 566                                       LLVMVectorSameWidth<0, llvm_i1_ty>],
 567                                  [IntrReadWriteArgMem]>;
 568
 569 def int_masked_load  : Intrinsic<[llvm_anyvector_ty],
 570                                  [llvm_ptr_ty, LLVMMatchType<0>, llvm_i32_ty,
 571                                   LLVMVectorSameWidth<0, llvm_i1_ty>],
 572                                  [IntrReadArgMem]>;
 573 //===----------------------------------------------------------------------===//
 574 // Target-specific intrinsics
 575 //===----------------------------------------------------------------------===//
 576
 577 include "llvm/IR/IntrinsicsPowerPC.td"
 578 include "llvm/IR/IntrinsicsX86.td"
 579 include "llvm/IR/IntrinsicsARM.td"
 580 include "llvm/IR/IntrinsicsAArch64.td"
 581 include "llvm/IR/IntrinsicsXCore.td"
 582 include "llvm/IR/IntrinsicsHexagon.td"
 583 include "llvm/IR/IntrinsicsNVVM.td"
 584 include "llvm/IR/IntrinsicsMips.td"
 585 include "llvm/IR/IntrinsicsR600.td"