cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(HandleLLVMStdlib)
   6 include(AddLLVMDefinitions)
   7 include(CheckCCompilerFlag)
   8 include(CheckCXXCompilerFlag)
   9
  10 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
  11   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  12     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
  13       message(FATAL_ERROR "Host GCC version must be at least 4.7!")
  14     endif()
  15   elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  16     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
  17       message(FATAL_ERROR "Host Clang version must be at least 3.1!")
  18     endif()
  19
  20     # Also test that we aren't using too old of a version of libstdc++ with the
  21     # Clang compiler. This is tricky as there is no real way to check the
  22     # version of libstdc++ directly. Instead we test for a known bug in
  23     # libstdc++4.6 that is fixed in libstdc++4.7.
  24     if(NOT LLVM_ENABLE_LIBCXX)
  25       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  26       set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  27       set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
  28       if (ANDROID)
  29         set(CMAKE_REQUIRED_LIBRARIES "atomic")
  30       endif()
  31       check_cxx_source_compiles("
  32 #include <atomic>
  33 std::atomic<float> x(0.0f);
  34 int main() { return (float)x; }"
  35         LLVM_NO_OLD_LIBSTDCXX)
  36       if(NOT LLVM_NO_OLD_LIBSTDCXX)
  37         message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
  38       endif()
  39       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
  40       set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
  41     endif()
  42   elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  43     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 17.0)
  44       message(FATAL_ERROR "Host Visual Studio must be at least 2012 (MSVC 17.0)")
  45     endif()
  46   endif()
  47 endif()
  48
  49 if( LLVM_ENABLE_ASSERTIONS )
  50   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  51   if( NOT MSVC )
  52     add_definitions( -D_DEBUG )
  53   endif()
  54   # On non-Debug builds cmake automatically defines NDEBUG, so we
  55   # explicitly undefine it:
  56   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  57     add_definitions( -UNDEBUG )
  58     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  59     set(REGEXP_NDEBUG "(^| )[/-]D *NDEBUG($| )")
  60     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  61       CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
  62     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  63       CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO}")
  64     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  65       CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL}")
  66   endif()
  67 else()
  68   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  69     if( NOT MSVC_IDE AND NOT XCODE )
  70       add_definitions( -DNDEBUG )
  71     endif()
  72   endif()
  73 endif()
  74
  75 if(WIN32)
  76   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  77   if(CYGWIN)
  78     set(LLVM_ON_WIN32 0)
  79     set(LLVM_ON_UNIX 1)
  80   else(CYGWIN)
  81     set(LLVM_ON_WIN32 1)
  82     set(LLVM_ON_UNIX 0)
  83   endif(CYGWIN)
  84   # Maximum path length is 160 for non-unicode paths
  85   set(MAXPATHLEN 160)
  86 else(WIN32)
  87   if(UNIX)
  88     set(LLVM_ON_WIN32 0)
  89     set(LLVM_ON_UNIX 1)
  90     if(APPLE)
  91       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  92     else(APPLE)
  93       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
  94     endif(APPLE)
  95     # FIXME: Maximum path length is currently set to 'safe' fixed value
  96     set(MAXPATHLEN 2024)
  97   else(UNIX)
  98     MESSAGE(SEND_ERROR "Unable to determine platform")
  99   endif(UNIX)
 100 endif(WIN32)
 101
 102 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 103 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 104
 105 # We use *.dylib rather than *.so on darwin.
 106 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 107
 108 if(APPLE)
 109   # Darwin-specific linker flags for loadable modules.
 110   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 111 endif()
 112
 113 function(add_flag_or_print_warning flag)
 114   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
 115   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
 116   if (C_SUPPORTS_FLAG AND CXX_SUPPORTS_FLAG)
 117     message(STATUS "Building with ${flag}")
 118     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 119     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 120   else()
 121     message(WARNING "${flag} is not supported.")
 122   endif()
 123 endfunction()
 124
 125 function(append value)
 126   foreach(variable ${ARGN})
 127     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 128   endforeach(variable)
 129 endfunction()
 130
 131 function(append_if condition value)
 132   if (${condition})
 133     foreach(variable ${ARGN})
 134       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 135     endforeach(variable)
 136   endif()
 137 endfunction()
 138
 139 macro(add_flag_if_supported flag)
 140   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
 141   append_if(C_SUPPORTS_FLAG "${flag}" CMAKE_C_FLAGS)
 142   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
 143   append_if(CXX_SUPPORTS_FLAG "${flag}" CMAKE_CXX_FLAGS)
 144 endmacro()
 145
 146 if( LLVM_ENABLE_PIC )
 147   if( XCODE )
 148     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 149     # know how to disable this, so just force ENABLE_PIC off for now.
 150     message(WARNING "-fPIC not supported with Xcode.")
 151   elseif( WIN32 OR CYGWIN)
 152     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 153   else()
 154     add_flag_or_print_warning("-fPIC")
 155
 156     if( WIN32 OR CYGWIN)
 157       # MinGW warns if -fvisibility-inlines-hidden is used.
 158     else()
 159       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 160       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 161     endif()
 162   endif()
 163 endif()
 164
 165 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 166   # TODO: support other platforms and toolchains.
 167   if( LLVM_BUILD_32_BITS )
 168     message(STATUS "Building 32 bits executables and libraries.")
 169     add_llvm_definitions( -m32 )
 170     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 171     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 172     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 173   endif( LLVM_BUILD_32_BITS )
 174 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 175
 176 if( XCODE )
 177   # For Xcode enable several build settings that correspond to
 178   # many warnings that are on by default in Clang but are
 179   # not enabled for historical reasons.  For versions of Xcode
 180   # that do not support these options they will simply
 181   # be ignored.
 182   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 183   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 184   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 185   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 186   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 187   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 188   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 189   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 190   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 191   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 192   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 193   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 194   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 195   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 196   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 197 endif()
 198
 199 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 200 # to use.
 201 if( MSVC_IDE )
 202   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 203     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 204   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 205     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 206       add_llvm_definitions( /MP )
 207     else()
 208       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 209       add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 210     endif()
 211   else()
 212     message(STATUS "Parallel compilation disabled")
 213   endif()
 214 endif()
 215
 216 if( MSVC )
 217   include(ChooseMSVCCRT)
 218
 219   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 220     # set stack reserved size to ~10MB
 221     # CMake previously automatically set this value for MSVC builds, but the
 222     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 223     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 224     # C++ templates in Clang.
 225     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 226   endif()
 227
 228   if( MSVC11 )
 229     add_llvm_definitions(-D_VARIADIC_MAX=10)
 230   endif()
 231
 232   # Add definitions that make MSVC much less annoying.
 233   add_llvm_definitions(
 234     # For some reason MS wants to deprecate a bunch of standard functions...
 235     -D_CRT_SECURE_NO_DEPRECATE
 236     -D_CRT_SECURE_NO_WARNINGS
 237     -D_CRT_NONSTDC_NO_DEPRECATE
 238     -D_CRT_NONSTDC_NO_WARNINGS
 239     -D_SCL_SECURE_NO_DEPRECATE
 240     -D_SCL_SECURE_NO_WARNINGS
 241
 242     # Disabled warnings.
 243     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 244     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 245     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 246     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 247     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 248     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 249     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 250     -wd4355 # Suppress ''this' : used in base member initializer list'
 251     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 252     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 253     -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 254     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 255
 256     # Promoted warnings.
 257     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 258
 259     # Promoted warnings to errors.
 260     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 261     )
 262
 263   # Enable warnings
 264   if (LLVM_ENABLE_WARNINGS)
 265     add_llvm_definitions( /W4 )
 266     if (LLVM_ENABLE_PEDANTIC)
 267       # No MSVC equivalent available
 268     endif (LLVM_ENABLE_PEDANTIC)
 269   endif (LLVM_ENABLE_WARNINGS)
 270   if (LLVM_ENABLE_WERROR)
 271     add_llvm_definitions( /WX )
 272   endif (LLVM_ENABLE_WERROR)
 273 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 274   if (LLVM_ENABLE_WARNINGS)
 275     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 276
 277     # Turn off missing field initializer warnings for gcc to avoid noise from
 278     # false positives with empty {}. Turn them on otherwise (they're off by
 279     # default for clang).
 280     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 281     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 282       if (CMAKE_COMPILER_IS_GNUCXX)
 283         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 284       else()
 285         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 286       endif()
 287     endif()
 288
 289     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 290     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 291     append_if(CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_CXX_FLAGS)
 292     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 293     append_if(C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_C_FLAGS)
 294     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 295     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 296     check_cxx_compiler_flag("-Werror -Wnon-virtual-dtor" CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG)
 297     append_if(CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 298   endif (LLVM_ENABLE_WARNINGS)
 299   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 300   if (LLVM_ENABLE_CXX1Y)
 301     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 302     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 303   else()
 304     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 305     if (CXX_SUPPORTS_CXX11)
 306       if (CYGWIN OR MINGW)
 307         # MinGW and Cygwin are a bit stricter and lack things like
 308         # 'strdup', 'stricmp', etc in c++11 mode.
 309         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 310       else()
 311         append("-std=c++11" CMAKE_CXX_FLAGS)
 312       endif()
 313     else()
 314       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 315     endif()
 316   endif()
 317 endif( MSVC )
 318
 319 macro(append_common_sanitizer_flags)
 320   # Append -fno-omit-frame-pointer and turn on debug info to get better
 321   # stack traces.
 322   add_flag_if_supported("-fno-omit-frame-pointer")
 323   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 324       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 325     add_flag_if_supported("-gline-tables-only")
 326   endif()
 327   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 328   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 329     add_flag_if_supported("-O1")
 330   endif()
 331 endmacro()
 332
 333 # Turn on sanitizers if necessary.
 334 if(LLVM_USE_SANITIZER)
 335   if (LLVM_ON_UNIX)
 336     if (LLVM_USE_SANITIZER STREQUAL "Address")
 337       append_common_sanitizer_flags()
 338       add_flag_or_print_warning("-fsanitize=address")
 339     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 340       append_common_sanitizer_flags()
 341       add_flag_or_print_warning("-fsanitize=memory")
 342       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 343         add_flag_or_print_warning("-fsanitize-memory-track-origins")
 344       endif()
 345     else()
 346       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 347     endif()
 348   else()
 349     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 350   endif()
 351 endif()
 352
 353 # Turn on -gsplit-dwarf if requested
 354 if(LLVM_USE_SPLIT_DWARF)
 355   add_llvm_definitions("-gsplit-dwarf")
 356 endif()
 357
 358 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 359 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 360 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 361
 362 # clang doesn't print colored diagnostics when invoked from Ninja
 363 if (UNIX AND
 364     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 365     CMAKE_GENERATOR STREQUAL "Ninja")
 366   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 367 endif()
 368
 369 # Add flags for add_dead_strip().
 370 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 371 # But MinSizeRel seems to add that automatically, so maybe disable these
 372 # flags instead if LLVM_NO_DEAD_STRIP is set.
 373 if(NOT CYGWIN AND NOT WIN32)
 374   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 375     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 376     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 377       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 378       # Doing so will break sanitizers.
 379       check_c_compiler_flag("-Werror -ffunction-sections" C_SUPPORTS_FFUNCTION_SECTIONS)
 380       check_cxx_compiler_flag("-Werror -ffunction-sections" CXX_SUPPORTS_FFUNCTION_SECTIONS)
 381       append_if(C_SUPPORTS_FFUNCTION_SECTIONS "-ffunction-sections" CMAKE_C_FLAGS)
 382       append_if(CXX_SUPPORTS_FFUNCTION_SECTIONS "-ffunction-sections" CMAKE_CXX_FLAGS)
 383     endif()
 384     check_c_compiler_flag("-Werror -fdata-sections" C_SUPPORTS_FDATA_SECTIONS)
 385     check_cxx_compiler_flag("-Werror -fdata-sections" CXX_SUPPORTS_FDATA_SECTIONS)
 386     append_if(C_SUPPORTS_FDATA_SECTIONS "-fdata-sections" CMAKE_C_FLAGS)
 387     append_if(CXX_SUPPORTS_FDATA_SECTIONS "-fdata-sections" CMAKE_CXX_FLAGS)
 388   endif()
 389 endif()
 390
 391 if(CYGWIN OR MINGW)
 392   # Prune --out-implib from executables. It doesn't make sense even
 393   # with --export-all-symbols.
 394   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 395     CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
 396   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 397     CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
 398 endif()
 399
 400 if(MSVC)
 401   # Remove flags here, for exceptions and RTTI.
 402   # Each target property or source property should be responsible to control
 403   # them.
 404   # CL.EXE complains to override flags like "/GR /GR-".
 405   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 406   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 407 endif()