cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(HandleLLVMStdlib)
   6 include(AddLLVMDefinitions)
   7 include(CheckCCompilerFlag)
   8 include(CheckCXXCompilerFlag)
   9
  10 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
  11   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  12     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
  13       message(FATAL_ERROR "Host GCC version must be at least 4.7!")
  14     endif()
  15   elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  16     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
  17       message(FATAL_ERROR "Host Clang version must be at least 3.1!")
  18     endif()
  19
  20     # Also test that we aren't using too old of a version of libstdc++ with the
  21     # Clang compiler. This is tricky as there is no real way to check the
  22     # version of libstdc++ directly. Instead we test for a known bug in
  23     # libstdc++4.6 that is fixed in libstdc++4.7.
  24     if(NOT LLVM_ENABLE_LIBCXX)
  25       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  26       set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  27       set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
  28       if (ANDROID)
  29         set(CMAKE_REQUIRED_LIBRARIES "atomic")
  30       endif()
  31       check_cxx_source_compiles("
  32 #include <atomic>
  33 std::atomic<float> x(0.0f);
  34 int main() { return (float)x; }"
  35         LLVM_NO_OLD_LIBSTDCXX)
  36       if(NOT LLVM_NO_OLD_LIBSTDCXX)
  37         message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
  38       endif()
  39       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
  40       set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
  41     endif()
  42   elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  43     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 17.0)
  44       message(FATAL_ERROR "Host Visual Studio must be at least 2012 (MSVC 17.0)")
  45     endif()
  46   endif()
  47 endif()
  48
  49 if( LLVM_ENABLE_ASSERTIONS )
  50   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  51   if( NOT MSVC )
  52     add_definitions( -D_DEBUG )
  53   endif()
  54   # On non-Debug builds cmake automatically defines NDEBUG, so we
  55   # explicitly undefine it:
  56   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  57     add_definitions( -UNDEBUG )
  58     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  59     set(REGEXP_NDEBUG "(^| )[/-]D *NDEBUG($| )")
  60     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  61       CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
  62     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  63       CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO}")
  64     string (REGEX REPLACE "${REGEXP_NDEBUG}" " "
  65       CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL}")
  66   endif()
  67 else()
  68   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  69     if( NOT MSVC_IDE AND NOT XCODE )
  70       add_definitions( -DNDEBUG )
  71     endif()
  72   endif()
  73 endif()
  74
  75 if(WIN32)
  76   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  77   if(CYGWIN)
  78     set(LLVM_ON_WIN32 0)
  79     set(LLVM_ON_UNIX 1)
  80   else(CYGWIN)
  81     set(LLVM_ON_WIN32 1)
  82     set(LLVM_ON_UNIX 0)
  83   endif(CYGWIN)
  84   # Maximum path length is 160 for non-unicode paths
  85   set(MAXPATHLEN 160)
  86 else(WIN32)
  87   if(UNIX)
  88     set(LLVM_ON_WIN32 0)
  89     set(LLVM_ON_UNIX 1)
  90     if(APPLE)
  91       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  92     else(APPLE)
  93       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
  94     endif(APPLE)
  95     # FIXME: Maximum path length is currently set to 'safe' fixed value
  96     set(MAXPATHLEN 2024)
  97   else(UNIX)
  98     MESSAGE(SEND_ERROR "Unable to determine platform")
  99   endif(UNIX)
 100 endif(WIN32)
 101
 102 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 103 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 104
 105 # We use *.dylib rather than *.so on darwin.
 106 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 107
 108 function(add_flag_or_print_warning flag)
 109   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
 110   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
 111   if (C_SUPPORTS_FLAG AND CXX_SUPPORTS_FLAG)
 112     message(STATUS "Building with ${flag}")
 113     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 114     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 115   else()
 116     message(WARNING "${flag} is not supported.")
 117   endif()
 118 endfunction()
 119
 120 function(append value)
 121   foreach(variable ${ARGN})
 122     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 123   endforeach(variable)
 124 endfunction()
 125
 126 function(append_if condition value)
 127   if (${condition})
 128     foreach(variable ${ARGN})
 129       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 130     endforeach(variable)
 131   endif()
 132 endfunction()
 133
 134 macro(add_flag_if_supported flag)
 135   check_c_compiler_flag(${flag} C_SUPPORTS_FLAG)
 136   append_if(C_SUPPORTS_FLAG "${flag}" CMAKE_C_FLAGS)
 137   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_FLAG)
 138   append_if(CXX_SUPPORTS_FLAG "${flag}" CMAKE_CXX_FLAGS)
 139 endmacro()
 140
 141 if( LLVM_ENABLE_PIC )
 142   if( XCODE )
 143     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 144     # know how to disable this, so just force ENABLE_PIC off for now.
 145     message(WARNING "-fPIC not supported with Xcode.")
 146   elseif( WIN32 OR CYGWIN)
 147     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 148   else()
 149     add_flag_or_print_warning("-fPIC")
 150
 151     if( WIN32 OR CYGWIN)
 152       # MinGW warns if -fvisibility-inlines-hidden is used.
 153     else()
 154       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 155       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 156     endif()
 157   endif()
 158 endif()
 159
 160 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 161   # TODO: support other platforms and toolchains.
 162   if( LLVM_BUILD_32_BITS )
 163     message(STATUS "Building 32 bits executables and libraries.")
 164     add_llvm_definitions( -m32 )
 165     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 166     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 167     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 168   endif( LLVM_BUILD_32_BITS )
 169 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 170
 171 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 172 # to use.
 173 if( MSVC_IDE )
 174   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 175     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 176   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 177     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 178       add_llvm_definitions( /MP )
 179     else()
 180       if (MSVC10)
 181         message(FATAL_ERROR
 182           "Due to a bug in CMake only 0 and 1 is supported for "
 183           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 184       else()
 185         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 186         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 187       endif()
 188     endif()
 189   else()
 190     message(STATUS "Parallel compilation disabled")
 191   endif()
 192 endif()
 193
 194 if( MSVC )
 195   include(ChooseMSVCCRT)
 196
 197   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 198     # set stack reserved size to ~10MB
 199     # CMake previously automatically set this value for MSVC builds, but the
 200     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 201     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 202     # C++ templates in Clang.
 203     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 204   endif()
 205
 206   if( MSVC10 )
 207     # MSVC 10 will complain about headers in the STL not being exported, but
 208     # will not complain in MSVC 11.
 209     add_llvm_definitions(
 210       -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 211     )
 212   elseif( MSVC11 )
 213     add_llvm_definitions(-D_VARIADIC_MAX=10)
 214   endif()
 215
 216   # Add definitions that make MSVC much less annoying.
 217   add_llvm_definitions(
 218     # For some reason MS wants to deprecate a bunch of standard functions...
 219     -D_CRT_SECURE_NO_DEPRECATE
 220     -D_CRT_SECURE_NO_WARNINGS
 221     -D_CRT_NONSTDC_NO_DEPRECATE
 222     -D_CRT_NONSTDC_NO_WARNINGS
 223     -D_SCL_SECURE_NO_DEPRECATE
 224     -D_SCL_SECURE_NO_WARNINGS
 225
 226     # Disabled warnings.
 227     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 228     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 229     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 230     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 231     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 232     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 233     -wd4355 # Suppress ''this' : used in base member initializer list'
 234     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 235     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 236     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 237     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 238
 239     # Promoted warnings.
 240     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 241
 242     # Promoted warnings to errors.
 243     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 244     )
 245
 246   # Enable warnings
 247   if (LLVM_ENABLE_WARNINGS)
 248     add_llvm_definitions( /W4 )
 249     if (LLVM_ENABLE_PEDANTIC)
 250       # No MSVC equivalent available
 251     endif (LLVM_ENABLE_PEDANTIC)
 252   endif (LLVM_ENABLE_WARNINGS)
 253   if (LLVM_ENABLE_WERROR)
 254     add_llvm_definitions( /WX )
 255   endif (LLVM_ENABLE_WERROR)
 256 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 257   if (LLVM_ENABLE_WARNINGS)
 258     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 259
 260     # Turn off missing field initializer warnings for gcc to avoid noise from
 261     # false positives with empty {}. Turn them on otherwise (they're off by
 262     # default for clang).
 263     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 264     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 265       if (CMAKE_COMPILER_IS_GNUCXX)
 266         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 267       else()
 268         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 269       endif()
 270     endif()
 271
 272     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 273     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 274     append_if(CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_CXX_FLAGS)
 275     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 276     append_if(C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_C_FLAGS)
 277     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 278     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 279     check_cxx_compiler_flag("-Werror -Wnon-virtual-dtor" CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG)
 280     append_if(CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 281   endif (LLVM_ENABLE_WARNINGS)
 282   if (LLVM_ENABLE_WERROR)
 283     add_llvm_definitions( -Werror )
 284   endif (LLVM_ENABLE_WERROR)
 285   if (LLVM_ENABLE_CXX11)
 286     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 287     append_if(CXX_SUPPORTS_CXX11 "-std=c++11" CMAKE_CXX_FLAGS)
 288   endif (LLVM_ENABLE_CXX11)
 289 endif( MSVC )
 290
 291 macro(append_common_sanitizer_flags)
 292   # Append -fno-omit-frame-pointer and turn on debug info to get better
 293   # stack traces.
 294   add_flag_if_supported("-fno-omit-frame-pointer")
 295   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 296       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 297     add_flag_if_supported("-gline-tables-only")
 298   endif()
 299   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 300   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 301     add_flag_if_supported("-O1")
 302   endif()
 303 endmacro()
 304
 305 # Turn on sanitizers if necessary.
 306 if(LLVM_USE_SANITIZER)
 307   if (LLVM_ON_UNIX)
 308     if (LLVM_USE_SANITIZER STREQUAL "Address")
 309       append_common_sanitizer_flags()
 310       add_flag_or_print_warning("-fsanitize=address")
 311     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 312       append_common_sanitizer_flags()
 313       add_flag_or_print_warning("-fsanitize=memory")
 314       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 315         add_flag_or_print_warning("-fsanitize-memory-track-origins")
 316       endif()
 317     else()
 318       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 319     endif()
 320   else()
 321     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 322   endif()
 323 endif()
 324
 325 # Turn on -gsplit-dwarf if requested
 326 if(LLVM_USE_SPLIT_DWARF)
 327   add_llvm_definitions("-gsplit-dwarf")
 328 endif()
 329
 330 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 331 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 332 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 333
 334 # clang doesn't print colored diagnostics when invoked from Ninja
 335 if (UNIX AND
 336     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 337     CMAKE_GENERATOR STREQUAL "Ninja")
 338   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 339 endif()
 340
 341 # Add flags for add_dead_strip().
 342 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 343 # But MinSizeRel seems to add that automatically, so maybe disable these
 344 # flags instead if LLVM_NO_DEAD_STRIP is set.
 345 if(NOT CYGWIN AND NOT WIN32)
 346   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 347     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 348     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 349       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 350       # Doing so will break sanitizers.
 351       check_c_compiler_flag("-Werror -ffunction-sections" C_SUPPORTS_FFUNCTION_SECTIONS)
 352       check_cxx_compiler_flag("-Werror -ffunction-sections" CXX_SUPPORTS_FFUNCTION_SECTIONS)
 353       append_if(C_SUPPORTS_FFUNCTION_SECTIONS "-ffunction-sections" CMAKE_C_FLAGS)
 354       append_if(CXX_SUPPORTS_FFUNCTION_SECTIONS "-ffunction-sections" CMAKE_CXX_FLAGS)
 355     endif()
 356     check_c_compiler_flag("-Werror -fdata-sections" C_SUPPORTS_FDATA_SECTIONS)
 357     check_cxx_compiler_flag("-Werror -fdata-sections" CXX_SUPPORTS_FDATA_SECTIONS)
 358     append_if(C_SUPPORTS_FDATA_SECTIONS "-fdata-sections" CMAKE_C_FLAGS)
 359     append_if(CXX_SUPPORTS_FDATA_SECTIONS "-fdata-sections" CMAKE_CXX_FLAGS)
 360   endif()
 361 endif()
 362
 363 if(MSVC)
 364   # Remove flags here, for exceptions and RTTI.
 365   # Each target property or source property should be responsible to control
 366   # them.
 367   # CL.EXE complains to override flags like "/GR /GR-".
 368   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 369   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 370 endif()