cmake/modules/HandleLLVMOptions.cmake

   1 include(AddLLVMDefinitions)
   2
   3 if( CMAKE_COMPILER_IS_GNUCXX )
   4   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
   5 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
   6   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
   7 endif()
   8
   9 # Run-time build mode; It is used for unittests.
  10 if(MSVC_IDE)
  11   # Expect "$(Configuration)", "$(OutDir)", etc.
  12   # It is expanded by msbuild or similar.
  13   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
  14 elseif(NOT CMAKE_BUILD_TYPE STREQUAL "")
  15   # Expect "Release" "Debug", etc.
  16   # Or unittests could not run.
  17   set(RUNTIME_BUILD_MODE ${CMAKE_BUILD_TYPE})
  18 else()
  19   # It might be "."
  20   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
  21 endif()
  22
  23 set(LIT_ARGS_DEFAULT "-sv")
  24 if (MSVC OR XCODE)
  25   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
  26 endif()
  27 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}"
  28     CACHE STRING "Default options for lit")
  29
  30 if( LLVM_ENABLE_ASSERTIONS )
  31   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  32   if( NOT MSVC )
  33     add_definitions( -D_DEBUG )
  34   endif()
  35   # On Release builds cmake automatically defines NDEBUG, so we
  36   # explicitly undefine it:
  37   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  38     add_definitions( -UNDEBUG )
  39     set(LLVM_BUILD_MODE "Release")
  40   else()
  41     set(LLVM_BUILD_MODE "Debug")
  42   endif()
  43   set(LLVM_BUILD_MODE "${LLVM_BUILD_MODE}+Asserts")
  44 else()
  45   set(LLVM_BUILD_MODE "Release")
  46   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  47     if( NOT MSVC_IDE AND NOT XCODE )
  48       add_definitions( -DNDEBUG )
  49     endif()
  50   endif()
  51 endif()
  52
  53 if(WIN32)
  54   if(CYGWIN)
  55     set(LLVM_ON_WIN32 0)
  56     set(LLVM_ON_UNIX 1)
  57   else(CYGWIN)
  58     set(LLVM_ON_WIN32 1)
  59     set(LLVM_ON_UNIX 0)
  60
  61     # This is effective only on Win32 hosts to use gnuwin32 tools.
  62     set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
  63   endif(CYGWIN)
  64   set(LTDL_SHLIB_EXT ".dll")
  65   set(EXEEXT ".exe")
  66   # Maximum path length is 160 for non-unicode paths
  67   set(MAXPATHLEN 160)
  68 else(WIN32)
  69   if(UNIX)
  70     set(LLVM_ON_WIN32 0)
  71     set(LLVM_ON_UNIX 1)
  72     if(APPLE)
  73       set(LTDL_SHLIB_EXT ".dylib")
  74     else(APPLE)
  75       set(LTDL_SHLIB_EXT ".so")
  76     endif(APPLE)
  77     set(EXEEXT "")
  78     # FIXME: Maximum path length is currently set to 'safe' fixed value
  79     set(MAXPATHLEN 2024)
  80   else(UNIX)
  81     MESSAGE(SEND_ERROR "Unable to determine platform")
  82   endif(UNIX)
  83 endif(WIN32)
  84
  85 if( LLVM_ENABLE_PIC )
  86   if( XCODE )
  87     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
  88     # know how to disable this, so just force ENABLE_PIC off for now.
  89     message(WARNING "-fPIC not supported with Xcode.")
  90   elseif( WIN32 )
  91     # On Windows all code is PIC. MinGW warns if -fPIC is used.
  92   else()
  93     include(CheckCXXCompilerFlag)
  94     check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  95     if( SUPPORTS_FPIC_FLAG )
  96       message(STATUS "Building with -fPIC")
  97       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  98       set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
  99     else( SUPPORTS_FPIC_FLAG )
 100       message(WARNING "-fPIC not supported.")
 101     endif()
 102   endif()
 103 endif()
 104
 105 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 106   # TODO: support other platforms and toolchains.
 107   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 108   if( LLVM_BUILD_32_BITS )
 109     message(STATUS "Building 32 bits executables and libraries.")
 110     add_llvm_definitions( -m32 )
 111     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 112     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 113   endif( LLVM_BUILD_32_BITS )
 114 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 115
 116 if( MSVC_IDE AND ( MSVC90 OR MSVC10 ) )
 117   # Only Visual Studio 2008 and 2010 officially supports /MP.
 118   # Visual Studio 2005 do support it but it's experimental there.
 119   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 120     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 121   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 122     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 123       add_llvm_definitions( /MP )
 124     else()
 125       if (MSVC10)
 126         message(FATAL_ERROR
 127           "Due to a bug in CMake only 0 and 1 is supported for "
 128           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 129       else()
 130         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 131         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 132       endif()
 133     endif()
 134   else()
 135     message(STATUS "Parallel compilation disabled")
 136   endif()
 137 endif()
 138
 139 if( MSVC )
 140   include(ChooseMSVCCRT)
 141
 142   # Add definitions that make MSVC much less annoying.
 143   add_llvm_definitions(
 144     # For some reason MS wants to deprecate a bunch of standard functions...
 145     -D_CRT_SECURE_NO_DEPRECATE
 146     -D_CRT_SECURE_NO_WARNINGS
 147     -D_CRT_NONSTDC_NO_DEPRECATE
 148     -D_CRT_NONSTDC_NO_WARNINGS
 149     -D_SCL_SECURE_NO_DEPRECATE
 150     -D_SCL_SECURE_NO_WARNINGS
 151
 152     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 153     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 154     -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
 155     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 156     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 157     -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 158     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 159     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 160     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 161     -wd4355 # Suppress ''this' : used in base member initializer list'
 162     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 163     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 164     -wd4715 # Suppress ''function' : not all control paths return a value'
 165     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 166     -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
 167     -wd4181 # Suppress 'qualifier applied to reference type; ignored'
 168     -w14062 # Promote "enumerator in switch of enum is not handled" to level 1 warning.
 169     )
 170
 171   # Enable warnings
 172   if (LLVM_ENABLE_WARNINGS)
 173     add_llvm_definitions( /W4 /Wall )
 174     if (LLVM_ENABLE_PEDANTIC)
 175       # No MSVC equivalent available
 176     endif (LLVM_ENABLE_PEDANTIC)
 177   endif (LLVM_ENABLE_WARNINGS)
 178   if (LLVM_ENABLE_WERROR)
 179     add_llvm_definitions( /WX )
 180   endif (LLVM_ENABLE_WERROR)
 181 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 182   if (LLVM_ENABLE_WARNINGS)
 183     add_llvm_definitions( -Wall -W -Wno-unused-parameter -Wwrite-strings )
 184     if (LLVM_ENABLE_PEDANTIC)
 185       add_llvm_definitions( -pedantic -Wno-long-long )
 186     endif (LLVM_ENABLE_PEDANTIC)
 187   endif (LLVM_ENABLE_WARNINGS)
 188   if (LLVM_ENABLE_WERROR)
 189     add_llvm_definitions( -Werror )
 190   endif (LLVM_ENABLE_WERROR)
 191 endif( MSVC )
 192
 193 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 194 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 195
 196 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)