cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(add_llvm_symbol_exports target_name export_file)
   6   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
   7     set(native_export_file "${target_name}.exports")
   8     add_custom_command(OUTPUT ${native_export_file}
   9       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  10       DEPENDS ${export_file}
  11       VERBATIM
  12       COMMENT "Creating export file for ${target_name}")
  13     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  14                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  15   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  16     # Gold and BFD ld require a version script rather than a plain list.
  17     set(native_export_file "${target_name}.exports")
  18     # FIXME: Don't write the "local:" line on OpenBSD.
  19     add_custom_command(OUTPUT ${native_export_file}
  20       COMMAND echo "{" > ${native_export_file}
  21       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  22       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  23       COMMAND echo "  local: *;" >> ${native_export_file}
  24       COMMAND echo "};" >> ${native_export_file}
  25       DEPENDS ${export_file}
  26       VERBATIM
  27       COMMENT "Creating export file for ${target_name}")
  28     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  29                  LINK_FLAGS " -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  30   else()
  31     set(native_export_file "${target_name}.def")
  32
  33     set(CAT "type")
  34     if(CYGWIN)
  35       set(CAT "cat")
  36     endif()
  37
  38     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  39     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  40
  41     add_custom_command(OUTPUT ${native_export_file}
  42       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  43       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  44       DEPENDS ${export_file}
  45       VERBATIM
  46       COMMENT "Creating export file for ${target_name}")
  47     if(CYGWIN OR MINGW)
  48       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  49                    LINK_FLAGS "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  50     else()
  51       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  52                    LINK_FLAGS "/DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  53     endif()
  54   endif()
  55
  56   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
  57
  58   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
  59   foreach(src ${srcs})
  60     get_filename_component(extension ${src} EXT)
  61     if(extension STREQUAL ".cpp")
  62       set(first_source_file ${src})
  63       break()
  64     endif()
  65   endforeach()
  66
  67   # Force re-linking when the exports file changes. Actually, it
  68   # forces recompilation of the source file. The LINK_DEPENDS target
  69   # property only works for makefile-based generators.
  70   set_property(SOURCE ${first_source_file} APPEND PROPERTY
  71     OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
  72
  73   set_property(DIRECTORY APPEND
  74     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
  75
  76   add_dependencies(${target_name} ${target_name}_exports)
  77 endfunction(add_llvm_symbol_exports)
  78
  79 macro(add_llvm_library name)
  80   llvm_process_sources( ALL_FILES ${ARGN} )
  81   add_library( ${name} ${ALL_FILES} )
  82   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
  83   if( LLVM_COMMON_DEPENDS )
  84     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  85   endif( LLVM_COMMON_DEPENDS )
  86
  87   if( BUILD_SHARED_LIBS )
  88     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  89     if (MSVC)
  90       set_target_properties(${name}
  91         PROPERTIES
  92         IMPORT_SUFFIX ".imp")
  93     endif ()
  94
  95     if (LLVM_EXPORTED_SYMBOL_FILE)
  96       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
  97     endif()
  98   endif()
  99
 100   # Ensure that the system libraries always comes last on the
 101   # list. Without this, linking the unit tests on MinGW fails.
 102   link_system_libs( ${name} )
 103
 104   if( EXCLUDE_FROM_ALL )
 105     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 106   else()
 107     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 108       install(TARGETS ${name}
 109         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 110         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 111     endif()
 112   endif()
 113   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 114
 115   # Add the explicit dependency information for this library.
 116   #
 117   # It would be nice to verify that we have the dependencies for this library
 118   # name, but using get_property(... SET) doesn't suffice to determine if a
 119   # property has been set to an empty value.
 120   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 121   target_link_libraries(${name} ${lib_deps})
 122 endmacro(add_llvm_library name)
 123
 124 macro(add_llvm_loadable_module name)
 125   if( NOT LLVM_ON_UNIX OR CYGWIN )
 126     message(STATUS "Loadable modules not supported on this platform.
 127 ${name} ignored.")
 128     # Add empty "phony" target
 129     add_custom_target(${name})
 130   else()
 131     llvm_process_sources( ALL_FILES ${ARGN} )
 132     if (MODULE)
 133       set(libkind MODULE)
 134     else()
 135       set(libkind SHARED)
 136     endif()
 137
 138     add_library( ${name} ${libkind} ${ALL_FILES} )
 139     set_target_properties( ${name} PROPERTIES PREFIX "" )
 140
 141     if (LLVM_EXPORTED_SYMBOL_FILE)
 142       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 143     endif(LLVM_EXPORTED_SYMBOL_FILE)
 144
 145     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 146     link_system_libs( ${name} )
 147
 148     if (APPLE)
 149       # Darwin-specific linker flags for loadable modules.
 150       set_target_properties(${name} PROPERTIES
 151         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 152     endif()
 153
 154     if( EXCLUDE_FROM_ALL )
 155       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 156     else()
 157       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 158         install(TARGETS ${name}
 159           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 160           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 161       endif()
 162     endif()
 163   endif()
 164
 165   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 166 endmacro(add_llvm_loadable_module name)
 167
 168
 169 macro(add_llvm_executable name)
 170   llvm_process_sources( ALL_FILES ${ARGN} )
 171   if( EXCLUDE_FROM_ALL )
 172     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 173   else()
 174     add_executable(${name} ${ALL_FILES})
 175   endif()
 176
 177   if (LLVM_EXPORTED_SYMBOL_FILE)
 178     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 179   endif(LLVM_EXPORTED_SYMBOL_FILE)
 180
 181   set(EXCLUDE_FROM_ALL OFF)
 182   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 183   if( LLVM_COMMON_DEPENDS )
 184     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 185   endif( LLVM_COMMON_DEPENDS )
 186   link_system_libs( ${name} )
 187 endmacro(add_llvm_executable name)
 188
 189
 190 set (LLVM_TOOLCHAIN_TOOLS
 191   llvm-ar
 192   llvm-objdump
 193   )
 194
 195 macro(add_llvm_tool name)
 196   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
 197   if( NOT LLVM_BUILD_TOOLS )
 198     set(EXCLUDE_FROM_ALL ON)
 199   endif()
 200   add_llvm_executable(${name} ${ARGN})
 201
 202   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 203   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 204     if( LLVM_BUILD_TOOLS )
 205       install(TARGETS ${name} RUNTIME DESTINATION bin)
 206     endif()
 207   endif()
 208   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 209 endmacro(add_llvm_tool name)
 210
 211
 212 macro(add_llvm_example name)
 213 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
 214   if( NOT LLVM_BUILD_EXAMPLES )
 215     set(EXCLUDE_FROM_ALL ON)
 216   endif()
 217   add_llvm_executable(${name} ${ARGN})
 218   if( LLVM_BUILD_EXAMPLES )
 219     install(TARGETS ${name} RUNTIME DESTINATION examples)
 220   endif()
 221   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 222 endmacro(add_llvm_example name)
 223
 224
 225 macro(add_llvm_utility name)
 226   add_llvm_executable(${name} ${ARGN})
 227   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 228 endmacro(add_llvm_utility name)
 229
 230
 231 macro(add_llvm_target target_name)
 232   include_directories(BEFORE
 233     ${CMAKE_CURRENT_BINARY_DIR}
 234     ${CMAKE_CURRENT_SOURCE_DIR})
 235   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 236   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 237 endmacro(add_llvm_target)
 238
 239 # Add external project that may want to be built as part of llvm such as Clang,
 240 # lld, and Polly. This adds two options. One for the source directory of the
 241 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 242 # enable or disable building it with everything else.
 243 # Additional parameter can be specified as the name of directory.
 244 macro(add_llvm_external_project name)
 245   set(add_llvm_external_dir "${ARGN}")
 246   if("${add_llvm_external_dir}" STREQUAL "")
 247     set(add_llvm_external_dir ${name})
 248   endif()
 249   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 250   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 251   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 252   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 253       CACHE PATH "Path to ${name} source directory")
 254   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 255       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 256     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 257            "Whether to build ${name} as part of LLVM" ON)
 258     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 259       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 260     endif()
 261   endif()
 262 endmacro(add_llvm_external_project)
 263
 264 macro(add_llvm_tool_subdirectory name)
 265   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 266   add_subdirectory(${name})
 267 endmacro(add_llvm_tool_subdirectory)
 268
 269 macro(ignore_llvm_tool_subdirectory name)
 270   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 271 endmacro(ignore_llvm_tool_subdirectory)
 272
 273 function(add_llvm_implicit_external_projects)
 274   set(list_of_implicit_subdirs "")
 275   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 276   foreach(dir ${sub-dirs})
 277     if(IS_DIRECTORY "${dir}")
 278       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 279       if( tool_subdir_ignore EQUAL -1
 280           AND EXISTS "${dir}/CMakeLists.txt")
 281         get_filename_component(fn "${dir}" NAME)
 282         list(APPEND list_of_implicit_subdirs "${fn}")
 283       endif()
 284     endif()
 285   endforeach()
 286
 287   foreach(external_proj ${list_of_implicit_subdirs})
 288     add_llvm_external_project("${external_proj}")
 289   endforeach()
 290 endfunction(add_llvm_implicit_external_projects)
 291
 292 # Generic support for adding a unittest.
 293 function(add_unittest test_suite test_name)
 294   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 295   if( NOT LLVM_BUILD_TESTS )
 296     set(EXCLUDE_FROM_ALL ON)
 297   endif()
 298
 299   add_llvm_executable(${test_name} ${ARGN})
 300   target_link_libraries(${test_name}
 301     gtest
 302     gtest_main
 303     LLVMSupport # gtest needs it for raw_ostream.
 304     )
 305
 306   add_dependencies(${test_suite} ${test_name})
 307   get_target_property(test_suite_folder ${test_suite} FOLDER)
 308   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 309     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 310   endif ()
 311
 312   # Visual Studio 2012 only supports up to 8 template parameters in
 313   # std::tr1::tuple by default, but gtest requires 10
 314   if (MSVC AND MSVC_VERSION EQUAL 1700)
 315     set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 316   endif ()
 317
 318   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 319   set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
 320   if (NOT LLVM_ENABLE_THREADS)
 321     set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 322   endif ()
 323
 324   get_property(target_compile_flags TARGET ${test_name} PROPERTY COMPILE_FLAGS)
 325   if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 326     set(target_compile_flags "${target_compile_flags} -fno-rtti")
 327   elseif (MSVC)
 328     llvm_replace_compiler_option(target_compile_flags "/GR" "/GR-")
 329   endif ()
 330
 331   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 332     set(target_compile_flags "${target_compile_flags} -Wno-variadic-macros")
 333   endif ()
 334   set_property(TARGET ${test_name} PROPERTY COMPILE_FLAGS "${target_compile_flags}")
 335 endfunction()
 336
 337 # This function provides an automatic way to 'configure'-like generate a file
 338 # based on a set of common and custom variables, specifically targeting the
 339 # variables needed for the 'lit.site.cfg' files. This function bundles the
 340 # common variables that any Lit instance is likely to need, and custom
 341 # variables can be passed in.
 342 function(configure_lit_site_cfg input output)
 343   foreach(c ${LLVM_TARGETS_TO_BUILD})
 344     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 345   endforeach(c)
 346   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 347
 348   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 349   set(SHLIBDIR "${LLVM_LIBRARY_OUTPUT_INTDIR}")
 350
 351   if(BUILD_SHARED_LIBS)
 352     set(LLVM_SHARED_LIBS_ENABLED "1")
 353   else()
 354     set(LLVM_SHARED_LIBS_ENABLED "0")
 355   endif(BUILD_SHARED_LIBS)
 356
 357   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 358     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 359   else() # Default for all other unix like systems.
 360     # CMake hardcodes the library locaction using rpath.
 361     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 362     # build dir. We pass it anyways.
 363     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 364   endif()
 365
 366   # Configuration-time: See Unit/lit.site.cfg.in
 367   if (CMAKE_CFG_INTDIR STREQUAL ".")
 368     set(LLVM_BUILD_MODE ".")
 369   else ()
 370     set(LLVM_BUILD_MODE "%(build_mode)s")
 371   endif ()
 372
 373   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 374   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 375   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 376   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_OUTPUT_INTDIR})
 377   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 378   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 379   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 380
 381   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 382     set(ENABLE_ASSERTIONS "1")
 383   else()
 384     set(ENABLE_ASSERTIONS "0")
 385   endif()
 386
 387   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 388   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 389
 390   if (CLANG_ENABLE_ARCMT)
 391     set(ENABLE_CLANG_ARCMT "1")
 392   else()
 393     set(ENABLE_CLANG_ARCMT "0")
 394   endif()
 395   if (CLANG_ENABLE_REWRITER)
 396     set(ENABLE_CLANG_REWRITER "1")
 397   else()
 398     set(ENABLE_CLANG_REWRITER "0")
 399   endif()
 400   if (CLANG_ENABLE_STATIC_ANALYZER)
 401     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 402   else()
 403     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 404   endif()
 405
 406   configure_file(${input} ${output} @ONLY)
 407 endfunction()
 408
 409 # A raw function to create a lit target. This is used to implement the testuite
 410 # management functions.
 411 function(add_lit_target target comment)
 412   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 413   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 414   separate_arguments(LIT_ARGS)
 415   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 416     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 417   endif ()
 418   set(LIT_COMMAND
 419     ${PYTHON_EXECUTABLE}
 420     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 421     ${LIT_ARGS}
 422     )
 423   foreach(param ${ARG_PARAMS})
 424     list(APPEND LIT_COMMAND --param ${param})
 425   endforeach()
 426   if( ARG_DEPENDS )
 427     add_custom_target(${target}
 428       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 429       COMMENT "${comment}"
 430       )
 431     add_dependencies(${target} ${ARG_DEPENDS})
 432   else()
 433     add_custom_target(${target}
 434       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 435     message(STATUS "${target} does nothing.")
 436   endif()
 437
 438   # Tests should be excluded from "Build Solution".
 439   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 440 endfunction()
 441
 442 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 443 function(add_lit_testsuite target comment)
 444   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 445
 446   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 447   if(NOT EXCLUDE_FROM_ALL)
 448     # Register the testsuites, params and depends for the global check rule.
 449     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 450     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 451     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 452     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 453   endif()
 454
 455   # Produce a specific suffixed check rule.
 456   add_lit_target(${target} ${comment}
 457     ${ARG_DEFAULT_ARGS}
 458     PARAMS ${ARG_PARAMS}
 459     DEPENDS ${ARG_DEPENDS}
 460     ARGS ${ARG_ARGS}
 461     )
 462 endfunction()