cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(AddLLVMDefinitions)
   6 include(CheckCCompilerFlag)
   7 include(CheckCXXCompilerFlag)
   8
   9 if( CMAKE_COMPILER_IS_GNUCXX )
  10   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  11 elseif( MSVC )
  12   set(LLVM_COMPILER_IS_GCC_COMPATIBLE OFF)
  13 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
  14   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  15 endif()
  16
  17 if( LLVM_ENABLE_ASSERTIONS )
  18   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  19   if( NOT MSVC )
  20     add_definitions( -D_DEBUG )
  21   endif()
  22   # On non-Debug builds cmake automatically defines NDEBUG, so we
  23   # explicitly undefine it:
  24   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  25     add_definitions( -UNDEBUG )
  26     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  27     set(REGEXP_NDEBUG "(^| )[/-]D *NDEBUG($| )")
  28     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  29       CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
  30     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  31       CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO}")
  32     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  33       CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL}")
  34   endif()
  35 else()
  36   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  37     if( NOT MSVC_IDE AND NOT XCODE )
  38       add_definitions( -DNDEBUG )
  39     endif()
  40   endif()
  41 endif()
  42
  43 if(WIN32)
  44   if(CYGWIN)
  45     set(LLVM_ON_WIN32 0)
  46     set(LLVM_ON_UNIX 1)
  47   else(CYGWIN)
  48     set(LLVM_ON_WIN32 1)
  49     set(LLVM_ON_UNIX 0)
  50   endif(CYGWIN)
  51   set(LTDL_SHLIB_EXT ".dll")
  52   set(EXEEXT ".exe")
  53   # Maximum path length is 160 for non-unicode paths
  54   set(MAXPATHLEN 160)
  55 else(WIN32)
  56   if(UNIX)
  57     set(LLVM_ON_WIN32 0)
  58     set(LLVM_ON_UNIX 1)
  59     if(APPLE)
  60       set(LTDL_SHLIB_EXT ".dylib")
  61     else(APPLE)
  62       set(LTDL_SHLIB_EXT ".so")
  63     endif(APPLE)
  64     set(EXEEXT "")
  65     # FIXME: Maximum path length is currently set to 'safe' fixed value
  66     set(MAXPATHLEN 2024)
  67   else(UNIX)
  68     MESSAGE(SEND_ERROR "Unable to determine platform")
  69   endif(UNIX)
  70 endif(WIN32)
  71
  72 function(add_flag_or_print_warning flag)
  73   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
  74   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
  75   if (C_SUPPORTS_FLAG AND CXX_SUPPORTS_FLAG)
  76     message(STATUS "Building with ${flag}")
  77     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
  78     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
  79   else()
  80     message(WARNING "${flag} is not supported.")
  81   endif()
  82 endfunction()
  83
  84 function(append value)
  85   foreach(variable ${ARGN})
  86     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
  87   endforeach(variable)
  88 endfunction()
  89
  90 function(append_if condition value)
  91   if (${condition})
  92     foreach(variable ${ARGN})
  93       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
  94     endforeach(variable)
  95   endif()
  96 endfunction()
  97
  98 macro(add_flag_if_supported flag)
  99   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
 100   append_if(C_SUPPORTS_FLAG "${flag}" CMAKE_C_FLAGS)
 101   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
 102   append_if(CXX_SUPPORTS_FLAG "${flag}" CMAKE_CXX_FLAGS)
 103 endmacro()
 104
 105 if( LLVM_ENABLE_PIC )
 106   if( XCODE )
 107     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 108     # know how to disable this, so just force ENABLE_PIC off for now.
 109     message(WARNING "-fPIC not supported with Xcode.")
 110   elseif( WIN32 OR CYGWIN)
 111     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 112   else()
 113     add_flag_or_print_warning("-fPIC")
 114
 115     if( WIN32 OR CYGWIN)
 116       # MinGW warns if -fvisibility-inlines-hidden is used.
 117     else()
 118       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 119       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 120     endif()
 121   endif()
 122 endif()
 123
 124 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 125   # TODO: support other platforms and toolchains.
 126   if( LLVM_BUILD_32_BITS )
 127     message(STATUS "Building 32 bits executables and libraries.")
 128     add_llvm_definitions( -m32 )
 129     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 130     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 131     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 132   endif( LLVM_BUILD_32_BITS )
 133 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 134
 135 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 136 # to use.
 137 if( MSVC_IDE )
 138   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 139     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 140   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 141     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 142       add_llvm_definitions( /MP )
 143     else()
 144       if (MSVC10)
 145         message(FATAL_ERROR
 146           "Due to a bug in CMake only 0 and 1 is supported for "
 147           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 148       else()
 149         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 150         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 151       endif()
 152     endif()
 153   else()
 154     message(STATUS "Parallel compilation disabled")
 155   endif()
 156 endif()
 157
 158 if( MSVC )
 159   include(ChooseMSVCCRT)
 160
 161   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 162     # set stack reserved size to ~10MB
 163     # CMake previously automatically set this value for MSVC builds, but the
 164     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 165     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 166     # C++ templates in Clang.
 167     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 168   endif()
 169
 170   if( MSVC10 )
 171     # MSVC 10 will complain about headers in the STL not being exported, but
 172     # will not complain in MSVC 11.
 173     add_llvm_definitions(
 174       -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 175     )
 176   elseif( MSVC11 )
 177     add_llvm_definitions(-D_VARIADIC_MAX=10)
 178   endif()
 179
 180   # Add definitions that make MSVC much less annoying.
 181   add_llvm_definitions(
 182     # For some reason MS wants to deprecate a bunch of standard functions...
 183     -D_CRT_SECURE_NO_DEPRECATE
 184     -D_CRT_SECURE_NO_WARNINGS
 185     -D_CRT_NONSTDC_NO_DEPRECATE
 186     -D_CRT_NONSTDC_NO_WARNINGS
 187     -D_SCL_SECURE_NO_DEPRECATE
 188     -D_SCL_SECURE_NO_WARNINGS
 189
 190     # Disabled warnings.
 191     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 192     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 193     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 194     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 195     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 196     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 197     -wd4355 # Suppress ''this' : used in base member initializer list'
 198     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 199     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 200     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 201     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 202
 203     # Promoted warnings.
 204     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 205
 206     # Promoted warnings to errors.
 207     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 208     )
 209
 210   # Enable warnings
 211   if (LLVM_ENABLE_WARNINGS)
 212     add_llvm_definitions( /W4 )
 213     if (LLVM_ENABLE_PEDANTIC)
 214       # No MSVC equivalent available
 215     endif (LLVM_ENABLE_PEDANTIC)
 216   endif (LLVM_ENABLE_WARNINGS)
 217   if (LLVM_ENABLE_WERROR)
 218     add_llvm_definitions( /WX )
 219   endif (LLVM_ENABLE_WERROR)
 220 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 221   if (LLVM_ENABLE_WARNINGS)
 222     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 223
 224     # Turn off missing field initializer warnings for gcc to avoid noise from
 225     # false positives with empty {}. Turn them on otherwise (they're off by
 226     # default for clang).
 227     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 228     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 229       if (CMAKE_COMPILER_IS_GNUCXX)
 230         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 231       else()
 232         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 233       endif()
 234     endif()
 235
 236     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 237     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 238     append_if(CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_CXX_FLAGS)
 239     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 240     append_if(C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_C_FLAGS)
 241     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 242     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 243     check_cxx_compiler_flag("-Werror -Wnon-virtual-dtor" CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG)
 244     append_if(CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 245   endif (LLVM_ENABLE_WARNINGS)
 246   if (LLVM_ENABLE_WERROR)
 247     add_llvm_definitions( -Werror )
 248   endif (LLVM_ENABLE_WERROR)
 249   if (LLVM_ENABLE_CXX11)
 250     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 251     append_if(CXX_SUPPORTS_CXX11 "-std=c++11" CMAKE_CXX_FLAGS)
 252   endif (LLVM_ENABLE_CXX11)
 253 endif( MSVC )
 254
 255 macro(append_common_sanitizer_flags)
 256   # Append -fno-omit-frame-pointer and turn on debug info to get better
 257   # stack traces.
 258   add_flag_if_supported("-fno-omit-frame-pointer")
 259   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 260       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 261     add_flag_if_supported("-gline-tables-only")
 262   endif()
 263   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 264   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 265     add_flag_if_supported("-O1")
 266   endif()
 267 endmacro()
 268
 269 # Turn on sanitizers if necessary.
 270 if(LLVM_USE_SANITIZER)
 271   if (LLVM_ON_UNIX)
 272     if (LLVM_USE_SANITIZER STREQUAL "Address")
 273       append_common_sanitizer_flags()
 274       add_flag_or_print_warning("-fsanitize=address")
 275     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 276       append_common_sanitizer_flags()
 277       add_flag_or_print_warning("-fsanitize=memory")
 278       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 279         add_flag_or_print_warning("-fsanitize-memory-track-origins")
 280       endif()
 281     else()
 282       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 283     endif()
 284   else()
 285     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 286   endif()
 287 endif()
 288
 289 # Turn on -gsplit-dwarf if requested
 290 if(LLVM_USE_SPLIT_DWARF)
 291   add_llvm_definitions("-gsplit-dwarf")
 292 endif()
 293
 294 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 295 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 296 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 297
 298 # clang doesn't print colored diagnostics when invoked from Ninja
 299 if (UNIX AND
 300     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 301     CMAKE_GENERATOR STREQUAL "Ninja")
 302   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 303 endif()