cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3
   4 macro(add_llvm_library name)
   5   llvm_process_sources( ALL_FILES ${ARGN} )
   6   add_library( ${name} ${ALL_FILES} )
   7   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
   8   if( LLVM_COMMON_DEPENDS )
   9     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  10   endif( LLVM_COMMON_DEPENDS )
  11
  12   if( BUILD_SHARED_LIBS )
  13     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  14   endif()
  15
  16   # Ensure that the system libraries always comes last on the
  17   # list. Without this, linking the unit tests on MinGW fails.
  18   link_system_libs( ${name} )
  19
  20   if( EXCLUDE_FROM_ALL )
  21     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
  22   else()
  23     install(TARGETS ${name}
  24       LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  25       ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  26   endif()
  27   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
  28
  29   # Add the explicit dependency information for this library.
  30   #
  31   # It would be nice to verify that we have the dependencies for this library
  32   # name, but using get_property(... SET) doesn't suffice to determine if a
  33   # property has been set to an empty value.
  34   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
  35   target_link_libraries(${name} ${lib_deps})
  36 endmacro(add_llvm_library name)
  37
  38 macro(add_llvm_library_dependencies name)
  39 endmacro(add_llvm_library_dependencies name)
  40
  41 macro(add_llvm_loadable_module name)
  42   if( NOT LLVM_ON_UNIX OR CYGWIN )
  43     message(STATUS "Loadable modules not supported on this platform.
  44 ${name} ignored.")
  45     # Add empty "phony" target
  46     add_custom_target(${name})
  47   else()
  48     llvm_process_sources( ALL_FILES ${ARGN} )
  49     if (MODULE)
  50       set(libkind MODULE)
  51     else()
  52       set(libkind SHARED)
  53     endif()
  54
  55     add_library( ${name} ${libkind} ${ALL_FILES} )
  56     set_target_properties( ${name} PROPERTIES PREFIX "" )
  57
  58     llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  59     link_system_libs( ${name} )
  60
  61     if (APPLE)
  62       # Darwin-specific linker flags for loadable modules.
  63       set_target_properties(${name} PROPERTIES
  64         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
  65     endif()
  66
  67     if( EXCLUDE_FROM_ALL )
  68       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
  69     else()
  70       install(TARGETS ${name}
  71         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  72         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  73     endif()
  74   endif()
  75
  76   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
  77 endmacro(add_llvm_loadable_module name)
  78
  79
  80 macro(add_llvm_executable name)
  81   llvm_process_sources( ALL_FILES ${ARGN} )
  82   if( EXCLUDE_FROM_ALL )
  83     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
  84   else()
  85     add_executable(${name} ${ALL_FILES})
  86   endif()
  87   set(EXCLUDE_FROM_ALL OFF)
  88   target_link_libraries( ${name} ${LLVM_USED_LIBS} )
  89   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
  90   if( LLVM_COMMON_DEPENDS )
  91     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  92   endif( LLVM_COMMON_DEPENDS )
  93   link_system_libs( ${name} )
  94 endmacro(add_llvm_executable name)
  95
  96
  97 macro(add_llvm_tool name)
  98   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
  99   if( NOT LLVM_BUILD_TOOLS )
 100     set(EXCLUDE_FROM_ALL ON)
 101   endif()
 102   add_llvm_executable(${name} ${ARGN})
 103   if( LLVM_BUILD_TOOLS )
 104     install(TARGETS ${name} RUNTIME DESTINATION bin)
 105   endif()
 106   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 107 endmacro(add_llvm_tool name)
 108
 109
 110 macro(add_llvm_example name)
 111 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
 112   if( NOT LLVM_BUILD_EXAMPLES )
 113     set(EXCLUDE_FROM_ALL ON)
 114   endif()
 115   add_llvm_executable(${name} ${ARGN})
 116   if( LLVM_BUILD_EXAMPLES )
 117     install(TARGETS ${name} RUNTIME DESTINATION examples)
 118   endif()
 119   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 120 endmacro(add_llvm_example name)
 121
 122
 123 macro(add_llvm_utility name)
 124   add_llvm_executable(${name} ${ARGN})
 125   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 126 endmacro(add_llvm_utility name)
 127
 128
 129 macro(add_llvm_target target_name)
 130   include_directories(BEFORE
 131     ${CMAKE_CURRENT_BINARY_DIR}
 132     ${CMAKE_CURRENT_SOURCE_DIR})
 133   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 134   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 135 endmacro(add_llvm_target)