cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 macro(add_llvm_library name)
   6   llvm_process_sources( ALL_FILES ${ARGN} )
   7   add_library( ${name} ${ALL_FILES} )
   8   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
   9   if( LLVM_COMMON_DEPENDS )
  10     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  11   endif( LLVM_COMMON_DEPENDS )
  12
  13   if( BUILD_SHARED_LIBS )
  14     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  15   endif()
  16
  17   # Ensure that the system libraries always comes last on the
  18   # list. Without this, linking the unit tests on MinGW fails.
  19   link_system_libs( ${name} )
  20
  21   if( EXCLUDE_FROM_ALL )
  22     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
  23   else()
  24     install(TARGETS ${name}
  25       LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  26       ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  27   endif()
  28   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
  29
  30   # Add the explicit dependency information for this library.
  31   #
  32   # It would be nice to verify that we have the dependencies for this library
  33   # name, but using get_property(... SET) doesn't suffice to determine if a
  34   # property has been set to an empty value.
  35   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
  36   target_link_libraries(${name} ${lib_deps})
  37 endmacro(add_llvm_library name)
  38
  39 macro(add_llvm_loadable_module name)
  40   if( NOT LLVM_ON_UNIX OR CYGWIN )
  41     message(STATUS "Loadable modules not supported on this platform.
  42 ${name} ignored.")
  43     # Add empty "phony" target
  44     add_custom_target(${name})
  45   else()
  46     llvm_process_sources( ALL_FILES ${ARGN} )
  47     if (MODULE)
  48       set(libkind MODULE)
  49     else()
  50       set(libkind SHARED)
  51     endif()
  52
  53     add_library( ${name} ${libkind} ${ALL_FILES} )
  54     set_target_properties( ${name} PROPERTIES PREFIX "" )
  55
  56     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  57     link_system_libs( ${name} )
  58
  59     if (APPLE)
  60       # Darwin-specific linker flags for loadable modules.
  61       set_target_properties(${name} PROPERTIES
  62         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
  63     endif()
  64
  65     if( EXCLUDE_FROM_ALL )
  66       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
  67     else()
  68       install(TARGETS ${name}
  69         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  70         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  71     endif()
  72   endif()
  73
  74   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
  75 endmacro(add_llvm_loadable_module name)
  76
  77
  78 macro(add_llvm_executable name)
  79   llvm_process_sources( ALL_FILES ${ARGN} )
  80   if( EXCLUDE_FROM_ALL )
  81     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
  82   else()
  83     add_executable(${name} ${ALL_FILES})
  84   endif()
  85   set(EXCLUDE_FROM_ALL OFF)
  86   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  87   if( LLVM_COMMON_DEPENDS )
  88     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  89   endif( LLVM_COMMON_DEPENDS )
  90   link_system_libs( ${name} )
  91 endmacro(add_llvm_executable name)
  92
  93
  94 macro(add_llvm_tool name)
  95   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
  96   if( NOT LLVM_BUILD_TOOLS )
  97     set(EXCLUDE_FROM_ALL ON)
  98   endif()
  99   add_llvm_executable(${name} ${ARGN})
 100   if( LLVM_BUILD_TOOLS )
 101     install(TARGETS ${name} RUNTIME DESTINATION bin)
 102   endif()
 103   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 104 endmacro(add_llvm_tool name)
 105
 106
 107 macro(add_llvm_example name)
 108 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
 109   if( NOT LLVM_BUILD_EXAMPLES )
 110     set(EXCLUDE_FROM_ALL ON)
 111   endif()
 112   add_llvm_executable(${name} ${ARGN})
 113   if( LLVM_BUILD_EXAMPLES )
 114     install(TARGETS ${name} RUNTIME DESTINATION examples)
 115   endif()
 116   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 117 endmacro(add_llvm_example name)
 118
 119
 120 macro(add_llvm_utility name)
 121   add_llvm_executable(${name} ${ARGN})
 122   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 123 endmacro(add_llvm_utility name)
 124
 125
 126 macro(add_llvm_target target_name)
 127   include_directories(BEFORE
 128     ${CMAKE_CURRENT_BINARY_DIR}
 129     ${CMAKE_CURRENT_SOURCE_DIR})
 130   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 131   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 132 endmacro(add_llvm_target)
 133
 134 # Add external project that may want to be built as part of llvm such as Clang,
 135 # lld, and Polly. This adds two options. One for the source directory of the
 136 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 137 # enable or disable building it with everthing else.
 138 # Additional parameter can be specified as the name of directory.
 139 macro(add_llvm_external_project name)
 140   set(add_llvm_external_dir "${ARGN}")
 141   if("${add_llvm_external_dir}" STREQUAL "")
 142     set(add_llvm_external_dir ${name})
 143   endif()
 144   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 145   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 146   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 147       CACHE PATH "Path to ${name} source directory")
 148   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 149       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 150     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 151            "Whether to build ${name} as part of LLVM" ON)
 152     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 153       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 154     endif()
 155   endif()
 156 endmacro(add_llvm_external_project)
 157
 158 # Returns directory where unittest should reside.
 159 function(get_unittest_directory dir)
 160   if (CMAKE_BUILD_TYPE)
 161    set(result ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_BUILD_TYPE})
 162   else()
 163    set(result ${CMAKE_CURRENT_BINARY_DIR})
 164   endif()
 165   set(${dir} ${result} PARENT_SCOPE)
 166 endfunction()
 167
 168 # Generic support for adding a unittest.
 169 function(add_unittest test_suite test_name)
 170   get_unittest_directory(OUTPUT_DIR)
 171   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${OUTPUT_DIR})
 172   if( NOT LLVM_BUILD_TESTS )
 173     set(EXCLUDE_FROM_ALL ON)
 174   endif()
 175
 176   add_llvm_executable(${test_name} ${ARGN})
 177   target_link_libraries(${test_name}
 178     gtest
 179     gtest_main
 180     LLVMSupport # gtest needs it for raw_ostream.
 181     )
 182
 183   add_dependencies(${test_suite} ${test_name})
 184   get_target_property(test_suite_folder ${test_suite} FOLDER)
 185   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 186     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 187   endif ()
 188
 189   # Visual Studio 2012 only supports up to 8 template parameters in
 190   # std::tr1::tuple by default, but gtest requires 10
 191   if (MSVC AND MSVC_VERSION EQUAL 1700)
 192     set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 193   endif ()
 194
 195   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 196   set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
 197   if (NOT LLVM_ENABLE_THREADS)
 198     set_property(TARGET ${test_name} APPEND PROPERTY COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 199   endif ()
 200
 201   get_property(target_compile_flags TARGET ${test_name} PROPERTY COMPILE_FLAGS)
 202   if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
 203     set(target_compile_flags "${target_compile_flags} -fno-rtti")
 204   elseif (MSVC)
 205     set(target_compile_flags "${target_compile_flags} /GR-")
 206   endif ()
 207
 208   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 209     set(target_compile_flags "${target_compile_flags} -Wno-variadic-macros")
 210   endif ()
 211   set_property(TARGET ${test_name} PROPERTY COMPILE_FLAGS "${target_compile_flags}")
 212 endfunction()
 213
 214 # This function provides an automatic way to 'configure'-like generate a file
 215 # based on a set of common and custom variables, specifically targetting the
 216 # variables needed for the 'lit.site.cfg' files. This function bundles the
 217 # common variables that any Lit instance is likely to need, and custom
 218 # variables can be passed in.
 219 function(configure_lit_site_cfg input output)
 220   foreach(c ${LLVM_TARGETS_TO_BUILD})
 221     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 222   endforeach(c)
 223   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 224
 225   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 226   set(SHLIBDIR "${LLVM_BINARY_DIR}/lib/${CMAKE_CFG_INTDIR}")
 227
 228   if(BUILD_SHARED_LIBS)
 229     set(LLVM_SHARED_LIBS_ENABLED "1")
 230   else()
 231     set(LLVM_SHARED_LIBS_ENABLED "0")
 232   endif(BUILD_SHARED_LIBS)
 233
 234   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 235     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 236   else() # Default for all other unix like systems.
 237     # CMake hardcodes the library locaction using rpath.
 238     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 239     # build dir. We pass it anyways.
 240     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 241   endif()
 242
 243   # Configuration-time: See Unit/lit.site.cfg.in
 244   set(LLVM_BUILD_MODE "%(build_mode)s")
 245
 246   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 247   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 248   set(LLVM_TOOLS_DIR "${LLVM_TOOLS_BINARY_DIR}/%(build_config)s")
 249   set(LLVM_LIBS_DIR "${LLVM_BINARY_DIR}/lib/%(build_config)s")
 250   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 251   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 252   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 253
 254   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 255     set(ENABLE_ASSERTIONS "1")
 256   else()
 257     set(ENABLE_ASSERTIONS "0")
 258   endif()
 259
 260   set(HOST_OS ${CMAKE_HOST_SYSTEM_NAME})
 261   set(HOST_ARCH ${CMAKE_HOST_SYSTEM_PROCESSOR})
 262
 263   configure_file(${input} ${output} @ONLY)
 264 endfunction()
 265
 266 # A raw function to create a lit target. This is used to implement the testuite
 267 # management functions.
 268 function(add_lit_target target comment)
 269   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 270   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 271   separate_arguments(LIT_ARGS)
 272   set(LIT_COMMAND
 273     ${PYTHON_EXECUTABLE}
 274     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 275     --param build_config=${CMAKE_CFG_INTDIR}
 276     --param build_mode=${RUNTIME_BUILD_MODE}
 277     ${LIT_ARGS}
 278     )
 279   foreach(param ${ARG_PARAMS})
 280     list(APPEND LIT_COMMAND --param ${param})
 281   endforeach()
 282   if( ARG_DEPENDS )
 283     add_custom_target(${target}
 284       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 285       COMMENT "${comment}"
 286       )
 287     add_dependencies(${target} ${ARG_DEPENDS})
 288   else()
 289     add_custom_target(${target}
 290       COMMAND cmake -E echo "${target} does nothing, no tools built.")
 291     message(STATUS "${target} does nothing.")
 292   endif()
 293 endfunction()
 294
 295 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 296 function(add_lit_testsuite target comment)
 297   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 298
 299   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 300   if(NOT EXCLUDE_FROM_ALL)
 301     # Register the testsuites, params and depends for the global check rule.
 302     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 303     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 304     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 305     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 306   endif()
 307
 308   # Produce a specific suffixed check rule.
 309   add_lit_target(${target} ${comment}
 310     ${ARG_DEFAULT_ARGS}
 311     PARAMS ${ARG_PARAMS}
 312     DEPENDS ${ARG_DEPENDS}
 313     ARGS ${ARG_ARGS}
 314     )
 315 endfunction()