cmake/modules/TableGen.cmake

   1 # LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
   2 # Extra parameters for `tblgen' may come after `ofn' parameter.
   3 # Adds the name of the generated file to TABLEGEN_OUTPUT.
   4
   5 macro(tablegen project ofn)
   6   file(GLOB local_tds "*.td")
   7   file(GLOB_RECURSE global_tds "${LLVM_MAIN_SRC_DIR}/include/llvm/*.td")
   8
   9   if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  10     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  11   else()
  12     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
  13       ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
  14   endif()
  15   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  16     # Generate tablegen output in a temporary file.
  17     COMMAND ${${project}_TABLEGEN_EXE} ${ARGN} -I ${CMAKE_CURRENT_SOURCE_DIR}
  18     -I ${LLVM_MAIN_SRC_DIR}/lib/Target -I ${LLVM_MAIN_INCLUDE_DIR}
  19     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  20     -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  21     # The file in LLVM_TARGET_DEFINITIONS may be not in the current
  22     # directory and local_tds may not contain it, so we must
  23     # explicitly list it here:
  24     DEPENDS ${${project}_TABLEGEN_EXE} ${local_tds} ${global_tds}
  25     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  26     COMMENT "Building ${ofn}..."
  27     )
  28   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  29     # Only update the real output file if there are any differences.
  30     # This prevents recompilation of all the files depending on it if there
  31     # aren't any.
  32     COMMAND ${CMAKE_COMMAND} -E copy_if_different
  33         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  34         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  35     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  36     COMMENT ""
  37     )
  38
  39   # `make clean' must remove all those generated files:
  40   set_property(DIRECTORY APPEND
  41     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${ofn}.tmp ${ofn})
  42
  43   set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn})
  44   set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  45     PROPERTIES GENERATED 1)
  46 endmacro(tablegen)
  47
  48 function(add_public_tablegen_target target)
  49   # Creates a target for publicly exporting tablegen dependencies.
  50   if( TABLEGEN_OUTPUT )
  51     add_custom_target(${target}
  52       DEPENDS ${TABLEGEN_OUTPUT})
  53     add_dependencies(${target} ${LLVM_COMMON_DEPENDS})
  54   endif( TABLEGEN_OUTPUT )
  55 endfunction()
  56
  57 if(CMAKE_CROSSCOMPILING)
  58   set(CX_NATIVE_TG_DIR "${CMAKE_BINARY_DIR}/native")
  59
  60   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}
  61     COMMAND ${CMAKE_COMMAND} -E make_directory ${CX_NATIVE_TG_DIR}
  62     COMMENT "Creating ${CX_NATIVE_TG_DIR}...")
  63
  64   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}/CMakeCache.txt
  65     COMMAND ${CMAKE_COMMAND} -UMAKE_TOOLCHAIN_FILE -DCMAKE_BUILD_TYPE=Release
  66                              -DLLVM_BUILD_POLLY=OFF ${CMAKE_SOURCE_DIR}
  67     WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
  68     DEPENDS ${CX_NATIVE_TG_DIR}
  69     COMMENT "Configuring native TableGen...")
  70
  71   add_custom_target(ConfigureNativeTableGen DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt)
  72
  73   set_directory_properties(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES ${CX_NATIVE_TG_DIR})
  74 endif()
  75
  76 macro(add_tablegen target project)
  77   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
  78
  79   set(${target}_OLD_LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS})
  80   set(LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS} TableGen)
  81   add_llvm_utility(${target} ${ARGN})
  82   set(LLVM_LINK_COMPONENTS ${${target}_OLD_LLVM_LINK_COMPONENTS})
  83
  84   set(${project}_TABLEGEN "${target}" CACHE
  85       STRING "Native TableGen executable. Saves building one when cross-compiling.")
  86
  87   # Upgrade existing LLVM_TABLEGEN setting.
  88   if(${project} STREQUAL LLVM)
  89     if(${LLVM_TABLEGEN} STREQUAL tblgen)
  90       set(LLVM_TABLEGEN "${target}" CACHE
  91           STRING "Native TableGen executable. Saves building one when cross-compiling."
  92           FORCE)
  93     endif()
  94   endif()
  95
  96   # Effective tblgen executable to be used:
  97   set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN} PARENT_SCOPE)
  98
  99   if(CMAKE_CROSSCOMPILING)
 100     if( ${${project}_TABLEGEN} STREQUAL "${target}" )
 101       set(${project}_TABLEGEN_EXE "${CX_NATIVE_TG_DIR}/bin/${target}")
 102       set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN_EXE} PARENT_SCOPE)
 103
 104       add_custom_command(OUTPUT ${${project}_TABLEGEN_EXE}
 105         COMMAND ${CMAKE_BUILD_TOOL} ${target}
 106         DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt
 107         WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
 108         COMMENT "Building native TableGen...")
 109       add_custom_target(${project}NativeTableGen DEPENDS ${${project}_TABLEGEN_EXE})
 110       add_dependencies(${project}NativeTableGen ConfigureNativeTableGen)
 111
 112       add_dependencies(${target} ${project}NativeTableGen)
 113     endif()
 114   endif()
 115
 116   if( MINGW )
 117     target_link_libraries(${target} imagehlp psapi)
 118     if(CMAKE_SIZEOF_VOID_P MATCHES "8")
 119       set_target_properties(${target} PROPERTIES LINK_FLAGS -Wl,--stack,16777216)
 120     endif(CMAKE_SIZEOF_VOID_P MATCHES "8")
 121   endif( MINGW )
 122   if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD AND NOT BEOS )
 123     target_link_libraries(${target} pthread)
 124   endif()
 125
 126   install(TARGETS ${target} RUNTIME DESTINATION bin)
 127 endmacro()