cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(AddLLVMDefinitions)
   6 include(CheckCCompilerFlag)
   7 include(CheckCXXCompilerFlag)
   8
   9 if( CMAKE_COMPILER_IS_GNUCXX )
  10   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  11 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
  12   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  13 endif()
  14
  15 if( LLVM_ENABLE_ASSERTIONS )
  16   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  17   if( NOT MSVC )
  18     add_definitions( -D_DEBUG )
  19   endif()
  20   # On Release builds cmake automatically defines NDEBUG, so we
  21   # explicitly undefine it:
  22   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  23     add_definitions( -UNDEBUG )
  24   endif()
  25 else()
  26   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  27     if( NOT MSVC_IDE AND NOT XCODE )
  28       add_definitions( -DNDEBUG )
  29     endif()
  30   endif()
  31 endif()
  32
  33 if(WIN32)
  34   if(CYGWIN)
  35     set(LLVM_ON_WIN32 0)
  36     set(LLVM_ON_UNIX 1)
  37   else(CYGWIN)
  38     set(LLVM_ON_WIN32 1)
  39     set(LLVM_ON_UNIX 0)
  40   endif(CYGWIN)
  41   set(LTDL_SHLIB_EXT ".dll")
  42   set(EXEEXT ".exe")
  43   # Maximum path length is 160 for non-unicode paths
  44   set(MAXPATHLEN 160)
  45 else(WIN32)
  46   if(UNIX)
  47     set(LLVM_ON_WIN32 0)
  48     set(LLVM_ON_UNIX 1)
  49     if(APPLE)
  50       set(LTDL_SHLIB_EXT ".dylib")
  51     else(APPLE)
  52       set(LTDL_SHLIB_EXT ".so")
  53     endif(APPLE)
  54     set(EXEEXT "")
  55     # FIXME: Maximum path length is currently set to 'safe' fixed value
  56     set(MAXPATHLEN 2024)
  57   else(UNIX)
  58     MESSAGE(SEND_ERROR "Unable to determine platform")
  59   endif(UNIX)
  60 endif(WIN32)
  61
  62 if( LLVM_ENABLE_PIC )
  63   if( XCODE )
  64     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
  65     # know how to disable this, so just force ENABLE_PIC off for now.
  66     message(WARNING "-fPIC not supported with Xcode.")
  67   elseif( WIN32 OR CYGWIN)
  68     # On Windows all code is PIC. MinGW warns if -fPIC is used.
  69   else()
  70     check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  71     if( SUPPORTS_FPIC_FLAG )
  72       message(STATUS "Building with -fPIC")
  73       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  74       set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
  75     else( SUPPORTS_FPIC_FLAG )
  76       message(WARNING "-fPIC not supported.")
  77     endif()
  78
  79     if( WIN32 OR CYGWIN)
  80       # MinGW warns if -fvisibility-inlines-hidden is used.
  81     else()
  82       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
  83       if( SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG )
  84         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
  85       endif()
  86      endif()
  87   endif()
  88 endif()
  89
  90 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
  91   # TODO: support other platforms and toolchains.
  92   if( LLVM_BUILD_32_BITS )
  93     message(STATUS "Building 32 bits executables and libraries.")
  94     add_llvm_definitions( -m32 )
  95     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
  96     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
  97     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
  98   endif( LLVM_BUILD_32_BITS )
  99 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 100
 101 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 102 # to use.
 103 if( MSVC_IDE )
 104   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 105     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 106   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 107     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 108       add_llvm_definitions( /MP )
 109     else()
 110       if (MSVC10)
 111         message(FATAL_ERROR
 112           "Due to a bug in CMake only 0 and 1 is supported for "
 113           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 114       else()
 115         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 116         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 117       endif()
 118     endif()
 119   else()
 120     message(STATUS "Parallel compilation disabled")
 121   endif()
 122 endif()
 123
 124 if( MSVC )
 125   include(ChooseMSVCCRT)
 126
 127   if( MSVC11 )
 128     add_llvm_definitions(-D_VARIADIC_MAX=10)
 129   endif()
 130
 131   # Add definitions that make MSVC much less annoying.
 132   add_llvm_definitions(
 133     # For some reason MS wants to deprecate a bunch of standard functions...
 134     -D_CRT_SECURE_NO_DEPRECATE
 135     -D_CRT_SECURE_NO_WARNINGS
 136     -D_CRT_NONSTDC_NO_DEPRECATE
 137     -D_CRT_NONSTDC_NO_WARNINGS
 138     -D_SCL_SECURE_NO_DEPRECATE
 139     -D_SCL_SECURE_NO_WARNINGS
 140
 141     # Disabled warnings.
 142     -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
 143     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 144     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 145     -wd4181 # Suppress 'qualifier applied to reference type; ignored'
 146     -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
 147     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 148     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 149     -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 150     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 151     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 152     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 153     -wd4355 # Suppress ''this' : used in base member initializer list'
 154     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 155     -wd4551 # Suppress 'function call missing argument list'
 156     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 157     -wd4715 # Suppress ''function' : not all control paths return a value'
 158     -wd4722 # Suppress ''function' : destructor never returns, potential memory leak'
 159     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 160
 161     # Promoted warnings.
 162     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 163
 164     # Promoted warnings to errors.
 165     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 166     )
 167
 168   # Enable warnings
 169   if (LLVM_ENABLE_WARNINGS)
 170     add_llvm_definitions( /W4 )
 171     if (LLVM_ENABLE_PEDANTIC)
 172       # No MSVC equivalent available
 173     endif (LLVM_ENABLE_PEDANTIC)
 174   endif (LLVM_ENABLE_WARNINGS)
 175   if (LLVM_ENABLE_WERROR)
 176     add_llvm_definitions( /WX )
 177   endif (LLVM_ENABLE_WERROR)
 178 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 179   if (LLVM_ENABLE_WARNINGS)
 180     add_llvm_definitions( -Wall -W -Wno-unused-parameter -Wwrite-strings )
 181
 182     # Turn off missing field initializer warnings for gcc to avoid noise from
 183     # false positives with empty {}. Turn them on otherwise (they're off by
 184     # default for clang).
 185     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 186     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 187       if (CMAKE_COMPILER_IS_GNUCXX)
 188         add_llvm_definitions( -Wno-missing-field-initializers )
 189       else()
 190         add_llvm_definitions( -Wmissing-field-initializers )
 191       endif()
 192     endif()
 193
 194     if (LLVM_ENABLE_PEDANTIC)
 195       add_llvm_definitions( -pedantic -Wno-long-long )
 196       check_cxx_compiler_flag("-Werror -Wnested-anon-types" CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG)
 197       if( CXX_SUPPORTS_NO_NESTED_ANON_TYPES_FLAG )
 198         set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-nested-anon-types" )
 199       endif()
 200     endif (LLVM_ENABLE_PEDANTIC)
 201     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 202     if( CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG )
 203       set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wcovered-switch-default" )
 204     endif()
 205     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 206     if( C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG )
 207       set( CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wcovered-switch-default" )
 208     endif()
 209     if (USE_NO_UNINITIALIZED)
 210       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-uninitialized")
 211     endif()
 212     if (USE_NO_MAYBE_UNINITIALIZED)
 213       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-maybe-uninitialized")
 214     endif()
 215   endif (LLVM_ENABLE_WARNINGS)
 216   if (LLVM_ENABLE_WERROR)
 217     add_llvm_definitions( -Werror )
 218   endif (LLVM_ENABLE_WERROR)
 219 endif( MSVC )
 220
 221 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 222 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 223 add_llvm_definitions( -D__STDC_LIMIT_MACROS )