cmake/modules/LLVMProcessSources.cmake

   1 include(AddFileDependencies)
   2
   3
   4 macro(add_td_sources srcs)
   5   file(GLOB tds *.td)
   6   if( tds )
   7     source_group("TableGen descriptions" FILES ${tds})
   8     set_source_files_properties(${tds} PROPERTIES HEADER_FILE_ONLY ON)
   9     list(APPEND ${srcs} ${tds})
  10   endif()
  11 endmacro(add_td_sources)
  12
  13
  14 macro(add_header_files srcs)
  15   file(GLOB hds *.h)
  16   if( hds )
  17     set_source_files_properties(${hds} PROPERTIES HEADER_FILE_ONLY ON)
  18     list(APPEND ${srcs} ${hds})
  19   endif()
  20 endmacro(add_header_files)
  21
  22
  23 function(llvm_process_sources OUT_VAR)
  24   set( sources ${ARGN} )
  25   llvm_check_source_file_list( ${sources} )
  26   # Create file dependencies on the tablegenned files, if any.  Seems
  27   # that this is not strictly needed, as dependencies of the .cpp
  28   # sources on the tablegenned .inc files are detected and handled,
  29   # but just in case...
  30   foreach( s ${sources} )
  31     set( f ${CMAKE_CURRENT_SOURCE_DIR}/${s} )
  32     add_file_dependencies( ${f} ${TABLEGEN_OUTPUT} )
  33   endforeach(s)
  34   if( MSVC_IDE )
  35     # This adds .td and .h files to the Visual Studio solution:
  36     add_td_sources(sources)
  37     add_header_files(sources)
  38   endif()
  39   set( ${OUT_VAR} ${sources} PARENT_SCOPE )
  40 endfunction(llvm_process_sources)
  41
  42
  43 function(llvm_check_source_file_list)
  44   set(listed ${ARGN})
  45   file(GLOB globbed *.cpp)
  46   foreach(g ${globbed})
  47     get_filename_component(fn ${g} NAME)
  48     list(FIND listed ${fn} idx)
  49     if( idx LESS 0 )
  50       message(SEND_ERROR "Found unknown source file ${g}
  51 Please update ${CMAKE_CURRENT_SOURCE_DIR}/CMakeLists.txt\n")
  52     endif()
  53   endforeach()
  54 endfunction(llvm_check_source_file_list)