cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVMConfig)
   3
   4 macro(add_llvm_library name)
   5   llvm_process_sources( ALL_FILES ${ARGN} )
   6   add_library( ${name} ${ALL_FILES} )
   7   set( llvm_libs ${llvm_libs} ${name} PARENT_SCOPE)
   8   set( llvm_lib_targets ${llvm_lib_targets} ${name} PARENT_SCOPE )
   9   if( LLVM_COMMON_DEPENDS )
  10     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  11   endif( LLVM_COMMON_DEPENDS )
  12   install(TARGETS ${name}
  13     LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  14     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  15   # The LLVM Target library shall be built before its sublibraries
  16   # (asmprinter, etc) because those may use tablegenned files which
  17   # generation is triggered by the main LLVM target library. Necessary
  18   # for parallel builds:
  19   if( CURRENT_LLVM_TARGET )
  20     add_dependencies(${name} ${CURRENT_LLVM_TARGET})
  21   endif()
  22 endmacro(add_llvm_library name)
  23
  24
  25 macro(add_llvm_loadable_module name)
  26   if( NOT LLVM_ON_UNIX )
  27     message(STATUS "Loadable modules not supported on this platform.
  28 ${name} ignored.")
  29   else()
  30     set(BUILD_SHARED_LIBS ON)
  31     llvm_process_sources( ALL_FILES ${ARGN} )
  32     add_library( ${name} MODULE ${ALL_FILES} )
  33     set_target_properties( ${name} PROPERTIES PREFIX "" )
  34     install(TARGETS ${name}
  35       LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  36       ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  37   endif()
  38 endmacro(add_llvm_loadable_module name)
  39
  40
  41 macro(add_llvm_executable name)
  42   llvm_process_sources( ALL_FILES ${ARGN} )
  43   add_executable(${name} ${ALL_FILES})
  44   if( LLVM_USED_LIBS )
  45     foreach(lib ${LLVM_USED_LIBS})
  46       target_link_libraries( ${name} ${lib} )
  47     endforeach(lib)
  48   endif( LLVM_USED_LIBS )
  49   if( LLVM_LINK_COMPONENTS )
  50     llvm_config(${name} ${LLVM_LINK_COMPONENTS})
  51   endif( LLVM_LINK_COMPONENTS )
  52   get_system_libs(llvm_system_libs)
  53   if( llvm_system_libs )
  54     target_link_libraries(${name} ${llvm_system_libs})
  55   endif()
  56   if( LLVM_COMMON_DEPENDS )
  57     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  58   endif( LLVM_COMMON_DEPENDS )
  59 endmacro(add_llvm_executable name)
  60
  61
  62 macro(add_llvm_tool name)
  63   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
  64   add_llvm_executable(${name} ${ARGN})
  65   install(TARGETS ${name}
  66     RUNTIME DESTINATION bin)
  67 endmacro(add_llvm_tool name)
  68
  69
  70 macro(add_llvm_example name)
  71 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
  72   add_llvm_executable(${name} ${ARGN})
  73   install(TARGETS ${name}
  74     RUNTIME DESTINATION examples)
  75 endmacro(add_llvm_example name)
  76
  77
  78 macro(add_llvm_target target_name)
  79   if( TABLEGEN_OUTPUT )
  80     add_custom_target(${target_name}Table_gen
  81       DEPENDS ${TABLEGEN_OUTPUT})
  82     add_dependencies(${target_name}Table_gen ${LLVM_COMMON_DEPENDS})
  83   endif( TABLEGEN_OUTPUT )
  84   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
  85   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
  86   if ( TABLEGEN_OUTPUT )
  87     add_dependencies(LLVM${target_name} ${target_name}Table_gen)
  88   endif (TABLEGEN_OUTPUT)
  89   set(CURRENT_LLVM_TARGET LLVM${target_name} PARENT_SCOPE)
  90 endmacro(add_llvm_target)