cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130
 131   # Add dependency to *_exports later -- CMake issue 14747
 132   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 133   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 134 endfunction(add_llvm_symbol_exports)
 135
 136 function(add_dead_strip target_name)
 137   if(NOT LLVM_NO_DEAD_STRIP)
 138     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,-dead_strip")
 141     elseif(NOT WIN32)
 142       # Object files are compiled with -ffunction-data-sections.
 143       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 144                    LINK_FLAGS " -Wl,--gc-sections")
 145     endif()
 146   endif()
 147 endfunction(add_dead_strip)
 148
 149 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 150 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 151 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 152 function(set_output_directory target bindir libdir)
 153   # Do nothing if *_OUTPUT_INTDIR is empty.
 154   if("${bindir}" STREQUAL "")
 155     return()
 156   endif()
 157
 158   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 159   # It affects output of add_library(MODULE).
 160   if(WIN32 OR CYGWIN)
 161     # DLL platform
 162     set(moddir ${bindir})
 163   else()
 164     set(moddir ${libdir})
 165   endif()
 166   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 167     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 168       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 169       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 170       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 171       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 172       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 173       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 174       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 175     endforeach()
 176   else()
 177     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 178     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 179     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 180   endif()
 181 endfunction()
 182
 183 # llvm_add_library(name sources...
 184 #   SHARED;STATIC
 185 #     STATIC by default w/o BUILD_SHARED_LIBS.
 186 #     SHARED by default w/  BUILD_SHARED_LIBS.
 187 #   MODULE
 188 #     Target ${name} might not be created on unsupported platforms.
 189 #     Check with "if(TARGET ${name})".
 190 #   OUTPUT_NAME name
 191 #     Corresponds to OUTPUT_NAME in target properties.
 192 #   DEPENDS targets...
 193 #     Same semantics as add_dependencies().
 194 #   LINK_COMPONENTS components...
 195 #     Same as the variable LLVM_LINK_COMPONENTS.
 196 #   LINK_LIBS lib_targets...
 197 #     Same semantics as target_link_libraries().
 198 #   ADDITIONAL_HEADERS
 199 #     May specify header files for IDE generators.
 200 #   )
 201 function(llvm_add_library name)
 202   cmake_parse_arguments(ARG
 203     "MODULE;SHARED;STATIC"
 204     "OUTPUT_NAME"
 205     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 206     ${ARGN})
 207   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 208   if(ARG_ADDITIONAL_HEADERS)
 209     # Pass through ADDITIONAL_HEADERS.
 210     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 211   endif()
 212   if(ARG_OBJLIBS)
 213     set(ALL_FILES ${ARG_OBJLIBS})
 214   else()
 215     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 216   endif()
 217
 218   if(ARG_MODULE)
 219     if(ARG_SHARED OR ARG_STATIC)
 220       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 221     endif()
 222     if(NOT LLVM_ENABLE_PLUGINS)
 223       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 224       return()
 225     endif()
 226   else()
 227     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 228       set(ARG_SHARED TRUE)
 229     endif()
 230     if(NOT ARG_SHARED)
 231       set(ARG_STATIC TRUE)
 232     endif()
 233   endif()
 234
 235   # Generate objlib
 236   if(ARG_SHARED AND ARG_STATIC)
 237     # Generate an obj library for both targets.
 238     set(obj_name "obj.${name}")
 239     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 240       ${ALL_FILES}
 241       )
 242     llvm_update_compile_flags(${obj_name})
 243     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 244
 245     # Do add_dependencies(obj) later due to CMake issue 14747.
 246     list(APPEND objlibs ${obj_name})
 247
 248     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 249   endif()
 250
 251   if(ARG_SHARED AND ARG_STATIC)
 252     # static
 253     set(name_static "${name}_static")
 254     if(ARG_OUTPUT_NAME)
 255       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 256     endif()
 257     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 258     llvm_add_library(${name_static} STATIC
 259       ${output_name}
 260       OBJLIBS ${ALL_FILES} # objlib
 261       LINK_LIBS ${ARG_LINK_LIBS}
 262       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 263       )
 264     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 265     set(ARG_STATIC)
 266   endif()
 267
 268   if(ARG_MODULE)
 269     add_library(${name} MODULE ${ALL_FILES})
 270   elseif(ARG_SHARED)
 271     add_library(${name} SHARED ${ALL_FILES})
 272   else()
 273     add_library(${name} STATIC ${ALL_FILES})
 274   endif()
 275   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 276   llvm_update_compile_flags(${name})
 277   add_dead_strip( ${name} )
 278   if(ARG_OUTPUT_NAME)
 279     set_target_properties(${name}
 280       PROPERTIES
 281       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 282       )
 283   endif()
 284
 285   if(ARG_MODULE)
 286     set_target_properties(${name} PROPERTIES
 287       PREFIX ""
 288       SUFFIX ${LLVM_PLUGIN_EXT}
 289       )
 290   endif()
 291
 292   if(ARG_SHARED)
 293     if(WIN32)
 294       set_target_properties(${name} PROPERTIES
 295         PREFIX ""
 296         )
 297     endif()
 298     if (MSVC)
 299       set_target_properties(${name}
 300         PROPERTIES
 301         IMPORT_SUFFIX ".imp")
 302     endif ()
 303   endif()
 304
 305   if(ARG_MODULE OR ARG_SHARED)
 306     if (LLVM_EXPORTED_SYMBOL_FILE)
 307       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 308     endif()
 309   endif()
 310
 311   # Add the explicit dependency information for this library.
 312   #
 313   # It would be nice to verify that we have the dependencies for this library
 314   # name, but using get_property(... SET) doesn't suffice to determine if a
 315   # property has been set to an empty value.
 316   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 317
 318   llvm_map_components_to_libnames(llvm_libs
 319     ${ARG_LINK_COMPONENTS}
 320     ${LLVM_LINK_COMPONENTS}
 321     )
 322
 323   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 324     # Link libs w/o keywords, assuming PUBLIC.
 325     target_link_libraries(${name}
 326       ${ARG_LINK_LIBS}
 327       ${lib_deps}
 328       ${llvm_libs}
 329       )
 330   elseif(ARG_STATIC)
 331     target_link_libraries(${name} INTERFACE
 332       ${ARG_LINK_LIBS}
 333       ${lib_deps}
 334       ${llvm_libs}
 335       )
 336   elseif((CYGWIN OR WIN32) AND ARG_SHARED)
 337     # Win32's import library may be unaware of its dependent libs.
 338     target_link_libraries(${name} PRIVATE
 339       ${ARG_LINK_LIBS}
 340       ${lib_deps}
 341       ${llvm_libs}
 342       )
 343   elseif(ARG_SHARED AND BUILD_SHARED_LIBS)
 344     # FIXME: It may be PRIVATE since SO knows its dependent libs.
 345     target_link_libraries(${name} PUBLIC
 346       ${ARG_LINK_LIBS}
 347       ${lib_deps}
 348       ${llvm_libs}
 349       )
 350   else()
 351     # MODULE|SHARED
 352     target_link_libraries(${name} PRIVATE
 353       ${ARG_LINK_LIBS}
 354       ${lib_deps}
 355       ${llvm_libs}
 356       )
 357   endif()
 358
 359   if(LLVM_COMMON_DEPENDS)
 360     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 361     # Add dependencies also to objlibs.
 362     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 363     foreach(objlib ${objlibs})
 364       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 365     endforeach()
 366   endif()
 367 endfunction()
 368
 369 macro(add_llvm_library name)
 370   if( BUILD_SHARED_LIBS )
 371     llvm_add_library(${name} SHARED ${ARGN})
 372   else()
 373     llvm_add_library(${name} ${ARGN})
 374   endif()
 375   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 376
 377   if( EXCLUDE_FROM_ALL )
 378     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 379   else()
 380     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 381       install(TARGETS ${name}
 382         EXPORT LLVMExports
 383         RUNTIME DESTINATION bin
 384         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 385         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 386     endif()
 387     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 388   endif()
 389   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 390 endmacro(add_llvm_library name)
 391
 392 macro(add_llvm_loadable_module name)
 393   llvm_add_library(${name} MODULE ${ARGN})
 394   if(NOT TARGET ${name})
 395     # Add empty "phony" target
 396     add_custom_target(${name})
 397   else()
 398     if( EXCLUDE_FROM_ALL )
 399       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 400     else()
 401       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 402         if(WIN32 OR CYGWIN)
 403           # DLL platform
 404           set(dlldir "bin")
 405         else()
 406           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 407         endif()
 408         install(TARGETS ${name}
 409           EXPORT LLVMExports
 410           LIBRARY DESTINATION ${dlldir}
 411           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 412       endif()
 413       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 414     endif()
 415   endif()
 416
 417   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 418 endmacro(add_llvm_loadable_module name)
 419
 420
 421 macro(add_llvm_executable name)
 422   llvm_process_sources( ALL_FILES ${ARGN} )
 423   if( EXCLUDE_FROM_ALL )
 424     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 425   else()
 426     add_executable(${name} ${ALL_FILES})
 427   endif()
 428   llvm_update_compile_flags(${name})
 429   add_dead_strip( ${name} )
 430
 431   if (LLVM_EXPORTED_SYMBOL_FILE)
 432     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 433   endif(LLVM_EXPORTED_SYMBOL_FILE)
 434
 435   set(EXCLUDE_FROM_ALL OFF)
 436   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 437   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 438   if( LLVM_COMMON_DEPENDS )
 439     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 440   endif( LLVM_COMMON_DEPENDS )
 441 endmacro(add_llvm_executable name)
 442
 443
 444 set (LLVM_TOOLCHAIN_TOOLS
 445   llvm-ar
 446   llvm-objdump
 447   )
 448
 449 macro(add_llvm_tool name)
 450   if( NOT LLVM_BUILD_TOOLS )
 451     set(EXCLUDE_FROM_ALL ON)
 452   endif()
 453   add_llvm_executable(${name} ${ARGN})
 454
 455   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 456   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 457     if( LLVM_BUILD_TOOLS )
 458       install(TARGETS ${name}
 459               EXPORT LLVMExports
 460               RUNTIME DESTINATION bin)
 461     endif()
 462   endif()
 463   if( LLVM_BUILD_TOOLS )
 464     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 465   endif()
 466   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 467 endmacro(add_llvm_tool name)
 468
 469
 470 macro(add_llvm_example name)
 471   if( NOT LLVM_BUILD_EXAMPLES )
 472     set(EXCLUDE_FROM_ALL ON)
 473   endif()
 474   add_llvm_executable(${name} ${ARGN})
 475   if( LLVM_BUILD_EXAMPLES )
 476     install(TARGETS ${name} RUNTIME DESTINATION examples)
 477   endif()
 478   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 479 endmacro(add_llvm_example name)
 480
 481
 482 macro(add_llvm_utility name)
 483   add_llvm_executable(${name} ${ARGN})
 484   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 485 endmacro(add_llvm_utility name)
 486
 487
 488 macro(add_llvm_target target_name)
 489   include_directories(BEFORE
 490     ${CMAKE_CURRENT_BINARY_DIR}
 491     ${CMAKE_CURRENT_SOURCE_DIR})
 492   add_llvm_library(LLVM${target_name} ${ARGN})
 493   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 494 endmacro(add_llvm_target)
 495
 496 # Add external project that may want to be built as part of llvm such as Clang,
 497 # lld, and Polly. This adds two options. One for the source directory of the
 498 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 499 # enable or disable building it with everything else.
 500 # Additional parameter can be specified as the name of directory.
 501 macro(add_llvm_external_project name)
 502   set(add_llvm_external_dir "${ARGN}")
 503   if("${add_llvm_external_dir}" STREQUAL "")
 504     set(add_llvm_external_dir ${name})
 505   endif()
 506   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 507   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 508   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 509   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 510       CACHE PATH "Path to ${name} source directory")
 511   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 512       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 513     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 514            "Whether to build ${name} as part of LLVM" ON)
 515     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 516       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 517     endif()
 518   endif()
 519 endmacro(add_llvm_external_project)
 520
 521 macro(add_llvm_tool_subdirectory name)
 522   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 523   add_subdirectory(${name})
 524 endmacro(add_llvm_tool_subdirectory)
 525
 526 macro(ignore_llvm_tool_subdirectory name)
 527   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 528 endmacro(ignore_llvm_tool_subdirectory)
 529
 530 function(add_llvm_implicit_external_projects)
 531   set(list_of_implicit_subdirs "")
 532   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 533   foreach(dir ${sub-dirs})
 534     if(IS_DIRECTORY "${dir}")
 535       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 536       if( tool_subdir_ignore EQUAL -1
 537           AND EXISTS "${dir}/CMakeLists.txt")
 538         get_filename_component(fn "${dir}" NAME)
 539         list(APPEND list_of_implicit_subdirs "${fn}")
 540       endif()
 541     endif()
 542   endforeach()
 543
 544   foreach(external_proj ${list_of_implicit_subdirs})
 545     add_llvm_external_project("${external_proj}")
 546   endforeach()
 547 endfunction(add_llvm_implicit_external_projects)
 548
 549 # Generic support for adding a unittest.
 550 function(add_unittest test_suite test_name)
 551   if( NOT LLVM_BUILD_TESTS )
 552     set(EXCLUDE_FROM_ALL ON)
 553   endif()
 554
 555   # Visual Studio 2012 only supports up to 8 template parameters in
 556   # std::tr1::tuple by default, but gtest requires 10
 557   if (MSVC AND MSVC_VERSION EQUAL 1700)
 558     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 559   endif ()
 560
 561   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 562   if (NOT LLVM_ENABLE_THREADS)
 563     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 564   endif ()
 565
 566   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 567     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 568   endif ()
 569
 570   set(LLVM_REQUIRES_RTTI OFF)
 571
 572   add_llvm_executable(${test_name} ${ARGN})
 573   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 574   set_output_directory(${test_name} ${outdir} ${outdir})
 575   target_link_libraries(${test_name}
 576     gtest
 577     gtest_main
 578     LLVMSupport # gtest needs it for raw_ostream.
 579     )
 580
 581   add_dependencies(${test_suite} ${test_name})
 582   get_target_property(test_suite_folder ${test_suite} FOLDER)
 583   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 584     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 585   endif ()
 586 endfunction()
 587
 588 # This function provides an automatic way to 'configure'-like generate a file
 589 # based on a set of common and custom variables, specifically targeting the
 590 # variables needed for the 'lit.site.cfg' files. This function bundles the
 591 # common variables that any Lit instance is likely to need, and custom
 592 # variables can be passed in.
 593 function(configure_lit_site_cfg input output)
 594   foreach(c ${LLVM_TARGETS_TO_BUILD})
 595     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 596   endforeach(c)
 597   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 598
 599   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 600
 601   # Configuration-time: See Unit/lit.site.cfg.in
 602   if (CMAKE_CFG_INTDIR STREQUAL ".")
 603     set(LLVM_BUILD_MODE ".")
 604   else ()
 605     set(LLVM_BUILD_MODE "%(build_mode)s")
 606   endif ()
 607
 608   # They below might not be the build tree but provided binary tree.
 609   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 610   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 611   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 612   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 613
 614   # SHLIBDIR points the build tree.
 615   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 616
 617   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 618   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 619   # plugins. We may rename it.
 620   if(LLVM_ENABLE_PLUGINS)
 621     set(ENABLE_SHARED "1")
 622   else()
 623     set(ENABLE_SHARED "0")
 624   endif()
 625
 626   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 627     set(ENABLE_ASSERTIONS "1")
 628   else()
 629     set(ENABLE_ASSERTIONS "0")
 630   endif()
 631
 632   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 633   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 634
 635   configure_file(${input} ${output} @ONLY)
 636 endfunction()
 637
 638 # A raw function to create a lit target. This is used to implement the testuite
 639 # management functions.
 640 function(add_lit_target target comment)
 641   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 642   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 643   separate_arguments(LIT_ARGS)
 644   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 645     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 646   endif ()
 647   if (LLVM_MAIN_SRC_DIR)
 648     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 649   else()
 650     find_program(LIT_COMMAND llvm-lit)
 651   endif ()
 652   list(APPEND LIT_COMMAND ${LIT_ARGS})
 653   foreach(param ${ARG_PARAMS})
 654     list(APPEND LIT_COMMAND --param ${param})
 655   endforeach()
 656   if( ARG_DEPENDS )
 657     add_custom_target(${target}
 658       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 659       COMMENT "${comment}"
 660       )
 661     add_dependencies(${target} ${ARG_DEPENDS})
 662   else()
 663     add_custom_target(${target}
 664       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 665     message(STATUS "${target} does nothing.")
 666   endif()
 667
 668   # Tests should be excluded from "Build Solution".
 669   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 670 endfunction()
 671
 672 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 673 function(add_lit_testsuite target comment)
 674   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 675
 676   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 677   if(NOT EXCLUDE_FROM_ALL)
 678     # Register the testsuites, params and depends for the global check rule.
 679     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 680     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 681     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 682     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 683   endif()
 684
 685   # Produce a specific suffixed check rule.
 686   add_lit_target(${target} ${comment}
 687     ${ARG_DEFAULT_ARGS}
 688     PARAMS ${ARG_PARAMS}
 689     DEPENDS ${ARG_DEPENDS}
 690     ARGS ${ARG_ARGS}
 691     )
 692 endfunction()