Add missing break in AArch64DAGToDAGISel::Select() switch case
[oota-llvm.git] / docs / LangRef.rst
1 ==============================
2 LLVM Language Reference Manual
3 ==============================
4
5 .. contents::
6    :local:
7    :depth: 4
8
9 Abstract
10 ========
11
12 This document is a reference manual for the LLVM assembly language. LLVM
13 is a Static Single Assignment (SSA) based representation that provides
14 type safety, low-level operations, flexibility, and the capability of
15 representing 'all' high-level languages cleanly. It is the common code
16 representation used throughout all phases of the LLVM compilation
17 strategy.
18
19 Introduction
20 ============
21
22 The LLVM code representation is designed to be used in three different
23 forms: as an in-memory compiler IR, as an on-disk bitcode representation
24 (suitable for fast loading by a Just-In-Time compiler), and as a human
25 readable assembly language representation. This allows LLVM to provide a
26 powerful intermediate representation for efficient compiler
27 transformations and analysis, while providing a natural means to debug
28 and visualize the transformations. The three different forms of LLVM are
29 all equivalent. This document describes the human readable
30 representation and notation.
31
32 The LLVM representation aims to be light-weight and low-level while
33 being expressive, typed, and extensible at the same time. It aims to be
34 a "universal IR" of sorts, by being at a low enough level that
35 high-level ideas may be cleanly mapped to it (similar to how
36 microprocessors are "universal IR's", allowing many source languages to
37 be mapped to them). By providing type information, LLVM can be used as
38 the target of optimizations: for example, through pointer analysis, it
39 can be proven that a C automatic variable is never accessed outside of
40 the current function, allowing it to be promoted to a simple SSA value
41 instead of a memory location.
42
43 .. _wellformed:
44
45 Well-Formedness
46 ---------------
47
48 It is important to note that this document describes 'well formed' LLVM
49 assembly language. There is a difference between what the parser accepts
50 and what is considered 'well formed'. For example, the following
51 instruction is syntactically okay, but not well formed:
52
53 .. code-block:: llvm
54
55     %x = add i32 1, %x
56
57 because the definition of ``%x`` does not dominate all of its uses. The
58 LLVM infrastructure provides a verification pass that may be used to
59 verify that an LLVM module is well formed. This pass is automatically
60 run by the parser after parsing input assembly and by the optimizer
61 before it outputs bitcode. The violations pointed out by the verifier
62 pass indicate bugs in transformation passes or input to the parser.
63
64 .. _identifiers:
65
66 Identifiers
67 ===========
68
69 LLVM identifiers come in two basic types: global and local. Global
70 identifiers (functions, global variables) begin with the ``'@'``
71 character. Local identifiers (register names, types) begin with the
72 ``'%'`` character. Additionally, there are three different formats for
73 identifiers, for different purposes:
74
75 #. Named values are represented as a string of characters with their
76    prefix. For example, ``%foo``, ``@DivisionByZero``,
77    ``%a.really.long.identifier``. The actual regular expression used is
78    '``[%@][-a-zA-Z$._][-a-zA-Z$._0-9]*``'. Identifiers that require other
79    characters in their names can be surrounded with quotes. Special
80    characters may be escaped using ``"\xx"`` where ``xx`` is the ASCII
81    code for the character in hexadecimal. In this way, any character can
82    be used in a name value, even quotes themselves. The ``"\01"`` prefix
83    can be used on global variables to suppress mangling.
84 #. Unnamed values are represented as an unsigned numeric value with
85    their prefix. For example, ``%12``, ``@2``, ``%44``.
86 #. Constants, which are described in the section Constants_ below.
87
88 LLVM requires that values start with a prefix for two reasons: Compilers
89 don't need to worry about name clashes with reserved words, and the set
90 of reserved words may be expanded in the future without penalty.
91 Additionally, unnamed identifiers allow a compiler to quickly come up
92 with a temporary variable without having to avoid symbol table
93 conflicts.
94
95 Reserved words in LLVM are very similar to reserved words in other
96 languages. There are keywords for different opcodes ('``add``',
97 '``bitcast``', '``ret``', etc...), for primitive type names ('``void``',
98 '``i32``', etc...), and others. These reserved words cannot conflict
99 with variable names, because none of them start with a prefix character
100 (``'%'`` or ``'@'``).
101
102 Here is an example of LLVM code to multiply the integer variable
103 '``%X``' by 8:
104
105 The easy way:
106
107 .. code-block:: llvm
108
109     %result = mul i32 %X, 8
110
111 After strength reduction:
112
113 .. code-block:: llvm
114
115     %result = shl i32 %X, 3
116
117 And the hard way:
118
119 .. code-block:: llvm
120
121     %0 = add i32 %X, %X           ; yields i32:%0
122     %1 = add i32 %0, %0           ; yields i32:%1
123     %result = add i32 %1, %1
124
125 This last way of multiplying ``%X`` by 8 illustrates several important
126 lexical features of LLVM:
127
128 #. Comments are delimited with a '``;``' and go until the end of line.
129 #. Unnamed temporaries are created when the result of a computation is
130    not assigned to a named value.
131 #. Unnamed temporaries are numbered sequentially (using a per-function
132    incrementing counter, starting with 0). Note that basic blocks and unnamed
133    function parameters are included in this numbering. For example, if the
134    entry basic block is not given a label name and all function parameters are
135    named, then it will get number 0.
136
137 It also shows a convention that we follow in this document. When
138 demonstrating instructions, we will follow an instruction with a comment
139 that defines the type and name of value produced.
140
141 High Level Structure
142 ====================
143
144 Module Structure
145 ----------------
146
147 LLVM programs are composed of ``Module``'s, each of which is a
148 translation unit of the input programs. Each module consists of
149 functions, global variables, and symbol table entries. Modules may be
150 combined together with the LLVM linker, which merges function (and
151 global variable) definitions, resolves forward declarations, and merges
152 symbol table entries. Here is an example of the "hello world" module:
153
154 .. code-block:: llvm
155
156     ; Declare the string constant as a global constant.
157     @.str = private unnamed_addr constant [13 x i8] c"hello world\0A\00"
158
159     ; External declaration of the puts function
160     declare i32 @puts(i8* nocapture) nounwind
161
162     ; Definition of main function
163     define i32 @main() {   ; i32()*
164       ; Convert [13 x i8]* to i8  *...
165       %cast210 = getelementptr [13 x i8], [13 x i8]* @.str, i64 0, i64 0
166
167       ; Call puts function to write out the string to stdout.
168       call i32 @puts(i8* %cast210)
169       ret i32 0
170     }
171
172     ; Named metadata
173     !0 = !{i32 42, null, !"string"}
174     !foo = !{!0}
175
176 This example is made up of a :ref:`global variable <globalvars>` named
177 "``.str``", an external declaration of the "``puts``" function, a
178 :ref:`function definition <functionstructure>` for "``main``" and
179 :ref:`named metadata <namedmetadatastructure>` "``foo``".
180
181 In general, a module is made up of a list of global values (where both
182 functions and global variables are global values). Global values are
183 represented by a pointer to a memory location (in this case, a pointer
184 to an array of char, and a pointer to a function), and have one of the
185 following :ref:`linkage types <linkage>`.
186
187 .. _linkage:
188
189 Linkage Types
190 -------------
191
192 All Global Variables and Functions have one of the following types of
193 linkage:
194
195 ``private``
196     Global values with "``private``" linkage are only directly
197     accessible by objects in the current module. In particular, linking
198     code into a module with an private global value may cause the
199     private to be renamed as necessary to avoid collisions. Because the
200     symbol is private to the module, all references can be updated. This
201     doesn't show up in any symbol table in the object file.
202 ``internal``
203     Similar to private, but the value shows as a local symbol
204     (``STB_LOCAL`` in the case of ELF) in the object file. This
205     corresponds to the notion of the '``static``' keyword in C.
206 ``available_externally``
207     Globals with "``available_externally``" linkage are never emitted
208     into the object file corresponding to the LLVM module. They exist to
209     allow inlining and other optimizations to take place given knowledge
210     of the definition of the global, which is known to be somewhere
211     outside the module. Globals with ``available_externally`` linkage
212     are allowed to be discarded at will, and are otherwise the same as
213     ``linkonce_odr``. This linkage type is only allowed on definitions,
214     not declarations.
215 ``linkonce``
216     Globals with "``linkonce``" linkage are merged with other globals of
217     the same name when linkage occurs. This can be used to implement
218     some forms of inline functions, templates, or other code which must
219     be generated in each translation unit that uses it, but where the
220     body may be overridden with a more definitive definition later.
221     Unreferenced ``linkonce`` globals are allowed to be discarded. Note
222     that ``linkonce`` linkage does not actually allow the optimizer to
223     inline the body of this function into callers because it doesn't
224     know if this definition of the function is the definitive definition
225     within the program or whether it will be overridden by a stronger
226     definition. To enable inlining and other optimizations, use
227     "``linkonce_odr``" linkage.
228 ``weak``
229     "``weak``" linkage has the same merging semantics as ``linkonce``
230     linkage, except that unreferenced globals with ``weak`` linkage may
231     not be discarded. This is used for globals that are declared "weak"
232     in C source code.
233 ``common``
234     "``common``" linkage is most similar to "``weak``" linkage, but they
235     are used for tentative definitions in C, such as "``int X;``" at
236     global scope. Symbols with "``common``" linkage are merged in the
237     same way as ``weak symbols``, and they may not be deleted if
238     unreferenced. ``common`` symbols may not have an explicit section,
239     must have a zero initializer, and may not be marked
240     ':ref:`constant <globalvars>`'. Functions and aliases may not have
241     common linkage.
242
243 .. _linkage_appending:
244
245 ``appending``
246     "``appending``" linkage may only be applied to global variables of
247     pointer to array type. When two global variables with appending
248     linkage are linked together, the two global arrays are appended
249     together. This is the LLVM, typesafe, equivalent of having the
250     system linker append together "sections" with identical names when
251     .o files are linked.
252 ``extern_weak``
253     The semantics of this linkage follow the ELF object file model: the
254     symbol is weak until linked, if not linked, the symbol becomes null
255     instead of being an undefined reference.
256 ``linkonce_odr``, ``weak_odr``
257     Some languages allow differing globals to be merged, such as two
258     functions with different semantics. Other languages, such as
259     ``C++``, ensure that only equivalent globals are ever merged (the
260     "one definition rule" --- "ODR"). Such languages can use the
261     ``linkonce_odr`` and ``weak_odr`` linkage types to indicate that the
262     global will only be merged with equivalent globals. These linkage
263     types are otherwise the same as their non-``odr`` versions.
264 ``external``
265     If none of the above identifiers are used, the global is externally
266     visible, meaning that it participates in linkage and can be used to
267     resolve external symbol references.
268
269 It is illegal for a function *declaration* to have any linkage type
270 other than ``external`` or ``extern_weak``.
271
272 .. _callingconv:
273
274 Calling Conventions
275 -------------------
276
277 LLVM :ref:`functions <functionstructure>`, :ref:`calls <i_call>` and
278 :ref:`invokes <i_invoke>` can all have an optional calling convention
279 specified for the call. The calling convention of any pair of dynamic
280 caller/callee must match, or the behavior of the program is undefined.
281 The following calling conventions are supported by LLVM, and more may be
282 added in the future:
283
284 "``ccc``" - The C calling convention
285     This calling convention (the default if no other calling convention
286     is specified) matches the target C calling conventions. This calling
287     convention supports varargs function calls and tolerates some
288     mismatch in the declared prototype and implemented declaration of
289     the function (as does normal C).
290 "``fastcc``" - The fast calling convention
291     This calling convention attempts to make calls as fast as possible
292     (e.g. by passing things in registers). This calling convention
293     allows the target to use whatever tricks it wants to produce fast
294     code for the target, without having to conform to an externally
295     specified ABI (Application Binary Interface). `Tail calls can only
296     be optimized when this, the GHC or the HiPE convention is
297     used. <CodeGenerator.html#id80>`_ This calling convention does not
298     support varargs and requires the prototype of all callees to exactly
299     match the prototype of the function definition.
300 "``coldcc``" - The cold calling convention
301     This calling convention attempts to make code in the caller as
302     efficient as possible under the assumption that the call is not
303     commonly executed. As such, these calls often preserve all registers
304     so that the call does not break any live ranges in the caller side.
305     This calling convention does not support varargs and requires the
306     prototype of all callees to exactly match the prototype of the
307     function definition. Furthermore the inliner doesn't consider such function
308     calls for inlining.
309 "``cc 10``" - GHC convention
310     This calling convention has been implemented specifically for use by
311     the `Glasgow Haskell Compiler (GHC) <http://www.haskell.org/ghc>`_.
312     It passes everything in registers, going to extremes to achieve this
313     by disabling callee save registers. This calling convention should
314     not be used lightly but only for specific situations such as an
315     alternative to the *register pinning* performance technique often
316     used when implementing functional programming languages. At the
317     moment only X86 supports this convention and it has the following
318     limitations:
319
320     -  On *X86-32* only supports up to 4 bit type parameters. No
321        floating point types are supported.
322     -  On *X86-64* only supports up to 10 bit type parameters and 6
323        floating point parameters.
324
325     This calling convention supports `tail call
326     optimization <CodeGenerator.html#id80>`_ but requires both the
327     caller and callee are using it.
328 "``cc 11``" - The HiPE calling convention
329     This calling convention has been implemented specifically for use by
330     the `High-Performance Erlang
331     (HiPE) <http://www.it.uu.se/research/group/hipe/>`_ compiler, *the*
332     native code compiler of the `Ericsson's Open Source Erlang/OTP
333     system <http://www.erlang.org/download.shtml>`_. It uses more
334     registers for argument passing than the ordinary C calling
335     convention and defines no callee-saved registers. The calling
336     convention properly supports `tail call
337     optimization <CodeGenerator.html#id80>`_ but requires that both the
338     caller and the callee use it. It uses a *register pinning*
339     mechanism, similar to GHC's convention, for keeping frequently
340     accessed runtime components pinned to specific hardware registers.
341     At the moment only X86 supports this convention (both 32 and 64
342     bit).
343 "``webkit_jscc``" - WebKit's JavaScript calling convention
344     This calling convention has been implemented for `WebKit FTL JIT
345     <https://trac.webkit.org/wiki/FTLJIT>`_. It passes arguments on the
346     stack right to left (as cdecl does), and returns a value in the
347     platform's customary return register.
348 "``anyregcc``" - Dynamic calling convention for code patching
349     This is a special convention that supports patching an arbitrary code
350     sequence in place of a call site. This convention forces the call
351     arguments into registers but allows them to be dynamically
352     allocated. This can currently only be used with calls to
353     llvm.experimental.patchpoint because only this intrinsic records
354     the location of its arguments in a side table. See :doc:`StackMaps`.
355 "``preserve_mostcc``" - The `PreserveMost` calling convention
356     This calling convention attempts to make the code in the caller as
357     unintrusive as possible. This convention behaves identically to the `C`
358     calling convention on how arguments and return values are passed, but it
359     uses a different set of caller/callee-saved registers. This alleviates the
360     burden of saving and recovering a large register set before and after the
361     call in the caller. If the arguments are passed in callee-saved registers,
362     then they will be preserved by the callee across the call. This doesn't
363     apply for values returned in callee-saved registers.
364
365     - On X86-64 the callee preserves all general purpose registers, except for
366       R11. R11 can be used as a scratch register. Floating-point registers
367       (XMMs/YMMs) are not preserved and need to be saved by the caller.
368
369     The idea behind this convention is to support calls to runtime functions
370     that have a hot path and a cold path. The hot path is usually a small piece
371     of code that doesn't use many registers. The cold path might need to call out to
372     another function and therefore only needs to preserve the caller-saved
373     registers, which haven't already been saved by the caller. The
374     `PreserveMost` calling convention is very similar to the `cold` calling
375     convention in terms of caller/callee-saved registers, but they are used for
376     different types of function calls. `coldcc` is for function calls that are
377     rarely executed, whereas `preserve_mostcc` function calls are intended to be
378     on the hot path and definitely executed a lot. Furthermore `preserve_mostcc`
379     doesn't prevent the inliner from inlining the function call.
380
381     This calling convention will be used by a future version of the ObjectiveC
382     runtime and should therefore still be considered experimental at this time.
383     Although this convention was created to optimize certain runtime calls to
384     the ObjectiveC runtime, it is not limited to this runtime and might be used
385     by other runtimes in the future too. The current implementation only
386     supports X86-64, but the intention is to support more architectures in the
387     future.
388 "``preserve_allcc``" - The `PreserveAll` calling convention
389     This calling convention attempts to make the code in the caller even less
390     intrusive than the `PreserveMost` calling convention. This calling
391     convention also behaves identical to the `C` calling convention on how
392     arguments and return values are passed, but it uses a different set of
393     caller/callee-saved registers. This removes the burden of saving and
394     recovering a large register set before and after the call in the caller. If
395     the arguments are passed in callee-saved registers, then they will be
396     preserved by the callee across the call. This doesn't apply for values
397     returned in callee-saved registers.
398
399     - On X86-64 the callee preserves all general purpose registers, except for
400       R11. R11 can be used as a scratch register. Furthermore it also preserves
401       all floating-point registers (XMMs/YMMs).
402
403     The idea behind this convention is to support calls to runtime functions
404     that don't need to call out to any other functions.
405
406     This calling convention, like the `PreserveMost` calling convention, will be
407     used by a future version of the ObjectiveC runtime and should be considered
408     experimental at this time.
409 "``cc <n>``" - Numbered convention
410     Any calling convention may be specified by number, allowing
411     target-specific calling conventions to be used. Target specific
412     calling conventions start at 64.
413
414 More calling conventions can be added/defined on an as-needed basis, to
415 support Pascal conventions or any other well-known target-independent
416 convention.
417
418 .. _visibilitystyles:
419
420 Visibility Styles
421 -----------------
422
423 All Global Variables and Functions have one of the following visibility
424 styles:
425
426 "``default``" - Default style
427     On targets that use the ELF object file format, default visibility
428     means that the declaration is visible to other modules and, in
429     shared libraries, means that the declared entity may be overridden.
430     On Darwin, default visibility means that the declaration is visible
431     to other modules. Default visibility corresponds to "external
432     linkage" in the language.
433 "``hidden``" - Hidden style
434     Two declarations of an object with hidden visibility refer to the
435     same object if they are in the same shared object. Usually, hidden
436     visibility indicates that the symbol will not be placed into the
437     dynamic symbol table, so no other module (executable or shared
438     library) can reference it directly.
439 "``protected``" - Protected style
440     On ELF, protected visibility indicates that the symbol will be
441     placed in the dynamic symbol table, but that references within the
442     defining module will bind to the local symbol. That is, the symbol
443     cannot be overridden by another module.
444
445 A symbol with ``internal`` or ``private`` linkage must have ``default``
446 visibility.
447
448 .. _dllstorageclass:
449
450 DLL Storage Classes
451 -------------------
452
453 All Global Variables, Functions and Aliases can have one of the following
454 DLL storage class:
455
456 ``dllimport``
457     "``dllimport``" causes the compiler to reference a function or variable via
458     a global pointer to a pointer that is set up by the DLL exporting the
459     symbol. On Microsoft Windows targets, the pointer name is formed by
460     combining ``__imp_`` and the function or variable name.
461 ``dllexport``
462     "``dllexport``" causes the compiler to provide a global pointer to a pointer
463     in a DLL, so that it can be referenced with the ``dllimport`` attribute. On
464     Microsoft Windows targets, the pointer name is formed by combining
465     ``__imp_`` and the function or variable name. Since this storage class
466     exists for defining a dll interface, the compiler, assembler and linker know
467     it is externally referenced and must refrain from deleting the symbol.
468
469 .. _tls_model:
470
471 Thread Local Storage Models
472 ---------------------------
473
474 A variable may be defined as ``thread_local``, which means that it will
475 not be shared by threads (each thread will have a separated copy of the
476 variable). Not all targets support thread-local variables. Optionally, a
477 TLS model may be specified:
478
479 ``localdynamic``
480     For variables that are only used within the current shared library.
481 ``initialexec``
482     For variables in modules that will not be loaded dynamically.
483 ``localexec``
484     For variables defined in the executable and only used within it.
485
486 If no explicit model is given, the "general dynamic" model is used.
487
488 The models correspond to the ELF TLS models; see `ELF Handling For
489 Thread-Local Storage <http://people.redhat.com/drepper/tls.pdf>`_ for
490 more information on under which circumstances the different models may
491 be used. The target may choose a different TLS model if the specified
492 model is not supported, or if a better choice of model can be made.
493
494 A model can also be specified in an alias, but then it only governs how
495 the alias is accessed. It will not have any effect in the aliasee.
496
497 For platforms without linker support of ELF TLS model, the -femulated-tls
498 flag can be used to generate GCC compatible emulated TLS code.
499
500 .. _namedtypes:
501
502 Structure Types
503 ---------------
504
505 LLVM IR allows you to specify both "identified" and "literal" :ref:`structure
506 types <t_struct>`. Literal types are uniqued structurally, but identified types
507 are never uniqued. An :ref:`opaque structural type <t_opaque>` can also be used
508 to forward declare a type that is not yet available.
509
510 An example of an identified structure specification is:
511
512 .. code-block:: llvm
513
514     %mytype = type { %mytype*, i32 }
515
516 Prior to the LLVM 3.0 release, identified types were structurally uniqued. Only
517 literal types are uniqued in recent versions of LLVM.
518
519 .. _globalvars:
520
521 Global Variables
522 ----------------
523
524 Global variables define regions of memory allocated at compilation time
525 instead of run-time.
526
527 Global variable definitions must be initialized.
528
529 Global variables in other translation units can also be declared, in which
530 case they don't have an initializer.
531
532 Either global variable definitions or declarations may have an explicit section
533 to be placed in and may have an optional explicit alignment specified.
534
535 A variable may be defined as a global ``constant``, which indicates that
536 the contents of the variable will **never** be modified (enabling better
537 optimization, allowing the global data to be placed in the read-only
538 section of an executable, etc). Note that variables that need runtime
539 initialization cannot be marked ``constant`` as there is a store to the
540 variable.
541
542 LLVM explicitly allows *declarations* of global variables to be marked
543 constant, even if the final definition of the global is not. This
544 capability can be used to enable slightly better optimization of the
545 program, but requires the language definition to guarantee that
546 optimizations based on the 'constantness' are valid for the translation
547 units that do not include the definition.
548
549 As SSA values, global variables define pointer values that are in scope
550 (i.e. they dominate) all basic blocks in the program. Global variables
551 always define a pointer to their "content" type because they describe a
552 region of memory, and all memory objects in LLVM are accessed through
553 pointers.
554
555 Global variables can be marked with ``unnamed_addr`` which indicates
556 that the address is not significant, only the content. Constants marked
557 like this can be merged with other constants if they have the same
558 initializer. Note that a constant with significant address *can* be
559 merged with a ``unnamed_addr`` constant, the result being a constant
560 whose address is significant.
561
562 A global variable may be declared to reside in a target-specific
563 numbered address space. For targets that support them, address spaces
564 may affect how optimizations are performed and/or what target
565 instructions are used to access the variable. The default address space
566 is zero. The address space qualifier must precede any other attributes.
567
568 LLVM allows an explicit section to be specified for globals. If the
569 target supports it, it will emit globals to the section specified.
570 Additionally, the global can placed in a comdat if the target has the necessary
571 support.
572
573 By default, global initializers are optimized by assuming that global
574 variables defined within the module are not modified from their
575 initial values before the start of the global initializer. This is
576 true even for variables potentially accessible from outside the
577 module, including those with external linkage or appearing in
578 ``@llvm.used`` or dllexported variables. This assumption may be suppressed
579 by marking the variable with ``externally_initialized``.
580
581 An explicit alignment may be specified for a global, which must be a
582 power of 2. If not present, or if the alignment is set to zero, the
583 alignment of the global is set by the target to whatever it feels
584 convenient. If an explicit alignment is specified, the global is forced
585 to have exactly that alignment. Targets and optimizers are not allowed
586 to over-align the global if the global has an assigned section. In this
587 case, the extra alignment could be observable: for example, code could
588 assume that the globals are densely packed in their section and try to
589 iterate over them as an array, alignment padding would break this
590 iteration. The maximum alignment is ``1 << 29``.
591
592 Globals can also have a :ref:`DLL storage class <dllstorageclass>`.
593
594 Variables and aliases can have a
595 :ref:`Thread Local Storage Model <tls_model>`.
596
597 Syntax::
598
599     [@<GlobalVarName> =] [Linkage] [Visibility] [DLLStorageClass] [ThreadLocal]
600                          [unnamed_addr] [AddrSpace] [ExternallyInitialized]
601                          <global | constant> <Type> [<InitializerConstant>]
602                          [, section "name"] [, comdat [($name)]]
603                          [, align <Alignment>]
604
605 For example, the following defines a global in a numbered address space
606 with an initializer, section, and alignment:
607
608 .. code-block:: llvm
609
610     @G = addrspace(5) constant float 1.0, section "foo", align 4
611
612 The following example just declares a global variable
613
614 .. code-block:: llvm
615
616    @G = external global i32
617
618 The following example defines a thread-local global with the
619 ``initialexec`` TLS model:
620
621 .. code-block:: llvm
622
623     @G = thread_local(initialexec) global i32 0, align 4
624
625 .. _functionstructure:
626
627 Functions
628 ---------
629
630 LLVM function definitions consist of the "``define``" keyword, an
631 optional :ref:`linkage type <linkage>`, an optional :ref:`visibility
632 style <visibility>`, an optional :ref:`DLL storage class <dllstorageclass>`,
633 an optional :ref:`calling convention <callingconv>`,
634 an optional ``unnamed_addr`` attribute, a return type, an optional
635 :ref:`parameter attribute <paramattrs>` for the return type, a function
636 name, a (possibly empty) argument list (each with optional :ref:`parameter
637 attributes <paramattrs>`), optional :ref:`function attributes <fnattrs>`,
638 an optional section, an optional alignment,
639 an optional :ref:`comdat <langref_comdats>`,
640 an optional :ref:`garbage collector name <gc>`, an optional :ref:`prefix <prefixdata>`,
641 an optional :ref:`prologue <prologuedata>`,
642 an optional :ref:`personality <personalityfn>`,
643 an opening curly brace, a list of basic blocks, and a closing curly brace.
644
645 LLVM function declarations consist of the "``declare``" keyword, an
646 optional :ref:`linkage type <linkage>`, an optional :ref:`visibility
647 style <visibility>`, an optional :ref:`DLL storage class <dllstorageclass>`,
648 an optional :ref:`calling convention <callingconv>`,
649 an optional ``unnamed_addr`` attribute, a return type, an optional
650 :ref:`parameter attribute <paramattrs>` for the return type, a function
651 name, a possibly empty list of arguments, an optional alignment, an optional
652 :ref:`garbage collector name <gc>`, an optional :ref:`prefix <prefixdata>`,
653 and an optional :ref:`prologue <prologuedata>`.
654
655 A function definition contains a list of basic blocks, forming the CFG (Control
656 Flow Graph) for the function. Each basic block may optionally start with a label
657 (giving the basic block a symbol table entry), contains a list of instructions,
658 and ends with a :ref:`terminator <terminators>` instruction (such as a branch or
659 function return). If an explicit label is not provided, a block is assigned an
660 implicit numbered label, using the next value from the same counter as used for
661 unnamed temporaries (:ref:`see above<identifiers>`). For example, if a function
662 entry block does not have an explicit label, it will be assigned label "%0",
663 then the first unnamed temporary in that block will be "%1", etc.
664
665 The first basic block in a function is special in two ways: it is
666 immediately executed on entrance to the function, and it is not allowed
667 to have predecessor basic blocks (i.e. there can not be any branches to
668 the entry block of a function). Because the block can have no
669 predecessors, it also cannot have any :ref:`PHI nodes <i_phi>`.
670
671 LLVM allows an explicit section to be specified for functions. If the
672 target supports it, it will emit functions to the section specified.
673 Additionally, the function can be placed in a COMDAT.
674
675 An explicit alignment may be specified for a function. If not present,
676 or if the alignment is set to zero, the alignment of the function is set
677 by the target to whatever it feels convenient. If an explicit alignment
678 is specified, the function is forced to have at least that much
679 alignment. All alignments must be a power of 2.
680
681 If the ``unnamed_addr`` attribute is given, the address is known to not
682 be significant and two identical functions can be merged.
683
684 Syntax::
685
686     define [linkage] [visibility] [DLLStorageClass]
687            [cconv] [ret attrs]
688            <ResultType> @<FunctionName> ([argument list])
689            [unnamed_addr] [fn Attrs] [section "name"] [comdat [($name)]]
690            [align N] [gc] [prefix Constant] [prologue Constant]
691            [personality Constant] { ... }
692
693 The argument list is a comma separated sequence of arguments where each
694 argument is of the following form:
695
696 Syntax::
697
698    <type> [parameter Attrs] [name]
699
700
701 .. _langref_aliases:
702
703 Aliases
704 -------
705
706 Aliases, unlike function or variables, don't create any new data. They
707 are just a new symbol and metadata for an existing position.
708
709 Aliases have a name and an aliasee that is either a global value or a
710 constant expression.
711
712 Aliases may have an optional :ref:`linkage type <linkage>`, an optional
713 :ref:`visibility style <visibility>`, an optional :ref:`DLL storage class
714 <dllstorageclass>` and an optional :ref:`tls model <tls_model>`.
715
716 Syntax::
717
718     @<Name> = [Linkage] [Visibility] [DLLStorageClass] [ThreadLocal] [unnamed_addr] alias <AliaseeTy> @<Aliasee>
719
720 The linkage must be one of ``private``, ``internal``, ``linkonce``, ``weak``,
721 ``linkonce_odr``, ``weak_odr``, ``external``. Note that some system linkers
722 might not correctly handle dropping a weak symbol that is aliased.
723
724 Aliases that are not ``unnamed_addr`` are guaranteed to have the same address as
725 the aliasee expression. ``unnamed_addr`` ones are only guaranteed to point
726 to the same content.
727
728 Since aliases are only a second name, some restrictions apply, of which
729 some can only be checked when producing an object file:
730
731 * The expression defining the aliasee must be computable at assembly
732   time. Since it is just a name, no relocations can be used.
733
734 * No alias in the expression can be weak as the possibility of the
735   intermediate alias being overridden cannot be represented in an
736   object file.
737
738 * No global value in the expression can be a declaration, since that
739   would require a relocation, which is not possible.
740
741 .. _langref_comdats:
742
743 Comdats
744 -------
745
746 Comdat IR provides access to COFF and ELF object file COMDAT functionality.
747
748 Comdats have a name which represents the COMDAT key. All global objects that
749 specify this key will only end up in the final object file if the linker chooses
750 that key over some other key. Aliases are placed in the same COMDAT that their
751 aliasee computes to, if any.
752
753 Comdats have a selection kind to provide input on how the linker should
754 choose between keys in two different object files.
755
756 Syntax::
757
758     $<Name> = comdat SelectionKind
759
760 The selection kind must be one of the following:
761
762 ``any``
763     The linker may choose any COMDAT key, the choice is arbitrary.
764 ``exactmatch``
765     The linker may choose any COMDAT key but the sections must contain the
766     same data.
767 ``largest``
768     The linker will choose the section containing the largest COMDAT key.
769 ``noduplicates``
770     The linker requires that only section with this COMDAT key exist.
771 ``samesize``
772     The linker may choose any COMDAT key but the sections must contain the
773     same amount of data.
774
775 Note that the Mach-O platform doesn't support COMDATs and ELF only supports
776 ``any`` as a selection kind.
777
778 Here is an example of a COMDAT group where a function will only be selected if
779 the COMDAT key's section is the largest:
780
781 .. code-block:: llvm
782
783    $foo = comdat largest
784    @foo = global i32 2, comdat($foo)
785
786    define void @bar() comdat($foo) {
787      ret void
788    }
789
790 As a syntactic sugar the ``$name`` can be omitted if the name is the same as
791 the global name:
792
793 .. code-block:: llvm
794
795   $foo = comdat any
796   @foo = global i32 2, comdat
797
798
799 In a COFF object file, this will create a COMDAT section with selection kind
800 ``IMAGE_COMDAT_SELECT_LARGEST`` containing the contents of the ``@foo`` symbol
801 and another COMDAT section with selection kind
802 ``IMAGE_COMDAT_SELECT_ASSOCIATIVE`` which is associated with the first COMDAT
803 section and contains the contents of the ``@bar`` symbol.
804
805 There are some restrictions on the properties of the global object.
806 It, or an alias to it, must have the same name as the COMDAT group when
807 targeting COFF.
808 The contents and size of this object may be used during link-time to determine
809 which COMDAT groups get selected depending on the selection kind.
810 Because the name of the object must match the name of the COMDAT group, the
811 linkage of the global object must not be local; local symbols can get renamed
812 if a collision occurs in the symbol table.
813
814 The combined use of COMDATS and section attributes may yield surprising results.
815 For example:
816
817 .. code-block:: llvm
818
819    $foo = comdat any
820    $bar = comdat any
821    @g1 = global i32 42, section "sec", comdat($foo)
822    @g2 = global i32 42, section "sec", comdat($bar)
823
824 From the object file perspective, this requires the creation of two sections
825 with the same name. This is necessary because both globals belong to different
826 COMDAT groups and COMDATs, at the object file level, are represented by
827 sections.
828
829 Note that certain IR constructs like global variables and functions may
830 create COMDATs in the object file in addition to any which are specified using
831 COMDAT IR. This arises when the code generator is configured to emit globals
832 in individual sections (e.g. when `-data-sections` or `-function-sections`
833 is supplied to `llc`).
834
835 .. _namedmetadatastructure:
836
837 Named Metadata
838 --------------
839
840 Named metadata is a collection of metadata. :ref:`Metadata
841 nodes <metadata>` (but not metadata strings) are the only valid
842 operands for a named metadata.
843
844 #. Named metadata are represented as a string of characters with the
845    metadata prefix. The rules for metadata names are the same as for
846    identifiers, but quoted names are not allowed. ``"\xx"`` type escapes
847    are still valid, which allows any character to be part of a name.
848
849 Syntax::
850
851     ; Some unnamed metadata nodes, which are referenced by the named metadata.
852     !0 = !{!"zero"}
853     !1 = !{!"one"}
854     !2 = !{!"two"}
855     ; A named metadata.
856     !name = !{!0, !1, !2}
857
858 .. _paramattrs:
859
860 Parameter Attributes
861 --------------------
862
863 The return type and each parameter of a function type may have a set of
864 *parameter attributes* associated with them. Parameter attributes are
865 used to communicate additional information about the result or
866 parameters of a function. Parameter attributes are considered to be part
867 of the function, not of the function type, so functions with different
868 parameter attributes can have the same function type.
869
870 Parameter attributes are simple keywords that follow the type specified.
871 If multiple parameter attributes are needed, they are space separated.
872 For example:
873
874 .. code-block:: llvm
875
876     declare i32 @printf(i8* noalias nocapture, ...)
877     declare i32 @atoi(i8 zeroext)
878     declare signext i8 @returns_signed_char()
879
880 Note that any attributes for the function result (``nounwind``,
881 ``readonly``) come immediately after the argument list.
882
883 Currently, only the following parameter attributes are defined:
884
885 ``zeroext``
886     This indicates to the code generator that the parameter or return
887     value should be zero-extended to the extent required by the target's
888     ABI (which is usually 32-bits, but is 8-bits for a i1 on x86-64) by
889     the caller (for a parameter) or the callee (for a return value).
890 ``signext``
891     This indicates to the code generator that the parameter or return
892     value should be sign-extended to the extent required by the target's
893     ABI (which is usually 32-bits) by the caller (for a parameter) or
894     the callee (for a return value).
895 ``inreg``
896     This indicates that this parameter or return value should be treated
897     in a special target-dependent fashion while emitting code for
898     a function call or return (usually, by putting it in a register as
899     opposed to memory, though some targets use it to distinguish between
900     two different kinds of registers). Use of this attribute is
901     target-specific.
902 ``byval``
903     This indicates that the pointer parameter should really be passed by
904     value to the function. The attribute implies that a hidden copy of
905     the pointee is made between the caller and the callee, so the callee
906     is unable to modify the value in the caller. This attribute is only
907     valid on LLVM pointer arguments. It is generally used to pass
908     structs and arrays by value, but is also valid on pointers to
909     scalars. The copy is considered to belong to the caller not the
910     callee (for example, ``readonly`` functions should not write to
911     ``byval`` parameters). This is not a valid attribute for return
912     values.
913
914     The byval attribute also supports specifying an alignment with the
915     align attribute. It indicates the alignment of the stack slot to
916     form and the known alignment of the pointer specified to the call
917     site. If the alignment is not specified, then the code generator
918     makes a target-specific assumption.
919
920 .. _attr_inalloca:
921
922 ``inalloca``
923
924     The ``inalloca`` argument attribute allows the caller to take the
925     address of outgoing stack arguments. An ``inalloca`` argument must
926     be a pointer to stack memory produced by an ``alloca`` instruction.
927     The alloca, or argument allocation, must also be tagged with the
928     inalloca keyword. Only the last argument may have the ``inalloca``
929     attribute, and that argument is guaranteed to be passed in memory.
930
931     An argument allocation may be used by a call at most once because
932     the call may deallocate it. The ``inalloca`` attribute cannot be
933     used in conjunction with other attributes that affect argument
934     storage, like ``inreg``, ``nest``, ``sret``, or ``byval``. The
935     ``inalloca`` attribute also disables LLVM's implicit lowering of
936     large aggregate return values, which means that frontend authors
937     must lower them with ``sret`` pointers.
938
939     When the call site is reached, the argument allocation must have
940     been the most recent stack allocation that is still live, or the
941     results are undefined. It is possible to allocate additional stack
942     space after an argument allocation and before its call site, but it
943     must be cleared off with :ref:`llvm.stackrestore
944     <int_stackrestore>`.
945
946     See :doc:`InAlloca` for more information on how to use this
947     attribute.
948
949 ``sret``
950     This indicates that the pointer parameter specifies the address of a
951     structure that is the return value of the function in the source
952     program. This pointer must be guaranteed by the caller to be valid:
953     loads and stores to the structure may be assumed by the callee
954     not to trap and to be properly aligned. This may only be applied to
955     the first parameter. This is not a valid attribute for return
956     values.
957
958 ``align <n>``
959     This indicates that the pointer value may be assumed by the optimizer to
960     have the specified alignment.
961
962     Note that this attribute has additional semantics when combined with the
963     ``byval`` attribute.
964
965 .. _noalias:
966
967 ``noalias``
968     This indicates that objects accessed via pointer values
969     :ref:`based <pointeraliasing>` on the argument or return value are not also
970     accessed, during the execution of the function, via pointer values not
971     *based* on the argument or return value. The attribute on a return value
972     also has additional semantics described below. The caller shares the
973     responsibility with the callee for ensuring that these requirements are met.
974     For further details, please see the discussion of the NoAlias response in
975     :ref:`alias analysis <Must, May, or No>`.
976
977     Note that this definition of ``noalias`` is intentionally similar
978     to the definition of ``restrict`` in C99 for function arguments.
979
980     For function return values, C99's ``restrict`` is not meaningful,
981     while LLVM's ``noalias`` is. Furthermore, the semantics of the ``noalias``
982     attribute on return values are stronger than the semantics of the attribute
983     when used on function arguments. On function return values, the ``noalias``
984     attribute indicates that the function acts like a system memory allocation
985     function, returning a pointer to allocated storage disjoint from the
986     storage for any other object accessible to the caller.
987
988 ``nocapture``
989     This indicates that the callee does not make any copies of the
990     pointer that outlive the callee itself. This is not a valid
991     attribute for return values.
992
993 .. _nest:
994
995 ``nest``
996     This indicates that the pointer parameter can be excised using the
997     :ref:`trampoline intrinsics <int_trampoline>`. This is not a valid
998     attribute for return values and can only be applied to one parameter.
999
1000 ``returned``
1001     This indicates that the function always returns the argument as its return
1002     value. This is an optimization hint to the code generator when generating
1003     the caller, allowing tail call optimization and omission of register saves
1004     and restores in some cases; it is not checked or enforced when generating
1005     the callee. The parameter and the function return type must be valid
1006     operands for the :ref:`bitcast instruction <i_bitcast>`. This is not a
1007     valid attribute for return values and can only be applied to one parameter.
1008
1009 ``nonnull``
1010     This indicates that the parameter or return pointer is not null. This
1011     attribute may only be applied to pointer typed parameters. This is not
1012     checked or enforced by LLVM, the caller must ensure that the pointer
1013     passed in is non-null, or the callee must ensure that the returned pointer
1014     is non-null.
1015
1016 ``dereferenceable(<n>)``
1017     This indicates that the parameter or return pointer is dereferenceable. This
1018     attribute may only be applied to pointer typed parameters. A pointer that
1019     is dereferenceable can be loaded from speculatively without a risk of
1020     trapping. The number of bytes known to be dereferenceable must be provided
1021     in parentheses. It is legal for the number of bytes to be less than the
1022     size of the pointee type. The ``nonnull`` attribute does not imply
1023     dereferenceability (consider a pointer to one element past the end of an
1024     array), however ``dereferenceable(<n>)`` does imply ``nonnull`` in
1025     ``addrspace(0)`` (which is the default address space).
1026
1027 ``dereferenceable_or_null(<n>)``
1028     This indicates that the parameter or return value isn't both
1029     non-null and non-dereferenceable (up to ``<n>`` bytes) at the same
1030     time. All non-null pointers tagged with
1031     ``dereferenceable_or_null(<n>)`` are ``dereferenceable(<n>)``.
1032     For address space 0 ``dereferenceable_or_null(<n>)`` implies that
1033     a pointer is exactly one of ``dereferenceable(<n>)`` or ``null``,
1034     and in other address spaces ``dereferenceable_or_null(<n>)``
1035     implies that a pointer is at least one of ``dereferenceable(<n>)``
1036     or ``null`` (i.e. it may be both ``null`` and
1037     ``dereferenceable(<n>)``). This attribute may only be applied to
1038     pointer typed parameters.
1039
1040 .. _gc:
1041
1042 Garbage Collector Strategy Names
1043 --------------------------------
1044
1045 Each function may specify a garbage collector strategy name, which is simply a
1046 string:
1047
1048 .. code-block:: llvm
1049
1050     define void @f() gc "name" { ... }
1051
1052 The supported values of *name* includes those :ref:`built in to LLVM
1053 <builtin-gc-strategies>` and any provided by loaded plugins. Specifying a GC
1054 strategy will cause the compiler to alter its output in order to support the
1055 named garbage collection algorithm. Note that LLVM itself does not contain a
1056 garbage collector, this functionality is restricted to generating machine code
1057 which can interoperate with a collector provided externally.
1058
1059 .. _prefixdata:
1060
1061 Prefix Data
1062 -----------
1063
1064 Prefix data is data associated with a function which the code
1065 generator will emit immediately before the function's entrypoint.
1066 The purpose of this feature is to allow frontends to associate
1067 language-specific runtime metadata with specific functions and make it
1068 available through the function pointer while still allowing the
1069 function pointer to be called.
1070
1071 To access the data for a given function, a program may bitcast the
1072 function pointer to a pointer to the constant's type and dereference
1073 index -1. This implies that the IR symbol points just past the end of
1074 the prefix data. For instance, take the example of a function annotated
1075 with a single ``i32``,
1076
1077 .. code-block:: llvm
1078
1079     define void @f() prefix i32 123 { ... }
1080
1081 The prefix data can be referenced as,
1082
1083 .. code-block:: llvm
1084
1085     %0 = bitcast void* () @f to i32*
1086     %a = getelementptr inbounds i32, i32* %0, i32 -1
1087     %b = load i32, i32* %a
1088
1089 Prefix data is laid out as if it were an initializer for a global variable
1090 of the prefix data's type. The function will be placed such that the
1091 beginning of the prefix data is aligned. This means that if the size
1092 of the prefix data is not a multiple of the alignment size, the
1093 function's entrypoint will not be aligned. If alignment of the
1094 function's entrypoint is desired, padding must be added to the prefix
1095 data.
1096
1097 A function may have prefix data but no body. This has similar semantics
1098 to the ``available_externally`` linkage in that the data may be used by the
1099 optimizers but will not be emitted in the object file.
1100
1101 .. _prologuedata:
1102
1103 Prologue Data
1104 -------------
1105
1106 The ``prologue`` attribute allows arbitrary code (encoded as bytes) to
1107 be inserted prior to the function body. This can be used for enabling
1108 function hot-patching and instrumentation.
1109
1110 To maintain the semantics of ordinary function calls, the prologue data must
1111 have a particular format. Specifically, it must begin with a sequence of
1112 bytes which decode to a sequence of machine instructions, valid for the
1113 module's target, which transfer control to the point immediately succeeding
1114 the prologue data, without performing any other visible action. This allows
1115 the inliner and other passes to reason about the semantics of the function
1116 definition without needing to reason about the prologue data. Obviously this
1117 makes the format of the prologue data highly target dependent.
1118
1119 A trivial example of valid prologue data for the x86 architecture is ``i8 144``,
1120 which encodes the ``nop`` instruction:
1121
1122 .. code-block:: llvm
1123
1124     define void @f() prologue i8 144 { ... }
1125
1126 Generally prologue data can be formed by encoding a relative branch instruction
1127 which skips the metadata, as in this example of valid prologue data for the
1128 x86_64 architecture, where the first two bytes encode ``jmp .+10``:
1129
1130 .. code-block:: llvm
1131
1132     %0 = type <{ i8, i8, i8* }>
1133
1134     define void @f() prologue %0 <{ i8 235, i8 8, i8* @md}> { ... }
1135
1136 A function may have prologue data but no body. This has similar semantics
1137 to the ``available_externally`` linkage in that the data may be used by the
1138 optimizers but will not be emitted in the object file.
1139
1140 .. _personalityfn:
1141
1142 Personality Function
1143 --------------------
1144
1145 The ``personality`` attribute permits functions to specify what function
1146 to use for exception handling.
1147
1148 .. _attrgrp:
1149
1150 Attribute Groups
1151 ----------------
1152
1153 Attribute groups are groups of attributes that are referenced by objects within
1154 the IR. They are important for keeping ``.ll`` files readable, because a lot of
1155 functions will use the same set of attributes. In the degenerative case of a
1156 ``.ll`` file that corresponds to a single ``.c`` file, the single attribute
1157 group will capture the important command line flags used to build that file.
1158
1159 An attribute group is a module-level object. To use an attribute group, an
1160 object references the attribute group's ID (e.g. ``#37``). An object may refer
1161 to more than one attribute group. In that situation, the attributes from the
1162 different groups are merged.
1163
1164 Here is an example of attribute groups for a function that should always be
1165 inlined, has a stack alignment of 4, and which shouldn't use SSE instructions:
1166
1167 .. code-block:: llvm
1168
1169    ; Target-independent attributes:
1170    attributes #0 = { alwaysinline alignstack=4 }
1171
1172    ; Target-dependent attributes:
1173    attributes #1 = { "no-sse" }
1174
1175    ; Function @f has attributes: alwaysinline, alignstack=4, and "no-sse".
1176    define void @f() #0 #1 { ... }
1177
1178 .. _fnattrs:
1179
1180 Function Attributes
1181 -------------------
1182
1183 Function attributes are set to communicate additional information about
1184 a function. Function attributes are considered to be part of the
1185 function, not of the function type, so functions with different function
1186 attributes can have the same function type.
1187
1188 Function attributes are simple keywords that follow the type specified.
1189 If multiple attributes are needed, they are space separated. For
1190 example:
1191
1192 .. code-block:: llvm
1193
1194     define void @f() noinline { ... }
1195     define void @f() alwaysinline { ... }
1196     define void @f() alwaysinline optsize { ... }
1197     define void @f() optsize { ... }
1198
1199 ``alignstack(<n>)``
1200     This attribute indicates that, when emitting the prologue and
1201     epilogue, the backend should forcibly align the stack pointer.
1202     Specify the desired alignment, which must be a power of two, in
1203     parentheses.
1204 ``alwaysinline``
1205     This attribute indicates that the inliner should attempt to inline
1206     this function into callers whenever possible, ignoring any active
1207     inlining size threshold for this caller.
1208 ``builtin``
1209     This indicates that the callee function at a call site should be
1210     recognized as a built-in function, even though the function's declaration
1211     uses the ``nobuiltin`` attribute. This is only valid at call sites for
1212     direct calls to functions that are declared with the ``nobuiltin``
1213     attribute.
1214 ``cold``
1215     This attribute indicates that this function is rarely called. When
1216     computing edge weights, basic blocks post-dominated by a cold
1217     function call are also considered to be cold; and, thus, given low
1218     weight.
1219 ``convergent``
1220     This attribute indicates that the callee is dependent on a convergent
1221     thread execution pattern under certain parallel execution models.
1222     Transformations that are execution model agnostic may only move or
1223     tranform this call if the final location is control equivalent to its
1224     original position in the program, where control equivalence is defined as
1225     A dominates B and B post-dominates A, or vice versa.
1226 ``inlinehint``
1227     This attribute indicates that the source code contained a hint that
1228     inlining this function is desirable (such as the "inline" keyword in
1229     C/C++). It is just a hint; it imposes no requirements on the
1230     inliner.
1231 ``jumptable``
1232     This attribute indicates that the function should be added to a
1233     jump-instruction table at code-generation time, and that all address-taken
1234     references to this function should be replaced with a reference to the
1235     appropriate jump-instruction-table function pointer. Note that this creates
1236     a new pointer for the original function, which means that code that depends
1237     on function-pointer identity can break. So, any function annotated with
1238     ``jumptable`` must also be ``unnamed_addr``.
1239 ``minsize``
1240     This attribute suggests that optimization passes and code generator
1241     passes make choices that keep the code size of this function as small
1242     as possible and perform optimizations that may sacrifice runtime
1243     performance in order to minimize the size of the generated code.
1244 ``naked``
1245     This attribute disables prologue / epilogue emission for the
1246     function. This can have very system-specific consequences.
1247 ``nobuiltin``
1248     This indicates that the callee function at a call site is not recognized as
1249     a built-in function. LLVM will retain the original call and not replace it
1250     with equivalent code based on the semantics of the built-in function, unless
1251     the call site uses the ``builtin`` attribute. This is valid at call sites
1252     and on function declarations and definitions.
1253 ``noduplicate``
1254     This attribute indicates that calls to the function cannot be
1255     duplicated. A call to a ``noduplicate`` function may be moved
1256     within its parent function, but may not be duplicated within
1257     its parent function.
1258
1259     A function containing a ``noduplicate`` call may still
1260     be an inlining candidate, provided that the call is not
1261     duplicated by inlining. That implies that the function has
1262     internal linkage and only has one call site, so the original
1263     call is dead after inlining.
1264 ``noimplicitfloat``
1265     This attributes disables implicit floating point instructions.
1266 ``noinline``
1267     This attribute indicates that the inliner should never inline this
1268     function in any situation. This attribute may not be used together
1269     with the ``alwaysinline`` attribute.
1270 ``nonlazybind``
1271     This attribute suppresses lazy symbol binding for the function. This
1272     may make calls to the function faster, at the cost of extra program
1273     startup time if the function is not called during program startup.
1274 ``noredzone``
1275     This attribute indicates that the code generator should not use a
1276     red zone, even if the target-specific ABI normally permits it.
1277 ``noreturn``
1278     This function attribute indicates that the function never returns
1279     normally. This produces undefined behavior at runtime if the
1280     function ever does dynamically return.
1281 ``nounwind``
1282     This function attribute indicates that the function never raises an
1283     exception. If the function does raise an exception, its runtime
1284     behavior is undefined. However, functions marked nounwind may still
1285     trap or generate asynchronous exceptions. Exception handling schemes
1286     that are recognized by LLVM to handle asynchronous exceptions, such
1287     as SEH, will still provide their implementation defined semantics.
1288 ``optnone``
1289     This function attribute indicates that the function is not optimized
1290     by any optimization or code generator passes with the
1291     exception of interprocedural optimization passes.
1292     This attribute cannot be used together with the ``alwaysinline``
1293     attribute; this attribute is also incompatible
1294     with the ``minsize`` attribute and the ``optsize`` attribute.
1295
1296     This attribute requires the ``noinline`` attribute to be specified on
1297     the function as well, so the function is never inlined into any caller.
1298     Only functions with the ``alwaysinline`` attribute are valid
1299     candidates for inlining into the body of this function.
1300 ``optsize``
1301     This attribute suggests that optimization passes and code generator
1302     passes make choices that keep the code size of this function low,
1303     and otherwise do optimizations specifically to reduce code size as
1304     long as they do not significantly impact runtime performance.
1305 ``readnone``
1306     On a function, this attribute indicates that the function computes its
1307     result (or decides to unwind an exception) based strictly on its arguments,
1308     without dereferencing any pointer arguments or otherwise accessing
1309     any mutable state (e.g. memory, control registers, etc) visible to
1310     caller functions. It does not write through any pointer arguments
1311     (including ``byval`` arguments) and never changes any state visible
1312     to callers. This means that it cannot unwind exceptions by calling
1313     the ``C++`` exception throwing methods.
1314
1315     On an argument, this attribute indicates that the function does not
1316     dereference that pointer argument, even though it may read or write the
1317     memory that the pointer points to if accessed through other pointers.
1318 ``readonly``
1319     On a function, this attribute indicates that the function does not write
1320     through any pointer arguments (including ``byval`` arguments) or otherwise
1321     modify any state (e.g. memory, control registers, etc) visible to
1322     caller functions. It may dereference pointer arguments and read
1323     state that may be set in the caller. A readonly function always
1324     returns the same value (or unwinds an exception identically) when
1325     called with the same set of arguments and global state. It cannot
1326     unwind an exception by calling the ``C++`` exception throwing
1327     methods.
1328
1329     On an argument, this attribute indicates that the function does not write
1330     through this pointer argument, even though it may write to the memory that
1331     the pointer points to.
1332 ``argmemonly``
1333     This attribute indicates that the only memory accesses inside function are
1334     loads and stores from objects pointed to by its pointer-typed arguments,
1335     with arbitrary offsets. Or in other words, all memory operations in the
1336     function can refer to memory only using pointers based on its function
1337     arguments.
1338     Note that ``argmemonly`` can be used together with ``readonly`` attribute
1339     in order to specify that function reads only from its arguments.
1340 ``returns_twice``
1341     This attribute indicates that this function can return twice. The C
1342     ``setjmp`` is an example of such a function. The compiler disables
1343     some optimizations (like tail calls) in the caller of these
1344     functions.
1345 ``safestack``
1346     This attribute indicates that
1347     `SafeStack <http://clang.llvm.org/docs/SafeStack.html>`_
1348     protection is enabled for this function.
1349
1350     If a function that has a ``safestack`` attribute is inlined into a
1351     function that doesn't have a ``safestack`` attribute or which has an
1352     ``ssp``, ``sspstrong`` or ``sspreq`` attribute, then the resulting
1353     function will have a ``safestack`` attribute.
1354 ``sanitize_address``
1355     This attribute indicates that AddressSanitizer checks
1356     (dynamic address safety analysis) are enabled for this function.
1357 ``sanitize_memory``
1358     This attribute indicates that MemorySanitizer checks (dynamic detection
1359     of accesses to uninitialized memory) are enabled for this function.
1360 ``sanitize_thread``
1361     This attribute indicates that ThreadSanitizer checks
1362     (dynamic thread safety analysis) are enabled for this function.
1363 ``ssp``
1364     This attribute indicates that the function should emit a stack
1365     smashing protector. It is in the form of a "canary" --- a random value
1366     placed on the stack before the local variables that's checked upon
1367     return from the function to see if it has been overwritten. A
1368     heuristic is used to determine if a function needs stack protectors
1369     or not. The heuristic used will enable protectors for functions with:
1370
1371     - Character arrays larger than ``ssp-buffer-size`` (default 8).
1372     - Aggregates containing character arrays larger than ``ssp-buffer-size``.
1373     - Calls to alloca() with variable sizes or constant sizes greater than
1374       ``ssp-buffer-size``.
1375
1376     Variables that are identified as requiring a protector will be arranged
1377     on the stack such that they are adjacent to the stack protector guard.
1378
1379     If a function that has an ``ssp`` attribute is inlined into a
1380     function that doesn't have an ``ssp`` attribute, then the resulting
1381     function will have an ``ssp`` attribute.
1382 ``sspreq``
1383     This attribute indicates that the function should *always* emit a
1384     stack smashing protector. This overrides the ``ssp`` function
1385     attribute.
1386
1387     Variables that are identified as requiring a protector will be arranged
1388     on the stack such that they are adjacent to the stack protector guard.
1389     The specific layout rules are:
1390
1391     #. Large arrays and structures containing large arrays
1392        (``>= ssp-buffer-size``) are closest to the stack protector.
1393     #. Small arrays and structures containing small arrays
1394        (``< ssp-buffer-size``) are 2nd closest to the protector.
1395     #. Variables that have had their address taken are 3rd closest to the
1396        protector.
1397
1398     If a function that has an ``sspreq`` attribute is inlined into a
1399     function that doesn't have an ``sspreq`` attribute or which has an
1400     ``ssp`` or ``sspstrong`` attribute, then the resulting function will have
1401     an ``sspreq`` attribute.
1402 ``sspstrong``
1403     This attribute indicates that the function should emit a stack smashing
1404     protector. This attribute causes a strong heuristic to be used when
1405     determining if a function needs stack protectors. The strong heuristic
1406     will enable protectors for functions with:
1407
1408     - Arrays of any size and type
1409     - Aggregates containing an array of any size and type.
1410     - Calls to alloca().
1411     - Local variables that have had their address taken.
1412
1413     Variables that are identified as requiring a protector will be arranged
1414     on the stack such that they are adjacent to the stack protector guard.
1415     The specific layout rules are:
1416
1417     #. Large arrays and structures containing large arrays
1418        (``>= ssp-buffer-size``) are closest to the stack protector.
1419     #. Small arrays and structures containing small arrays
1420        (``< ssp-buffer-size``) are 2nd closest to the protector.
1421     #. Variables that have had their address taken are 3rd closest to the
1422        protector.
1423
1424     This overrides the ``ssp`` function attribute.
1425
1426     If a function that has an ``sspstrong`` attribute is inlined into a
1427     function that doesn't have an ``sspstrong`` attribute, then the
1428     resulting function will have an ``sspstrong`` attribute.
1429 ``"thunk"``
1430     This attribute indicates that the function will delegate to some other
1431     function with a tail call. The prototype of a thunk should not be used for
1432     optimization purposes. The caller is expected to cast the thunk prototype to
1433     match the thunk target prototype.
1434 ``uwtable``
1435     This attribute indicates that the ABI being targeted requires that
1436     an unwind table entry be produced for this function even if we can
1437     show that no exceptions passes by it. This is normally the case for
1438     the ELF x86-64 abi, but it can be disabled for some compilation
1439     units.
1440
1441 .. _moduleasm:
1442
1443 Module-Level Inline Assembly
1444 ----------------------------
1445
1446 Modules may contain "module-level inline asm" blocks, which corresponds
1447 to the GCC "file scope inline asm" blocks. These blocks are internally
1448 concatenated by LLVM and treated as a single unit, but may be separated
1449 in the ``.ll`` file if desired. The syntax is very simple:
1450
1451 .. code-block:: llvm
1452
1453     module asm "inline asm code goes here"
1454     module asm "more can go here"
1455
1456 The strings can contain any character by escaping non-printable
1457 characters. The escape sequence used is simply "\\xx" where "xx" is the
1458 two digit hex code for the number.
1459
1460 Note that the assembly string *must* be parseable by LLVM's integrated assembler
1461 (unless it is disabled), even when emitting a ``.s`` file.
1462
1463 .. _langref_datalayout:
1464
1465 Data Layout
1466 -----------
1467
1468 A module may specify a target specific data layout string that specifies
1469 how data is to be laid out in memory. The syntax for the data layout is
1470 simply:
1471
1472 .. code-block:: llvm
1473
1474     target datalayout = "layout specification"
1475
1476 The *layout specification* consists of a list of specifications
1477 separated by the minus sign character ('-'). Each specification starts
1478 with a letter and may include other information after the letter to
1479 define some aspect of the data layout. The specifications accepted are
1480 as follows:
1481
1482 ``E``
1483     Specifies that the target lays out data in big-endian form. That is,
1484     the bits with the most significance have the lowest address
1485     location.
1486 ``e``
1487     Specifies that the target lays out data in little-endian form. That
1488     is, the bits with the least significance have the lowest address
1489     location.
1490 ``S<size>``
1491     Specifies the natural alignment of the stack in bits. Alignment
1492     promotion of stack variables is limited to the natural stack
1493     alignment to avoid dynamic stack realignment. The stack alignment
1494     must be a multiple of 8-bits. If omitted, the natural stack
1495     alignment defaults to "unspecified", which does not prevent any
1496     alignment promotions.
1497 ``p[n]:<size>:<abi>:<pref>``
1498     This specifies the *size* of a pointer and its ``<abi>`` and
1499     ``<pref>``\erred alignments for address space ``n``. All sizes are in
1500     bits. The address space, ``n``, is optional, and if not specified,
1501     denotes the default address space 0. The value of ``n`` must be
1502     in the range [1,2^23).
1503 ``i<size>:<abi>:<pref>``
1504     This specifies the alignment for an integer type of a given bit
1505     ``<size>``. The value of ``<size>`` must be in the range [1,2^23).
1506 ``v<size>:<abi>:<pref>``
1507     This specifies the alignment for a vector type of a given bit
1508     ``<size>``.
1509 ``f<size>:<abi>:<pref>``
1510     This specifies the alignment for a floating point type of a given bit
1511     ``<size>``. Only values of ``<size>`` that are supported by the target
1512     will work. 32 (float) and 64 (double) are supported on all targets; 80
1513     or 128 (different flavors of long double) are also supported on some
1514     targets.
1515 ``a:<abi>:<pref>``
1516     This specifies the alignment for an object of aggregate type.
1517 ``m:<mangling>``
1518     If present, specifies that llvm names are mangled in the output. The
1519     options are
1520
1521     * ``e``: ELF mangling: Private symbols get a ``.L`` prefix.
1522     * ``m``: Mips mangling: Private symbols get a ``$`` prefix.
1523     * ``o``: Mach-O mangling: Private symbols get ``L`` prefix. Other
1524       symbols get a ``_`` prefix.
1525     * ``w``: Windows COFF prefix:  Similar to Mach-O, but stdcall and fastcall
1526       functions also get a suffix based on the frame size.
1527 ``n<size1>:<size2>:<size3>...``
1528     This specifies a set of native integer widths for the target CPU in
1529     bits. For example, it might contain ``n32`` for 32-bit PowerPC,
1530     ``n32:64`` for PowerPC 64, or ``n8:16:32:64`` for X86-64. Elements of
1531     this set are considered to support most general arithmetic operations
1532     efficiently.
1533
1534 On every specification that takes a ``<abi>:<pref>``, specifying the
1535 ``<pref>`` alignment is optional. If omitted, the preceding ``:``
1536 should be omitted too and ``<pref>`` will be equal to ``<abi>``.
1537
1538 When constructing the data layout for a given target, LLVM starts with a
1539 default set of specifications which are then (possibly) overridden by
1540 the specifications in the ``datalayout`` keyword. The default
1541 specifications are given in this list:
1542
1543 -  ``E`` - big endian
1544 -  ``p:64:64:64`` - 64-bit pointers with 64-bit alignment.
1545 -  ``p[n]:64:64:64`` - Other address spaces are assumed to be the
1546    same as the default address space.
1547 -  ``S0`` - natural stack alignment is unspecified
1548 -  ``i1:8:8`` - i1 is 8-bit (byte) aligned
1549 -  ``i8:8:8`` - i8 is 8-bit (byte) aligned
1550 -  ``i16:16:16`` - i16 is 16-bit aligned
1551 -  ``i32:32:32`` - i32 is 32-bit aligned
1552 -  ``i64:32:64`` - i64 has ABI alignment of 32-bits but preferred
1553    alignment of 64-bits
1554 -  ``f16:16:16`` - half is 16-bit aligned
1555 -  ``f32:32:32`` - float is 32-bit aligned
1556 -  ``f64:64:64`` - double is 64-bit aligned
1557 -  ``f128:128:128`` - quad is 128-bit aligned
1558 -  ``v64:64:64`` - 64-bit vector is 64-bit aligned
1559 -  ``v128:128:128`` - 128-bit vector is 128-bit aligned
1560 -  ``a:0:64`` - aggregates are 64-bit aligned
1561
1562 When LLVM is determining the alignment for a given type, it uses the
1563 following rules:
1564
1565 #. If the type sought is an exact match for one of the specifications,
1566    that specification is used.
1567 #. If no match is found, and the type sought is an integer type, then
1568    the smallest integer type that is larger than the bitwidth of the
1569    sought type is used. If none of the specifications are larger than
1570    the bitwidth then the largest integer type is used. For example,
1571    given the default specifications above, the i7 type will use the
1572    alignment of i8 (next largest) while both i65 and i256 will use the
1573    alignment of i64 (largest specified).
1574 #. If no match is found, and the type sought is a vector type, then the
1575    largest vector type that is smaller than the sought vector type will
1576    be used as a fall back. This happens because <128 x double> can be
1577    implemented in terms of 64 <2 x double>, for example.
1578
1579 The function of the data layout string may not be what you expect.
1580 Notably, this is not a specification from the frontend of what alignment
1581 the code generator should use.
1582
1583 Instead, if specified, the target data layout is required to match what
1584 the ultimate *code generator* expects. This string is used by the
1585 mid-level optimizers to improve code, and this only works if it matches
1586 what the ultimate code generator uses. There is no way to generate IR
1587 that does not embed this target-specific detail into the IR. If you
1588 don't specify the string, the default specifications will be used to
1589 generate a Data Layout and the optimization phases will operate
1590 accordingly and introduce target specificity into the IR with respect to
1591 these default specifications.
1592
1593 .. _langref_triple:
1594
1595 Target Triple
1596 -------------
1597
1598 A module may specify a target triple string that describes the target
1599 host. The syntax for the target triple is simply:
1600
1601 .. code-block:: llvm
1602
1603     target triple = "x86_64-apple-macosx10.7.0"
1604
1605 The *target triple* string consists of a series of identifiers delimited
1606 by the minus sign character ('-'). The canonical forms are:
1607
1608 ::
1609
1610     ARCHITECTURE-VENDOR-OPERATING_SYSTEM
1611     ARCHITECTURE-VENDOR-OPERATING_SYSTEM-ENVIRONMENT
1612
1613 This information is passed along to the backend so that it generates
1614 code for the proper architecture. It's possible to override this on the
1615 command line with the ``-mtriple`` command line option.
1616
1617 .. _pointeraliasing:
1618
1619 Pointer Aliasing Rules
1620 ----------------------
1621
1622 Any memory access must be done through a pointer value associated with
1623 an address range of the memory access, otherwise the behavior is
1624 undefined. Pointer values are associated with address ranges according
1625 to the following rules:
1626
1627 -  A pointer value is associated with the addresses associated with any
1628    value it is *based* on.
1629 -  An address of a global variable is associated with the address range
1630    of the variable's storage.
1631 -  The result value of an allocation instruction is associated with the
1632    address range of the allocated storage.
1633 -  A null pointer in the default address-space is associated with no
1634    address.
1635 -  An integer constant other than zero or a pointer value returned from
1636    a function not defined within LLVM may be associated with address
1637    ranges allocated through mechanisms other than those provided by
1638    LLVM. Such ranges shall not overlap with any ranges of addresses
1639    allocated by mechanisms provided by LLVM.
1640
1641 A pointer value is *based* on another pointer value according to the
1642 following rules:
1643
1644 -  A pointer value formed from a ``getelementptr`` operation is *based*
1645    on the first value operand of the ``getelementptr``.
1646 -  The result value of a ``bitcast`` is *based* on the operand of the
1647    ``bitcast``.
1648 -  A pointer value formed by an ``inttoptr`` is *based* on all pointer
1649    values that contribute (directly or indirectly) to the computation of
1650    the pointer's value.
1651 -  The "*based* on" relationship is transitive.
1652
1653 Note that this definition of *"based"* is intentionally similar to the
1654 definition of *"based"* in C99, though it is slightly weaker.
1655
1656 LLVM IR does not associate types with memory. The result type of a
1657 ``load`` merely indicates the size and alignment of the memory from
1658 which to load, as well as the interpretation of the value. The first
1659 operand type of a ``store`` similarly only indicates the size and
1660 alignment of the store.
1661
1662 Consequently, type-based alias analysis, aka TBAA, aka
1663 ``-fstrict-aliasing``, is not applicable to general unadorned LLVM IR.
1664 :ref:`Metadata <metadata>` may be used to encode additional information
1665 which specialized optimization passes may use to implement type-based
1666 alias analysis.
1667
1668 .. _volatile:
1669
1670 Volatile Memory Accesses
1671 ------------------------
1672
1673 Certain memory accesses, such as :ref:`load <i_load>`'s,
1674 :ref:`store <i_store>`'s, and :ref:`llvm.memcpy <int_memcpy>`'s may be
1675 marked ``volatile``. The optimizers must not change the number of
1676 volatile operations or change their order of execution relative to other
1677 volatile operations. The optimizers *may* change the order of volatile
1678 operations relative to non-volatile operations. This is not Java's
1679 "volatile" and has no cross-thread synchronization behavior.
1680
1681 IR-level volatile loads and stores cannot safely be optimized into
1682 llvm.memcpy or llvm.memmove intrinsics even when those intrinsics are
1683 flagged volatile. Likewise, the backend should never split or merge
1684 target-legal volatile load/store instructions.
1685
1686 .. admonition:: Rationale
1687
1688  Platforms may rely on volatile loads and stores of natively supported
1689  data width to be executed as single instruction. For example, in C
1690  this holds for an l-value of volatile primitive type with native
1691  hardware support, but not necessarily for aggregate types. The
1692  frontend upholds these expectations, which are intentionally
1693  unspecified in the IR. The rules above ensure that IR transformations
1694  do not violate the frontend's contract with the language.
1695
1696 .. _memmodel:
1697
1698 Memory Model for Concurrent Operations
1699 --------------------------------------
1700
1701 The LLVM IR does not define any way to start parallel threads of
1702 execution or to register signal handlers. Nonetheless, there are
1703 platform-specific ways to create them, and we define LLVM IR's behavior
1704 in their presence. This model is inspired by the C++0x memory model.
1705
1706 For a more informal introduction to this model, see the :doc:`Atomics`.
1707
1708 We define a *happens-before* partial order as the least partial order
1709 that
1710
1711 -  Is a superset of single-thread program order, and
1712 -  When a *synchronizes-with* ``b``, includes an edge from ``a`` to
1713    ``b``. *Synchronizes-with* pairs are introduced by platform-specific
1714    techniques, like pthread locks, thread creation, thread joining,
1715    etc., and by atomic instructions. (See also :ref:`Atomic Memory Ordering
1716    Constraints <ordering>`).
1717
1718 Note that program order does not introduce *happens-before* edges
1719 between a thread and signals executing inside that thread.
1720
1721 Every (defined) read operation (load instructions, memcpy, atomic
1722 loads/read-modify-writes, etc.) R reads a series of bytes written by
1723 (defined) write operations (store instructions, atomic
1724 stores/read-modify-writes, memcpy, etc.). For the purposes of this
1725 section, initialized globals are considered to have a write of the
1726 initializer which is atomic and happens before any other read or write
1727 of the memory in question. For each byte of a read R, R\ :sub:`byte`
1728 may see any write to the same byte, except:
1729
1730 -  If write\ :sub:`1`  happens before write\ :sub:`2`, and
1731    write\ :sub:`2` happens before R\ :sub:`byte`, then
1732    R\ :sub:`byte` does not see write\ :sub:`1`.
1733 -  If R\ :sub:`byte` happens before write\ :sub:`3`, then
1734    R\ :sub:`byte` does not see write\ :sub:`3`.
1735
1736 Given that definition, R\ :sub:`byte` is defined as follows:
1737
1738 -  If R is volatile, the result is target-dependent. (Volatile is
1739    supposed to give guarantees which can support ``sig_atomic_t`` in
1740    C/C++, and may be used for accesses to addresses that do not behave
1741    like normal memory. It does not generally provide cross-thread
1742    synchronization.)
1743 -  Otherwise, if there is no write to the same byte that happens before
1744    R\ :sub:`byte`, R\ :sub:`byte` returns ``undef`` for that byte.
1745 -  Otherwise, if R\ :sub:`byte` may see exactly one write,
1746    R\ :sub:`byte` returns the value written by that write.
1747 -  Otherwise, if R is atomic, and all the writes R\ :sub:`byte` may
1748    see are atomic, it chooses one of the values written. See the :ref:`Atomic
1749    Memory Ordering Constraints <ordering>` section for additional
1750    constraints on how the choice is made.
1751 -  Otherwise R\ :sub:`byte` returns ``undef``.
1752
1753 R returns the value composed of the series of bytes it read. This
1754 implies that some bytes within the value may be ``undef`` **without**
1755 the entire value being ``undef``. Note that this only defines the
1756 semantics of the operation; it doesn't mean that targets will emit more
1757 than one instruction to read the series of bytes.
1758
1759 Note that in cases where none of the atomic intrinsics are used, this
1760 model places only one restriction on IR transformations on top of what
1761 is required for single-threaded execution: introducing a store to a byte
1762 which might not otherwise be stored is not allowed in general.
1763 (Specifically, in the case where another thread might write to and read
1764 from an address, introducing a store can change a load that may see
1765 exactly one write into a load that may see multiple writes.)
1766
1767 .. _ordering:
1768
1769 Atomic Memory Ordering Constraints
1770 ----------------------------------
1771
1772 Atomic instructions (:ref:`cmpxchg <i_cmpxchg>`,
1773 :ref:`atomicrmw <i_atomicrmw>`, :ref:`fence <i_fence>`,
1774 :ref:`atomic load <i_load>`, and :ref:`atomic store <i_store>`) take
1775 ordering parameters that determine which other atomic instructions on
1776 the same address they *synchronize with*. These semantics are borrowed
1777 from Java and C++0x, but are somewhat more colloquial. If these
1778 descriptions aren't precise enough, check those specs (see spec
1779 references in the :doc:`atomics guide <Atomics>`).
1780 :ref:`fence <i_fence>` instructions treat these orderings somewhat
1781 differently since they don't take an address. See that instruction's
1782 documentation for details.
1783
1784 For a simpler introduction to the ordering constraints, see the
1785 :doc:`Atomics`.
1786
1787 ``unordered``
1788     The set of values that can be read is governed by the happens-before
1789     partial order. A value cannot be read unless some operation wrote
1790     it. This is intended to provide a guarantee strong enough to model
1791     Java's non-volatile shared variables. This ordering cannot be
1792     specified for read-modify-write operations; it is not strong enough
1793     to make them atomic in any interesting way.
1794 ``monotonic``
1795     In addition to the guarantees of ``unordered``, there is a single
1796     total order for modifications by ``monotonic`` operations on each
1797     address. All modification orders must be compatible with the
1798     happens-before order. There is no guarantee that the modification
1799     orders can be combined to a global total order for the whole program
1800     (and this often will not be possible). The read in an atomic
1801     read-modify-write operation (:ref:`cmpxchg <i_cmpxchg>` and
1802     :ref:`atomicrmw <i_atomicrmw>`) reads the value in the modification
1803     order immediately before the value it writes. If one atomic read
1804     happens before another atomic read of the same address, the later
1805     read must see the same value or a later value in the address's
1806     modification order. This disallows reordering of ``monotonic`` (or
1807     stronger) operations on the same address. If an address is written
1808     ``monotonic``-ally by one thread, and other threads ``monotonic``-ally
1809     read that address repeatedly, the other threads must eventually see
1810     the write. This corresponds to the C++0x/C1x
1811     ``memory_order_relaxed``.
1812 ``acquire``
1813     In addition to the guarantees of ``monotonic``, a
1814     *synchronizes-with* edge may be formed with a ``release`` operation.
1815     This is intended to model C++'s ``memory_order_acquire``.
1816 ``release``
1817     In addition to the guarantees of ``monotonic``, if this operation
1818     writes a value which is subsequently read by an ``acquire``
1819     operation, it *synchronizes-with* that operation. (This isn't a
1820     complete description; see the C++0x definition of a release
1821     sequence.) This corresponds to the C++0x/C1x
1822     ``memory_order_release``.
1823 ``acq_rel`` (acquire+release)
1824     Acts as both an ``acquire`` and ``release`` operation on its
1825     address. This corresponds to the C++0x/C1x ``memory_order_acq_rel``.
1826 ``seq_cst`` (sequentially consistent)
1827     In addition to the guarantees of ``acq_rel`` (``acquire`` for an
1828     operation that only reads, ``release`` for an operation that only
1829     writes), there is a global total order on all
1830     sequentially-consistent operations on all addresses, which is
1831     consistent with the *happens-before* partial order and with the
1832     modification orders of all the affected addresses. Each
1833     sequentially-consistent read sees the last preceding write to the
1834     same address in this global order. This corresponds to the C++0x/C1x
1835     ``memory_order_seq_cst`` and Java volatile.
1836
1837 .. _singlethread:
1838
1839 If an atomic operation is marked ``singlethread``, it only *synchronizes
1840 with* or participates in modification and seq\_cst total orderings with
1841 other operations running in the same thread (for example, in signal
1842 handlers).
1843
1844 .. _fastmath:
1845
1846 Fast-Math Flags
1847 ---------------
1848
1849 LLVM IR floating-point binary ops (:ref:`fadd <i_fadd>`,
1850 :ref:`fsub <i_fsub>`, :ref:`fmul <i_fmul>`, :ref:`fdiv <i_fdiv>`,
1851 :ref:`frem <i_frem>`, :ref:`fcmp <i_fcmp>`) have the following flags that can
1852 be set to enable otherwise unsafe floating point operations
1853
1854 ``nnan``
1855    No NaNs - Allow optimizations to assume the arguments and result are not
1856    NaN. Such optimizations are required to retain defined behavior over
1857    NaNs, but the value of the result is undefined.
1858
1859 ``ninf``
1860    No Infs - Allow optimizations to assume the arguments and result are not
1861    +/-Inf. Such optimizations are required to retain defined behavior over
1862    +/-Inf, but the value of the result is undefined.
1863
1864 ``nsz``
1865    No Signed Zeros - Allow optimizations to treat the sign of a zero
1866    argument or result as insignificant.
1867
1868 ``arcp``
1869    Allow Reciprocal - Allow optimizations to use the reciprocal of an
1870    argument rather than perform division.
1871
1872 ``fast``
1873    Fast - Allow algebraically equivalent transformations that may
1874    dramatically change results in floating point (e.g. reassociate). This
1875    flag implies all the others.
1876
1877 .. _uselistorder:
1878
1879 Use-list Order Directives
1880 -------------------------
1881
1882 Use-list directives encode the in-memory order of each use-list, allowing the
1883 order to be recreated. ``<order-indexes>`` is a comma-separated list of
1884 indexes that are assigned to the referenced value's uses. The referenced
1885 value's use-list is immediately sorted by these indexes.
1886
1887 Use-list directives may appear at function scope or global scope. They are not
1888 instructions, and have no effect on the semantics of the IR. When they're at
1889 function scope, they must appear after the terminator of the final basic block.
1890
1891 If basic blocks have their address taken via ``blockaddress()`` expressions,
1892 ``uselistorder_bb`` can be used to reorder their use-lists from outside their
1893 function's scope.
1894
1895 :Syntax:
1896
1897 ::
1898
1899     uselistorder <ty> <value>, { <order-indexes> }
1900     uselistorder_bb @function, %block { <order-indexes> }
1901
1902 :Examples:
1903
1904 ::
1905
1906     define void @foo(i32 %arg1, i32 %arg2) {
1907     entry:
1908       ; ... instructions ...
1909     bb:
1910       ; ... instructions ...
1911
1912       ; At function scope.
1913       uselistorder i32 %arg1, { 1, 0, 2 }
1914       uselistorder label %bb, { 1, 0 }
1915     }
1916
1917     ; At global scope.
1918     uselistorder i32* @global, { 1, 2, 0 }
1919     uselistorder i32 7, { 1, 0 }
1920     uselistorder i32 (i32) @bar, { 1, 0 }
1921     uselistorder_bb @foo, %bb, { 5, 1, 3, 2, 0, 4 }
1922
1923 .. _typesystem:
1924
1925 Type System
1926 ===========
1927
1928 The LLVM type system is one of the most important features of the
1929 intermediate representation. Being typed enables a number of
1930 optimizations to be performed on the intermediate representation
1931 directly, without having to do extra analyses on the side before the
1932 transformation. A strong type system makes it easier to read the
1933 generated code and enables novel analyses and transformations that are
1934 not feasible to perform on normal three address code representations.
1935
1936 .. _t_void:
1937
1938 Void Type
1939 ---------
1940
1941 :Overview:
1942
1943
1944 The void type does not represent any value and has no size.
1945
1946 :Syntax:
1947
1948
1949 ::
1950
1951       void
1952
1953
1954 .. _t_function:
1955
1956 Function Type
1957 -------------
1958
1959 :Overview:
1960
1961
1962 The function type can be thought of as a function signature. It consists of a
1963 return type and a list of formal parameter types. The return type of a function
1964 type is a void type or first class type --- except for :ref:`label <t_label>`
1965 and :ref:`metadata <t_metadata>` types.
1966
1967 :Syntax:
1968
1969 ::
1970
1971       <returntype> (<parameter list>)
1972
1973 ...where '``<parameter list>``' is a comma-separated list of type
1974 specifiers. Optionally, the parameter list may include a type ``...``, which
1975 indicates that the function takes a variable number of arguments. Variable
1976 argument functions can access their arguments with the :ref:`variable argument
1977 handling intrinsic <int_varargs>` functions. '``<returntype>``' is any type
1978 except :ref:`label <t_label>` and :ref:`metadata <t_metadata>`.
1979
1980 :Examples:
1981
1982 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1983 | ``i32 (i32)``                   | function taking an ``i32``, returning an ``i32``                                                                                                                    |
1984 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1985 | ``float (i16, i32 *) *``        | :ref:`Pointer <t_pointer>` to a function that takes an ``i16`` and a :ref:`pointer <t_pointer>` to ``i32``, returning ``float``.                                    |
1986 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1987 | ``i32 (i8*, ...)``              | A vararg function that takes at least one :ref:`pointer <t_pointer>` to ``i8`` (char in C), which returns an integer. This is the signature for ``printf`` in LLVM. |
1988 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1989 | ``{i32, i32} (i32)``            | A function taking an ``i32``, returning a :ref:`structure <t_struct>` containing two ``i32`` values                                                                 |
1990 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1991
1992 .. _t_firstclass:
1993
1994 First Class Types
1995 -----------------
1996
1997 The :ref:`first class <t_firstclass>` types are perhaps the most important.
1998 Values of these types are the only ones which can be produced by
1999 instructions.
2000
2001 .. _t_single_value:
2002
2003 Single Value Types
2004 ^^^^^^^^^^^^^^^^^^
2005
2006 These are the types that are valid in registers from CodeGen's perspective.
2007
2008 .. _t_integer:
2009
2010 Integer Type
2011 """"""""""""
2012
2013 :Overview:
2014
2015 The integer type is a very simple type that simply specifies an
2016 arbitrary bit width for the integer type desired. Any bit width from 1
2017 bit to 2\ :sup:`23`\ -1 (about 8 million) can be specified.
2018
2019 :Syntax:
2020
2021 ::
2022
2023       iN
2024
2025 The number of bits the integer will occupy is specified by the ``N``
2026 value.
2027
2028 Examples:
2029 *********
2030
2031 +----------------+------------------------------------------------+
2032 | ``i1``         | a single-bit integer.                          |
2033 +----------------+------------------------------------------------+
2034 | ``i32``        | a 32-bit integer.                              |
2035 +----------------+------------------------------------------------+
2036 | ``i1942652``   | a really big integer of over 1 million bits.   |
2037 +----------------+------------------------------------------------+
2038
2039 .. _t_floating:
2040
2041 Floating Point Types
2042 """"""""""""""""""""
2043
2044 .. list-table::
2045    :header-rows: 1
2046
2047    * - Type
2048      - Description
2049
2050    * - ``half``
2051      - 16-bit floating point value
2052
2053    * - ``float``
2054      - 32-bit floating point value
2055
2056    * - ``double``
2057      - 64-bit floating point value
2058
2059    * - ``fp128``
2060      - 128-bit floating point value (112-bit mantissa)
2061
2062    * - ``x86_fp80``
2063      -  80-bit floating point value (X87)
2064
2065    * - ``ppc_fp128``
2066      - 128-bit floating point value (two 64-bits)
2067
2068 X86_mmx Type
2069 """"""""""""
2070
2071 :Overview:
2072
2073 The x86_mmx type represents a value held in an MMX register on an x86
2074 machine. The operations allowed on it are quite limited: parameters and
2075 return values, load and store, and bitcast. User-specified MMX
2076 instructions are represented as intrinsic or asm calls with arguments
2077 and/or results of this type. There are no arrays, vectors or constants
2078 of this type.
2079
2080 :Syntax:
2081
2082 ::
2083
2084       x86_mmx
2085
2086
2087 .. _t_pointer:
2088
2089 Pointer Type
2090 """"""""""""
2091
2092 :Overview:
2093
2094 The pointer type is used to specify memory locations. Pointers are
2095 commonly used to reference objects in memory.
2096
2097 Pointer types may have an optional address space attribute defining the
2098 numbered address space where the pointed-to object resides. The default
2099 address space is number zero. The semantics of non-zero address spaces
2100 are target-specific.
2101
2102 Note that LLVM does not permit pointers to void (``void*``) nor does it
2103 permit pointers to labels (``label*``). Use ``i8*`` instead.
2104
2105 :Syntax:
2106
2107 ::
2108
2109       <type> *
2110
2111 :Examples:
2112
2113 +-------------------------+--------------------------------------------------------------------------------------------------------------+
2114 | ``[4 x i32]*``          | A :ref:`pointer <t_pointer>` to :ref:`array <t_array>` of four ``i32`` values.                               |
2115 +-------------------------+--------------------------------------------------------------------------------------------------------------+
2116 | ``i32 (i32*) *``        | A :ref:`pointer <t_pointer>` to a :ref:`function <t_function>` that takes an ``i32*``, returning an ``i32``. |
2117 +-------------------------+--------------------------------------------------------------------------------------------------------------+
2118 | ``i32 addrspace(5)*``   | A :ref:`pointer <t_pointer>` to an ``i32`` value that resides in address space #5.                           |
2119 +-------------------------+--------------------------------------------------------------------------------------------------------------+
2120
2121 .. _t_vector:
2122
2123 Vector Type
2124 """""""""""
2125
2126 :Overview:
2127
2128 A vector type is a simple derived type that represents a vector of
2129 elements. Vector types are used when multiple primitive data are
2130 operated in parallel using a single instruction (SIMD). A vector type
2131 requires a size (number of elements) and an underlying primitive data
2132 type. Vector types are considered :ref:`first class <t_firstclass>`.
2133
2134 :Syntax:
2135
2136 ::
2137
2138       < <# elements> x <elementtype> >
2139
2140 The number of elements is a constant integer value larger than 0;
2141 elementtype may be any integer, floating point or pointer type. Vectors
2142 of size zero are not allowed.
2143
2144 :Examples:
2145
2146 +-------------------+--------------------------------------------------+
2147 | ``<4 x i32>``     | Vector of 4 32-bit integer values.               |
2148 +-------------------+--------------------------------------------------+
2149 | ``<8 x float>``   | Vector of 8 32-bit floating-point values.        |
2150 +-------------------+--------------------------------------------------+
2151 | ``<2 x i64>``     | Vector of 2 64-bit integer values.               |
2152 +-------------------+--------------------------------------------------+
2153 | ``<4 x i64*>``    | Vector of 4 pointers to 64-bit integer values.   |
2154 +-------------------+--------------------------------------------------+
2155
2156 .. _t_label:
2157
2158 Label Type
2159 ^^^^^^^^^^
2160
2161 :Overview:
2162
2163 The label type represents code labels.
2164
2165 :Syntax:
2166
2167 ::
2168
2169       label
2170
2171 .. _t_token:
2172
2173 Token Type
2174 ^^^^^^^^^^
2175
2176 :Overview:
2177
2178 The token type is used when a value is associated with an instruction
2179 but all uses of the value must not attempt to introspect or obscure it.
2180 As such, it is not appropriate to have a :ref:`phi <i_phi>` or
2181 :ref:`select <i_select>` of type token.
2182
2183 :Syntax:
2184
2185 ::
2186
2187       token
2188
2189
2190
2191 .. _t_metadata:
2192
2193 Metadata Type
2194 ^^^^^^^^^^^^^
2195
2196 :Overview:
2197
2198 The metadata type represents embedded metadata. No derived types may be
2199 created from metadata except for :ref:`function <t_function>` arguments.
2200
2201 :Syntax:
2202
2203 ::
2204
2205       metadata
2206
2207 .. _t_aggregate:
2208
2209 Aggregate Types
2210 ^^^^^^^^^^^^^^^
2211
2212 Aggregate Types are a subset of derived types that can contain multiple
2213 member types. :ref:`Arrays <t_array>` and :ref:`structs <t_struct>` are
2214 aggregate types. :ref:`Vectors <t_vector>` are not considered to be
2215 aggregate types.
2216
2217 .. _t_array:
2218
2219 Array Type
2220 """"""""""
2221
2222 :Overview:
2223
2224 The array type is a very simple derived type that arranges elements
2225 sequentially in memory. The array type requires a size (number of
2226 elements) and an underlying data type.
2227
2228 :Syntax:
2229
2230 ::
2231
2232       [<# elements> x <elementtype>]
2233
2234 The number of elements is a constant integer value; ``elementtype`` may
2235 be any type with a size.
2236
2237 :Examples:
2238
2239 +------------------+--------------------------------------+
2240 | ``[40 x i32]``   | Array of 40 32-bit integer values.   |
2241 +------------------+--------------------------------------+
2242 | ``[41 x i32]``   | Array of 41 32-bit integer values.   |
2243 +------------------+--------------------------------------+
2244 | ``[4 x i8]``     | Array of 4 8-bit integer values.     |
2245 +------------------+--------------------------------------+
2246
2247 Here are some examples of multidimensional arrays:
2248
2249 +-----------------------------+----------------------------------------------------------+
2250 | ``[3 x [4 x i32]]``         | 3x4 array of 32-bit integer values.                      |
2251 +-----------------------------+----------------------------------------------------------+
2252 | ``[12 x [10 x float]]``     | 12x10 array of single precision floating point values.   |
2253 +-----------------------------+----------------------------------------------------------+
2254 | ``[2 x [3 x [4 x i16]]]``   | 2x3x4 array of 16-bit integer values.                    |
2255 +-----------------------------+----------------------------------------------------------+
2256
2257 There is no restriction on indexing beyond the end of the array implied
2258 by a static type (though there are restrictions on indexing beyond the
2259 bounds of an allocated object in some cases). This means that
2260 single-dimension 'variable sized array' addressing can be implemented in
2261 LLVM with a zero length array type. An implementation of 'pascal style
2262 arrays' in LLVM could use the type "``{ i32, [0 x float]}``", for
2263 example.
2264
2265 .. _t_struct:
2266
2267 Structure Type
2268 """"""""""""""
2269
2270 :Overview:
2271
2272 The structure type is used to represent a collection of data members
2273 together in memory. The elements of a structure may be any type that has
2274 a size.
2275
2276 Structures in memory are accessed using '``load``' and '``store``' by
2277 getting a pointer to a field with the '``getelementptr``' instruction.
2278 Structures in registers are accessed using the '``extractvalue``' and
2279 '``insertvalue``' instructions.
2280
2281 Structures may optionally be "packed" structures, which indicate that
2282 the alignment of the struct is one byte, and that there is no padding
2283 between the elements. In non-packed structs, padding between field types
2284 is inserted as defined by the DataLayout string in the module, which is
2285 required to match what the underlying code generator expects.
2286
2287 Structures can either be "literal" or "identified". A literal structure
2288 is defined inline with other types (e.g. ``{i32, i32}*``) whereas
2289 identified types are always defined at the top level with a name.
2290 Literal types are uniqued by their contents and can never be recursive
2291 or opaque since there is no way to write one. Identified types can be
2292 recursive, can be opaqued, and are never uniqued.
2293
2294 :Syntax:
2295
2296 ::
2297
2298       %T1 = type { <type list> }     ; Identified normal struct type
2299       %T2 = type <{ <type list> }>   ; Identified packed struct type
2300
2301 :Examples:
2302
2303 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2304 | ``{ i32, i32, i32 }``        | A triple of three ``i32`` values                                                                                                                                                      |
2305 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2306 | ``{ float, i32 (i32) * }``   | A pair, where the first element is a ``float`` and the second element is a :ref:`pointer <t_pointer>` to a :ref:`function <t_function>` that takes an ``i32``, returning an ``i32``.  |
2307 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2308 | ``<{ i8, i32 }>``            | A packed struct known to be 5 bytes in size.                                                                                                                                          |
2309 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2310
2311 .. _t_opaque:
2312
2313 Opaque Structure Types
2314 """"""""""""""""""""""
2315
2316 :Overview:
2317
2318 Opaque structure types are used to represent named structure types that
2319 do not have a body specified. This corresponds (for example) to the C
2320 notion of a forward declared structure.
2321
2322 :Syntax:
2323
2324 ::
2325
2326       %X = type opaque
2327       %52 = type opaque
2328
2329 :Examples:
2330
2331 +--------------+-------------------+
2332 | ``opaque``   | An opaque type.   |
2333 +--------------+-------------------+
2334
2335 .. _constants:
2336
2337 Constants
2338 =========
2339
2340 LLVM has several different basic types of constants. This section
2341 describes them all and their syntax.
2342
2343 Simple Constants
2344 ----------------
2345
2346 **Boolean constants**
2347     The two strings '``true``' and '``false``' are both valid constants
2348     of the ``i1`` type.
2349 **Integer constants**
2350     Standard integers (such as '4') are constants of the
2351     :ref:`integer <t_integer>` type. Negative numbers may be used with
2352     integer types.
2353 **Floating point constants**
2354     Floating point constants use standard decimal notation (e.g.
2355     123.421), exponential notation (e.g. 1.23421e+2), or a more precise
2356     hexadecimal notation (see below). The assembler requires the exact
2357     decimal value of a floating-point constant. For example, the
2358     assembler accepts 1.25 but rejects 1.3 because 1.3 is a repeating
2359     decimal in binary. Floating point constants must have a :ref:`floating
2360     point <t_floating>` type.
2361 **Null pointer constants**
2362     The identifier '``null``' is recognized as a null pointer constant
2363     and must be of :ref:`pointer type <t_pointer>`.
2364
2365 The one non-intuitive notation for constants is the hexadecimal form of
2366 floating point constants. For example, the form
2367 '``double    0x432ff973cafa8000``' is equivalent to (but harder to read
2368 than) '``double 4.5e+15``'. The only time hexadecimal floating point
2369 constants are required (and the only time that they are generated by the
2370 disassembler) is when a floating point constant must be emitted but it
2371 cannot be represented as a decimal floating point number in a reasonable
2372 number of digits. For example, NaN's, infinities, and other special
2373 values are represented in their IEEE hexadecimal format so that assembly
2374 and disassembly do not cause any bits to change in the constants.
2375
2376 When using the hexadecimal form, constants of types half, float, and
2377 double are represented using the 16-digit form shown above (which
2378 matches the IEEE754 representation for double); half and float values
2379 must, however, be exactly representable as IEEE 754 half and single
2380 precision, respectively. Hexadecimal format is always used for long
2381 double, and there are three forms of long double. The 80-bit format used
2382 by x86 is represented as ``0xK`` followed by 20 hexadecimal digits. The
2383 128-bit format used by PowerPC (two adjacent doubles) is represented by
2384 ``0xM`` followed by 32 hexadecimal digits. The IEEE 128-bit format is
2385 represented by ``0xL`` followed by 32 hexadecimal digits. Long doubles
2386 will only work if they match the long double format on your target.
2387 The IEEE 16-bit format (half precision) is represented by ``0xH``
2388 followed by 4 hexadecimal digits. All hexadecimal formats are big-endian
2389 (sign bit at the left).
2390
2391 There are no constants of type x86_mmx.
2392
2393 .. _complexconstants:
2394
2395 Complex Constants
2396 -----------------
2397
2398 Complex constants are a (potentially recursive) combination of simple
2399 constants and smaller complex constants.
2400
2401 **Structure constants**
2402     Structure constants are represented with notation similar to
2403     structure type definitions (a comma separated list of elements,
2404     surrounded by braces (``{}``)). For example:
2405     "``{ i32 4, float 17.0, i32* @G }``", where "``@G``" is declared as
2406     "``@G = external global i32``". Structure constants must have
2407     :ref:`structure type <t_struct>`, and the number and types of elements
2408     must match those specified by the type.
2409 **Array constants**
2410     Array constants are represented with notation similar to array type
2411     definitions (a comma separated list of elements, surrounded by
2412     square brackets (``[]``)). For example:
2413     "``[ i32 42, i32 11, i32 74 ]``". Array constants must have
2414     :ref:`array type <t_array>`, and the number and types of elements must
2415     match those specified by the type. As a special case, character array
2416     constants may also be represented as a double-quoted string using the ``c``
2417     prefix. For example: "``c"Hello World\0A\00"``".
2418 **Vector constants**
2419     Vector constants are represented with notation similar to vector
2420     type definitions (a comma separated list of elements, surrounded by
2421     less-than/greater-than's (``<>``)). For example:
2422     "``< i32 42, i32 11, i32 74, i32 100 >``". Vector constants
2423     must have :ref:`vector type <t_vector>`, and the number and types of
2424     elements must match those specified by the type.
2425 **Zero initialization**
2426     The string '``zeroinitializer``' can be used to zero initialize a
2427     value to zero of *any* type, including scalar and
2428     :ref:`aggregate <t_aggregate>` types. This is often used to avoid
2429     having to print large zero initializers (e.g. for large arrays) and
2430     is always exactly equivalent to using explicit zero initializers.
2431 **Metadata node**
2432     A metadata node is a constant tuple without types. For example:
2433     "``!{!0, !{!2, !0}, !"test"}``". Metadata can reference constant values,
2434     for example: "``!{!0, i32 0, i8* @global, i64 (i64)* @function, !"str"}``".
2435     Unlike other typed constants that are meant to be interpreted as part of
2436     the instruction stream, metadata is a place to attach additional
2437     information such as debug info.
2438
2439 Global Variable and Function Addresses
2440 --------------------------------------
2441
2442 The addresses of :ref:`global variables <globalvars>` and
2443 :ref:`functions <functionstructure>` are always implicitly valid
2444 (link-time) constants. These constants are explicitly referenced when
2445 the :ref:`identifier for the global <identifiers>` is used and always have
2446 :ref:`pointer <t_pointer>` type. For example, the following is a legal LLVM
2447 file:
2448
2449 .. code-block:: llvm
2450
2451     @X = global i32 17
2452     @Y = global i32 42
2453     @Z = global [2 x i32*] [ i32* @X, i32* @Y ]
2454
2455 .. _undefvalues:
2456
2457 Undefined Values
2458 ----------------
2459
2460 The string '``undef``' can be used anywhere a constant is expected, and
2461 indicates that the user of the value may receive an unspecified
2462 bit-pattern. Undefined values may be of any type (other than '``label``'
2463 or '``void``') and be used anywhere a constant is permitted.
2464
2465 Undefined values are useful because they indicate to the compiler that
2466 the program is well defined no matter what value is used. This gives the
2467 compiler more freedom to optimize. Here are some examples of
2468 (potentially surprising) transformations that are valid (in pseudo IR):
2469
2470 .. code-block:: llvm
2471
2472       %A = add %X, undef
2473       %B = sub %X, undef
2474       %C = xor %X, undef
2475     Safe:
2476       %A = undef
2477       %B = undef
2478       %C = undef
2479
2480 This is safe because all of the output bits are affected by the undef
2481 bits. Any output bit can have a zero or one depending on the input bits.
2482
2483 .. code-block:: llvm
2484
2485       %A = or %X, undef
2486       %B = and %X, undef
2487     Safe:
2488       %A = -1
2489       %B = 0
2490     Unsafe:
2491       %A = undef
2492       %B = undef
2493
2494 These logical operations have bits that are not always affected by the
2495 input. For example, if ``%X`` has a zero bit, then the output of the
2496 '``and``' operation will always be a zero for that bit, no matter what
2497 the corresponding bit from the '``undef``' is. As such, it is unsafe to
2498 optimize or assume that the result of the '``and``' is '``undef``'.
2499 However, it is safe to assume that all bits of the '``undef``' could be
2500 0, and optimize the '``and``' to 0. Likewise, it is safe to assume that
2501 all the bits of the '``undef``' operand to the '``or``' could be set,
2502 allowing the '``or``' to be folded to -1.
2503
2504 .. code-block:: llvm
2505
2506       %A = select undef, %X, %Y
2507       %B = select undef, 42, %Y
2508       %C = select %X, %Y, undef
2509     Safe:
2510       %A = %X     (or %Y)
2511       %B = 42     (or %Y)
2512       %C = %Y
2513     Unsafe:
2514       %A = undef
2515       %B = undef
2516       %C = undef
2517
2518 This set of examples shows that undefined '``select``' (and conditional
2519 branch) conditions can go *either way*, but they have to come from one
2520 of the two operands. In the ``%A`` example, if ``%X`` and ``%Y`` were
2521 both known to have a clear low bit, then ``%A`` would have to have a
2522 cleared low bit. However, in the ``%C`` example, the optimizer is
2523 allowed to assume that the '``undef``' operand could be the same as
2524 ``%Y``, allowing the whole '``select``' to be eliminated.
2525
2526 .. code-block:: llvm
2527
2528       %A = xor undef, undef
2529
2530       %B = undef
2531       %C = xor %B, %B
2532
2533       %D = undef
2534       %E = icmp slt %D, 4
2535       %F = icmp gte %D, 4
2536
2537     Safe:
2538       %A = undef
2539       %B = undef
2540       %C = undef
2541       %D = undef
2542       %E = undef
2543       %F = undef
2544
2545 This example points out that two '``undef``' operands are not
2546 necessarily the same. This can be surprising to people (and also matches
2547 C semantics) where they assume that "``X^X``" is always zero, even if
2548 ``X`` is undefined. This isn't true for a number of reasons, but the
2549 short answer is that an '``undef``' "variable" can arbitrarily change
2550 its value over its "live range". This is true because the variable
2551 doesn't actually *have a live range*. Instead, the value is logically
2552 read from arbitrary registers that happen to be around when needed, so
2553 the value is not necessarily consistent over time. In fact, ``%A`` and
2554 ``%C`` need to have the same semantics or the core LLVM "replace all
2555 uses with" concept would not hold.
2556
2557 .. code-block:: llvm
2558
2559       %A = fdiv undef, %X
2560       %B = fdiv %X, undef
2561     Safe:
2562       %A = undef
2563     b: unreachable
2564
2565 These examples show the crucial difference between an *undefined value*
2566 and *undefined behavior*. An undefined value (like '``undef``') is
2567 allowed to have an arbitrary bit-pattern. This means that the ``%A``
2568 operation can be constant folded to '``undef``', because the '``undef``'
2569 could be an SNaN, and ``fdiv`` is not (currently) defined on SNaN's.
2570 However, in the second example, we can make a more aggressive
2571 assumption: because the ``undef`` is allowed to be an arbitrary value,
2572 we are allowed to assume that it could be zero. Since a divide by zero
2573 has *undefined behavior*, we are allowed to assume that the operation
2574 does not execute at all. This allows us to delete the divide and all
2575 code after it. Because the undefined operation "can't happen", the
2576 optimizer can assume that it occurs in dead code.
2577
2578 .. code-block:: llvm
2579
2580     a:  store undef -> %X
2581     b:  store %X -> undef
2582     Safe:
2583     a: <deleted>
2584     b: unreachable
2585
2586 These examples reiterate the ``fdiv`` example: a store *of* an undefined
2587 value can be assumed to not have any effect; we can assume that the
2588 value is overwritten with bits that happen to match what was already
2589 there. However, a store *to* an undefined location could clobber
2590 arbitrary memory, therefore, it has undefined behavior.
2591
2592 .. _poisonvalues:
2593
2594 Poison Values
2595 -------------
2596
2597 Poison values are similar to :ref:`undef values <undefvalues>`, however
2598 they also represent the fact that an instruction or constant expression
2599 that cannot evoke side effects has nevertheless detected a condition
2600 that results in undefined behavior.
2601
2602 There is currently no way of representing a poison value in the IR; they
2603 only exist when produced by operations such as :ref:`add <i_add>` with
2604 the ``nsw`` flag.
2605
2606 Poison value behavior is defined in terms of value *dependence*:
2607
2608 -  Values other than :ref:`phi <i_phi>` nodes depend on their operands.
2609 -  :ref:`Phi <i_phi>` nodes depend on the operand corresponding to
2610    their dynamic predecessor basic block.
2611 -  Function arguments depend on the corresponding actual argument values
2612    in the dynamic callers of their functions.
2613 -  :ref:`Call <i_call>` instructions depend on the :ref:`ret <i_ret>`
2614    instructions that dynamically transfer control back to them.
2615 -  :ref:`Invoke <i_invoke>` instructions depend on the
2616    :ref:`ret <i_ret>`, :ref:`resume <i_resume>`, or exception-throwing
2617    call instructions that dynamically transfer control back to them.
2618 -  Non-volatile loads and stores depend on the most recent stores to all
2619    of the referenced memory addresses, following the order in the IR
2620    (including loads and stores implied by intrinsics such as
2621    :ref:`@llvm.memcpy <int_memcpy>`.)
2622 -  An instruction with externally visible side effects depends on the
2623    most recent preceding instruction with externally visible side
2624    effects, following the order in the IR. (This includes :ref:`volatile
2625    operations <volatile>`.)
2626 -  An instruction *control-depends* on a :ref:`terminator
2627    instruction <terminators>` if the terminator instruction has
2628    multiple successors and the instruction is always executed when
2629    control transfers to one of the successors, and may not be executed
2630    when control is transferred to another.
2631 -  Additionally, an instruction also *control-depends* on a terminator
2632    instruction if the set of instructions it otherwise depends on would
2633    be different if the terminator had transferred control to a different
2634    successor.
2635 -  Dependence is transitive.
2636
2637 Poison values have the same behavior as :ref:`undef values <undefvalues>`,
2638 with the additional effect that any instruction that has a *dependence*
2639 on a poison value has undefined behavior.
2640
2641 Here are some examples:
2642
2643 .. code-block:: llvm
2644
2645     entry:
2646       %poison = sub nuw i32 0, 1           ; Results in a poison value.
2647       %still_poison = and i32 %poison, 0   ; 0, but also poison.
2648       %poison_yet_again = getelementptr i32, i32* @h, i32 %still_poison
2649       store i32 0, i32* %poison_yet_again  ; memory at @h[0] is poisoned
2650
2651       store i32 %poison, i32* @g           ; Poison value stored to memory.
2652       %poison2 = load i32, i32* @g         ; Poison value loaded back from memory.
2653
2654       store volatile i32 %poison, i32* @g  ; External observation; undefined behavior.
2655
2656       %narrowaddr = bitcast i32* @g to i16*
2657       %wideaddr = bitcast i32* @g to i64*
2658       %poison3 = load i16, i16* %narrowaddr ; Returns a poison value.
2659       %poison4 = load i64, i64* %wideaddr  ; Returns a poison value.
2660
2661       %cmp = icmp slt i32 %poison, 0       ; Returns a poison value.
2662       br i1 %cmp, label %true, label %end  ; Branch to either destination.
2663
2664     true:
2665       store volatile i32 0, i32* @g        ; This is control-dependent on %cmp, so
2666                                            ; it has undefined behavior.
2667       br label %end
2668
2669     end:
2670       %p = phi i32 [ 0, %entry ], [ 1, %true ]
2671                                            ; Both edges into this PHI are
2672                                            ; control-dependent on %cmp, so this
2673                                            ; always results in a poison value.
2674
2675       store volatile i32 0, i32* @g        ; This would depend on the store in %true
2676                                            ; if %cmp is true, or the store in %entry
2677                                            ; otherwise, so this is undefined behavior.
2678
2679       br i1 %cmp, label %second_true, label %second_end
2680                                            ; The same branch again, but this time the
2681                                            ; true block doesn't have side effects.
2682
2683     second_true:
2684       ; No side effects!
2685       ret void
2686
2687     second_end:
2688       store volatile i32 0, i32* @g        ; This time, the instruction always depends
2689                                            ; on the store in %end. Also, it is
2690                                            ; control-equivalent to %end, so this is
2691                                            ; well-defined (ignoring earlier undefined
2692                                            ; behavior in this example).
2693
2694 .. _blockaddress:
2695
2696 Addresses of Basic Blocks
2697 -------------------------
2698
2699 ``blockaddress(@function, %block)``
2700
2701 The '``blockaddress``' constant computes the address of the specified
2702 basic block in the specified function, and always has an ``i8*`` type.
2703 Taking the address of the entry block is illegal.
2704
2705 This value only has defined behavior when used as an operand to the
2706 ':ref:`indirectbr <i_indirectbr>`' instruction, or for comparisons
2707 against null. Pointer equality tests between labels addresses results in
2708 undefined behavior --- though, again, comparison against null is ok, and
2709 no label is equal to the null pointer. This may be passed around as an
2710 opaque pointer sized value as long as the bits are not inspected. This
2711 allows ``ptrtoint`` and arithmetic to be performed on these values so
2712 long as the original value is reconstituted before the ``indirectbr``
2713 instruction.
2714
2715 Finally, some targets may provide defined semantics when using the value
2716 as the operand to an inline assembly, but that is target specific.
2717
2718 .. _constantexprs:
2719
2720 Constant Expressions
2721 --------------------
2722
2723 Constant expressions are used to allow expressions involving other
2724 constants to be used as constants. Constant expressions may be of any
2725 :ref:`first class <t_firstclass>` type and may involve any LLVM operation
2726 that does not have side effects (e.g. load and call are not supported).
2727 The following is the syntax for constant expressions:
2728
2729 ``trunc (CST to TYPE)``
2730     Truncate a constant to another type. The bit size of CST must be
2731     larger than the bit size of TYPE. Both types must be integers.
2732 ``zext (CST to TYPE)``
2733     Zero extend a constant to another type. The bit size of CST must be
2734     smaller than the bit size of TYPE. Both types must be integers.
2735 ``sext (CST to TYPE)``
2736     Sign extend a constant to another type. The bit size of CST must be
2737     smaller than the bit size of TYPE. Both types must be integers.
2738 ``fptrunc (CST to TYPE)``
2739     Truncate a floating point constant to another floating point type.
2740     The size of CST must be larger than the size of TYPE. Both types
2741     must be floating point.
2742 ``fpext (CST to TYPE)``
2743     Floating point extend a constant to another type. The size of CST
2744     must be smaller or equal to the size of TYPE. Both types must be
2745     floating point.
2746 ``fptoui (CST to TYPE)``
2747     Convert a floating point constant to the corresponding unsigned
2748     integer constant. TYPE must be a scalar or vector integer type. CST
2749     must be of scalar or vector floating point type. Both CST and TYPE
2750     must be scalars, or vectors of the same number of elements. If the
2751     value won't fit in the integer type, the results are undefined.
2752 ``fptosi (CST to TYPE)``
2753     Convert a floating point constant to the corresponding signed
2754     integer constant. TYPE must be a scalar or vector integer type. CST
2755     must be of scalar or vector floating point type. Both CST and TYPE
2756     must be scalars, or vectors of the same number of elements. If the
2757     value won't fit in the integer type, the results are undefined.
2758 ``uitofp (CST to TYPE)``
2759     Convert an unsigned integer constant to the corresponding floating
2760     point constant. TYPE must be a scalar or vector floating point type.
2761     CST must be of scalar or vector integer type. Both CST and TYPE must
2762     be scalars, or vectors of the same number of elements. If the value
2763     won't fit in the floating point type, the results are undefined.
2764 ``sitofp (CST to TYPE)``
2765     Convert a signed integer constant to the corresponding floating
2766     point constant. TYPE must be a scalar or vector floating point type.
2767     CST must be of scalar or vector integer type. Both CST and TYPE must
2768     be scalars, or vectors of the same number of elements. If the value
2769     won't fit in the floating point type, the results are undefined.
2770 ``ptrtoint (CST to TYPE)``
2771     Convert a pointer typed constant to the corresponding integer
2772     constant. ``TYPE`` must be an integer type. ``CST`` must be of
2773     pointer type. The ``CST`` value is zero extended, truncated, or
2774     unchanged to make it fit in ``TYPE``.
2775 ``inttoptr (CST to TYPE)``
2776     Convert an integer constant to a pointer constant. TYPE must be a
2777     pointer type. CST must be of integer type. The CST value is zero
2778     extended, truncated, or unchanged to make it fit in a pointer size.
2779     This one is *really* dangerous!
2780 ``bitcast (CST to TYPE)``
2781     Convert a constant, CST, to another TYPE. The constraints of the
2782     operands are the same as those for the :ref:`bitcast
2783     instruction <i_bitcast>`.
2784 ``addrspacecast (CST to TYPE)``
2785     Convert a constant pointer or constant vector of pointer, CST, to another
2786     TYPE in a different address space. The constraints of the operands are the
2787     same as those for the :ref:`addrspacecast instruction <i_addrspacecast>`.
2788 ``getelementptr (TY, CSTPTR, IDX0, IDX1, ...)``, ``getelementptr inbounds (TY, CSTPTR, IDX0, IDX1, ...)``
2789     Perform the :ref:`getelementptr operation <i_getelementptr>` on
2790     constants. As with the :ref:`getelementptr <i_getelementptr>`
2791     instruction, the index list may have zero or more indexes, which are
2792     required to make sense for the type of "pointer to TY".
2793 ``select (COND, VAL1, VAL2)``
2794     Perform the :ref:`select operation <i_select>` on constants.
2795 ``icmp COND (VAL1, VAL2)``
2796     Performs the :ref:`icmp operation <i_icmp>` on constants.
2797 ``fcmp COND (VAL1, VAL2)``
2798     Performs the :ref:`fcmp operation <i_fcmp>` on constants.
2799 ``extractelement (VAL, IDX)``
2800     Perform the :ref:`extractelement operation <i_extractelement>` on
2801     constants.
2802 ``insertelement (VAL, ELT, IDX)``
2803     Perform the :ref:`insertelement operation <i_insertelement>` on
2804     constants.
2805 ``shufflevector (VEC1, VEC2, IDXMASK)``
2806     Perform the :ref:`shufflevector operation <i_shufflevector>` on
2807     constants.
2808 ``extractvalue (VAL, IDX0, IDX1, ...)``
2809     Perform the :ref:`extractvalue operation <i_extractvalue>` on
2810     constants. The index list is interpreted in a similar manner as
2811     indices in a ':ref:`getelementptr <i_getelementptr>`' operation. At
2812     least one index value must be specified.
2813 ``insertvalue (VAL, ELT, IDX0, IDX1, ...)``
2814     Perform the :ref:`insertvalue operation <i_insertvalue>` on constants.
2815     The index list is interpreted in a similar manner as indices in a
2816     ':ref:`getelementptr <i_getelementptr>`' operation. At least one index
2817     value must be specified.
2818 ``OPCODE (LHS, RHS)``
2819     Perform the specified operation of the LHS and RHS constants. OPCODE
2820     may be any of the :ref:`binary <binaryops>` or :ref:`bitwise
2821     binary <bitwiseops>` operations. The constraints on operands are
2822     the same as those for the corresponding instruction (e.g. no bitwise
2823     operations on floating point values are allowed).
2824
2825 Other Values
2826 ============
2827
2828 .. _inlineasmexprs:
2829
2830 Inline Assembler Expressions
2831 ----------------------------
2832
2833 LLVM supports inline assembler expressions (as opposed to :ref:`Module-Level
2834 Inline Assembly <moduleasm>`) through the use of a special value. This value
2835 represents the inline assembler as a template string (containing the
2836 instructions to emit), a list of operand constraints (stored as a string), a
2837 flag that indicates whether or not the inline asm expression has side effects,
2838 and a flag indicating whether the function containing the asm needs to align its
2839 stack conservatively.
2840
2841 The template string supports argument substitution of the operands using "``$``"
2842 followed by a number, to indicate substitution of the given register/memory
2843 location, as specified by the constraint string. "``${NUM:MODIFIER}``" may also
2844 be used, where ``MODIFIER`` is a target-specific annotation for how to print the
2845 operand (See :ref:`inline-asm-modifiers`).
2846
2847 A literal "``$``" may be included by using "``$$``" in the template. To include
2848 other special characters into the output, the usual "``\XX``" escapes may be
2849 used, just as in other strings. Note that after template substitution, the
2850 resulting assembly string is parsed by LLVM's integrated assembler unless it is
2851 disabled -- even when emitting a ``.s`` file -- and thus must contain assembly
2852 syntax known to LLVM.
2853
2854 LLVM's support for inline asm is modeled closely on the requirements of Clang's
2855 GCC-compatible inline-asm support. Thus, the feature-set and the constraint and
2856 modifier codes listed here are similar or identical to those in GCC's inline asm
2857 support. However, to be clear, the syntax of the template and constraint strings
2858 described here is *not* the same as the syntax accepted by GCC and Clang, and,
2859 while most constraint letters are passed through as-is by Clang, some get
2860 translated to other codes when converting from the C source to the LLVM
2861 assembly.
2862
2863 An example inline assembler expression is:
2864
2865 .. code-block:: llvm
2866
2867     i32 (i32) asm "bswap $0", "=r,r"
2868
2869 Inline assembler expressions may **only** be used as the callee operand
2870 of a :ref:`call <i_call>` or an :ref:`invoke <i_invoke>` instruction.
2871 Thus, typically we have:
2872
2873 .. code-block:: llvm
2874
2875     %X = call i32 asm "bswap $0", "=r,r"(i32 %Y)
2876
2877 Inline asms with side effects not visible in the constraint list must be
2878 marked as having side effects. This is done through the use of the
2879 '``sideeffect``' keyword, like so:
2880
2881 .. code-block:: llvm
2882
2883     call void asm sideeffect "eieio", ""()
2884
2885 In some cases inline asms will contain code that will not work unless
2886 the stack is aligned in some way, such as calls or SSE instructions on
2887 x86, yet will not contain code that does that alignment within the asm.
2888 The compiler should make conservative assumptions about what the asm
2889 might contain and should generate its usual stack alignment code in the
2890 prologue if the '``alignstack``' keyword is present:
2891
2892 .. code-block:: llvm
2893
2894     call void asm alignstack "eieio", ""()
2895
2896 Inline asms also support using non-standard assembly dialects. The
2897 assumed dialect is ATT. When the '``inteldialect``' keyword is present,
2898 the inline asm is using the Intel dialect. Currently, ATT and Intel are
2899 the only supported dialects. An example is:
2900
2901 .. code-block:: llvm
2902
2903     call void asm inteldialect "eieio", ""()
2904
2905 If multiple keywords appear the '``sideeffect``' keyword must come
2906 first, the '``alignstack``' keyword second and the '``inteldialect``'
2907 keyword last.
2908
2909 Inline Asm Constraint String
2910 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
2911
2912 The constraint list is a comma-separated string, each element containing one or
2913 more constraint codes.
2914
2915 For each element in the constraint list an appropriate register or memory
2916 operand will be chosen, and it will be made available to assembly template
2917 string expansion as ``$0`` for the first constraint in the list, ``$1`` for the
2918 second, etc.
2919
2920 There are three different types of constraints, which are distinguished by a
2921 prefix symbol in front of the constraint code: Output, Input, and Clobber. The
2922 constraints must always be given in that order: outputs first, then inputs, then
2923 clobbers. They cannot be intermingled.
2924
2925 There are also three different categories of constraint codes:
2926
2927 - Register constraint. This is either a register class, or a fixed physical
2928   register. This kind of constraint will allocate a register, and if necessary,
2929   bitcast the argument or result to the appropriate type.
2930 - Memory constraint. This kind of constraint is for use with an instruction
2931   taking a memory operand. Different constraints allow for different addressing
2932   modes used by the target.
2933 - Immediate value constraint. This kind of constraint is for an integer or other
2934   immediate value which can be rendered directly into an instruction. The
2935   various target-specific constraints allow the selection of a value in the
2936   proper range for the instruction you wish to use it with.
2937
2938 Output constraints
2939 """"""""""""""""""
2940
2941 Output constraints are specified by an "``=``" prefix (e.g. "``=r``"). This
2942 indicates that the assembly will write to this operand, and the operand will
2943 then be made available as a return value of the ``asm`` expression. Output
2944 constraints do not consume an argument from the call instruction. (Except, see
2945 below about indirect outputs).
2946
2947 Normally, it is expected that no output locations are written to by the assembly
2948 expression until *all* of the inputs have been read. As such, LLVM may assign
2949 the same register to an output and an input. If this is not safe (e.g. if the
2950 assembly contains two instructions, where the first writes to one output, and
2951 the second reads an input and writes to a second output), then the "``&``"
2952 modifier must be used (e.g. "``=&r``") to specify that the output is an
2953 "early-clobber" output. Marking an ouput as "early-clobber" ensures that LLVM
2954 will not use the same register for any inputs (other than an input tied to this
2955 output).
2956
2957 Input constraints
2958 """""""""""""""""
2959
2960 Input constraints do not have a prefix -- just the constraint codes. Each input
2961 constraint will consume one argument from the call instruction. It is not
2962 permitted for the asm to write to any input register or memory location (unless
2963 that input is tied to an output). Note also that multiple inputs may all be
2964 assigned to the same register, if LLVM can determine that they necessarily all
2965 contain the same value.
2966
2967 Instead of providing a Constraint Code, input constraints may also "tie"
2968 themselves to an output constraint, by providing an integer as the constraint
2969 string. Tied inputs still consume an argument from the call instruction, and
2970 take up a position in the asm template numbering as is usual -- they will simply
2971 be constrained to always use the same register as the output they've been tied
2972 to. For example, a constraint string of "``=r,0``" says to assign a register for
2973 output, and use that register as an input as well (it being the 0'th
2974 constraint).
2975
2976 It is permitted to tie an input to an "early-clobber" output. In that case, no
2977 *other* input may share the same register as the input tied to the early-clobber
2978 (even when the other input has the same value).
2979
2980 You may only tie an input to an output which has a register constraint, not a
2981 memory constraint. Only a single input may be tied to an output.
2982
2983 There is also an "interesting" feature which deserves a bit of explanation: if a
2984 register class constraint allocates a register which is too small for the value
2985 type operand provided as input, the input value will be split into multiple
2986 registers, and all of them passed to the inline asm.
2987
2988 However, this feature is often not as useful as you might think.
2989
2990 Firstly, the registers are *not* guaranteed to be consecutive. So, on those
2991 architectures that have instructions which operate on multiple consecutive
2992 instructions, this is not an appropriate way to support them. (e.g. the 32-bit
2993 SparcV8 has a 64-bit load, which instruction takes a single 32-bit register. The
2994 hardware then loads into both the named register, and the next register. This
2995 feature of inline asm would not be useful to support that.)
2996
2997 A few of the targets provide a template string modifier allowing explicit access
2998 to the second register of a two-register operand (e.g. MIPS ``L``, ``M``, and
2999 ``D``). On such an architecture, you can actually access the second allocated
3000 register (yet, still, not any subsequent ones). But, in that case, you're still
3001 probably better off simply splitting the value into two separate operands, for
3002 clarity. (e.g. see the description of the ``A`` constraint on X86, which,
3003 despite existing only for use with this feature, is not really a good idea to
3004 use)
3005
3006 Indirect inputs and outputs
3007 """""""""""""""""""""""""""
3008
3009 Indirect output or input constraints can be specified by the "``*``" modifier
3010 (which goes after the "``=``" in case of an output). This indicates that the asm
3011 will write to or read from the contents of an *address* provided as an input
3012 argument. (Note that in this way, indirect outputs act more like an *input* than
3013 an output: just like an input, they consume an argument of the call expression,
3014 rather than producing a return value. An indirect output constraint is an
3015 "output" only in that the asm is expected to write to the contents of the input
3016 memory location, instead of just read from it).
3017
3018 This is most typically used for memory constraint, e.g. "``=*m``", to pass the
3019 address of a variable as a value.
3020
3021 It is also possible to use an indirect *register* constraint, but only on output
3022 (e.g. "``=*r``"). This will cause LLVM to allocate a register for an output
3023 value normally, and then, separately emit a store to the address provided as
3024 input, after the provided inline asm. (It's not clear what value this
3025 functionality provides, compared to writing the store explicitly after the asm
3026 statement, and it can only produce worse code, since it bypasses many
3027 optimization passes. I would recommend not using it.)
3028
3029
3030 Clobber constraints
3031 """""""""""""""""""
3032
3033 A clobber constraint is indicated by a "``~``" prefix. A clobber does not
3034 consume an input operand, nor generate an output. Clobbers cannot use any of the
3035 general constraint code letters -- they may use only explicit register
3036 constraints, e.g. "``~{eax}``". The one exception is that a clobber string of
3037 "``~{memory}``" indicates that the assembly writes to arbitrary undeclared
3038 memory locations -- not only the memory pointed to by a declared indirect
3039 output.
3040
3041
3042 Constraint Codes
3043 """"""""""""""""
3044 After a potential prefix comes constraint code, or codes.
3045
3046 A Constraint Code is either a single letter (e.g. "``r``"), a "``^``" character
3047 followed by two letters (e.g. "``^wc``"), or "``{``" register-name "``}``"
3048 (e.g. "``{eax}``").
3049
3050 The one and two letter constraint codes are typically chosen to be the same as
3051 GCC's constraint codes.
3052
3053 A single constraint may include one or more than constraint code in it, leaving
3054 it up to LLVM to choose which one to use. This is included mainly for
3055 compatibility with the translation of GCC inline asm coming from clang.
3056
3057 There are two ways to specify alternatives, and either or both may be used in an
3058 inline asm constraint list:
3059
3060 1) Append the codes to each other, making a constraint code set. E.g. "``im``"
3061    or "``{eax}m``". This means "choose any of the options in the set". The
3062    choice of constraint is made independently for each constraint in the
3063    constraint list.
3064
3065 2) Use "``|``" between constraint code sets, creating alternatives. Every
3066    constraint in the constraint list must have the same number of alternative
3067    sets. With this syntax, the same alternative in *all* of the items in the
3068    constraint list will be chosen together.
3069
3070 Putting those together, you might have a two operand constraint string like
3071 ``"rm|r,ri|rm"``. This indicates that if operand 0 is ``r`` or ``m``, then
3072 operand 1 may be one of ``r`` or ``i``. If operand 0 is ``r``, then operand 1
3073 may be one of ``r`` or ``m``. But, operand 0 and 1 cannot both be of type m.
3074
3075 However, the use of either of the alternatives features is *NOT* recommended, as
3076 LLVM is not able to make an intelligent choice about which one to use. (At the
3077 point it currently needs to choose, not enough information is available to do so
3078 in a smart way.) Thus, it simply tries to make a choice that's most likely to
3079 compile, not one that will be optimal performance. (e.g., given "``rm``", it'll
3080 always choose to use memory, not registers). And, if given multiple registers,
3081 or multiple register classes, it will simply choose the first one. (In fact, it
3082 doesn't currently even ensure explicitly specified physical registers are
3083 unique, so specifying multiple physical registers as alternatives, like
3084 ``{r11}{r12},{r11}{r12}``, will assign r11 to both operands, not at all what was
3085 intended.)
3086
3087 Supported Constraint Code List
3088 """"""""""""""""""""""""""""""
3089
3090 The constraint codes are, in general, expected to behave the same way they do in
3091 GCC. LLVM's support is often implemented on an 'as-needed' basis, to support C
3092 inline asm code which was supported by GCC. A mismatch in behavior between LLVM
3093 and GCC likely indicates a bug in LLVM.
3094
3095 Some constraint codes are typically supported by all targets:
3096
3097 - ``r``: A register in the target's general purpose register class.
3098 - ``m``: A memory address operand. It is target-specific what addressing modes
3099   are supported, typical examples are register, or register + register offset,
3100   or register + immediate offset (of some target-specific size).
3101 - ``i``: An integer constant (of target-specific width). Allows either a simple
3102   immediate, or a relocatable value.
3103 - ``n``: An integer constant -- *not* including relocatable values.
3104 - ``s``: An integer constant, but allowing *only* relocatable values.
3105 - ``X``: Allows an operand of any kind, no constraint whatsoever. Typically
3106   useful to pass a label for an asm branch or call.
3107
3108   .. FIXME: but that surely isn't actually okay to jump out of an asm
3109      block without telling llvm about the control transfer???)
3110
3111 - ``{register-name}``: Requires exactly the named physical register.
3112
3113 Other constraints are target-specific:
3114
3115 AArch64:
3116
3117 - ``z``: An immediate integer 0. Outputs ``WZR`` or ``XZR``, as appropriate.
3118 - ``I``: An immediate integer valid for an ``ADD`` or ``SUB`` instruction,
3119   i.e. 0 to 4095 with optional shift by 12.
3120 - ``J``: An immediate integer that, when negated, is valid for an ``ADD`` or
3121   ``SUB`` instruction, i.e. -1 to -4095 with optional left shift by 12.
3122 - ``K``: An immediate integer that is valid for the 'bitmask immediate 32' of a
3123   logical instruction like ``AND``, ``EOR``, or ``ORR`` with a 32-bit register.
3124 - ``L``: An immediate integer that is valid for the 'bitmask immediate 64' of a
3125   logical instruction like ``AND``, ``EOR``, or ``ORR`` with a 64-bit register.
3126 - ``M``: An immediate integer for use with the ``MOV`` assembly alias on a
3127   32-bit register. This is a superset of ``K``: in addition to the bitmask
3128   immediate, also allows immediate integers which can be loaded with a single
3129   ``MOVZ`` or ``MOVL`` instruction.
3130 - ``N``: An immediate integer for use with the ``MOV`` assembly alias on a
3131   64-bit register. This is a superset of ``L``.
3132 - ``Q``: Memory address operand must be in a single register (no
3133   offsets). (However, LLVM currently does this for the ``m`` constraint as
3134   well.)
3135 - ``r``: A 32 or 64-bit integer register (W* or X*).
3136 - ``w``: A 32, 64, or 128-bit floating-point/SIMD register.
3137 - ``x``: A lower 128-bit floating-point/SIMD register (``V0`` to ``V15``).
3138
3139 AMDGPU:
3140
3141 - ``r``: A 32 or 64-bit integer register.
3142 - ``[0-9]v``: The 32-bit VGPR register, number 0-9.
3143 - ``[0-9]s``: The 32-bit SGPR register, number 0-9.
3144
3145
3146 All ARM modes:
3147
3148 - ``Q``, ``Um``, ``Un``, ``Uq``, ``Us``, ``Ut``, ``Uv``, ``Uy``: Memory address
3149   operand. Treated the same as operand ``m``, at the moment.
3150
3151 ARM and ARM's Thumb2 mode:
3152
3153 - ``j``: An immediate integer between 0 and 65535 (valid for ``MOVW``)
3154 - ``I``: An immediate integer valid for a data-processing instruction.
3155 - ``J``: An immediate integer between -4095 and 4095.
3156 - ``K``: An immediate integer whose bitwise inverse is valid for a
3157   data-processing instruction. (Can be used with template modifier "``B``" to
3158   print the inverted value).
3159 - ``L``: An immediate integer whose negation is valid for a data-processing
3160   instruction. (Can be used with template modifier "``n``" to print the negated
3161   value).
3162 - ``M``: A power of two or a integer between 0 and 32.
3163 - ``N``: Invalid immediate constraint.
3164 - ``O``: Invalid immediate constraint.
3165 - ``r``: A general-purpose 32-bit integer register (``r0-r15``).
3166 - ``l``: In Thumb2 mode, low 32-bit GPR registers (``r0-r7``). In ARM mode, same
3167   as ``r``.
3168 - ``h``: In Thumb2 mode, a high 32-bit GPR register (``r8-r15``). In ARM mode,
3169   invalid.
3170 - ``w``: A 32, 64, or 128-bit floating-point/SIMD register: ``s0-s31``,
3171   ``d0-d31``, or ``q0-q15``.
3172 - ``x``: A 32, 64, or 128-bit floating-point/SIMD register: ``s0-s15``,
3173   ``d0-d7``, or ``q0-q3``.
3174 - ``t``: A floating-point/SIMD register, only supports 32-bit values:
3175   ``s0-s31``.
3176
3177 ARM's Thumb1 mode:
3178
3179 - ``I``: An immediate integer between 0 and 255.
3180 - ``J``: An immediate integer between -255 and -1.
3181 - ``K``: An immediate integer between 0 and 255, with optional left-shift by
3182   some amount.
3183 - ``L``: An immediate integer between -7 and 7.
3184 - ``M``: An immediate integer which is a multiple of 4 between 0 and 1020.
3185 - ``N``: An immediate integer between 0 and 31.
3186 - ``O``: An immediate integer which is a multiple of 4 between -508 and 508.
3187 - ``r``: A low 32-bit GPR register (``r0-r7``).
3188 - ``l``: A low 32-bit GPR register (``r0-r7``).
3189 - ``h``: A high GPR register (``r0-r7``).
3190 - ``w``: A 32, 64, or 128-bit floating-point/SIMD register: ``s0-s31``,
3191   ``d0-d31``, or ``q0-q15``.
3192 - ``x``: A 32, 64, or 128-bit floating-point/SIMD register: ``s0-s15``,
3193   ``d0-d7``, or ``q0-q3``.
3194 - ``t``: A floating-point/SIMD register, only supports 32-bit values:
3195   ``s0-s31``.
3196
3197
3198 Hexagon:
3199
3200 - ``o``, ``v``: A memory address operand, treated the same as constraint ``m``,
3201   at the moment.
3202 - ``r``: A 32 or 64-bit register.
3203
3204 MSP430:
3205
3206 - ``r``: An 8 or 16-bit register.
3207
3208 MIPS:
3209
3210 - ``I``: An immediate signed 16-bit integer.
3211 - ``J``: An immediate integer zero.
3212 - ``K``: An immediate unsigned 16-bit integer.
3213 - ``L``: An immediate 32-bit integer, where the lower 16 bits are 0.
3214 - ``N``: An immediate integer between -65535 and -1.
3215 - ``O``: An immediate signed 15-bit integer.
3216 - ``P``: An immediate integer between 1 and 65535.
3217 - ``m``: A memory address operand. In MIPS-SE mode, allows a base address
3218   register plus 16-bit immediate offset. In MIPS mode, just a base register.
3219 - ``R``: A memory address operand. In MIPS-SE mode, allows a base address
3220   register plus a 9-bit signed offset. In MIPS mode, the same as constraint
3221   ``m``.
3222 - ``ZC``: A memory address operand, suitable for use in a ``pref``, ``ll``, or
3223   ``sc`` instruction on the given subtarget (details vary).
3224 - ``r``, ``d``,  ``y``: A 32 or 64-bit GPR register.
3225 - ``f``: A 32 or 64-bit FPU register (``F0-F31``), or a 128-bit MSA register
3226   (``W0-W31``). In the case of MSA registers, it is recommended to use the ``w``
3227   argument modifier for compatibility with GCC.
3228 - ``c``: A 32-bit or 64-bit GPR register suitable for indirect jump (always
3229   ``25``).
3230 - ``l``: The ``lo`` register, 32 or 64-bit.
3231 - ``x``: Invalid.
3232
3233 NVPTX:
3234
3235 - ``b``: A 1-bit integer register.
3236 - ``c`` or ``h``: A 16-bit integer register.
3237 - ``r``: A 32-bit integer register.
3238 - ``l`` or ``N``: A 64-bit integer register.
3239 - ``f``: A 32-bit float register.
3240 - ``d``: A 64-bit float register.
3241
3242
3243 PowerPC:
3244
3245 - ``I``: An immediate signed 16-bit integer.
3246 - ``J``: An immediate unsigned 16-bit integer, shifted left 16 bits.
3247 - ``K``: An immediate unsigned 16-bit integer.
3248 - ``L``: An immediate signed 16-bit integer, shifted left 16 bits.
3249 - ``M``: An immediate integer greater than 31.
3250 - ``N``: An immediate integer that is an exact power of 2.
3251 - ``O``: The immediate integer constant 0.
3252 - ``P``: An immediate integer constant whose negation is a signed 16-bit
3253   constant.
3254 - ``es``, ``o``, ``Q``, ``Z``, ``Zy``: A memory address operand, currently
3255   treated the same as ``m``.
3256 - ``r``: A 32 or 64-bit integer register.
3257 - ``b``: A 32 or 64-bit integer register, excluding ``R0`` (that is:
3258   ``R1-R31``).
3259 - ``f``: A 32 or 64-bit float register (``F0-F31``), or when QPX is enabled, a
3260   128 or 256-bit QPX register (``Q0-Q31``; aliases the ``F`` registers).
3261 - ``v``: For ``4 x f32`` or ``4 x f64`` types, when QPX is enabled, a
3262   128 or 256-bit QPX register (``Q0-Q31``), otherwise a 128-bit
3263   altivec vector register (``V0-V31``).
3264
3265   .. FIXME: is this a bug that v accepts QPX registers? I think this
3266      is supposed to only use the altivec vector registers?
3267
3268 - ``y``: Condition register (``CR0-CR7``).
3269 - ``wc``: An individual CR bit in a CR register.
3270 - ``wa``, ``wd``, ``wf``: Any 128-bit VSX vector register, from the full VSX
3271   register set (overlapping both the floating-point and vector register files).
3272 - ``ws``: A 32 or 64-bit floating point register, from the full VSX register
3273   set.
3274
3275 Sparc:
3276
3277 - ``I``: An immediate 13-bit signed integer.
3278 - ``r``: A 32-bit integer register.
3279
3280 SystemZ:
3281
3282 - ``I``: An immediate unsigned 8-bit integer.
3283 - ``J``: An immediate unsigned 12-bit integer.
3284 - ``K``: An immediate signed 16-bit integer.
3285 - ``L``: An immediate signed 20-bit integer.
3286 - ``M``: An immediate integer 0x7fffffff.
3287 - ``Q``, ``R``, ``S``, ``T``: A memory address operand, treated the same as
3288   ``m``, at the moment.
3289 - ``r`` or ``d``: A 32, 64, or 128-bit integer register.
3290 - ``a``: A 32, 64, or 128-bit integer address register (excludes R0, which in an
3291   address context evaluates as zero).
3292 - ``h``: A 32-bit value in the high part of a 64bit data register
3293   (LLVM-specific)
3294 - ``f``: A 32, 64, or 128-bit floating point register.
3295
3296 X86:
3297
3298 - ``I``: An immediate integer between 0 and 31.
3299 - ``J``: An immediate integer between 0 and 64.
3300 - ``K``: An immediate signed 8-bit integer.
3301 - ``L``: An immediate integer, 0xff or 0xffff or (in 64-bit mode only)
3302   0xffffffff.
3303 - ``M``: An immediate integer between 0 and 3.
3304 - ``N``: An immediate unsigned 8-bit integer.
3305 - ``O``: An immediate integer between 0 and 127.
3306 - ``e``: An immediate 32-bit signed integer.
3307 - ``Z``: An immediate 32-bit unsigned integer.
3308 - ``o``, ``v``: Treated the same as ``m``, at the moment.
3309 - ``q``: An 8, 16, 32, or 64-bit register which can be accessed as an 8-bit
3310   ``l`` integer register. On X86-32, this is the ``a``, ``b``, ``c``, and ``d``
3311   registers, and on X86-64, it is all of the integer registers.
3312 - ``Q``: An 8, 16, 32, or 64-bit register which can be accessed as an 8-bit
3313   ``h`` integer register. This is the ``a``, ``b``, ``c``, and ``d`` registers.
3314 - ``r`` or ``l``: An 8, 16, 32, or 64-bit integer register.
3315 - ``R``: An 8, 16, 32, or 64-bit "legacy" integer register -- one which has
3316   existed since i386, and can be accessed without the REX prefix.
3317 - ``f``: A 32, 64, or 80-bit '387 FPU stack pseudo-register.
3318 - ``y``: A 64-bit MMX register, if MMX is enabled.
3319 - ``x``: If SSE is enabled: a 32 or 64-bit scalar operand, or 128-bit vector
3320   operand in a SSE register. If AVX is also enabled, can also be a 256-bit
3321   vector operand in an AVX register. If AVX-512 is also enabled, can also be a
3322   512-bit vector operand in an AVX512 register, Otherwise, an error.
3323 - ``Y``: The same as ``x``, if *SSE2* is enabled, otherwise an error.
3324 - ``A``: Special case: allocates EAX first, then EDX, for a single operand (in
3325   32-bit mode, a 64-bit integer operand will get split into two registers). It
3326   is not recommended to use this constraint, as in 64-bit mode, the 64-bit
3327   operand will get allocated only to RAX -- if two 32-bit operands are needed,
3328   you're better off splitting it yourself, before passing it to the asm
3329   statement.
3330
3331 XCore:
3332
3333 - ``r``: A 32-bit integer register.
3334
3335
3336 .. _inline-asm-modifiers:
3337
3338 Asm template argument modifiers
3339 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
3340
3341 In the asm template string, modifiers can be used on the operand reference, like
3342 "``${0:n}``".
3343
3344 The modifiers are, in general, expected to behave the same way they do in
3345 GCC. LLVM's support is often implemented on an 'as-needed' basis, to support C
3346 inline asm code which was supported by GCC. A mismatch in behavior between LLVM
3347 and GCC likely indicates a bug in LLVM.
3348
3349 Target-independent:
3350
3351 - ``c``: Print an immediate integer constant unadorned, without
3352   the target-specific immediate punctuation (e.g. no ``$`` prefix).
3353 - ``n``: Negate and print immediate integer constant unadorned, without the
3354   target-specific immediate punctuation (e.g. no ``$`` prefix).
3355 - ``l``: Print as an unadorned label, without the target-specific label
3356   punctuation (e.g. no ``$`` prefix).
3357
3358 AArch64:
3359
3360 - ``w``: Print a GPR register with a ``w*`` name instead of ``x*`` name. E.g.,
3361   instead of ``x30``, print ``w30``.
3362 - ``x``: Print a GPR register with a ``x*`` name. (this is the default, anyhow).
3363 - ``b``, ``h``, ``s``, ``d``, ``q``: Print a floating-point/SIMD register with a
3364   ``b*``, ``h*``, ``s*``, ``d*``, or ``q*`` name, rather than the default of
3365   ``v*``.
3366
3367 AMDGPU:
3368
3369 - ``r``: No effect.
3370
3371 ARM:
3372
3373 - ``a``: Print an operand as an address (with ``[`` and ``]`` surrounding a
3374   register).
3375 - ``P``: No effect.
3376 - ``q``: No effect.
3377 - ``y``: Print a VFP single-precision register as an indexed double (e.g. print
3378   as ``d4[1]`` instead of ``s9``)
3379 - ``B``: Bitwise invert and print an immediate integer constant without ``#``
3380   prefix.
3381 - ``L``: Print the low 16-bits of an immediate integer constant.
3382 - ``M``: Print as a register set suitable for ldm/stm. Also prints *all*
3383   register operands subsequent to the specified one (!), so use carefully.
3384 - ``Q``: Print the low-order register of a register-pair, or the low-order
3385   register of a two-register operand.
3386 - ``R``: Print the high-order register of a register-pair, or the high-order
3387   register of a two-register operand.
3388 - ``H``: Print the second register of a register-pair. (On a big-endian system,
3389   ``H`` is equivalent to ``Q``, and on little-endian system, ``H`` is equivalent
3390   to ``R``.)
3391
3392   .. FIXME: H doesn't currently support printing the second register
3393      of a two-register operand.
3394
3395 - ``e``: Print the low doubleword register of a NEON quad register.
3396 - ``f``: Print the high doubleword register of a NEON quad register.
3397 - ``m``: Print the base register of a memory operand without the ``[`` and ``]``
3398   adornment.
3399
3400 Hexagon:
3401
3402 - ``L``: Print the second register of a two-register operand. Requires that it
3403   has been allocated consecutively to the first.
3404
3405   .. FIXME: why is it restricted to consecutive ones? And there's
3406      nothing that ensures that happens, is there?
3407
3408 - ``I``: Print the letter 'i' if the operand is an integer constant, otherwise
3409   nothing. Used to print 'addi' vs 'add' instructions.
3410
3411 MSP430:
3412
3413 No additional modifiers.
3414
3415 MIPS:
3416
3417 - ``X``: Print an immediate integer as hexadecimal
3418 - ``x``: Print the low 16 bits of an immediate integer as hexadecimal.
3419 - ``d``: Print an immediate integer as decimal.
3420 - ``m``: Subtract one and print an immediate integer as decimal.
3421 - ``z``: Print $0 if an immediate zero, otherwise print normally.
3422 - ``L``: Print the low-order register of a two-register operand, or prints the
3423   address of the low-order word of a double-word memory operand.
3424
3425   .. FIXME: L seems to be missing memory operand support.
3426
3427 - ``M``: Print the high-order register of a two-register operand, or prints the
3428   address of the high-order word of a double-word memory operand.
3429
3430   .. FIXME: M seems to be missing memory operand support.
3431
3432 - ``D``: Print the second register of a two-register operand, or prints the
3433   second word of a double-word memory operand. (On a big-endian system, ``D`` is
3434   equivalent to ``L``, and on little-endian system, ``D`` is equivalent to
3435   ``M``.)
3436 - ``w``: No effect. Provided for compatibility with GCC which requires this
3437   modifier in order to print MSA registers (``W0-W31``) with the ``f``
3438   constraint.
3439
3440 NVPTX:
3441
3442 - ``r``: No effect.
3443
3444 PowerPC:
3445
3446 - ``L``: Print the second register of a two-register operand. Requires that it
3447   has been allocated consecutively to the first.
3448
3449   .. FIXME: why is it restricted to consecutive ones? And there's
3450      nothing that ensures that happens, is there?
3451
3452 - ``I``: Print the letter 'i' if the operand is an integer constant, otherwise
3453   nothing. Used to print 'addi' vs 'add' instructions.
3454 - ``y``: For a memory operand, prints formatter for a two-register X-form
3455   instruction. (Currently always prints ``r0,OPERAND``).
3456 - ``U``: Prints 'u' if the memory operand is an update form, and nothing
3457   otherwise. (NOTE: LLVM does not support update form, so this will currently
3458   always print nothing)
3459 - ``X``: Prints 'x' if the memory operand is an indexed form. (NOTE: LLVM does
3460   not support indexed form, so this will currently always print nothing)
3461
3462 Sparc:
3463
3464 - ``r``: No effect.
3465
3466 SystemZ:
3467
3468 SystemZ implements only ``n``, and does *not* support any of the other
3469 target-independent modifiers.
3470
3471 X86:
3472
3473 - ``c``: Print an unadorned integer or symbol name. (The latter is
3474   target-specific behavior for this typically target-independent modifier).
3475 - ``A``: Print a register name with a '``*``' before it.
3476 - ``b``: Print an 8-bit register name (e.g. ``al``); do nothing on a memory
3477   operand.
3478 - ``h``: Print the upper 8-bit register name (e.g. ``ah``); do nothing on a
3479   memory operand.
3480 - ``w``: Print the 16-bit register name (e.g. ``ax``); do nothing on a memory
3481   operand.
3482 - ``k``: Print the 32-bit register name (e.g. ``eax``); do nothing on a memory
3483   operand.
3484 - ``q``: Print the 64-bit register name (e.g. ``rax``), if 64-bit registers are
3485   available, otherwise the 32-bit register name; do nothing on a memory operand.
3486 - ``n``: Negate and print an unadorned integer, or, for operands other than an
3487   immediate integer (e.g. a relocatable symbol expression), print a '-' before
3488   the operand. (The behavior for relocatable symbol expressions is a
3489   target-specific behavior for this typically target-independent modifier)
3490 - ``H``: Print a memory reference with additional offset +8.
3491 - ``P``: Print a memory reference or operand for use as the argument of a call
3492   instruction. (E.g. omit ``(rip)``, even though it's PC-relative.)
3493
3494 XCore:
3495
3496 No additional modifiers.
3497
3498
3499 Inline Asm Metadata
3500 ^^^^^^^^^^^^^^^^^^^
3501
3502 The call instructions that wrap inline asm nodes may have a
3503 "``!srcloc``" MDNode attached to it that contains a list of constant
3504 integers. If present, the code generator will use the integer as the
3505 location cookie value when report errors through the ``LLVMContext``
3506 error reporting mechanisms. This allows a front-end to correlate backend
3507 errors that occur with inline asm back to the source code that produced
3508 it. For example:
3509
3510 .. code-block:: llvm
3511
3512     call void asm sideeffect "something bad", ""(), !srcloc !42
3513     ...
3514     !42 = !{ i32 1234567 }
3515
3516 It is up to the front-end to make sense of the magic numbers it places
3517 in the IR. If the MDNode contains multiple constants, the code generator
3518 will use the one that corresponds to the line of the asm that the error
3519 occurs on.
3520
3521 .. _metadata:
3522
3523 Metadata
3524 ========
3525
3526 LLVM IR allows metadata to be attached to instructions in the program
3527 that can convey extra information about the code to the optimizers and
3528 code generator. One example application of metadata is source-level
3529 debug information. There are two metadata primitives: strings and nodes.
3530
3531 Metadata does not have a type, and is not a value. If referenced from a
3532 ``call`` instruction, it uses the ``metadata`` type.
3533
3534 All metadata are identified in syntax by a exclamation point ('``!``').
3535
3536 .. _metadata-string:
3537
3538 Metadata Nodes and Metadata Strings
3539 -----------------------------------
3540
3541 A metadata string is a string surrounded by double quotes. It can
3542 contain any character by escaping non-printable characters with
3543 "``\xx``" where "``xx``" is the two digit hex code. For example:
3544 "``!"test\00"``".
3545
3546 Metadata nodes are represented with notation similar to structure
3547 constants (a comma separated list of elements, surrounded by braces and
3548 preceded by an exclamation point). Metadata nodes can have any values as
3549 their operand. For example:
3550
3551 .. code-block:: llvm
3552
3553     !{ !"test\00", i32 10}
3554
3555 Metadata nodes that aren't uniqued use the ``distinct`` keyword. For example:
3556
3557 .. code-block:: llvm
3558
3559     !0 = distinct !{!"test\00", i32 10}
3560
3561 ``distinct`` nodes are useful when nodes shouldn't be merged based on their
3562 content. They can also occur when transformations cause uniquing collisions
3563 when metadata operands change.
3564
3565 A :ref:`named metadata <namedmetadatastructure>` is a collection of
3566 metadata nodes, which can be looked up in the module symbol table. For
3567 example:
3568
3569 .. code-block:: llvm
3570
3571     !foo = !{!4, !3}
3572
3573 Metadata can be used as function arguments. Here ``llvm.dbg.value``
3574 function is using two metadata arguments:
3575
3576 .. code-block:: llvm
3577
3578     call void @llvm.dbg.value(metadata !24, i64 0, metadata !25)
3579
3580 Metadata can be attached with an instruction. Here metadata ``!21`` is
3581 attached to the ``add`` instruction using the ``!dbg`` identifier:
3582
3583 .. code-block:: llvm
3584
3585     %indvar.next = add i64 %indvar, 1, !dbg !21
3586
3587 More information about specific metadata nodes recognized by the
3588 optimizers and code generator is found below.
3589
3590 .. _specialized-metadata:
3591
3592 Specialized Metadata Nodes
3593 ^^^^^^^^^^^^^^^^^^^^^^^^^^
3594
3595 Specialized metadata nodes are custom data structures in metadata (as opposed
3596 to generic tuples). Their fields are labelled, and can be specified in any
3597 order.
3598
3599 These aren't inherently debug info centric, but currently all the specialized
3600 metadata nodes are related to debug info.
3601
3602 .. _DICompileUnit:
3603
3604 DICompileUnit
3605 """""""""""""
3606
3607 ``DICompileUnit`` nodes represent a compile unit. The ``enums:``,
3608 ``retainedTypes:``, ``subprograms:``, ``globals:`` and ``imports:`` fields are
3609 tuples containing the debug info to be emitted along with the compile unit,