cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(AddLLVMDefinitions)
   6 include(CheckCCompilerFlag)
   7 include(CheckCXXCompilerFlag)
   8
   9 if( CMAKE_COMPILER_IS_GNUCXX )
  10   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  11 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
  12   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  13 endif()
  14
  15 if( LLVM_ENABLE_ASSERTIONS )
  16   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  17   if( NOT MSVC )
  18     add_definitions( -D_DEBUG )
  19   endif()
  20   # On Release builds cmake automatically defines NDEBUG, so we
  21   # explicitly undefine it:
  22   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  23     add_definitions( -UNDEBUG )
  24   endif()
  25 else()
  26   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  27     if( NOT MSVC_IDE AND NOT XCODE )
  28       add_definitions( -DNDEBUG )
  29     endif()
  30   endif()
  31 endif()
  32
  33 if(WIN32)
  34   if(CYGWIN)
  35     set(LLVM_ON_WIN32 0)
  36     set(LLVM_ON_UNIX 1)
  37   else(CYGWIN)
  38     set(LLVM_ON_WIN32 1)
  39     set(LLVM_ON_UNIX 0)
  40   endif(CYGWIN)
  41   set(LTDL_SHLIB_EXT ".dll")
  42   set(EXEEXT ".exe")
  43   # Maximum path length is 160 for non-unicode paths
  44   set(MAXPATHLEN 160)
  45 else(WIN32)
  46   if(UNIX)
  47     set(LLVM_ON_WIN32 0)
  48     set(LLVM_ON_UNIX 1)
  49     if(APPLE)
  50       set(LTDL_SHLIB_EXT ".dylib")
  51     else(APPLE)
  52       set(LTDL_SHLIB_EXT ".so")
  53     endif(APPLE)
  54     set(EXEEXT "")
  55     # FIXME: Maximum path length is currently set to 'safe' fixed value
  56     set(MAXPATHLEN 2024)
  57   else(UNIX)
  58     MESSAGE(SEND_ERROR "Unable to determine platform")
  59   endif(UNIX)
  60 endif(WIN32)
  61
  62 function(add_flag_or_print_warning flag)
  63   check_c_compiler_flag(${flag} C_SUPPORTS_${flag})
  64   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_${flag})
  65   if (C_SUPPORTS_${flag} AND CXX_SUPPORTS_${flag})
  66     message(STATUS "Building with ${flag}")
  67     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
  68     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
  69   else()
  70     message(WARNING "${flag} is not supported.")
  71   endif()
  72 endfunction()
  73
  74 function(append value)
  75   foreach(variable ${ARGN})
  76     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
  77   endforeach(variable)
  78 endfunction()
  79
  80 function(append_if condition value)
  81   if (${condition})
  82     foreach(variable ${ARGN})
  83       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
  84     endforeach(variable)
  85   endif()
  86 endfunction()
  87
  88 if( LLVM_ENABLE_PIC )
  89   if( XCODE )
  90     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
  91     # know how to disable this, so just force ENABLE_PIC off for now.
  92     message(WARNING "-fPIC not supported with Xcode.")
  93   elseif( WIN32 OR CYGWIN)
  94     # On Windows all code is PIC. MinGW warns if -fPIC is used.
  95   else()
  96     add_flag_or_print_warning("-fPIC")
  97
  98     if( WIN32 OR CYGWIN)
  99       # MinGW warns if -fvisibility-inlines-hidden is used.
 100     else()
 101       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 102       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 103     endif()
 104   endif()
 105 endif()
 106
 107 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 108   # TODO: support other platforms and toolchains.
 109   if( LLVM_BUILD_32_BITS )
 110     message(STATUS "Building 32 bits executables and libraries.")
 111     add_llvm_definitions( -m32 )
 112     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 113     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 114     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 115   endif( LLVM_BUILD_32_BITS )
 116 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 117
 118 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 119 # to use.
 120 if( MSVC_IDE )
 121   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 122     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 123   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 124     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 125       add_llvm_definitions( /MP )
 126     else()
 127       if (MSVC10)
 128         message(FATAL_ERROR
 129           "Due to a bug in CMake only 0 and 1 is supported for "
 130           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 131       else()
 132         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 133         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 134       endif()
 135     endif()
 136   else()
 137     message(STATUS "Parallel compilation disabled")
 138   endif()
 139 endif()
 140
 141 if( MSVC )
 142   include(ChooseMSVCCRT)
 143
 144   if( MSVC11 )
 145     add_llvm_definitions(-D_VARIADIC_MAX=10)
 146   endif()
 147
 148   # Add definitions that make MSVC much less annoying.
 149   add_llvm_definitions(
 150     # For some reason MS wants to deprecate a bunch of standard functions...
 151     -D_CRT_SECURE_NO_DEPRECATE
 152     -D_CRT_SECURE_NO_WARNINGS
 153     -D_CRT_NONSTDC_NO_DEPRECATE
 154     -D_CRT_NONSTDC_NO_WARNINGS
 155     -D_SCL_SECURE_NO_DEPRECATE
 156     -D_SCL_SECURE_NO_WARNINGS
 157
 158     # Disabled warnings.
 159     -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
 160     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 161     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 162     -wd4181 # Suppress 'qualifier applied to reference type; ignored'
 163     -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
 164     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 165     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 166     -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 167     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 168     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 169     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 170     -wd4355 # Suppress ''this' : used in base member initializer list'
 171     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 172     -wd4551 # Suppress 'function call missing argument list'
 173     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 174     -wd4715 # Suppress ''function' : not all control paths return a value'
 175     -wd4722 # Suppress ''function' : destructor never returns, potential memory leak'
 176     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 177
 178     # Promoted warnings.
 179     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 180
 181     # Promoted warnings to errors.
 182     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 183     )
 184
 185   # Enable warnings
 186   if (LLVM_ENABLE_WARNINGS)
 187     add_llvm_definitions( /W4 )
 188     if (LLVM_ENABLE_PEDANTIC)
 189       # No MSVC equivalent available
 190     endif (LLVM_ENABLE_PEDANTIC)
 191   endif (LLVM_ENABLE_WARNINGS)
 192   if (LLVM_ENABLE_WERROR)
 193     add_llvm_definitions( /WX )
 194   endif (LLVM_ENABLE_WERROR)
 195 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 196   if (LLVM_ENABLE_WARNINGS)
 197     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 198
 199     # Turn off missing field initializer warnings for gcc to avoid noise from
 200     # false positives with empty {}. Turn them on otherwise (they're off by
 201     # default for clang).
 202     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 203     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 204       if (CMAKE_COMPILER_IS_GNUCXX)
 205         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 206       else()
 207         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 208       endif()
 209     endif()
 210
 211     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 212     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 213     append_if(CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_CXX_FLAGS)
 214     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 215     append_if(C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG "-Wcovered-switch-default" CMAKE_C_FLAGS)
 216     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 217     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 218     check_cxx_compiler_flag("-Werror -Wnon-virtual-dtor" CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG)
 219     append_if(CXX_SUPPORTS_NON_VIRTUAL_DTOR_FLAG "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 220   endif (LLVM_ENABLE_WARNINGS)
 221   if (LLVM_ENABLE_WERROR)
 222     add_llvm_definitions( -Werror )
 223   endif (LLVM_ENABLE_WERROR)
 224 endif( MSVC )
 225
 226 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 227 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 228 add_llvm_definitions( -D__STDC_LIMIT_MACROS )