cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(AddLLVMDefinitions)
   6
   7 if( CMAKE_COMPILER_IS_GNUCXX )
   8   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
   9 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
  10   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  11 endif()
  12
  13 # Run-time build mode; It is used for unittests.
  14 if(MSVC_IDE)
  15   # Expect "$(Configuration)", "$(OutDir)", etc.
  16   # It is expanded by msbuild or similar.
  17   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
  18 elseif(NOT CMAKE_BUILD_TYPE STREQUAL "")
  19   # Expect "Release" "Debug", etc.
  20   # Or unittests could not run.
  21   set(RUNTIME_BUILD_MODE ${CMAKE_BUILD_TYPE})
  22 else()
  23   # It might be "."
  24   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
  25 endif()
  26
  27 if( LLVM_ENABLE_ASSERTIONS )
  28   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  29   if( NOT MSVC )
  30     add_definitions( -D_DEBUG )
  31   endif()
  32   # On Release builds cmake automatically defines NDEBUG, so we
  33   # explicitly undefine it:
  34   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  35     add_definitions( -UNDEBUG )
  36   endif()
  37 else()
  38   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  39     if( NOT MSVC_IDE AND NOT XCODE )
  40       add_definitions( -DNDEBUG )
  41     endif()
  42   endif()
  43 endif()
  44
  45 if(WIN32)
  46   if(CYGWIN)
  47     set(LLVM_ON_WIN32 0)
  48     set(LLVM_ON_UNIX 1)
  49   else(CYGWIN)
  50     set(LLVM_ON_WIN32 1)
  51     set(LLVM_ON_UNIX 0)
  52   endif(CYGWIN)
  53   set(LTDL_SHLIB_EXT ".dll")
  54   set(EXEEXT ".exe")
  55   # Maximum path length is 160 for non-unicode paths
  56   set(MAXPATHLEN 160)
  57 else(WIN32)
  58   if(UNIX)
  59     set(LLVM_ON_WIN32 0)
  60     set(LLVM_ON_UNIX 1)
  61     if(APPLE)
  62       set(LTDL_SHLIB_EXT ".dylib")
  63     else(APPLE)
  64       set(LTDL_SHLIB_EXT ".so")
  65     endif(APPLE)
  66     set(EXEEXT "")
  67     # FIXME: Maximum path length is currently set to 'safe' fixed value
  68     set(MAXPATHLEN 2024)
  69   else(UNIX)
  70     MESSAGE(SEND_ERROR "Unable to determine platform")
  71   endif(UNIX)
  72 endif(WIN32)
  73
  74 if( LLVM_ENABLE_PIC )
  75   if( XCODE )
  76     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
  77     # know how to disable this, so just force ENABLE_PIC off for now.
  78     message(WARNING "-fPIC not supported with Xcode.")
  79   elseif( WIN32 )
  80     # On Windows all code is PIC. MinGW warns if -fPIC is used.
  81   else()
  82     include(CheckCXXCompilerFlag)
  83     check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  84     if( SUPPORTS_FPIC_FLAG )
  85       message(STATUS "Building with -fPIC")
  86       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  87       set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
  88     else( SUPPORTS_FPIC_FLAG )
  89       message(WARNING "-fPIC not supported.")
  90     endif()
  91   endif()
  92 endif()
  93
  94 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
  95   # TODO: support other platforms and toolchains.
  96   if( LLVM_BUILD_32_BITS )
  97     message(STATUS "Building 32 bits executables and libraries.")
  98     add_llvm_definitions( -m32 )
  99     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 100     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 101   endif( LLVM_BUILD_32_BITS )
 102 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 103
 104 if( MSVC_IDE AND ( MSVC90 OR MSVC10 ) )
 105   # Only Visual Studio 2008 and 2010 officially supports /MP.
 106   # Visual Studio 2005 do support it but it's experimental there.
 107   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 108     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 109   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 110     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 111       add_llvm_definitions( /MP )
 112     else()
 113       if (MSVC10)
 114         message(FATAL_ERROR
 115           "Due to a bug in CMake only 0 and 1 is supported for "
 116           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 117       else()
 118         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 119         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 120       endif()
 121     endif()
 122   else()
 123     message(STATUS "Parallel compilation disabled")
 124   endif()
 125 endif()
 126
 127 if( MSVC )
 128   include(ChooseMSVCCRT)
 129
 130   # Add definitions that make MSVC much less annoying.
 131   add_llvm_definitions(
 132     # For some reason MS wants to deprecate a bunch of standard functions...
 133     -D_CRT_SECURE_NO_DEPRECATE
 134     -D_CRT_SECURE_NO_WARNINGS
 135     -D_CRT_NONSTDC_NO_DEPRECATE
 136     -D_CRT_NONSTDC_NO_WARNINGS
 137     -D_SCL_SECURE_NO_DEPRECATE
 138     -D_SCL_SECURE_NO_WARNINGS
 139
 140     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 141     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 142     -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
 143     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 144     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 145     -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 146     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 147     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 148     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 149     -wd4355 # Suppress ''this' : used in base member initializer list'
 150     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 151     -wd4551 # Suppress 'function call missing argument list'
 152     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 153     -wd4715 # Suppress ''function' : not all control paths return a value'
 154     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 155     -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
 156     -wd4181 # Suppress 'qualifier applied to reference type; ignored'
 157     -w14062 # Promote "enumerator in switch of enum is not handled" to level 1 warning.
 158     )
 159
 160   # Enable warnings
 161   if (LLVM_ENABLE_WARNINGS)
 162     add_llvm_definitions( /W4 /Wall )
 163     if (LLVM_ENABLE_PEDANTIC)
 164       # No MSVC equivalent available
 165     endif (LLVM_ENABLE_PEDANTIC)
 166   endif (LLVM_ENABLE_WARNINGS)
 167   if (LLVM_ENABLE_WERROR)
 168     add_llvm_definitions( /WX )
 169   endif (LLVM_ENABLE_WERROR)
 170 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 171   if (LLVM_ENABLE_WARNINGS)
 172     add_llvm_definitions( -Wall -W -Wno-unused-parameter -Wwrite-strings )
 173     if (LLVM_ENABLE_PEDANTIC)
 174       add_llvm_definitions( -pedantic -Wno-long-long )
 175     endif (LLVM_ENABLE_PEDANTIC)
 176   endif (LLVM_ENABLE_WARNINGS)
 177   if (LLVM_ENABLE_WERROR)
 178     add_llvm_definitions( -Werror )
 179   endif (LLVM_ENABLE_WERROR)
 180 endif( MSVC )
 181
 182 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 183 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 184 add_llvm_definitions( -D__STDC_LIMIT_MACROS )