cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(add_llvm_symbol_exports target_name export_file)
   6   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
   7     set(native_export_file "symbol.exports")
   8     add_custom_command(OUTPUT symbol.exports
   9       COMMAND sed -e "s/^/_/" < ${export_file} > symbol.exports
  10       DEPENDS ${export_file}
  11       VERBATIM
  12       COMMENT "Creating export file for ${target_name}")
  13     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  14                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/symbol.exports")
  15   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  16     # Gold and BFD ld require a version script rather than a plain list.
  17     set(native_export_file "symbol.exports")
  18     # FIXME: Don't write the "local:" line on OpenBSD.
  19     add_custom_command(OUTPUT symbol.exports
  20       COMMAND echo "{" > symbol.exports
  21       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> symbol.exports || :
  22       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> symbol.exports
  23       COMMAND echo "  local: *;" >> symbol.exports
  24       COMMAND echo "};" >> symbol.exports
  25       DEPENDS ${export_file}
  26       VERBATIM
  27       COMMENT "Creating export file for ${target_name}")
  28     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  29                  LINK_FLAGS " -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/symbol.exports")
  30   else()
  31     set(native_export_file "symbol.def")
  32
  33     set(CAT "type")
  34     if(CYGWIN)
  35       set(CAT "cat")
  36     endif()
  37
  38     add_custom_command(OUTPUT symbol.def
  39       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > symbol.def
  40       COMMAND ${CAT} ${export_file} >> symbol.def
  41       DEPENDS ${export_file}
  42       VERBATIM
  43       COMMENT "Creating export file for ${target_name}")
  44     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  45                  LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/symbol.def")
  46   endif()
  47
  48   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
  49
  50   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
  51   foreach(src ${srcs})
  52     get_filename_component(extension ${src} EXT)
  53     if(extension STREQUAL ".cpp")
  54       set(first_source_file ${src})
  55       break()
  56     endif()
  57   endforeach()
  58
  59   # Force re-linking when the exports file changes. Actually, it
  60   # forces recompilation of the source file. The LINK_DEPENDS target
  61   # property only works for makefile-based generators.
  62   set_property(SOURCE ${first_source_file} APPEND PROPERTY
  63     OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
  64
  65   set_property(DIRECTORY APPEND
  66     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
  67
  68   add_dependencies(${target_name} ${target_name}_exports)
  69 endfunction(add_llvm_symbol_exports)
  70
  71 macro(add_llvm_library name)
  72   llvm_process_sources( ALL_FILES ${ARGN} )
  73   add_library( ${name} ${ALL_FILES} )
  74   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
  75   if( LLVM_COMMON_DEPENDS )
  76     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  77   endif( LLVM_COMMON_DEPENDS )
  78
  79   if( BUILD_SHARED_LIBS )
  80     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  81     if (MSVC)
  82       set_target_properties(${name}
  83         PROPERTIES
  84         IMPORT_SUFFIX ".imp")
  85     endif ()
  86   endif()
  87
  88   if (LLVM_EXPORTED_SYMBOL_FILE)
  89     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
  90   endif()
  91
  92   # Ensure that the system libraries always comes last on the
  93   # list. Without this, linking the unit tests on MinGW fails.
  94   link_system_libs( ${name} )
  95
  96   if( EXCLUDE_FROM_ALL )
  97     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
  98   else()
  99     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 100       install(TARGETS ${name}
 101         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 102         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 103     endif()
 104   endif()
 105   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 106
 107   # Add the explicit dependency information for this library.
 108   #
 109   # It would be nice to verify that we have the dependencies for this library
 110   # name, but using get_property(... SET) doesn't suffice to determine if a
 111   # property has been set to an empty value.
 112   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 113   target_link_libraries(${name} ${lib_deps})
 114 endmacro(add_llvm_library name)
 115
 116 macro(add_llvm_loadable_module name)
 117   if( NOT LLVM_ON_UNIX OR CYGWIN )
 118     message(STATUS "Loadable modules not supported on this platform.
 119 ${name} ignored.")
 120     # Add empty "phony" target
 121     add_custom_target(${name})
 122   else()
 123     llvm_process_sources( ALL_FILES ${ARGN} )
 124     if (MODULE)
 125       set(libkind MODULE)
 126     else()
 127       set(libkind SHARED)
 128     endif()
 129
 130     if (LLVM_EXPORTED_SYMBOL_FILE)
 131       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 132     endif(LLVM_EXPORTED_SYMBOL_FILE)
 133
 134     add_library( ${name} ${libkind} ${ALL_FILES} )
 135     set_target_properties( ${name} PROPERTIES PREFIX "" )
 136
 137     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 138     link_system_libs( ${name} )
 139
 140     if (APPLE)
 141       # Darwin-specific linker flags for loadable modules.
 142       set_target_properties(${name} PROPERTIES
 143         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 144     endif()
 145
 146     if( EXCLUDE_FROM_ALL )
 147       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 148     else()
 149       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 150         install(TARGETS ${name}
 151           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 152           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 153       endif()
 154     endif()
 155   endif()
 156
 157   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 158 endmacro(add_llvm_loadable_module name)
 159
 160
 161 macro(add_llvm_executable name)
 162   llvm_process_sources( ALL_FILES ${ARGN} )
 163   if( EXCLUDE_FROM_ALL )
 164     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 165   else()
 166     add_executable(${name} ${ALL_FILES})
 167   endif()
 168
 169   if (LLVM_EXPORTED_SYMBOL_FILE)
 170     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 171   endif(LLVM_EXPORTED_SYMBOL_FILE)
 172
 173   set(EXCLUDE_FROM_ALL OFF)
 174   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 175   if( LLVM_COMMON_DEPENDS )
 176     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 177   endif( LLVM_COMMON_DEPENDS )
 178   link_system_libs( ${name} )
 179 endmacro(add_llvm_executable name)
 180
 181
 182 set (LLVM_TOOLCHAIN_TOOLS
 183   llvm-ar
 184   llvm-objdump
 185   )
 186
 187 macro(add_llvm_tool name)
 188   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
 189   if( NOT LLVM_BUILD_TOOLS )
 190     set(EXCLUDE_FROM_ALL ON)
 191   endif()
 192   add_llvm_executable(${name} ${ARGN})
 193
 194   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 195   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 196     if( LLVM_BUILD_TOOLS )
 197       install(TARGETS ${name} RUNTIME DESTINATION bin)
 198     endif()
 199   endif()
 200   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 201 endmacro(add_llvm_tool name)
 202
 203
 204 macro(add_llvm_example name)
 205 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
 206   if( NOT LLVM_BUILD_EXAMPLES )
 207     set(EXCLUDE_FROM_ALL ON)
 208   endif()
 209   add_llvm_executable(${name} ${ARGN})
 210   if( LLVM_BUILD_EXAMPLES )
 211     install(TARGETS ${name} RUNTIME DESTINATION examples)
 212   endif()
 213   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 214 endmacro(add_llvm_example name)
 215
 216
 217 macro(add_llvm_utility name)
 218   add_llvm_executable(${name} ${ARGN})
 219   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 220 endmacro(add_llvm_utility name)
 221
 222
 223 macro(add_llvm_target target_name)
 224   include_directories(BEFORE
 225     ${CMAKE_CURRENT_BINARY_DIR}
 226     ${CMAKE_CURRENT_SOURCE_DIR})
 227   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 228   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 229 endmacro(add_llvm_target)
 230
 231 # Add external project that may want to be built as part of llvm such as Clang,
 232 # lld, and Polly. This adds two options. One for the source directory of the
 233 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 234 # enable or disable building it with everything else.
 235 # Additional parameter can be specified as the name of directory.
 236 macro(add_llvm_external_project name)
 237   set(add_llvm_external_dir "${ARGN}")
 238   if("${add_llvm_external_dir}" STREQUAL "")
 239     set(add_llvm_external_dir ${name})
 240   endif()
 241   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 242   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 243   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 244   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 245       CACHE PATH "Path to ${name} source directory")
 246   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 247       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 248     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 249            "Whether to build ${name} as part of LLVM" ON)
 250     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 251       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 252     endif()
 253   endif()
 254 endmacro(add_llvm_external_project)
 255
 256 macro(add_llvm_tool_subdirectory name)
 257   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 258   add_subdirectory(${name})
 259 endmacro(add_llvm_tool_subdirectory)
 260
 261 macro(ignore_llvm_tool_subdirectory name)
 262   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 263 endmacro(ignore_llvm_tool_subdirectory)
 264
 265 function(add_llvm_implicit_external_projects)
 266   set(list_of_implicit_subdirs "")
 267   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 268   foreach(dir ${sub-dirs})
 269     if(IS_DIRECTORY "${dir}")
 270       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 271       if( tool_subdir_ignore EQUAL -1
 272           AND EXISTS "${dir}/CMakeLists.txt")
 273         get_filename_component(fn "${dir}" NAME)
 274         list(APPEND list_of_implicit_subdirs "${fn}")
 275       endif()
 276     endif()
 277   endforeach()
 278
 279   foreach(external_proj ${list_of_implicit_subdirs})
 280     add_llvm_external_project("${external_proj}")
 281   endforeach()
 282 endfunction(add_llvm_implicit_external_projects)
 283
 284 # Generic support for adding a unittest.
 285 function(add_unittest test_suite test_name)
 286   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
 287   if( NOT LLVM_BUILD_TESTS )
 288     set(EXCLUDE_FROM_ALL ON)
 289   endif()
 290
 291   add_llvm_executable(${test_name} ${ARGN})
 292   target_link_libraries(${test_name}
 293     gtest
 294     gtest_main
 295     LLVMSupport # gtest needs it for raw_ostream.
 296     )
 297
 298   add_dependencies(${test_suite} ${test_name})
 299   get_target_property(test_suite_folder ${test_suite} FOLDER)
 300   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 301     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 302   endif ()
 303
 304   # Visual Studio 2012 only supports up to 8 template parameters in
 305   # std::tr1::tuple by default, but gtest requires 10
 306   if (MSVC AND MSVC_VERSION EQUAL 1700)
 307     set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 308   endif ()
 309
 310   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 311   set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
 312   if (NOT LLVM_ENABLE_THREADS)
 313     set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 314   endif ()
 315
 316   get_property(target_compile_flags TARGET ${test_name} PROPERTY COMPILE_FLAGS)
 317   if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 318     set(target_compile_flags "${target_compile_flags} -fno-rtti")
 319   elseif (MSVC)
 320     llvm_replace_compiler_option(target_compile_flags "/GR" "/GR-")
 321   endif ()
 322
 323   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 324     set(target_compile_flags "${target_compile_flags} -Wno-variadic-macros")
 325   endif ()
 326   set_property(TARGET ${test_name} PROPERTY COMPILE_FLAGS "${target_compile_flags}")
 327 endfunction()
 328
 329 # This function provides an automatic way to 'configure'-like generate a file
 330 # based on a set of common and custom variables, specifically targeting the
 331 # variables needed for the 'lit.site.cfg' files. This function bundles the
 332 # common variables that any Lit instance is likely to need, and custom
 333 # variables can be passed in.
 334 function(configure_lit_site_cfg input output)
 335   foreach(c ${LLVM_TARGETS_TO_BUILD})
 336     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 337   endforeach(c)
 338   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 339
 340   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 341   set(SHLIBDIR "${LLVM_LIBRARY_OUTPUT_INTDIR}")
 342
 343   if(BUILD_SHARED_LIBS)
 344     set(LLVM_SHARED_LIBS_ENABLED "1")
 345   else()
 346     set(LLVM_SHARED_LIBS_ENABLED "0")
 347   endif(BUILD_SHARED_LIBS)
 348
 349   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 350     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 351   else() # Default for all other unix like systems.
 352     # CMake hardcodes the library locaction using rpath.
 353     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 354     # build dir. We pass it anyways.
 355     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 356   endif()
 357
 358   # Configuration-time: See Unit/lit.site.cfg.in
 359   if (CMAKE_CFG_INTDIR STREQUAL ".")
 360     set(LLVM_BUILD_MODE ".")
 361   else ()
 362     set(LLVM_BUILD_MODE "%(build_mode)s")
 363   endif ()
 364
 365   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 366   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 367   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 368   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_OUTPUT_INTDIR})
 369   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 370   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 371   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 372
 373   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 374     set(ENABLE_ASSERTIONS "1")
 375   else()
 376     set(ENABLE_ASSERTIONS "0")
 377   endif()
 378
 379   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 380   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 381
 382   if (CLANG_ENABLE_ARCMT)
 383     set(ENABLE_CLANG_ARCMT "1")
 384   else()
 385     set(ENABLE_CLANG_ARCMT "0")
 386   endif()
 387   if (CLANG_ENABLE_REWRITER)
 388     set(ENABLE_CLANG_REWRITER "1")
 389   else()
 390     set(ENABLE_CLANG_REWRITER "0")
 391   endif()
 392   if (CLANG_ENABLE_STATIC_ANALYZER)
 393     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 394   else()
 395     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 396   endif()
 397
 398   configure_file(${input} ${output} @ONLY)
 399 endfunction()
 400
 401 # A raw function to create a lit target. This is used to implement the testuite
 402 # management functions.
 403 function(add_lit_target target comment)
 404   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 405   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 406   separate_arguments(LIT_ARGS)
 407   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 408     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 409   endif ()
 410   set(LIT_COMMAND
 411     ${PYTHON_EXECUTABLE}
 412     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 413     ${LIT_ARGS}
 414     )
 415   foreach(param ${ARG_PARAMS})
 416     list(APPEND LIT_COMMAND --param ${param})
 417   endforeach()
 418   if( ARG_DEPENDS )
 419     add_custom_target(${target}
 420       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 421       COMMENT "${comment}"
 422       )
 423     add_dependencies(${target} ${ARG_DEPENDS})
 424   else()
 425     add_custom_target(${target}
 426       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 427     message(STATUS "${target} does nothing.")
 428   endif()
 429
 430   # Tests should be excluded from "Build Solution".
 431   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 432 endfunction()
 433
 434 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 435 function(add_lit_testsuite target comment)
 436   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 437
 438   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 439   if(NOT EXCLUDE_FROM_ALL)
 440     # Register the testsuites, params and depends for the global check rule.
 441     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 442     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 443     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 444     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 445   endif()
 446
 447   # Produce a specific suffixed check rule.
 448   add_lit_target(${target} ${comment}
 449     ${ARG_DEFAULT_ARGS}
 450     PARAMS ${ARG_PARAMS}
 451     DEPENDS ${ARG_DEPENDS}
 452     ARGS ${ARG_ARGS}
 453     )
 454 endfunction()