cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 macro(add_llvm_library name)
   6   llvm_process_sources( ALL_FILES ${ARGN} )
   7   add_library( ${name} ${ALL_FILES} )
   8   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
   9   if( LLVM_COMMON_DEPENDS )
  10     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  11   endif( LLVM_COMMON_DEPENDS )
  12
  13   if( BUILD_SHARED_LIBS )
  14     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  15     if (MSVC)
  16       set_target_properties(${name}
  17         PROPERTIES
  18         IMPORT_SUFFIX ".imp")
  19     endif ()
  20   endif()
  21
  22   # Ensure that the system libraries always comes last on the
  23   # list. Without this, linking the unit tests on MinGW fails.
  24   link_system_libs( ${name} )
  25
  26   if( EXCLUDE_FROM_ALL )
  27     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
  28   else()
  29     install(TARGETS ${name}
  30       LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  31       ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  32   endif()
  33   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
  34
  35   # Add the explicit dependency information for this library.
  36   #
  37   # It would be nice to verify that we have the dependencies for this library
  38   # name, but using get_property(... SET) doesn't suffice to determine if a
  39   # property has been set to an empty value.
  40   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
  41   target_link_libraries(${name} ${lib_deps})
  42 endmacro(add_llvm_library name)
  43
  44 macro(add_llvm_loadable_module name)
  45   if( NOT LLVM_ON_UNIX OR CYGWIN )
  46     message(STATUS "Loadable modules not supported on this platform.
  47 ${name} ignored.")
  48     # Add empty "phony" target
  49     add_custom_target(${name})
  50   else()
  51     llvm_process_sources( ALL_FILES ${ARGN} )
  52     if (MODULE)
  53       set(libkind MODULE)
  54     else()
  55       set(libkind SHARED)
  56     endif()
  57
  58     add_library( ${name} ${libkind} ${ALL_FILES} )
  59     set_target_properties( ${name} PROPERTIES PREFIX "" )
  60
  61     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  62     link_system_libs( ${name} )
  63
  64     if (APPLE)
  65       # Darwin-specific linker flags for loadable modules.
  66       set_target_properties(${name} PROPERTIES
  67         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
  68     endif()
  69
  70     if( EXCLUDE_FROM_ALL )
  71       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
  72     else()
  73       install(TARGETS ${name}
  74         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  75         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  76     endif()
  77   endif()
  78
  79   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
  80 endmacro(add_llvm_loadable_module name)
  81
  82
  83 macro(add_llvm_executable name)
  84   llvm_process_sources( ALL_FILES ${ARGN} )
  85   if( EXCLUDE_FROM_ALL )
  86     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
  87   else()
  88     add_executable(${name} ${ALL_FILES})
  89   endif()
  90   set(EXCLUDE_FROM_ALL OFF)
  91   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  92   if( LLVM_COMMON_DEPENDS )
  93     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  94   endif( LLVM_COMMON_DEPENDS )
  95   link_system_libs( ${name} )
  96 endmacro(add_llvm_executable name)
  97
  98
  99 macro(add_llvm_tool name)
 100   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
 101   if( NOT LLVM_BUILD_TOOLS )
 102     set(EXCLUDE_FROM_ALL ON)
 103   endif()
 104   add_llvm_executable(${name} ${ARGN})
 105   if( LLVM_BUILD_TOOLS )
 106     install(TARGETS ${name} RUNTIME DESTINATION bin)
 107   endif()
 108   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 109 endmacro(add_llvm_tool name)
 110
 111
 112 macro(add_llvm_example name)
 113 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
 114   if( NOT LLVM_BUILD_EXAMPLES )
 115     set(EXCLUDE_FROM_ALL ON)
 116   endif()
 117   add_llvm_executable(${name} ${ARGN})
 118   if( LLVM_BUILD_EXAMPLES )
 119     install(TARGETS ${name} RUNTIME DESTINATION examples)
 120   endif()
 121   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 122 endmacro(add_llvm_example name)
 123
 124
 125 macro(add_llvm_utility name)
 126   add_llvm_executable(${name} ${ARGN})
 127   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 128 endmacro(add_llvm_utility name)
 129
 130
 131 macro(add_llvm_target target_name)
 132   include_directories(BEFORE
 133     ${CMAKE_CURRENT_BINARY_DIR}
 134     ${CMAKE_CURRENT_SOURCE_DIR})
 135   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 136   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 137 endmacro(add_llvm_target)
 138
 139 # Add external project that may want to be built as part of llvm such as Clang,
 140 # lld, and Polly. This adds two options. One for the source directory of the
 141 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 142 # enable or disable building it with everthing else.
 143 # Additional parameter can be specified as the name of directory.
 144 macro(add_llvm_external_project name)
 145   set(add_llvm_external_dir "${ARGN}")
 146   if("${add_llvm_external_dir}" STREQUAL "")
 147     set(add_llvm_external_dir ${name})
 148   endif()
 149   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 150   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 151   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 152       CACHE PATH "Path to ${name} source directory")
 153   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 154       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 155     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 156            "Whether to build ${name} as part of LLVM" ON)
 157     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 158       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 159     endif()
 160   endif()
 161 endmacro(add_llvm_external_project)
 162
 163 # Generic support for adding a unittest.
 164 function(add_unittest test_suite test_name)
 165   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 166   if( NOT LLVM_BUILD_TESTS )
 167     set(EXCLUDE_FROM_ALL ON)
 168   endif()
 169
 170   add_llvm_executable(${test_name} ${ARGN})
 171   target_link_libraries(${test_name}
 172     gtest
 173     gtest_main
 174     LLVMSupport # gtest needs it for raw_ostream.
 175     )
 176
 177   add_dependencies(${test_suite} ${test_name})
 178   get_target_property(test_suite_folder ${test_suite} FOLDER)
 179   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 180     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 181   endif ()
 182
 183   # Visual Studio 2012 only supports up to 8 template parameters in
 184   # std::tr1::tuple by default, but gtest requires 10
 185   if (MSVC AND MSVC_VERSION EQUAL 1700)
 186     set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 187   endif ()
 188
 189   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 190   set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
 191   if (NOT LLVM_ENABLE_THREADS)
 192     set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 193   endif ()
 194
 195   get_property(target_compile_flags TARGET ${test_name} PROPERTY COMPILE_FLAGS)
 196   if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 197     set(target_compile_flags "${target_compile_flags} -fno-rtti")
 198   elseif (MSVC)
 199     llvm_replace_compiler_option(target_compile_flags "/GR" "/GR-")
 200   endif ()
 201
 202   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 203     set(target_compile_flags "${target_compile_flags} -Wno-variadic-macros")
 204   endif ()
 205   set_property(TARGET ${test_name} PROPERTY COMPILE_FLAGS "${target_compile_flags}")
 206 endfunction()
 207
 208 # This function provides an automatic way to 'configure'-like generate a file
 209 # based on a set of common and custom variables, specifically targetting the
 210 # variables needed for the 'lit.site.cfg' files. This function bundles the
 211 # common variables that any Lit instance is likely to need, and custom
 212 # variables can be passed in.
 213 function(configure_lit_site_cfg input output)
 214   foreach(c ${LLVM_TARGETS_TO_BUILD})
 215     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 216   endforeach(c)
 217   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 218
 219   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 220   set(SHLIBDIR "${LLVM_BINARY_DIR}/lib/${CMAKE_CFG_INTDIR}")
 221
 222   if(BUILD_SHARED_LIBS)
 223     set(LLVM_SHARED_LIBS_ENABLED "1")
 224   else()
 225     set(LLVM_SHARED_LIBS_ENABLED "0")
 226   endif(BUILD_SHARED_LIBS)
 227
 228   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 229     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 230   else() # Default for all other unix like systems.
 231     # CMake hardcodes the library locaction using rpath.
 232     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 233     # build dir. We pass it anyways.
 234     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 235   endif()
 236
 237   # Configuration-time: See Unit/lit.site.cfg.in
 238   set(LLVM_BUILD_MODE "%(build_mode)s")
 239
 240   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 241   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 242   set(LLVM_TOOLS_DIR "${LLVM_TOOLS_BINARY_DIR}/%(build_mode)s")
 243   set(LLVM_LIBS_DIR "${LLVM_BINARY_DIR}/lib/%(build_mode)s")
 244   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 245   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 246   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 247
 248   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 249     set(ENABLE_ASSERTIONS "1")
 250   else()
 251     set(ENABLE_ASSERTIONS "0")
 252   endif()
 253
 254   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 255   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 256
 257   configure_file(${input} ${output} @ONLY)
 258 endfunction()
 259
 260 # A raw function to create a lit target. This is used to implement the testuite
 261 # management functions.
 262 function(add_lit_target target comment)
 263   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 264   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 265   separate_arguments(LIT_ARGS)
 266   set(LIT_COMMAND
 267     ${PYTHON_EXECUTABLE}
 268     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 269     --param build_mode=${CMAKE_CFG_INTDIR}
 270     ${LIT_ARGS}
 271     )
 272   foreach(param ${ARG_PARAMS})
 273     list(APPEND LIT_COMMAND --param ${param})
 274   endforeach()
 275   if( ARG_DEPENDS )
 276     add_custom_target(${target}
 277       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 278       COMMENT "${comment}"
 279       )
 280     add_dependencies(${target} ${ARG_DEPENDS})
 281   else()
 282     add_custom_target(${target}
 283       COMMAND cmake -E echo "${target} does nothing, no tools built.")
 284     message(STATUS "${target} does nothing.")
 285   endif()
 286 endfunction()
 287
 288 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 289 function(add_lit_testsuite target comment)
 290   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 291
 292   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 293   if(NOT EXCLUDE_FROM_ALL)
 294     # Register the testsuites, params and depends for the global check rule.
 295     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 296     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 297     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 298     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 299   endif()
 300
 301   # Produce a specific suffixed check rule.
 302   add_lit_target(${target} ${comment}
 303     ${ARG_DEFAULT_ARGS}
 304     PARAMS ${ARG_PARAMS}
 305     DEPENDS ${ARG_DEPENDS}
 306     ARGS ${ARG_ARGS}
 307     )
 308 endfunction()