cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(HandleLLVMStdlib)
  10 include(AddLLVMDefinitions)
  11 include(CheckCCompilerFlag)
  12 include(CheckCXXCompilerFlag)
  13
  14 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
  15   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  16     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
  17       message(FATAL_ERROR "Host GCC version must be at least 4.7!")
  18     endif()
  19   elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  20     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
  21       message(FATAL_ERROR "Host Clang version must be at least 3.1!")
  22     endif()
  23
  24     if (CMAKE_CXX_SIMULATE_ID MATCHES "MSVC")
  25       if (CMAKE_CXX_SIMULATE_VERSION VERSION_LESS 18.0)
  26         message(FATAL_ERROR "Host Clang must have at least -fms-compatibility-version=18.0")
  27       endif()
  28       set(CLANG_CL 1)
  29     elseif(NOT LLVM_ENABLE_LIBCXX)
  30       # Otherwise, test that we aren't using too old of a version of libstdc++
  31       # with the Clang compiler. This is tricky as there is no real way to
  32       # check the version of libstdc++ directly. Instead we test for a known
  33       # bug in libstdc++4.6 that is fixed in libstdc++4.7.
  34       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  35       set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  36       set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
  37       check_cxx_source_compiles("
  38 #include <atomic>
  39 std::atomic<float> x(0.0f);
  40 int main() { return (float)x; }"
  41         LLVM_NO_OLD_LIBSTDCXX)
  42       if(NOT LLVM_NO_OLD_LIBSTDCXX)
  43         message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
  44       endif()
  45       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
  46       set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
  47     endif()
  48   elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  49     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 18.0)
  50       message(FATAL_ERROR "Host Visual Studio must be at least 2013")
  51     elseif(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 18.0.31101)
  52       message(WARNING "Host Visual Studio should at least be 2013 Update 4 (MSVC 18.0.31101)"
  53         "  due to miscompiles from earlier versions")
  54     endif()
  55   endif()
  56 endif()
  57
  58 if( LLVM_ENABLE_ASSERTIONS )
  59   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  60   if( NOT MSVC )
  61     add_definitions( -D_DEBUG )
  62   endif()
  63   # On non-Debug builds cmake automatically defines NDEBUG, so we
  64   # explicitly undefine it:
  65   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  66     add_definitions( -UNDEBUG )
  67     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  68     foreach (flags_var_to_scrub
  69         CMAKE_CXX_FLAGS_RELEASE
  70         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  71         CMAKE_CXX_FLAGS_MINSIZEREL
  72         CMAKE_C_FLAGS_RELEASE
  73         CMAKE_C_FLAGS_RELWITHDEBINFO
  74         CMAKE_C_FLAGS_MINSIZEREL)
  75       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  76         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  77     endforeach()
  78   endif()
  79 endif()
  80
  81 string(TOUPPER "${LLVM_ABI_BREAKING_CHECKS}" uppercase_LLVM_ABI_BREAKING_CHECKS)
  82
  83 if( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "WITH_ASSERTS" )
  84   if( LLVM_ENABLE_ASSERTIONS )
  85     set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  86   endif()
  87 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_ON" )
  88   set( LLVM_ENABLE_ABI_BREAKING_CHECKS 1 )
  89 elseif( uppercase_LLVM_ABI_BREAKING_CHECKS STREQUAL "FORCE_OFF" )
  90   # We don't need to do anything special to turn off ABI breaking checks.
  91 elseif( NOT DEFINED LLVM_ABI_BREAKING_CHECKS )
  92   # Treat LLVM_ABI_BREAKING_CHECKS like "FORCE_OFF" when it has not been
  93   # defined.
  94 else()
  95   message(FATAL_ERROR "Unknown value for LLVM_ABI_BREAKING_CHECKS: \"${LLVM_ABI_BREAKING_CHECKS}\"!")
  96 endif()
  97
  98 if(WIN32)
  99   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 100   if(CYGWIN)
 101     set(LLVM_ON_WIN32 0)
 102     set(LLVM_ON_UNIX 1)
 103   else(CYGWIN)
 104     set(LLVM_ON_WIN32 1)
 105     set(LLVM_ON_UNIX 0)
 106   endif(CYGWIN)
 107 else(WIN32)
 108   if(UNIX)
 109     set(LLVM_ON_WIN32 0)
 110     set(LLVM_ON_UNIX 1)
 111     if(APPLE)
 112       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
 113     else(APPLE)
 114       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
 115     endif(APPLE)
 116   else(UNIX)
 117     MESSAGE(SEND_ERROR "Unable to determine platform")
 118   endif(UNIX)
 119 endif(WIN32)
 120
 121 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
 122 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 123
 124 # We use *.dylib rather than *.so on darwin.
 125 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 126
 127 if(APPLE)
 128   # Darwin-specific linker flags for loadable modules.
 129   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 130 endif()
 131
 132 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 133 # build might work on ELF but fail on MachO/COFF.
 134 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32 OR
 135         ${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD") AND
 136    NOT LLVM_USE_SANITIZER)
 137   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 138 endif()
 139
 140
 141 function(append value)
 142   foreach(variable ${ARGN})
 143     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 144   endforeach(variable)
 145 endfunction()
 146
 147 function(append_if condition value)
 148   if (${condition})
 149     foreach(variable ${ARGN})
 150       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 151     endforeach(variable)
 152   endif()
 153 endfunction()
 154
 155 macro(add_flag_if_supported flag name)
 156   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 157   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 158   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 159   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 160 endmacro()
 161
 162 function(add_flag_or_print_warning flag name)
 163   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 164   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 165   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 166     message(STATUS "Building with ${flag}")
 167     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 168     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 169   else()
 170     message(WARNING "${flag} is not supported.")
 171   endif()
 172 endfunction()
 173
 174 if( LLVM_ENABLE_PIC )
 175   if( XCODE )
 176     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 177     # know how to disable this, so just force ENABLE_PIC off for now.
 178     message(WARNING "-fPIC not supported with Xcode.")
 179   elseif( WIN32 OR CYGWIN)
 180     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 181   else()
 182     add_flag_or_print_warning("-fPIC" FPIC)
 183
 184     if( WIN32 OR CYGWIN)
 185       # MinGW warns if -fvisibility-inlines-hidden is used.
 186     else()
 187       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 188       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 189     endif()
 190   endif()
 191 endif()
 192
 193 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 194   # TODO: support other platforms and toolchains.
 195   if( LLVM_BUILD_32_BITS )
 196     message(STATUS "Building 32 bits executables and libraries.")
 197     add_llvm_definitions( -m32 )
 198     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 199     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 200     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 201   endif( LLVM_BUILD_32_BITS )
 202 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 203
 204 if (LLVM_BUILD_STATIC)
 205   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 206 endif()
 207
 208 if( XCODE )
 209   # For Xcode enable several build settings that correspond to
 210   # many warnings that are on by default in Clang but are
 211   # not enabled for historical reasons.  For versions of Xcode
 212   # that do not support these options they will simply
 213   # be ignored.
 214   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 215   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 216   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 217   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 218   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 219   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 220   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 221   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 222   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 223   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 224   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 225   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 226   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 227   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 228   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 229 endif()
 230
 231 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 232 # to use.
 233 if( MSVC_IDE )
 234   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 235     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 236   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 237     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 238       add_llvm_definitions( /MP )
 239     else()
 240       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 241       add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 242     endif()
 243   else()
 244     message(STATUS "Parallel compilation disabled")
 245   endif()
 246 endif()
 247
 248 if( MSVC )
 249   include(ChooseMSVCCRT)
 250
 251   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 252     # set stack reserved size to ~10MB
 253     # CMake previously automatically set this value for MSVC builds, but the
 254     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 255     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 256     # C++ templates in Clang.
 257     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 258   endif()
 259
 260   if( MSVC11 )
 261     add_llvm_definitions(-D_VARIADIC_MAX=10)
 262   endif()
 263
 264   # Add definitions that make MSVC much less annoying.
 265   add_llvm_definitions(
 266     # For some reason MS wants to deprecate a bunch of standard functions...
 267     -D_CRT_SECURE_NO_DEPRECATE
 268     -D_CRT_SECURE_NO_WARNINGS
 269     -D_CRT_NONSTDC_NO_DEPRECATE
 270     -D_CRT_NONSTDC_NO_WARNINGS
 271     -D_SCL_SECURE_NO_DEPRECATE
 272     -D_SCL_SECURE_NO_WARNINGS
 273     )
 274
 275   set(msvc_warning_flags
 276     # Disabled warnings.
 277     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 278     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 279     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 280     -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 281     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 282     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 283     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 284     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 285     -wd4355 # Suppress ''this' : used in base member initializer list'
 286     -wd4456 # Suppress 'declaration of 'var' hides local variable'
 287     -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 288     -wd4458 # Suppress 'declaration of 'var' hides class member'
 289     -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 290     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 291     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 292     -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 293     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 294     -wd4100 # Suppress 'unreferenced formal parameter'
 295     -wd4127 # Suppress 'conditional expression is constant'
 296     -wd4512 # Suppress 'assignment operator could not be generated'
 297     -wd4505 # Suppress 'unreferenced local function has been removed'
 298     -wd4610 # Suppress '<class> can never be instantiated'
 299     -wd4510 # Suppress 'default constructor could not be generated'
 300     -wd4702 # Suppress 'unreachable code'
 301     -wd4245 # Suppress 'signed/unsigned mismatch'
 302     -wd4706 # Suppress 'assignment within conditional expression'
 303     -wd4310 # Suppress 'cast truncates constant value'
 304     -wd4701 # Suppress 'potentially uninitialized local variable'
 305     -wd4703 # Suppress 'potentially uninitialized local pointer variable'
 306     -wd4389 # Suppress 'signed/unsigned mismatch'
 307     -wd4611 # Suppress 'interaction between '_setjmp' and C++ object destruction is non-portable'
 308     -wd4805 # Suppress 'unsafe mix of type <type> and type <type> in operation'
 309     -wd4204 # Suppress 'nonstandard extension used : non-constant aggregate initializer'
 310
 311         # Ideally, we'd like this warning to be enabled, but MSVC 2013 doesn't
 312         # support the 'aligned' attribute in the way that clang sources requires (for
 313         # any code that uses the LLVM_ALIGNAS macro), so this is must be disabled to
 314         # avoid unwanted alignment warnings.
 315         # When we switch to requiring a version of MSVC that supports the 'alignas'
 316         # specifier (MSVC 2015?) this warning can be re-enabled.
 317     -wd4324 # Suppress 'structure was padded due to __declspec(align())'
 318
 319     # Promoted warnings.
 320     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 321
 322     # Promoted warnings to errors.
 323     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 324     )
 325
 326   # Enable warnings
 327   if (LLVM_ENABLE_WARNINGS)
 328     append("/W4" msvc_warning_flags)
 329     # CMake appends /W3 by default, and having /W3 followed by /W4 will result in
 330     # cl : Command line warning D9025 : overriding '/W3' with '/W4'.  Since this is
 331     # a command line warning and not a compiler warning, it cannot be suppressed except
 332     # by fixing the command line.
 333     string(REGEX REPLACE " /W[0-4]" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
 334     string(REGEX REPLACE " /W[0-4]" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 335
 336     if (LLVM_ENABLE_PEDANTIC)
 337       # No MSVC equivalent available
 338     endif (LLVM_ENABLE_PEDANTIC)
 339   endif (LLVM_ENABLE_WARNINGS)
 340   if (LLVM_ENABLE_WERROR)
 341     append("/WX" msvc_warning_flags)
 342   endif (LLVM_ENABLE_WERROR)
 343
 344   foreach(flag ${msvc_warning_flags})
 345     append("${flag}" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 346   endforeach(flag)
 347
 348   # Disable sized deallocation if the flag is supported. MSVC fails to compile
 349   # the operator new overload in User otherwise.
 350   check_c_compiler_flag("/WX /Zc:sizedDealloc-" SUPPORTS_SIZED_DEALLOC)
 351   append_if(SUPPORTS_SIZED_DEALLOC "/Zc:sizedDealloc-" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 352
 353 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 354   if (LLVM_ENABLE_WARNINGS)
 355     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 356     append("-Wcast-qual" CMAKE_CXX_FLAGS)
 357
 358     # Turn off missing field initializer warnings for gcc to avoid noise from
 359     # false positives with empty {}. Turn them on otherwise (they're off by
 360     # default for clang).
 361     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 362     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 363       if (CMAKE_COMPILER_IS_GNUCXX)
 364         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 365       else()
 366         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 367       endif()
 368     endif()
 369
 370     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 371     add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 372     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 373     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 374
 375     # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 376     # If it does, don't add it. So it won't be added on clang 3.4 and older.
 377     # This also catches cases when -Wnon-virtual-dtor isn't supported by
 378     # the compiler at all.
 379     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 380     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 381     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 382                                class derived final : public base { public: ~derived();};
 383                                int main() { return 0; }"
 384                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 385     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 386     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 387               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 388
 389     # Check if -Wcomment is OK with an // comment ending with '\' if the next
 390     # line is also a // comment.
 391     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 392     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 393     CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 394                             C_WCOMMENT_ALLOWS_LINE_WRAP)
 395     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 396     if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 397       append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 398     endif()
 399   endif (LLVM_ENABLE_WARNINGS)
 400   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 401   if (NOT LLVM_ENABLE_TIMESTAMPS)
 402     add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 403   endif ()
 404   if (LLVM_ENABLE_CXX1Y)
 405     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 406     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 407   else()
 408     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 409     if (CXX_SUPPORTS_CXX11)
 410       if (CYGWIN OR MINGW)
 411         # MinGW and Cygwin are a bit stricter and lack things like
 412         # 'strdup', 'stricmp', etc in c++11 mode.
 413         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 414       else()
 415         append("-std=c++11" CMAKE_CXX_FLAGS)
 416       endif()
 417     else()
 418       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 419     endif()
 420   endif()
 421   if (LLVM_ENABLE_MODULES)
 422     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 423     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fmodules -fcxx-modules")
 424     # Check that we can build code with modules enabled, and that repeatedly
 425     # including <cassert> still manages to respect NDEBUG properly.
 426     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 427                                #include <cassert>
 428                                #define NDEBUG
 429                                #include <cassert>
 430                                int main() { assert(this code is not compiled); }"
 431                                CXX_SUPPORTS_MODULES)
 432     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 433     if (CXX_SUPPORTS_MODULES)
 434       append_if(CXX_SUPPORTS_MODULES "-fmodules" CMAKE_C_FLAGS)
 435       append_if(CXX_SUPPORTS_MODULES "-fmodules -fcxx-modules" CMAKE_CXX_FLAGS)
 436     else()
 437       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 438     endif()
 439   endif(LLVM_ENABLE_MODULES)
 440 endif( MSVC )
 441
 442 macro(append_common_sanitizer_flags)
 443   # Append -fno-omit-frame-pointer and turn on debug info to get better
 444   # stack traces.
 445   add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 446   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 447       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 448     add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 449   endif()
 450   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 451   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 452     add_flag_if_supported("-O1" O1)
 453   endif()
 454 endmacro()
 455
 456 # Turn on sanitizers if necessary.
 457 if(LLVM_USE_SANITIZER)
 458   if (LLVM_ON_UNIX)
 459     if (LLVM_USE_SANITIZER STREQUAL "Address")
 460       append_common_sanitizer_flags()
 461       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 462     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 463       append_common_sanitizer_flags()
 464       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 465       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 466         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 467       endif()
 468     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 469       append_common_sanitizer_flags()
 470       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 471               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 472     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 473       append_common_sanitizer_flags()
 474       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 475     elseif (LLVM_USE_SANITIZER STREQUAL "Address;Undefined" OR
 476             LLVM_USE_SANITIZER STREQUAL "Undefined;Address")
 477       append_common_sanitizer_flags()
 478       append("-fsanitize=address,undefined -fno-sanitize=vptr,function -fno-sanitize-recover=all"
 479               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 480     else()
 481       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 482     endif()
 483   else()
 484     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 485   endif()
 486   if (LLVM_USE_SANITIZE_COVERAGE)
 487     append("-fsanitize-coverage=edge,indirect-calls,8bit-counters,trace-cmp" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 488   endif()
 489 endif()
 490
 491 # Turn on -gsplit-dwarf if requested
 492 if(LLVM_USE_SPLIT_DWARF)
 493   add_definitions("-gsplit-dwarf")
 494 endif()
 495
 496 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 497 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 498 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 499
 500 # clang doesn't print colored diagnostics when invoked from Ninja
 501 if (UNIX AND
 502     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 503     CMAKE_GENERATOR STREQUAL "Ninja")
 504   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 505 endif()
 506
 507 # Add flags for add_dead_strip().
 508 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 509 # But MinSizeRel seems to add that automatically, so maybe disable these
 510 # flags instead if LLVM_NO_DEAD_STRIP is set.
 511 if(NOT CYGWIN AND NOT WIN32)
 512   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin" AND
 513      NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 514     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 515     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 516       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 517       # Doing so will break sanitizers.
 518       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 519     endif()
 520     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 521   endif()
 522 endif()
 523
 524 if(CYGWIN OR MINGW)
 525   # Prune --out-implib from executables. It doesn't make sense even
 526   # with --export-all-symbols.
 527   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 528     CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
 529   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 530     CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
 531 endif()
 532
 533 if(MSVC)
 534   # Remove flags here, for exceptions and RTTI.
 535   # Each target property or source property should be responsible to control
 536   # them.
 537   # CL.EXE complains to override flags like "/GR /GR-".
 538   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 539   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 540 endif()
 541
 542 # Provide public options to globally control RTTI and EH
 543 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 544 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 545 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 546   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 547 endif()
 548
 549 # Plugin support
 550 # FIXME: Make this configurable.
 551 if(WIN32 OR CYGWIN)
 552   if(BUILD_SHARED_LIBS)
 553     set(LLVM_ENABLE_PLUGINS ON)
 554   else()
 555     set(LLVM_ENABLE_PLUGINS OFF)
 556   endif()
 557 else()
 558   set(LLVM_ENABLE_PLUGINS ON)
 559 endif()