cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVMConfig)
   3
   4 macro(add_llvm_library name)
   5   llvm_process_sources( ALL_FILES ${ARGN} )
   6   add_library( ${name} ${ALL_FILES} )
   7   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
   8   if( LLVM_COMMON_DEPENDS )
   9     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  10   endif( LLVM_COMMON_DEPENDS )
  11
  12   if( BUILD_SHARED_LIBS )
  13     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  14     get_system_libs(sl)
  15     target_link_libraries( ${name} ${sl} )
  16   endif()
  17
  18   install(TARGETS ${name}
  19     LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  20     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  21   # The LLVM Target library shall be built before its sublibraries
  22   # (asmprinter, etc) because those may use tablegenned files which
  23   # generation is triggered by the main LLVM target library. Necessary
  24   # for parallel builds:
  25   if( CURRENT_LLVM_TARGET )
  26     add_dependencies(${name} ${CURRENT_LLVM_TARGET})
  27   endif()
  28   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
  29 endmacro(add_llvm_library name)
  30
  31
  32 macro(add_llvm_loadable_module name)
  33   if( NOT LLVM_ON_UNIX OR CYGWIN )
  34     message(STATUS "Loadable modules not supported on this platform.
  35 ${name} ignored.")
  36     # Add empty "phony" target
  37     add_custom_target(${name})
  38   else()
  39     llvm_process_sources( ALL_FILES ${ARGN} )
  40     if (MODULE)
  41       set(libkind MODULE)
  42     else()
  43       set(libkind SHARED)
  44     endif()
  45
  46     add_library( ${name} ${libkind} ${ALL_FILES} )
  47     set_target_properties( ${name} PROPERTIES PREFIX "" )
  48
  49     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  50     get_system_libs(sl)
  51     target_link_libraries( ${name} ${sl} )
  52
  53     if (APPLE)
  54       # Darwin-specific linker flags for loadable modules.
  55       set_target_properties(${name} PROPERTIES
  56         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
  57     endif()
  58
  59     install(TARGETS ${name}
  60       LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  61       ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  62   endif()
  63
  64   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
  65 endmacro(add_llvm_loadable_module name)
  66
  67
  68 macro(add_llvm_executable name)
  69   llvm_process_sources( ALL_FILES ${ARGN} )
  70   if( EXCLUDE_FROM_ALL )
  71     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
  72   else()
  73     add_executable(${name} ${ALL_FILES})
  74   endif()
  75   set(EXCLUDE_FROM_ALL OFF)
  76   if( LLVM_USED_LIBS )
  77     foreach(lib ${LLVM_USED_LIBS})
  78       target_link_libraries( ${name} ${lib} )
  79     endforeach(lib)
  80   endif( LLVM_USED_LIBS )
  81   if( LLVM_LINK_COMPONENTS )
  82     llvm_config(${name} ${LLVM_LINK_COMPONENTS})
  83   endif( LLVM_LINK_COMPONENTS )
  84   if( LLVM_COMMON_DEPENDS )
  85     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  86   endif( LLVM_COMMON_DEPENDS )
  87   get_system_libs(llvm_system_libs)
  88   if( llvm_system_libs )
  89     target_link_libraries(${name} ${llvm_system_libs})
  90   endif()
  91 endmacro(add_llvm_executable name)
  92
  93
  94 macro(add_llvm_tool name)
  95   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
  96   if( NOT LLVM_BUILD_TOOLS )
  97     set(EXCLUDE_FROM_ALL ON)
  98   endif()
  99   add_llvm_executable(${name} ${ARGN})
 100   if( LLVM_BUILD_TOOLS )
 101     install(TARGETS ${name} RUNTIME DESTINATION bin)
 102   endif()
 103   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 104 endmacro(add_llvm_tool name)
 105
 106
 107 macro(add_llvm_example name)
 108 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
 109   if( NOT LLVM_BUILD_EXAMPLES )
 110     set(EXCLUDE_FROM_ALL ON)
 111   endif()
 112   add_llvm_executable(${name} ${ARGN})
 113   if( LLVM_BUILD_EXAMPLES )
 114     install(TARGETS ${name} RUNTIME DESTINATION examples)
 115   endif()
 116   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 117 endmacro(add_llvm_example name)
 118
 119
 120 macro(add_llvm_utility name)
 121   add_llvm_executable(${name} ${ARGN})
 122   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 123 endmacro(add_llvm_utility name)
 124
 125
 126 macro(add_llvm_target target_name)
 127   if( TABLEGEN_OUTPUT )
 128     add_custom_target(${target_name}Table_gen
 129       DEPENDS ${TABLEGEN_OUTPUT})
 130     add_dependencies(${target_name}Table_gen ${LLVM_COMMON_DEPENDS})
 131   endif( TABLEGEN_OUTPUT )
 132   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
 133   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 134   if ( TABLEGEN_OUTPUT )
 135     add_dependencies(LLVM${target_name} ${target_name}Table_gen)
 136     set_target_properties(${target_name}Table_gen PROPERTIES FOLDER "Tablegenning")
 137   endif (TABLEGEN_OUTPUT)
 138   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 139 endmacro(add_llvm_target)