cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if(LLVM_REQUIRES_EH OR LLVM_ENABLE_EH)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  30     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  31     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  32       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  33     elseif (MSVC)
  34       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  35     endif ()
  36   endif()
  37
  38   # Assume that;
  39   #   - LLVM_COMPILE_FLAGS is list.
  40   #   - PROPERTY COMPILE_FLAGS is string.
  41   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  42
  43   if(update_src_props)
  44     foreach(fn ${sources})
  45       get_filename_component(suf ${fn} EXT)
  46       if("${suf}" STREQUAL ".cpp")
  47         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  48           COMPILE_FLAGS "${target_compile_flags}")
  49       endif()
  50     endforeach()
  51   else()
  52     # Update target props, since all sources are C++.
  53     set_property(TARGET ${name} APPEND_STRING PROPERTY
  54       COMPILE_FLAGS "${target_compile_flags}")
  55   endif()
  56
  57   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  58 endfunction()
  59
  60 function(add_llvm_symbol_exports target_name export_file)
  61   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  62     set(native_export_file "${target_name}.exports")
  63     add_custom_command(OUTPUT ${native_export_file}
  64       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  65       DEPENDS ${export_file}
  66       VERBATIM
  67       COMMENT "Creating export file for ${target_name}")
  68     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  69                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  70   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  71     # Gold and BFD ld require a version script rather than a plain list.
  72     set(native_export_file "${target_name}.exports")
  73     # FIXME: Don't write the "local:" line on OpenBSD.
  74     add_custom_command(OUTPUT ${native_export_file}
  75       COMMAND echo "{" > ${native_export_file}
  76       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  77       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  78       COMMAND echo "  local: *;" >> ${native_export_file}
  79       COMMAND echo "};" >> ${native_export_file}
  80       DEPENDS ${export_file}
  81       VERBATIM
  82       COMMENT "Creating export file for ${target_name}")
  83     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  84                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  85   else()
  86     set(native_export_file "${target_name}.def")
  87
  88     set(CAT "type")
  89     if(CYGWIN)
  90       set(CAT "cat")
  91     endif()
  92
  93     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  94     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  95
  96     add_custom_command(OUTPUT ${native_export_file}
  97       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  98       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  99       DEPENDS ${export_file}
 100       VERBATIM
 101       COMMENT "Creating export file for ${target_name}")
 102     if(CYGWIN OR MINGW)
 103       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 104                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 105     else()
 106       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 107                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 108     endif()
 109   endif()
 110
 111   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 112   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 113
 114   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 115   foreach(src ${srcs})
 116     get_filename_component(extension ${src} EXT)
 117     if(extension STREQUAL ".cpp")
 118       set(first_source_file ${src})
 119       break()
 120     endif()
 121   endforeach()
 122
 123   # Force re-linking when the exports file changes. Actually, it
 124   # forces recompilation of the source file. The LINK_DEPENDS target
 125   # property only works for makefile-based generators.
 126   # FIXME: This is not safe because this will create the same target
 127   # ${native_export_file} in several different file:
 128   # - One where we emitted ${target_name}_exports
 129   # - One where we emitted the build command for the following object.
 130   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 131   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 132
 133   set_property(DIRECTORY APPEND
 134     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 135
 136   add_dependencies(${target_name} ${target_name}_exports)
 137
 138   # Add dependency to *_exports later -- CMake issue 14747
 139   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 140   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 141 endfunction(add_llvm_symbol_exports)
 142
 143 function(add_dead_strip target_name)
 144   if(NOT LLVM_NO_DEAD_STRIP)
 145     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 146       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 147                    LINK_FLAGS " -Wl,-dead_strip")
 148     elseif(NOT WIN32)
 149       # Object files are compiled with -ffunction-data-sections.
 150       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 151                    LINK_FLAGS " -Wl,--gc-sections")
 152     endif()
 153   endif()
 154 endfunction(add_dead_strip)
 155
 156 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 157 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 158 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 159 function(set_output_directory target bindir libdir)
 160   # Do nothing if *_OUTPUT_INTDIR is empty.
 161   if("${bindir}" STREQUAL "")
 162     return()
 163   endif()
 164
 165   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 166   # It affects output of add_library(MODULE).
 167   if(WIN32 OR CYGWIN)
 168     # DLL platform
 169     set(moddir ${bindir})
 170   else()
 171     set(moddir ${libdir})
 172   endif()
 173   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 174     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 175       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 176       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 177       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 178       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 179       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 180       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 181       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 182     endforeach()
 183   else()
 184     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 185     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 186     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 187   endif()
 188 endfunction()
 189
 190 # llvm_add_library(name sources...
 191 #   SHARED;STATIC
 192 #     STATIC by default w/o BUILD_SHARED_LIBS.
 193 #     SHARED by default w/  BUILD_SHARED_LIBS.
 194 #   MODULE
 195 #     Target ${name} might not be created on unsupported platforms.
 196 #     Check with "if(TARGET ${name})".
 197 #   OUTPUT_NAME name
 198 #     Corresponds to OUTPUT_NAME in target properties.
 199 #   DEPENDS targets...
 200 #     Same semantics as add_dependencies().
 201 #   LINK_COMPONENTS components...
 202 #     Same as the variable LLVM_LINK_COMPONENTS.
 203 #   LINK_LIBS lib_targets...
 204 #     Same semantics as target_link_libraries().
 205 #   ADDITIONAL_HEADERS
 206 #     May specify header files for IDE generators.
 207 #   )
 208 function(llvm_add_library name)
 209   cmake_parse_arguments(ARG
 210     "MODULE;SHARED;STATIC"
 211     "OUTPUT_NAME"
 212     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 213     ${ARGN})
 214   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 215   if(ARG_ADDITIONAL_HEADERS)
 216     # Pass through ADDITIONAL_HEADERS.
 217     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 218   endif()
 219   if(ARG_OBJLIBS)
 220     set(ALL_FILES ${ARG_OBJLIBS})
 221   else()
 222     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 223   endif()
 224
 225   if(ARG_MODULE)
 226     if(ARG_SHARED OR ARG_STATIC)
 227       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 228     endif()
 229     if(NOT LLVM_ENABLE_PLUGINS)
 230       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 231       return()
 232     endif()
 233   else()
 234     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 235       set(ARG_SHARED TRUE)
 236     endif()
 237     if(NOT ARG_SHARED)
 238       set(ARG_STATIC TRUE)
 239     endif()
 240   endif()
 241
 242   # Generate objlib
 243   if(ARG_SHARED AND ARG_STATIC)
 244     # Generate an obj library for both targets.
 245     set(obj_name "obj.${name}")
 246     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 247       ${ALL_FILES}
 248       )
 249     llvm_update_compile_flags(${obj_name})
 250     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 251
 252     # Do add_dependencies(obj) later due to CMake issue 14747.
 253     list(APPEND objlibs ${obj_name})
 254
 255     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 256   endif()
 257
 258   if(ARG_SHARED AND ARG_STATIC)
 259     # static
 260     set(name_static "${name}_static")
 261     if(ARG_OUTPUT_NAME)
 262       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 263     endif()
 264     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 265     llvm_add_library(${name_static} STATIC
 266       ${output_name}
 267       OBJLIBS ${ALL_FILES} # objlib
 268       LINK_LIBS ${ARG_LINK_LIBS}
 269       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 270       )
 271     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 272     set(ARG_STATIC)
 273   endif()
 274
 275   if(ARG_MODULE)
 276     add_library(${name} MODULE ${ALL_FILES})
 277   elseif(ARG_SHARED)
 278     add_library(${name} SHARED ${ALL_FILES})
 279   else()
 280     add_library(${name} STATIC ${ALL_FILES})
 281   endif()
 282   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 283   llvm_update_compile_flags(${name})
 284   add_dead_strip( ${name} )
 285   if(ARG_OUTPUT_NAME)
 286     set_target_properties(${name}
 287       PROPERTIES
 288       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 289       )
 290   endif()
 291
 292   if(ARG_MODULE)
 293     set_target_properties(${name} PROPERTIES
 294       PREFIX ""
 295       SUFFIX ${LLVM_PLUGIN_EXT}
 296       )
 297   endif()
 298
 299   if(ARG_SHARED)
 300     if(WIN32)
 301       set_target_properties(${name} PROPERTIES
 302         PREFIX ""
 303         )
 304     endif()
 305     if (MSVC)
 306       set_target_properties(${name}
 307         PROPERTIES
 308         IMPORT_SUFFIX ".imp")
 309     endif ()
 310   endif()
 311
 312   if(ARG_MODULE OR ARG_SHARED)
 313     if (LLVM_EXPORTED_SYMBOL_FILE)
 314       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 315     endif()
 316   endif()
 317
 318   # Add the explicit dependency information for this library.
 319   #
 320   # It would be nice to verify that we have the dependencies for this library
 321   # name, but using get_property(... SET) doesn't suffice to determine if a
 322   # property has been set to an empty value.
 323   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 324
 325   llvm_map_components_to_libnames(llvm_libs
 326     ${ARG_LINK_COMPONENTS}
 327     ${LLVM_LINK_COMPONENTS}
 328     )
 329
 330   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 331     # Link libs w/o keywords, assuming PUBLIC.
 332     target_link_libraries(${name}
 333       ${ARG_LINK_LIBS}
 334       ${lib_deps}
 335       ${llvm_libs}
 336       )
 337   elseif(ARG_STATIC)
 338     target_link_libraries(${name} INTERFACE
 339       ${ARG_LINK_LIBS}
 340       ${lib_deps}
 341       ${llvm_libs}
 342       )
 343   elseif((CYGWIN OR WIN32) AND ARG_SHARED)
 344     # Win32's import library may be unaware of its dependent libs.
 345     target_link_libraries(${name} PRIVATE
 346       ${ARG_LINK_LIBS}
 347       ${lib_deps}
 348       ${llvm_libs}
 349       )
 350   elseif(ARG_SHARED AND BUILD_SHARED_LIBS)
 351     # FIXME: It may be PRIVATE since SO knows its dependent libs.
 352     target_link_libraries(${name} PUBLIC
 353       ${ARG_LINK_LIBS}
 354       ${lib_deps}
 355       ${llvm_libs}
 356       )
 357   else()
 358     # MODULE|SHARED
 359     target_link_libraries(${name} PRIVATE
 360       ${ARG_LINK_LIBS}
 361       ${lib_deps}
 362       ${llvm_libs}
 363       )
 364   endif()
 365
 366   if(LLVM_COMMON_DEPENDS)
 367     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 368     # Add dependencies also to objlibs.
 369     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 370     foreach(objlib ${objlibs})
 371       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 372     endforeach()
 373   endif()
 374 endfunction()
 375
 376 macro(add_llvm_library name)
 377   if( BUILD_SHARED_LIBS )
 378     llvm_add_library(${name} SHARED ${ARGN})
 379   else()
 380     llvm_add_library(${name} ${ARGN})
 381   endif()
 382   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 383
 384   if( EXCLUDE_FROM_ALL )
 385     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 386   else()
 387     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 388       install(TARGETS ${name}
 389         EXPORT LLVMExports
 390         RUNTIME DESTINATION bin
 391         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 392         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 393     endif()
 394     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 395   endif()
 396   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 397 endmacro(add_llvm_library name)
 398
 399 macro(add_llvm_loadable_module name)
 400   llvm_add_library(${name} MODULE ${ARGN})
 401   if(NOT TARGET ${name})
 402     # Add empty "phony" target
 403     add_custom_target(${name})
 404   else()
 405     if( EXCLUDE_FROM_ALL )
 406       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 407     else()
 408       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 409         if(WIN32 OR CYGWIN)
 410           # DLL platform
 411           set(dlldir "bin")
 412         else()
 413           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 414         endif()
 415         install(TARGETS ${name}
 416           EXPORT LLVMExports
 417           LIBRARY DESTINATION ${dlldir}
 418           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 419       endif()
 420       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 421     endif()
 422   endif()
 423
 424   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 425 endmacro(add_llvm_loadable_module name)
 426
 427
 428 macro(add_llvm_executable name)
 429   llvm_process_sources( ALL_FILES ${ARGN} )
 430   if( EXCLUDE_FROM_ALL )
 431     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 432   else()
 433     add_executable(${name} ${ALL_FILES})
 434   endif()
 435   llvm_update_compile_flags(${name})
 436   add_dead_strip( ${name} )
 437
 438   if (LLVM_EXPORTED_SYMBOL_FILE)
 439     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 440   endif(LLVM_EXPORTED_SYMBOL_FILE)
 441
 442   set(EXCLUDE_FROM_ALL OFF)
 443   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 444   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 445   if( LLVM_COMMON_DEPENDS )
 446     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 447   endif( LLVM_COMMON_DEPENDS )
 448 endmacro(add_llvm_executable name)
 449
 450
 451 set (LLVM_TOOLCHAIN_TOOLS
 452   llvm-ar
 453   llvm-objdump
 454   )
 455
 456 macro(add_llvm_tool name)
 457   if( NOT LLVM_BUILD_TOOLS )
 458     set(EXCLUDE_FROM_ALL ON)
 459   endif()
 460   add_llvm_executable(${name} ${ARGN})
 461
 462   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 463   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 464     if( LLVM_BUILD_TOOLS )
 465       install(TARGETS ${name}
 466               EXPORT LLVMExports
 467               RUNTIME DESTINATION bin)
 468     endif()
 469   endif()
 470   if( LLVM_BUILD_TOOLS )
 471     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 472   endif()
 473   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 474 endmacro(add_llvm_tool name)
 475
 476
 477 macro(add_llvm_example name)
 478   if( NOT LLVM_BUILD_EXAMPLES )
 479     set(EXCLUDE_FROM_ALL ON)
 480   endif()
 481   add_llvm_executable(${name} ${ARGN})
 482   if( LLVM_BUILD_EXAMPLES )
 483     install(TARGETS ${name} RUNTIME DESTINATION examples)
 484   endif()
 485   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 486 endmacro(add_llvm_example name)
 487
 488
 489 macro(add_llvm_utility name)
 490   add_llvm_executable(${name} ${ARGN})
 491   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 492 endmacro(add_llvm_utility name)
 493
 494
 495 macro(add_llvm_target target_name)
 496   include_directories(BEFORE
 497     ${CMAKE_CURRENT_BINARY_DIR}
 498     ${CMAKE_CURRENT_SOURCE_DIR})
 499   add_llvm_library(LLVM${target_name} ${ARGN})
 500   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 501 endmacro(add_llvm_target)
 502
 503 # Add external project that may want to be built as part of llvm such as Clang,
 504 # lld, and Polly. This adds two options. One for the source directory of the
 505 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 506 # enable or disable building it with everything else.
 507 # Additional parameter can be specified as the name of directory.
 508 macro(add_llvm_external_project name)
 509   set(add_llvm_external_dir "${ARGN}")
 510   if("${add_llvm_external_dir}" STREQUAL "")
 511     set(add_llvm_external_dir ${name})
 512   endif()
 513   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 514   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 515   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 516   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 517       CACHE PATH "Path to ${name} source directory")
 518   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 519       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 520     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 521            "Whether to build ${name} as part of LLVM" ON)
 522     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 523       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 524     endif()
 525   endif()
 526 endmacro(add_llvm_external_project)
 527
 528 macro(add_llvm_tool_subdirectory name)
 529   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 530   add_subdirectory(${name})
 531 endmacro(add_llvm_tool_subdirectory)
 532
 533 macro(ignore_llvm_tool_subdirectory name)
 534   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 535 endmacro(ignore_llvm_tool_subdirectory)
 536
 537 function(add_llvm_implicit_external_projects)
 538   set(list_of_implicit_subdirs "")
 539   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 540   foreach(dir ${sub-dirs})
 541     if(IS_DIRECTORY "${dir}")
 542       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 543       if( tool_subdir_ignore EQUAL -1
 544           AND EXISTS "${dir}/CMakeLists.txt")
 545         get_filename_component(fn "${dir}" NAME)
 546         list(APPEND list_of_implicit_subdirs "${fn}")
 547       endif()
 548     endif()
 549   endforeach()
 550
 551   foreach(external_proj ${list_of_implicit_subdirs})
 552     add_llvm_external_project("${external_proj}")
 553   endforeach()
 554 endfunction(add_llvm_implicit_external_projects)
 555
 556 # Generic support for adding a unittest.
 557 function(add_unittest test_suite test_name)
 558   if( NOT LLVM_BUILD_TESTS )
 559     set(EXCLUDE_FROM_ALL ON)
 560   endif()
 561
 562   # Visual Studio 2012 only supports up to 8 template parameters in
 563   # std::tr1::tuple by default, but gtest requires 10
 564   if (MSVC AND MSVC_VERSION EQUAL 1700)
 565     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 566   endif ()
 567
 568   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 569   if (NOT LLVM_ENABLE_THREADS)
 570     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 571   endif ()
 572
 573   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 574     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 575   endif ()
 576
 577   set(LLVM_REQUIRES_RTTI OFF)
 578
 579   add_llvm_executable(${test_name} ${ARGN})
 580   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 581   set_output_directory(${test_name} ${outdir} ${outdir})
 582   target_link_libraries(${test_name}
 583     gtest
 584     gtest_main
 585     LLVMSupport # gtest needs it for raw_ostream.
 586     )
 587
 588   add_dependencies(${test_suite} ${test_name})
 589   get_target_property(test_suite_folder ${test_suite} FOLDER)
 590   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 591     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 592   endif ()
 593 endfunction()
 594
 595 # This function provides an automatic way to 'configure'-like generate a file
 596 # based on a set of common and custom variables, specifically targeting the
 597 # variables needed for the 'lit.site.cfg' files. This function bundles the
 598 # common variables that any Lit instance is likely to need, and custom
 599 # variables can be passed in.
 600 function(configure_lit_site_cfg input output)
 601   foreach(c ${LLVM_TARGETS_TO_BUILD})
 602     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 603   endforeach(c)
 604   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 605
 606   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 607
 608   # Configuration-time: See Unit/lit.site.cfg.in
 609   if (CMAKE_CFG_INTDIR STREQUAL ".")
 610     set(LLVM_BUILD_MODE ".")
 611   else ()
 612     set(LLVM_BUILD_MODE "%(build_mode)s")
 613   endif ()
 614
 615   # They below might not be the build tree but provided binary tree.
 616   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 617   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 618   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 619   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 620
 621   # SHLIBDIR points the build tree.
 622   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 623
 624   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 625   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 626   # plugins. We may rename it.
 627   if(LLVM_ENABLE_PLUGINS)
 628     set(ENABLE_SHARED "1")
 629   else()
 630     set(ENABLE_SHARED "0")
 631   endif()
 632
 633   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 634     set(ENABLE_ASSERTIONS "1")
 635   else()
 636     set(ENABLE_ASSERTIONS "0")
 637   endif()
 638
 639   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 640   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 641
 642   configure_file(${input} ${output} @ONLY)
 643 endfunction()
 644
 645 # A raw function to create a lit target. This is used to implement the testuite
 646 # management functions.
 647 function(add_lit_target target comment)
 648   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 649   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 650   separate_arguments(LIT_ARGS)
 651   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 652     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 653   endif ()
 654   if (LLVM_MAIN_SRC_DIR)
 655     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 656   else()
 657     find_program(LIT_COMMAND llvm-lit)
 658   endif ()
 659   list(APPEND LIT_COMMAND ${LIT_ARGS})
 660   foreach(param ${ARG_PARAMS})
 661     list(APPEND LIT_COMMAND --param ${param})
 662   endforeach()
 663   if( ARG_DEPENDS )
 664     add_custom_target(${target}
 665       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 666       COMMENT "${comment}"
 667       )
 668     add_dependencies(${target} ${ARG_DEPENDS})
 669   else()
 670     add_custom_target(${target}
 671       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 672     message(STATUS "${target} does nothing.")
 673   endif()
 674
 675   # Tests should be excluded from "Build Solution".
 676   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 677 endfunction()
 678
 679 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 680 function(add_lit_testsuite target comment)
 681   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 682
 683   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 684   if(NOT EXCLUDE_FROM_ALL)
 685     # Register the testsuites, params and depends for the global check rule.
 686     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 687     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 688     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 689     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 690   endif()
 691
 692   # Produce a specific suffixed check rule.
 693   add_lit_target(${target} ${comment}
 694     ${ARG_DEFAULT_ARGS}
 695     PARAMS ${ARG_PARAMS}
 696     DEPENDS ${ARG_DEPENDS}
 697     ARGS ${ARG_ARGS}
 698     )
 699 endfunction()