cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3
   4 macro(add_llvm_library name)
   5   create_tablegenning_custom_target( ${name} )
   6   llvm_process_sources( ALL_FILES ${ARGN} )
   7   add_library( ${name} ${ALL_FILES} )
   8   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
   9   if( LLVM_COMMON_DEPENDS )
  10     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  11   endif( LLVM_COMMON_DEPENDS )
  12
  13   if( BUILD_SHARED_LIBS )
  14     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  15   endif()
  16
  17   # Ensure that the system libraries always comes last on the
  18   # list. Without this, linking the unit tests on MinGW fails.
  19   link_system_libs( ${name} )
  20
  21   if( EXCLUDE_FROM_ALL )
  22     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
  23   else()
  24     install(TARGETS ${name}
  25       LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  26       ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  27   endif()
  28   # The LLVM Target library shall be built before its sublibraries
  29   # (asmprinter, etc) because those may use tablegenned files which
  30   # generation is triggered by the main LLVM target library. Necessary
  31   # for parallel builds:
  32   if( CURRENT_LLVM_TARGET )
  33     add_dependencies(${name} ${CURRENT_LLVM_TARGET})
  34   endif()
  35   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
  36   add_tablegenning_dependency( ${name} )
  37 endmacro(add_llvm_library name)
  38
  39
  40 macro(add_llvm_loadable_module name)
  41   if( NOT LLVM_ON_UNIX OR CYGWIN )
  42     message(STATUS "Loadable modules not supported on this platform.
  43 ${name} ignored.")
  44     # Add empty "phony" target
  45     add_custom_target(${name})
  46   else()
  47     llvm_process_sources( ALL_FILES ${ARGN} )
  48     if (MODULE)
  49       set(libkind MODULE)
  50     else()
  51       set(libkind SHARED)
  52     endif()
  53
  54     add_library( ${name} ${libkind} ${ALL_FILES} )
  55     set_target_properties( ${name} PROPERTIES PREFIX "" )
  56
  57     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  58     link_system_libs( ${name} )
  59
  60     if (APPLE)
  61       # Darwin-specific linker flags for loadable modules.
  62       set_target_properties(${name} PROPERTIES
  63         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
  64     endif()
  65
  66     if( EXCLUDE_FROM_ALL )
  67       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
  68     else()
  69       install(TARGETS ${name}
  70         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  71         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  72     endif()
  73   endif()
  74
  75   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
  76 endmacro(add_llvm_loadable_module name)
  77
  78
  79 macro(add_llvm_executable name)
  80   create_tablegenning_custom_target( ${name} )
  81   llvm_process_sources( ALL_FILES ${ARGN} )
  82   if( EXCLUDE_FROM_ALL )
  83     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
  84   else()
  85     add_executable(${name} ${ALL_FILES})
  86   endif()
  87   set(EXCLUDE_FROM_ALL OFF)
  88   target_link_libraries( ${name} ${LLVM_USED_LIBS} )
  89   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  90   if( LLVM_COMMON_DEPENDS )
  91     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  92   endif( LLVM_COMMON_DEPENDS )
  93   link_system_libs( ${name} )
  94   add_tablegenning_dependency( ${name} )
  95 endmacro(add_llvm_executable name)
  96
  97
  98 macro(add_llvm_tool name)
  99   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
 100   if( NOT LLVM_BUILD_TOOLS )
 101     set(EXCLUDE_FROM_ALL ON)
 102   endif()
 103   add_llvm_executable(${name} ${ARGN})
 104   if( LLVM_BUILD_TOOLS )
 105     install(TARGETS ${name} RUNTIME DESTINATION bin)
 106   endif()
 107   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 108 endmacro(add_llvm_tool name)
 109
 110
 111 macro(add_llvm_example name)
 112 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
 113   if( NOT LLVM_BUILD_EXAMPLES )
 114     set(EXCLUDE_FROM_ALL ON)
 115   endif()
 116   add_llvm_executable(${name} ${ARGN})
 117   if( LLVM_BUILD_EXAMPLES )
 118     install(TARGETS ${name} RUNTIME DESTINATION examples)
 119   endif()
 120   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 121 endmacro(add_llvm_example name)
 122
 123
 124 macro(add_llvm_utility name)
 125   add_llvm_executable(${name} ${ARGN})
 126   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 127 endmacro(add_llvm_utility name)
 128
 129
 130 macro(add_llvm_target target_name)
 131   include_directories(BEFORE
 132     ${CMAKE_CURRENT_BINARY_DIR}
 133     ${CMAKE_CURRENT_SOURCE_DIR})
 134   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 135   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 136 endmacro(add_llvm_target)