cmake/modules/LLVMExternalProjectUtils.cmake

   1 include(ExternalProject)
   2
   3 # llvm_ExternalProject_BuildCmd(out_var target)
   4 #   Utility function for constructing command lines for external project targets
   5 function(llvm_ExternalProject_BuildCmd out_var target)
   6   if (CMAKE_GENERATOR MATCHES "Make")
   7     # Use special command for Makefiles to support parallelism.
   8     set(${out_var} "$(MAKE)" "${target}" PARENT_SCOPE)
   9   else()
  10     set(${out_var} ${CMAKE_COMMAND} --build . --target ${target}
  11                                     --config $<CONFIGURATION> PARENT_SCOPE)
  12   endif()
  13 endfunction()
  14
  15 # llvm_ExternalProject_Add(name source_dir ...
  16 #   USE_TOOLCHAIN
  17 #     Use just-built tools (see TOOLCHAIN_TOOLS)
  18 #   EXCLUDE_FROM_ALL
  19 #     Exclude this project from the all target
  20 #   NO_INSTALL
  21 #     Don't generate install targets for this project
  22 #   CMAKE_ARGS arguments...
  23 #     Optional cmake arguments to pass when configuring the project
  24 #   TOOLCHAIN_TOOLS targets...
  25 #     Targets for toolchain tools (defaults to clang;lld)
  26 #   DEPENDS targets...
  27 #     Targets that this project depends on
  28 #   EXTRA_TARGETS targets...
  29 #     Extra targets in the subproject to generate targets for
  30 #   )
  31 function(llvm_ExternalProject_Add name source_dir)
  32   cmake_parse_arguments(ARG "USE_TOOLCHAIN;EXCLUDE_FROM_ALL;NO_INSTALL"
  33     "SOURCE_DIR"
  34     "CMAKE_ARGS;TOOLCHAIN_TOOLS;RUNTIME_LIBRARIES;DEPENDS;EXTRA_TARGETS" ${ARGN})
  35   canonicalize_tool_name(${name} nameCanon)
  36   if(NOT ARG_TOOLCHAIN_TOOLS)
  37     set(ARG_TOOLCHAIN_TOOLS clang lld)
  38   endif()
  39   foreach(tool ${ARG_TOOLCHAIN_TOOLS})
  40     if(TARGET ${tool})
  41       list(APPEND TOOLCHAIN_TOOLS ${tool})
  42       list(APPEND TOOLCHAIN_BINS $<TARGET_FILE:${tool}>)
  43     endif()
  44   endforeach()
  45
  46   if(NOT ARG_RUNTIME_LIBRARIES)
  47     set(ARG_RUNTIME_LIBRARIES compiler-rt libcxx)
  48   endif()
  49   foreach(lib ${ARG_RUNTIME_LIBRARIES})
  50     if(TARGET ${lib})
  51       list(APPEND RUNTIME_LIBRARIES ${lib})
  52     endif()
  53   endforeach()
  54
  55   list(FIND TOOLCHAIN_TOOLS clang FOUND_CLANG)
  56   if(FOUND_CLANG GREATER -1)
  57     set(CLANG_IN_TOOLCHAIN On)
  58   endif()
  59
  60   if(RUNTIME_LIBRARIES AND CLANG_IN_TOOLCHAIN)
  61     list(APPEND TOOLCHAIN_BINS ${RUNTIME_LIBRARIES})
  62   endif()
  63
  64   if(CMAKE_VERSION VERSION_GREATER 3.1.0)
  65     set(cmake_3_1_EXCLUDE_FROM_ALL EXCLUDE_FROM_ALL 1)
  66   endif()
  67
  68   if(CMAKE_VERSION VERSION_GREATER 3.3.20150708)
  69     set(cmake_3_4_USES_TERMINAL_OPTIONS
  70       USES_TERMINAL_CONFIGURE 1
  71       USES_TERMINAL_BUILD 1
  72       USES_TERMINAL_INSTALL 1
  73       )
  74     set(cmake_3_4_USES_TERMINAL USES_TERMINAL 1)
  75   endif()
  76
  77   if(CMAKE_VERSION VERSION_GREATER 3.1.20141116)
  78     set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  79   endif()
  80
  81   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/${name}-stamps/)
  82   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/${name}-bins/)
  83
  84   add_custom_target(${name}-clear
  85     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
  86     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
  87     COMMENT "Clobbering ${name} build and stamp directories"
  88     ${cmake_3_2_USES_TERMINAL}
  89     )
  90
  91   # Find all variables that start with COMPILER_RT and populate a variable with
  92   # them.
  93   get_cmake_property(variableNames VARIABLES)
  94   foreach(varaibleName ${variableNames})
  95     if(${varaibleName} MATCHES "^${nameCanon}")
  96       list(APPEND PASSTHROUGH_VARIABLES
  97         -D${varaibleName}=${${varaibleName}})
  98     endif()
  99   endforeach()
 100
 101   if(ARG_USE_TOOLCHAIN)
 102     if(CLANG_IN_TOOLCHAIN)
 103       set(compiler_args -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang
 104                         -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++)
 105     endif()
 106     list(APPEND ARG_DEPENDS ${TOOLCHAIN_TOOLS})
 107   endif()
 108
 109   add_custom_command(
 110     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${name}-clobber-stamp
 111     DEPENDS ${ARG_DEPENDS}
 112     COMMAND ${CMAKE_COMMAND} -E touch ${BINARY_DIR}/CMakeCache.txt
 113     COMMAND ${CMAKE_COMMAND} -E touch ${STAMP_DIR}/${name}-mkdir
 114     COMMAND ${CMAKE_COMMAND} -E touch ${CMAKE_CURRENT_BINARY_DIR}/${name}-clobber-stamp
 115     COMMENT "Clobbering bootstrap build and stamp directories"
 116     )
 117
 118   add_custom_target(${name}-clobber
 119     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${name}-clobber-stamp)
 120
 121   if(ARG_EXCLUDE_FROM_ALL)
 122     set(exclude ${cmake_3_1_EXCLUDE_FROM_ALL})
 123   endif()
 124
 125   ExternalProject_Add(${name}
 126     DEPENDS ${ARG_DEPENDS}
 127     ${name}-clobber
 128     PREFIX ${CMAKE_BINARY_DIR}/projects/${name}
 129     SOURCE_DIR ${source_dir}
 130     STAMP_DIR ${STAMP_DIR}
 131     BINARY_DIR ${BINARY_DIR}
 132     ${exclude}
 133     CMAKE_ARGS ${${nameCanon}_CMAKE_ARGS}
 134                ${compiler_args}
 135                -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
 136                ${ARG_CMAKE_ARGS}
 137                ${PASSTHROUGH_VARIABLES}
 138     INSTALL_COMMAND ""
 139     STEP_TARGETS configure build
 140     ${cmake_3_4_USES_TERMINAL_OPTIONS}
 141     )
 142
 143   if(ARG_USE_TOOLCHAIN)
 144     ExternalProject_Add_Step(${name} force-rebuild
 145       COMMENT "Forcing rebuild becaues tools have changed"
 146       DEPENDERS configure
 147       DEPENDS ${TOOLCHAIN_BINS}
 148       ${cmake_3_4_USES_TERMINAL} )
 149   endif()
 150
 151   if(ARG_USE_TOOLCHAIN)
 152     set(force_deps DEPENDS ${TOOLCHAIN_BINS})
 153   endif()
 154
 155   llvm_ExternalProject_BuildCmd(run_clean clean)
 156   ExternalProject_Add_Step(${name} clean
 157     COMMAND ${run_clean}
 158     COMMENT "Cleaning ${name}..."
 159     DEPENDEES configure
 160     ${force_deps}
 161     WORKING_DIRECTORY ${BINARY_DIR}
 162     ${cmake_3_4_USES_TERMINAL}
 163     )
 164   ExternalProject_Add_StepTargets(${name} clean)
 165
 166   if(ARG_USE_TOOLCHAIN)
 167     add_dependencies(${name}-clean ${name}-clobber)
 168     set_target_properties(${name}-clean PROPERTIES
 169       SOURCES ${CMAKE_CURRENT_BINARY_DIR}/${name}-clobber-stamp)
 170   endif()
 171
 172   if(NOT ARG_NO_INSTALL)
 173     install(CODE "execute_process\(COMMAND \${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=\${CMAKE_INSTALL_PREFIX} -P ${BINARY_DIR}/cmake_install.cmake \)"
 174       COMPONENT ${name})
 175
 176     add_custom_target(install-${name}
 177                       DEPENDS ${name}
 178                       COMMAND "${CMAKE_COMMAND}"
 179                                -DCMAKE_INSTALL_COMPONENT=${name}
 180                                -P "${CMAKE_BINARY_DIR}/cmake_install.cmake"
 181                       ${cmake_3_2_USES_TERMINAL})
 182   endif()
 183
 184   # Add top-level targets
 185   foreach(target ${ARG_EXTRA_TARGETS})
 186     llvm_ExternalProject_BuildCmd(build_runtime_cmd ${target})
 187     add_custom_target(${target}
 188       COMMAND ${build_runtime_cmd}
 189       DEPENDS ${name}-configure
 190       WORKING_DIRECTORY ${BINARY_DIR}
 191       VERBATIM
 192       ${cmake_3_2_USES_TERMINAL})
 193   endforeach()
 194 endfunction()