cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(HandleLLVMStdlib)
  10 include(AddLLVMDefinitions)
  11 include(CheckCCompilerFlag)
  12 include(CheckCXXCompilerFlag)
  13
  14 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
  15   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  16     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
  17       message(FATAL_ERROR "Host GCC version must be at least 4.7!")
  18     endif()
  19   elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  20     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
  21       message(FATAL_ERROR "Host Clang version must be at least 3.1!")
  22     endif()
  23
  24     if (CMAKE_CXX_SIMULATE_ID MATCHES "MSVC")
  25       if (CMAKE_CXX_SIMULATE_VERSION VERSION_LESS 18.0)
  26         message(FATAL_ERROR "Host Clang must have at least -fms-compatibility-version=18.0")
  27       endif()
  28       set(CLANG_CL 1)
  29     elseif(NOT LLVM_ENABLE_LIBCXX)
  30       # Otherwise, test that we aren't using too old of a version of libstdc++
  31       # with the Clang compiler. This is tricky as there is no real way to
  32       # check the version of libstdc++ directly. Instead we test for a known
  33       # bug in libstdc++4.6 that is fixed in libstdc++4.7.
  34       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  35       set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  36       set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
  37       check_cxx_source_compiles("
  38 #include <atomic>
  39 std::atomic<float> x(0.0f);
  40 int main() { return (float)x; }"
  41         LLVM_NO_OLD_LIBSTDCXX)
  42       if(NOT LLVM_NO_OLD_LIBSTDCXX)
  43         message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
  44       endif()
  45       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
  46       set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
  47     endif()
  48   elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  49     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 18.0)
  50       message(FATAL_ERROR "Host Visual Studio must be at least 2013")
  51     elseif(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 18.0.31101)
  52       message(WARNING "Host Visual Studio should at least be 2013 Update 4 (MSVC 18.0.31101)"
  53         "  due to miscompiles from earlier versions")
  54     endif()
  55   endif()
  56 endif()
  57
  58 if( LLVM_ENABLE_ASSERTIONS )
  59   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  60   if( NOT MSVC )
  61     add_definitions( -D_DEBUG )
  62   endif()
  63   # On non-Debug builds cmake automatically defines NDEBUG, so we
  64   # explicitly undefine it:
  65   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  66     add_definitions( -UNDEBUG )
  67     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  68     foreach (flags_var_to_scrub
  69         CMAKE_CXX_FLAGS_RELEASE
  70         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  71         CMAKE_CXX_FLAGS_MINSIZEREL
  72         CMAKE_C_FLAGS_RELEASE
  73         CMAKE_C_FLAGS_RELWITHDEBINFO
  74         CMAKE_C_FLAGS_MINSIZEREL)
  75       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  76         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  77     endforeach()
  78   endif()
  79 endif()
  80
  81 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
  82
  83 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
  84   if( LLVM_ENABLE_ASSERTIONS )
  85     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  86   endif()
  87 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
  88   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  89 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
  90   # We don't need to do anything special to turn off ABI breaking checks.
  91 elseif( NOT DEFINED LLVM_ABI_BREAKING_CHECKS )
  92   # Treat LLVM_ABI_BREAKING_CHECKS like "FORCE_OFF" when it has not been
  93   # defined.
  94 else()
  95   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
  96 endif()
  97
  98 if(WIN32)
  99   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 100   if(CYGWIN)
 101     set(LLVM_ON_WIN32 0)
 102     set(LLVM_ON_UNIX 1)
 103   else(CYGWIN)
 104     set(LLVM_ON_WIN32 1)
 105     set(LLVM_ON_UNIX 0)
 106   endif(CYGWIN)
 107 else(WIN32)
 108   if(UNIX)
 109     set(LLVM_ON_WIN32 0)
 110     set(LLVM_ON_UNIX 1)
 111     if(APPLE)
 112       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 113     else(APPLE)
 114       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
 115     endif(APPLE)
 116   else(UNIX)
 117     MESSAGE(SEND_ERROR "Unable to determine platform")
 118   endif(UNIX)
 119 endif(WIN32)
 120
 121 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 122 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 123
 124 # We use *.dylib rather than *.so on darwin.
 125 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 126
 127 if(APPLE)
 128   # Darwin-specific linker flags for loadable modules.
 129   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 130 endif()
 131
 132 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 133 # build might work on ELF but fail on MachO/COFF.
 134 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32 OR CYGWIN OR
 135         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD") AND
 136    NOT LLVM_USE_SANITIZER)
 137   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 138 endif()
 139
 140
 141 function(append value)
 142   foreach(variable ${ARGN})
 143     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 144   endforeach(variable)
 145 endfunction()
 146
 147 function(append_if condition value)
 148   if (${condition})
 149     foreach(variable ${ARGN})
 150       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 151     endforeach(variable)
 152   endif()
 153 endfunction()
 154
 155 macro(add_flag_if_supported flag name)
 156   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 157   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 158   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 159   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 160 endmacro()
 161
 162 function(add_flag_or_print_warning flag name)
 163   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 164   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 165   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 166     message(STATUS "Building with ${flag}")
 167     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 168     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 169   else()
 170     message(WARNING "${flag} is not supported.")
 171   endif()
 172 endfunction()
 173
 174 if( LLVM_ENABLE_PIC )
 175   if( XCODE )
 176     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 177     # know how to disable this, so just force ENABLE_PIC off for now.
 178     message(WARNING "-fPIC not supported with Xcode.")
 179   elseif( WIN32 OR CYGWIN)
 180     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 181   else()
 182     add_flag_or_print_warning("-fPIC" FPIC)
 183
 184     if( WIN32 OR CYGWIN)
 185       # MinGW warns if -fvisibility-inlines-hidden is used.
 186     else()
 187       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 188       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 189     endif()
 190   endif()
 191 endif()
 192
 193 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 194   # TODO: support other platforms and toolchains.
 195   if( LLVM_BUILD_32_BITS )
 196     message(STATUS "Building 32 bits executables and libraries.")
 197     add_llvm_definitions( -m32 )
 198     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 199     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 200     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 201   endif( LLVM_BUILD_32_BITS )
 202 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 203
 204 if (LLVM_BUILD_STATIC)
 205   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 206 endif()
 207
 208 if( XCODE )
 209   # For Xcode enable several build settings that correspond to
 210   # many warnings that are on by default in Clang but are
 211   # not enabled for historical reasons.  For versions of Xcode
 212   # that do not support these options they will simply
 213   # be ignored.
 214   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 215   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 216   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 217   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 218   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 219   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 220   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 221   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 222   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 223   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 224   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 225   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 226   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 227   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 228   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 229 endif()
 230
 231 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 232 # to use.
 233 if( MSVC_IDE )
 234   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 235     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 236   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 237     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 238       add_llvm_definitions( /MP )
 239     else()
 240       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 241       add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 242     endif()
 243   else()
 244     message(STATUS "Parallel compilation disabled")
 245   endif()
 246 endif()
 247
 248 if( MSVC )
 249   include(ChooseMSVCCRT)
 250
 251   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 252     # set stack reserved size to ~10MB
 253     # CMake previously automatically set this value for MSVC builds, but the
 254     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 255     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 256     # C++ templates in Clang.
 257     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 258   endif()
 259
 260   if( MSVC11 )
 261     add_llvm_definitions(-D_VARIADIC_MAX=10)
 262   endif()
 263
 264   # Add definitions that make MSVC much less annoying.
 265   add_llvm_definitions(
 266     # For some reason MS wants to deprecate a bunch of standard functions...
 267     -D_CRT_SECURE_NO_DEPRECATE
 268     -D_CRT_SECURE_NO_WARNINGS
 269     -D_CRT_NONSTDC_NO_DEPRECATE
 270     -D_CRT_NONSTDC_NO_WARNINGS
 271     -D_SCL_SECURE_NO_DEPRECATE
 272     -D_SCL_SECURE_NO_WARNINGS
 273     )
 274
 275   set(msvc_warning_flags
 276     # Disabled warnings.
 277     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 278     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 279     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 280     -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 281     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 282     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 283     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 284     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 285     -wd4355 # Suppress ''this' : used in base member initializer list'
 286     -wd4456 # Suppress 'declaration of 'var' hides local variable'
 287     -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 288     -wd4458 # Suppress 'declaration of 'var' hides class member'
 289     -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 290     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 291     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 292     -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 293     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 294     -wd4100 # Suppress 'unreferenced formal parameter'
 295     -wd4127 # Suppress 'conditional expression is constant'
 296     -wd4512 # Suppress 'assignment operator could not be generated'
 297     -wd4505 # Suppress 'unreferenced local function has been removed'
 298     -wd4610 # Suppress '<class> can never be instantiated'
 299     -wd4510 # Suppress 'default constructor could not be generated'
 300     -wd4702 # Suppress 'unreachable code'
 301     -wd4245 # Suppress 'signed/unsigned mismatch'
 302     -wd4706 # Suppress 'assignment within conditional expression'
 303     -wd4310 # Suppress 'cast truncates constant value'
 304     -wd4701 # Suppress 'potentially uninitialized local variable'
 305     -wd4703 # Suppress 'potentially uninitialized local pointer variable'
 306     -wd4389 # Suppress 'signed/unsigned mismatch'
 307     -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
 308     -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
 309     -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
 310     -wd4577 # Suppress 'noexcept used with no exception handling mode specified; termination on exception is not guaranteed'
 311     -wd4091 # Suppress 'typedef: ignored on left of '' when no variable is declared'
 312
 313         # Ideally, we'd like this warning to be enabled, but MSVC 2013 doesn't
 314         # support the 'aligned' attribute in the way that clang sources requires (for
 315         # any code that uses the LLVM_ALIGNAS macro), so this is must be disabled to
 316         # avoid unwanted alignment warnings.
 317         # When we switch to requiring a version of MSVC that supports the 'alignas'
 318         # specifier (MSVC 2015?) this warning can be re-enabled.
 319     -wd4324 # Suppress 'structure was padded due to __declspec(align())'
 320
 321     # Promoted warnings.
 322     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 323
 324     # Promoted warnings to errors.
 325     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 326     )
 327
 328   # Enable warnings
 329   if (LLVM_ENABLE_WARNINGS)
 330     append("/W4" msvc_warning_flags)
 331     # CMake appends /W3 by default, and having /W3 followed by /W4 will result in
 332     # cl : Command line warning D9025 : overriding '/W3' with '/W4'.  Since this is
 333     # a command line warning and not a compiler warning, it cannot be suppressed except
 334     # by fixing the command line.
 335     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 336     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 337
 338     if (LLVM_ENABLE_PEDANTIC)
 339       # No MSVC equivalent available
 340     endif (LLVM_ENABLE_PEDANTIC)
 341   endif (LLVM_ENABLE_WARNINGS)
 342   if (LLVM_ENABLE_WERROR)
 343     append("/WX" msvc_warning_flags)
 344   endif (LLVM_ENABLE_WERROR)
 345
 346   foreach(flag ${msvc_warning_flags})
 347     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 348   endforeach(flag)
 349
 350   # Disable sized deallocation if the flag is supported. MSVC fails to compile
 351   # the operator new overload in User otherwise.
 352   check_c_compiler_flag("/WX /Zc:sizedDealloc-" SUPPORTS_SIZED_DEALLOC)
 353   append_if(SUPPORTS_SIZED_DEALLOC "/Zc:sizedDealloc-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 354
 355 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 356   if (LLVM_ENABLE_WARNINGS)
 357     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 358     append("-Wcast-qual" CMAKE_CXX_FLAGS)
 359
 360     # Turn off missing field initializer warnings for gcc to avoid noise from
 361     # false positives with empty {}. Turn them on otherwise (they're off by
 362     # default for clang).
 363     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 364     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 365       if (CMAKE_COMPILER_IS_GNUCXX)
 366         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 367       else()
 368         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 369       endif()
 370     endif()
 371
 372     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 373     add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 374     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 375     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 376
 377     # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 378     # If it does, don't add it. So it won't be added on clang 3.4 and older.
 379     # This also catches cases when -Wnon-virtual-dtor isn't supported by
 380     # the compiler at all.
 381     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 382     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 383     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 384                                class derived final : public base { public: ~derived();};
 385                                int main() { return 0; }"
 386                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 387     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 388     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 389               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 390
 391     # Check if -Wcomment is OK with an // comment ending with '\' if the next
 392     # line is also a // comment.
 393     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 394     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 395     CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 396                             C_WCOMMENT_ALLOWS_LINE_WRAP)
 397     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 398     if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 399       append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 400     endif()
 401   endif (LLVM_ENABLE_WARNINGS)
 402   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 403   if (NOT LLVM_ENABLE_TIMESTAMPS)
 404     add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 405   endif ()
 406   if (LLVM_ENABLE_CXX1Y)
 407     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 408     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 409   else()
 410     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 411     if (CXX_SUPPORTS_CXX11)
 412       if (CYGWIN OR MINGW)
 413         # MinGW and Cygwin are a bit stricter and lack things like
 414         # 'strdup', 'stricmp', etc in c++11 mode.
 415         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 416       else()
 417         append("-std=c++11" CMAKE_CXX_FLAGS)
 418       endif()
 419     else()
 420       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 421     endif()
 422   endif()
 423   if (LLVM_ENABLE_MODULES)
 424     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 425     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fmodules -fcxx-modules")
 426     # Check that we can build code with modules enabled, and that repeatedly
 427     # including <cassert> still manages to respect NDEBUG properly.
 428     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 429                                #include <cassert>
 430                                #define NDEBUG
 431                                #include <cassert>
 432                                int main() { assert(this code is not compiled); }"
 433                                CXX_SUPPORTS_MODULES)
 434     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 435     if (CXX_SUPPORTS_MODULES)
 436       append_if(CXX_SUPPORTS_MODULES "-fmodules" CMAKE_C_FLAGS)
 437       append_if(CXX_SUPPORTS_MODULES "-fmodules -fcxx-modules" CMAKE_CXX_FLAGS)
 438     else()
 439       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 440     endif()
 441   endif(LLVM_ENABLE_MODULES)
 442 endif( MSVC )
 443
 444 macro(append_common_sanitizer_flags)
 445   # Append -fno-omit-frame-pointer and turn on debug info to get better
 446   # stack traces.
 447   add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 448   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 449       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 450     add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 451   endif()
 452   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 453   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 454     add_flag_if_supported("-O1" O1)
 455   endif()
 456 endmacro()
 457
 458 # Turn on sanitizers if necessary.
 459 if(LLVM_USE_SANITIZER)
 460   if (LLVM_ON_UNIX)
 461     if (LLVM_USE_SANITIZER STREQUAL "Address")
 462       append_common_sanitizer_flags()
 463       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 464     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 465       append_common_sanitizer_flags()
 466       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 467       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 468         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 469       endif()
 470     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 471       append_common_sanitizer_flags()
 472       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 473               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 474     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 475       append_common_sanitizer_flags()
 476       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 477     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
 478             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
 479       append_common_sanitizer_flags()
 480       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 481               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 482     else()
 483       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 484     endif()
 485   else()
 486     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 487   endif()
 488   if (LLVM_USE_SANITIZE_COVERAGE)
 489     append("-fsanitize-coverage=edge,indirect-calls,8bit-counters,trace-cmp" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 490   endif()
 491 endif()
 492
 493 # Turn on -gsplit-dwarf if requested
 494 if(LLVM_USE_SPLIT_DWARF)
 495   add_definitions("-gsplit-dwarf")
 496 endif()
 497
 498 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 499 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 500 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 501
 502 # clang doesn't print colored diagnostics when invoked from Ninja
 503 if (UNIX AND
 504     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 505     CMAKE_GENERATOR STREQUAL "Ninja")
 506   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 507 endif()
 508
 509 # Add flags for add_dead_strip().
 510 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 511 # But MinSizeRel seems to add that automatically, so maybe disable these
 512 # flags instead if LLVM_NO_DEAD_STRIP is set.
 513 if(NOT CYGWIN AND NOT WIN32)
 514   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND
 515      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 516     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 517     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 518       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 519       # Doing so will break sanitizers.
 520       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 521     endif()
 522     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 523   endif()
 524 endif()
 525
 526 if(CYGWIN OR MINGW)
 527   # Prune --out-implib from executables. It doesn't make sense even
 528   # with --export-all-symbols.
 529   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 530     CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
 531   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 532     CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
 533 endif()
 534
 535 if(MSVC)
 536   # Remove flags here, for exceptions and RTTI.
 537   # Each target property or source property should be responsible to control
 538   # them.
 539   # CL.EXE complains to override flags like "/GR /GR-".
 540   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 541   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 542 endif()
 543
 544 # Provide public options to globally control RTTI and EH
 545 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 546 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 547 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 548   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 549 endif()
 550
 551 # Plugin support
 552 # FIXME: Make this configurable.
 553 if(WIN32 OR CYGWIN)
 554   if(BUILD_SHARED_LIBS)
 555     set(LLVM_ENABLE_PLUGINS ON)
 556   else()
 557     set(LLVM_ENABLE_PLUGINS OFF)
 558   endif()
 559 else()
 560   set(LLVM_ENABLE_PLUGINS ON)
 561 endif()