cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3 include(DetermineGCCCompatible)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  30     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  31     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  32       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  33     elseif (MSVC)
  34       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  35     endif ()
  36   endif()
  37
  38   # Assume that;
  39   #   - LLVM_COMPILE_FLAGS is list.
  40   #   - PROPERTY COMPILE_FLAGS is string.
  41   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  42
  43   if(update_src_props)
  44     foreach(fn ${sources})
  45       get_filename_component(suf ${fn} EXT)
  46       if("${suf}" STREQUAL ".cpp")
  47         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  48           COMPILE_FLAGS "${target_compile_flags}")
  49       endif()
  50     endforeach()
  51   else()
  52     # Update target props, since all sources are C++.
  53     set_property(TARGET ${name} APPEND_STRING PROPERTY
  54       COMPILE_FLAGS "${target_compile_flags}")
  55   endif()
  56
  57   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  58 endfunction()
  59
  60 function(add_llvm_symbol_exports target_name export_file)
  61   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  62     set(native_export_file "${target_name}.exports")
  63     add_custom_command(OUTPUT ${native_export_file}
  64       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  65       DEPENDS ${export_file}
  66       VERBATIM
  67       COMMENT "Creating export file for ${target_name}")
  68     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  69                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  70   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  71     # Gold and BFD ld require a version script rather than a plain list.
  72     set(native_export_file "${target_name}.exports")
  73     # FIXME: Don't write the "local:" line on OpenBSD.
  74     add_custom_command(OUTPUT ${native_export_file}
  75       COMMAND echo "{" > ${native_export_file}
  76       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  77       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  78       COMMAND echo "  local: *;" >> ${native_export_file}
  79       COMMAND echo "};" >> ${native_export_file}
  80       DEPENDS ${export_file}
  81       VERBATIM
  82       COMMENT "Creating export file for ${target_name}")
  83     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  84       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  85                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  86     else()
  87       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  88                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  89     endif()
  90   else()
  91     set(native_export_file "${target_name}.def")
  92
  93     add_custom_command(OUTPUT ${native_export_file}
  94       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
  95         < ${export_file} > ${native_export_file}
  96       DEPENDS ${export_file}
  97       VERBATIM
  98       COMMENT "Creating export file for ${target_name}")
  99     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 100     if(MSVC)
 101       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 102     endif()
 103     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 104                  LINK_FLAGS " ${export_file_linker_flag}")
 105   endif()
 106
 107   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 108   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 109
 110   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 111   foreach(src ${srcs})
 112     get_filename_component(extension ${src} EXT)
 113     if(extension STREQUAL ".cpp")
 114       set(first_source_file ${src})
 115       break()
 116     endif()
 117   endforeach()
 118
 119   # Force re-linking when the exports file changes. Actually, it
 120   # forces recompilation of the source file. The LINK_DEPENDS target
 121   # property only works for makefile-based generators.
 122   # FIXME: This is not safe because this will create the same target
 123   # ${native_export_file} in several different file:
 124   # - One where we emitted ${target_name}_exports
 125   # - One where we emitted the build command for the following object.
 126   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 127   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 128
 129   set_property(DIRECTORY APPEND
 130     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 131
 132   add_dependencies(${target_name} ${target_name}_exports)
 133
 134   # Add dependency to *_exports later -- CMake issue 14747
 135   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 136   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 137 endfunction(add_llvm_symbol_exports)
 138
 139 if(NOT WIN32 AND NOT APPLE)
 140   execute_process(
 141     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 142     OUTPUT_VARIABLE stdout
 143     ERROR_QUIET
 144     )
 145   if("${stdout}" MATCHES "GNU gold")
 146     set(LLVM_LINKER_IS_GOLD ON)
 147   endif()
 148 endif()
 149
 150 function(add_link_opts target_name)
 151   # Don't use linker optimizations in debug builds since it slows down the
 152   # linker in a context where the optimizations are not important.
 153   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 154
 155     # Pass -O3 to the linker. This enabled different optimizations on different
 156     # linkers.
 157     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 158       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 159                    LINK_FLAGS " -Wl,-O3")
 160     endif()
 161
 162     if(LLVM_LINKER_IS_GOLD)
 163       # With gold gc-sections is always safe.
 164       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 165                    LINK_FLAGS " -Wl,--gc-sections")
 166       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 167       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 168     endif()
 169
 170     if(NOT LLVM_NO_DEAD_STRIP)
 171       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 172         # ld64's implementation of -dead_strip breaks tools that use plugins.
 173         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 174                      LINK_FLAGS " -Wl,-dead_strip")
 175       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 176         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 177                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 178       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 179         # Object files are compiled with -ffunction-data-sections.
 180         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 181         # tools that use plugins. Always pass --gc-sections once we require
 182         # a newer linker.
 183         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 184                      LINK_FLAGS " -Wl,--gc-sections")
 185       endif()
 186     endif()
 187   endif()
 188 endfunction(add_link_opts)
 189
 190 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 191 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 192 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 193 function(set_output_directory target)
 194   cmake_parse_arguments(ARG "" "BINARY_DIR;LIBRARY_DIR;" "" ${ARGN})
 195
 196   # module_dir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 197   # It affects output of add_library(MODULE).
 198   if(WIN32 OR CYGWIN)
 199     # DLL platform
 200     set(module_dir ${ARG_BINARY_DIR})
 201   else()
 202     set(module_dir ${ARG_LIBRARY_DIR})
 203   endif()
 204   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 205     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 206       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 207       if(ARG_BINARY_DIR)
 208         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${ARG_BINARY_DIR})
 209         set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 210       endif()
 211       if(ARG_LIBRARY_DIR)
 212         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${ARG_LIBRARY_DIR})
 213         set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 214       endif()
 215       if(module_dir)
 216         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${module_dir})
 217         set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 218       endif()
 219     endforeach()
 220   else()
 221     if(ARG_BINARY_DIR)
 222       set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${ARG_BINARY_DIR})
 223     endif()
 224     if(ARG_LIBRARY_DIR)
 225       set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${ARG_LIBRARY_DIR})
 226     endif()
 227     if(module_dir)
 228       set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${module_dir})
 229     endif()
 230   endif()
 231 endfunction()
 232
 233 # If on Windows and building with MSVC, add the resource script containing the
 234 # VERSIONINFO data to the project.  This embeds version resource information
 235 # into the output .exe or .dll.
 236 # TODO: Enable for MinGW Windows builds too.
 237 #
 238 function(add_windows_version_resource_file OUT_VAR)
 239   set(sources ${ARGN})
 240   if (MSVC)
 241     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 242     if(EXISTS ${resource_file})
 243       set(sources ${sources} ${resource_file})
 244       source_group("Resource Files" ${resource_file})
 245       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 246     endif()
 247   endif(MSVC)
 248
 249   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 250 endfunction(add_windows_version_resource_file)
 251
 252 # set_windows_version_resource_properties(name resource_file...
 253 #   VERSION_MAJOR int
 254 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 255 #   VERSION_MINOR int
 256 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 257 #   VERSION_PATCHLEVEL int
 258 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 259 #   VERSION_STRING
 260 #     Optional version string (defaults to PACKAGE_VERSION)
 261 #   PRODUCT_NAME
 262 #     Optional product name string (defaults to "LLVM")
 263 #   )
 264 function(set_windows_version_resource_properties name resource_file)
 265   cmake_parse_arguments(ARG
 266     ""
 267     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 268     ""
 269     ${ARGN})
 270
 271   if (NOT DEFINED ARG_VERSION_MAJOR)
 272     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 273   endif()
 274
 275   if (NOT DEFINED ARG_VERSION_MINOR)
 276     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 277   endif()
 278
 279   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 280     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 281   endif()
 282
 283   if (NOT DEFINED ARG_VERSION_STRING)
 284     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 285   endif()
 286
 287   if (NOT DEFINED ARG_PRODUCT_NAME)
 288     set(ARG_PRODUCT_NAME "LLVM")
 289   endif()
 290
 291   set_property(SOURCE ${resource_file}
 292                PROPERTY COMPILE_FLAGS /nologo)
 293   set_property(SOURCE ${resource_file}
 294                PROPERTY COMPILE_DEFINITIONS
 295                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 296                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 297                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 298                "RC_VERSION_FIELD_4=0"
 299                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 300                "RC_INTERNAL_NAME=\"${name}\""
 301                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 302                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 303 endfunction(set_windows_version_resource_properties)
 304
 305 # llvm_add_library(name sources...
 306 #   SHARED;STATIC
 307 #     STATIC by default w/o BUILD_SHARED_LIBS.
 308 #     SHARED by default w/  BUILD_SHARED_LIBS.
 309 #   MODULE
 310 #     Target ${name} might not be created on unsupported platforms.
 311 #     Check with "if(TARGET ${name})".
 312 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 313 #     Do not link this library to libLLVM, even if
 314 #     LLVM_LINK_LLVM_DYLIB is enabled.
 315 #   OUTPUT_NAME name
 316 #     Corresponds to OUTPUT_NAME in target properties.
 317 #   DEPENDS targets...
 318 #     Same semantics as add_dependencies().
 319 #   LINK_COMPONENTS components...
 320 #     Same as the variable LLVM_LINK_COMPONENTS.
 321 #   LINK_LIBS lib_targets...
 322 #     Same semantics as target_link_libraries().
 323 #   ADDITIONAL_HEADERS
 324 #     May specify header files for IDE generators.
 325 #   )
 326 function(llvm_add_library name)
 327   cmake_parse_arguments(ARG
 328     "MODULE;SHARED;STATIC;DISABLE_LLVM_LINK_LLVM_DYLIB"
 329     "OUTPUT_NAME"
 330     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 331     ${ARGN})
 332   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 333   if(ARG_ADDITIONAL_HEADERS)
 334     # Pass through ADDITIONAL_HEADERS.
 335     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 336   endif()
 337   if(ARG_OBJLIBS)
 338     set(ALL_FILES ${ARG_OBJLIBS})
 339   else()
 340     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 341   endif()
 342
 343   if(ARG_MODULE)
 344     if(ARG_SHARED OR ARG_STATIC)
 345       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 346     endif()
 347     if(NOT LLVM_ENABLE_PLUGINS)
 348       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 349       return()
 350     endif()
 351   else()
 352     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 353       set(ARG_SHARED TRUE)
 354     endif()
 355     if(NOT ARG_SHARED)
 356       set(ARG_STATIC TRUE)
 357     endif()
 358   endif()
 359
 360   # Generate objlib
 361   if(ARG_SHARED AND ARG_STATIC)
 362     # Generate an obj library for both targets.
 363     set(obj_name "obj.${name}")
 364     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 365       ${ALL_FILES}
 366       )
 367     llvm_update_compile_flags(${obj_name})
 368     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 369
 370     # Do add_dependencies(obj) later due to CMake issue 14747.
 371     list(APPEND objlibs ${obj_name})
 372
 373     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 374   endif()
 375
 376   if(ARG_SHARED AND ARG_STATIC)
 377     # static
 378     set(name_static "${name}_static")
 379     if(ARG_OUTPUT_NAME)
 380       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 381     endif()
 382     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 383     llvm_add_library(${name_static} STATIC
 384       ${output_name}
 385       OBJLIBS ${ALL_FILES} # objlib
 386       LINK_LIBS ${ARG_LINK_LIBS}
 387       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 388       )
 389     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 390     set(ARG_STATIC)
 391   endif()
 392
 393   if(ARG_MODULE)
 394     add_library(${name} MODULE ${ALL_FILES})
 395   elseif(ARG_SHARED)
 396     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 397     add_library(${name} SHARED ${ALL_FILES})
 398   else()
 399     add_library(${name} STATIC ${ALL_FILES})
 400   endif()
 401
 402   if(DEFINED windows_resource_file)
 403     set_windows_version_resource_properties(${name} ${windows_resource_file})
 404     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 405   endif()
 406
 407   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 408   # $<TARGET_OBJECTS> doesn't require compile flags.
 409   if(NOT obj_name)
 410     llvm_update_compile_flags(${name})
 411   endif()
 412   add_link_opts( ${name} )
 413   if(ARG_OUTPUT_NAME)
 414     set_target_properties(${name}
 415       PROPERTIES
 416       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 417       )
 418   endif()
 419
 420   if(ARG_MODULE)
 421     set_target_properties(${name} PROPERTIES
 422       PREFIX ""
 423       SUFFIX ${LLVM_PLUGIN_EXT}
 424       )
 425   endif()
 426
 427   if(ARG_SHARED)
 428     if(WIN32)
 429       set_target_properties(${name} PROPERTIES
 430         PREFIX ""
 431         )
 432     endif()
 433
 434     set_target_properties(${name}
 435       PROPERTIES
 436       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 437       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 438   endif()
 439
 440   if(ARG_MODULE OR ARG_SHARED)
 441     # Do not add -Dname_EXPORTS to the command-line when building files in this
 442     # target. Doing so is actively harmful for the modules build because it
 443     # creates extra module variants, and not useful because we don't use these
 444     # macros.
 445     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 446
 447     if (LLVM_EXPORTED_SYMBOL_FILE)
 448       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 449     endif()
 450   endif()
 451
 452   # Add the explicit dependency information for this library.
 453   #
 454   # It would be nice to verify that we have the dependencies for this library
 455   # name, but using get_property(... SET) doesn't suffice to determine if a
 456   # property has been set to an empty value.
 457   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 458
 459   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_STATIC AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 460     set(llvm_libs LLVM)
 461   else()
 462     llvm_map_components_to_libnames(llvm_libs
 463       ${ARG_LINK_COMPONENTS}
 464       ${LLVM_LINK_COMPONENTS}
 465       )
 466   endif()
 467
 468   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 469     # Link libs w/o keywords, assuming PUBLIC.
 470     target_link_libraries(${name}
 471       ${ARG_LINK_LIBS}
 472       ${lib_deps}
 473       ${llvm_libs}
 474       )
 475   elseif(ARG_STATIC)
 476     target_link_libraries(${name} INTERFACE
 477       ${ARG_LINK_LIBS}
 478       ${lib_deps}
 479       ${llvm_libs}
 480       )
 481   else()
 482     # We can use PRIVATE since SO knows its dependent libs.
 483     target_link_libraries(${name} PRIVATE
 484       ${ARG_LINK_LIBS}
 485       ${lib_deps}
 486       ${llvm_libs}
 487       )
 488   endif()
 489
 490   if(LLVM_COMMON_DEPENDS)
 491     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 492     # Add dependencies also to objlibs.
 493     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 494     foreach(objlib ${objlibs})
 495       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 496     endforeach()
 497   endif()
 498 endfunction()
 499
 500 macro(add_llvm_library name)
 501   cmake_parse_arguments(ARG
 502     "SHARED"
 503     ""
 504     ""
 505     ${ARGN})
 506   if( BUILD_SHARED_LIBS )
 507     llvm_add_library(${name} SHARED ${ARGN})
 508   else()
 509     llvm_add_library(${name} ${ARGN})
 510   endif()
 511   # The gtest libraries should not be installed or exported as a target
 512   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 513     set(_is_gtest TRUE)
 514   else()
 515     set(_is_gtest FALSE)
 516     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 517   endif()
 518
 519   if( EXCLUDE_FROM_ALL )
 520     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 521   elseif(NOT _is_gtest)
 522     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 523       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 524         if(WIN32 OR CYGWIN)
 525           set(install_type RUNTIME)
 526         else()
 527           set(install_type LIBRARY)
 528         endif()
 529       else()
 530         set(install_type ARCHIVE)
 531       endif()
 532
 533       install(TARGETS ${name}
 534             EXPORT LLVMExports
 535             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 536             COMPONENT ${name})
 537
 538       if (NOT CMAKE_CONFIGURATION_TYPES)
 539         add_custom_target(install-${name}
 540                           DEPENDS ${name}
 541                           COMMAND "${CMAKE_COMMAND}"
 542                                   -DCMAKE_INSTALL_COMPONENT=${name}
 543                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 544       endif()
 545     endif()
 546     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 547   endif()
 548   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 549 endmacro(add_llvm_library name)
 550
 551 macro(add_llvm_loadable_module name)
 552   llvm_add_library(${name} MODULE ${ARGN})
 553   if(NOT TARGET ${name})
 554     # Add empty "phony" target
 555     add_custom_target(${name})
 556   else()
 557     if( EXCLUDE_FROM_ALL )
 558       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 559     else()
 560       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 561         if(WIN32 OR CYGWIN)
 562           # DLL platform
 563           set(dlldir "bin")
 564         else()
 565           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 566         endif()
 567         install(TARGETS ${name}
 568           EXPORT LLVMExports
 569           LIBRARY DESTINATION ${dlldir}
 570           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 571       endif()
 572       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 573     endif()
 574   endif()
 575
 576   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 577 endmacro(add_llvm_loadable_module name)
 578
 579
 580 macro(add_llvm_executable name)
 581   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB" "" "" ${ARGN})
 582   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 583
 584   # Generate objlib
 585   if(LLVM_ENABLE_OBJLIB)
 586     # Generate an obj library for both targets.
 587     set(obj_name "obj.${name}")
 588     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 589       ${ALL_FILES}
 590       )
 591     llvm_update_compile_flags(${obj_name})
 592     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 593
 594     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 595   endif()
 596
 597   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 598
 599   if(XCODE)
 600     # Note: the dummy.cpp source file provides no definitions. However,
 601     # it forces Xcode to properly link the static library.
 602     list(APPEND ALL_FILES "${LLVM_MAIN_SRC_DIR}/cmake/dummy.cpp")
 603   endif()
 604
 605   if( EXCLUDE_FROM_ALL )
 606     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 607   else()
 608     add_executable(${name} ${ALL_FILES})
 609   endif()
 610
 611   if(DEFINED windows_resource_file)
 612     set_windows_version_resource_properties(${name} ${windows_resource_file})
 613   endif()
 614
 615   # $<TARGET_OBJECTS> doesn't require compile flags.
 616   if(NOT LLVM_ENABLE_OBJLIB)
 617     llvm_update_compile_flags(${name})
 618   endif()
 619   add_link_opts( ${name} )
 620
 621   # Do not add -Dname_EXPORTS to the command-line when building files in this
 622   # target. Doing so is actively harmful for the modules build because it
 623   # creates extra module variants, and not useful because we don't use these
 624   # macros.
 625   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 626
 627   if (LLVM_EXPORTED_SYMBOL_FILE)
 628     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 629   endif(LLVM_EXPORTED_SYMBOL_FILE)
 630
 631   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 632     set(USE_SHARED USE_SHARED)
 633   endif()
 634
 635   set(EXCLUDE_FROM_ALL OFF)
 636   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 637   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 638   if( LLVM_COMMON_DEPENDS )
 639     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 640   endif( LLVM_COMMON_DEPENDS )
 641 endmacro(add_llvm_executable name)
 642
 643 function(export_executable_symbols target)
 644   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 645     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 646   endif()
 647 endfunction()
 648
 649 if(NOT LLVM_TOOLCHAIN_TOOLS)
 650   set (LLVM_TOOLCHAIN_TOOLS
 651     llvm-ar
 652     llvm-ranlib
 653     llvm-lib
 654     llvm-objdump
 655     )
 656 endif()
 657
 658 macro(add_llvm_tool name)
 659   if( NOT LLVM_BUILD_TOOLS )
 660     set(EXCLUDE_FROM_ALL ON)
 661   endif()
 662   add_llvm_executable(${name} ${ARGN})
 663
 664   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 665   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 666     if( LLVM_BUILD_TOOLS )
 667       install(TARGETS ${name}
 668               EXPORT LLVMExports
 669               RUNTIME DESTINATION bin
 670               COMPONENT ${name})
 671
 672       if (NOT CMAKE_CONFIGURATION_TYPES)
 673         add_custom_target(install-${name}
 674                           DEPENDS ${name}
 675                           COMMAND "${CMAKE_COMMAND}"
 676                                   -DCMAKE_INSTALL_COMPONENT=${name}
 677                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 678       endif()
 679     endif()
 680   endif()
 681   if( LLVM_BUILD_TOOLS )
 682     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 683   endif()
 684   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 685 endmacro(add_llvm_tool name)
 686
 687
 688 macro(add_llvm_example name)
 689   if( NOT LLVM_BUILD_EXAMPLES )
 690     set(EXCLUDE_FROM_ALL ON)
 691   endif()
 692   add_llvm_executable(${name} ${ARGN})
 693   if( LLVM_BUILD_EXAMPLES )
 694     install(TARGETS ${name} RUNTIME DESTINATION examples)
 695   endif()
 696   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 697 endmacro(add_llvm_example name)
 698
 699
 700 macro(add_llvm_utility name)
 701   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 702   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 703   if( LLVM_INSTALL_UTILS )
 704     install (TARGETS ${name}
 705       RUNTIME DESTINATION bin
 706       COMPONENT ${name})
 707     if (NOT CMAKE_CONFIGURATION_TYPES)
 708       add_custom_target(install-${name}
 709                         DEPENDS ${name}
 710                         COMMAND "${CMAKE_COMMAND}"
 711                                 -DCMAKE_INSTALL_COMPONENT=${name}
 712                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 713     endif()
 714   endif()
 715 endmacro(add_llvm_utility name)
 716
 717
 718 macro(add_llvm_target target_name)
 719   include_directories(BEFORE
 720     ${CMAKE_CURRENT_BINARY_DIR}
 721     ${CMAKE_CURRENT_SOURCE_DIR})
 722   add_llvm_library(LLVM${target_name} ${ARGN})
 723   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 724 endmacro(add_llvm_target)
 725
 726 function(canonicalize_tool_name name output)
 727   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 728   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 729   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 730   set(${output} "${nameUPPER}" PARENT_SCOPE)
 731 endfunction(canonicalize_tool_name)
 732
 733 # Add external project that may want to be built as part of llvm such as Clang,
 734 # lld, and Polly. This adds two options. One for the source directory of the
 735 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 736 # enable or disable building it with everything else.
 737 # Additional parameter can be specified as the name of directory.
 738 macro(add_llvm_external_project name)
 739   set(add_llvm_external_dir "${ARGN}")
 740   if("${add_llvm_external_dir}" STREQUAL "")
 741     set(add_llvm_external_dir ${name})
 742   endif()
 743   canonicalize_tool_name(${name} nameUPPER)
 744   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 745     # Treat it as in-tree subproject.
 746     option(LLVM_TOOL_${nameUPPER}_BUILD
 747            "Whether to build ${name} as part of LLVM" On)
 748     mark_as_advanced(LLVM_TOOL_${name}_BUILD)
 749     if(LLVM_TOOL_${nameUPPER}_BUILD)
 750       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 751       # Don't process it in add_llvm_implicit_projects().
 752       set(LLVM_TOOL_${nameUPPER}_BUILD OFF)
 753     endif()
 754   else()
 755     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 756       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 757       CACHE PATH "Path to ${name} source directory")
 758     set(LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT ON)
 759     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 760       set(LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT OFF)
 761     endif()
 762     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 763       set(LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT OFF)
 764     endif()
 765     option(LLVM_TOOL_${nameUPPER}_BUILD
 766       "Whether to build ${name} as part of LLVM"
 767       ${LLVM_TOOL_${nameUPPER}_BUILD_DEFAULT})
 768     if (LLVM_TOOL_${nameUPPER}_BUILD)
 769       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 770         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 771       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 772         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 773       endif()
 774       # FIXME: It'd be redundant.
 775       set(LLVM_TOOL_${nameUPPER}_BUILD Off)
 776     endif()
 777   endif()
 778 endmacro(add_llvm_external_project)
 779
 780 macro(add_llvm_tool_subdirectory name)
 781   add_llvm_external_project(${name})
 782 endmacro(add_llvm_tool_subdirectory)
 783
 784 function(get_project_name_from_src_var var output)
 785   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 786          MACHED_TOOL "${var}")
 787   if(MACHED_TOOL)
 788     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 789   else()
 790     set(${output} PARENT_SCOPE)
 791   endif()
 792 endfunction()
 793
 794 function(create_llvm_tool_options)
 795   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 796   foreach(dir ${sub-dirs})
 797     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 798       canonicalize_tool_name(${dir} name)
 799       option(LLVM_TOOL_${name}_BUILD
 800            "Whether to build ${name} as part of LLVM" On)
 801       mark_as_advanced(LLVM_TOOL_${name}_BUILD)
 802     endif()
 803   endforeach()
 804 endfunction(create_llvm_tool_options)
 805
 806 function(add_llvm_implicit_projects)
 807   set(list_of_implicit_subdirs "")
 808   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 809   foreach(dir ${sub-dirs})
 810     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 811       canonicalize_tool_name(${dir} name)
 812       if (LLVM_TOOL_${name}_BUILD)
 813         get_filename_component(fn "${dir}" NAME)
 814         list(APPEND list_of_implicit_subdirs "${fn}")
 815       endif()
 816     endif()
 817   endforeach()
 818
 819   foreach(external_proj ${list_of_implicit_subdirs})
 820     add_llvm_external_project("${external_proj}")
 821   endforeach()
 822 endfunction(add_llvm_implicit_projects)
 823
 824 # Generic support for adding a unittest.
 825 function(add_unittest test_suite test_name)
 826   if( NOT LLVM_BUILD_TESTS )
 827     set(EXCLUDE_FROM_ALL ON)
 828   endif()
 829
 830   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 831   if (NOT LLVM_ENABLE_THREADS)
 832     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 833   endif ()
 834
 835   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 836     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 837   endif ()
 838
 839   set(LLVM_REQUIRES_RTTI OFF)
 840
 841   add_llvm_executable(${test_name} ${ARGN})
 842   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 843   set_output_directory(${test_name} BINARY_DIR ${outdir} LIBRARY_DIR ${outdir})
 844   target_link_libraries(${test_name}
 845     gtest
 846     gtest_main
 847     LLVMSupport # gtest needs it for raw_ostream.
 848     )
 849
 850   add_dependencies(${test_suite} ${test_name})
 851   get_target_property(test_suite_folder ${test_suite} FOLDER)
 852   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 853     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 854   endif ()
 855 endfunction()
 856
 857 function(llvm_add_go_executable binary pkgpath)
 858   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 859
 860   if(LLVM_BINDINGS MATCHES "go")
 861     # FIXME: This should depend only on the libraries Go needs.
 862     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 863     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 864     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 865     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 866     set(cppflags "")
 867     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 868     foreach(d ${include_dirs})
 869       set(cppflags "${cppflags} -I${d}")
 870     endforeach(d)
 871     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 872     if (LLVM_LINK_LLVM_DYLIB)
 873       set(linkmode "dylib")
 874     else()
 875       set(linkmode "component-libs")
 876     endif()
 877     add_custom_command(OUTPUT ${binpath}
 878       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "linkmode=${linkmode}"
 879               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 880       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 881               ${llvmlibs} ${ARG_DEPENDS}
 882       COMMENT "Building Go executable ${binary}"
 883       VERBATIM)
 884     if (ARG_ALL)
 885       add_custom_target(${binary} ALL DEPENDS ${binpath})
 886     else()
 887       add_custom_target(${binary} DEPENDS ${binpath})
 888     endif()
 889   endif()
 890 endfunction()
 891
 892 # This function provides an automatic way to 'configure'-like generate a file
 893 # based on a set of common and custom variables, specifically targeting the
 894 # variables needed for the 'lit.site.cfg' files. This function bundles the
 895 # common variables that any Lit instance is likely to need, and custom
 896 # variables can be passed in.
 897 function(configure_lit_site_cfg input output)
 898   foreach(c ${LLVM_TARGETS_TO_BUILD})
 899     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 900   endforeach(c)
 901   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 902
 903   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 904
 905   # Configuration-time: See Unit/lit.site.cfg.in
 906   if (CMAKE_CFG_INTDIR STREQUAL ".")
 907     set(LLVM_BUILD_MODE ".")
 908   else ()
 909     set(LLVM_BUILD_MODE "%(build_mode)s")
 910   endif ()
 911
 912   # They below might not be the build tree but provided binary tree.
 913   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 914   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 915   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 916   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 917
 918   # SHLIBDIR points the build tree.
 919   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 920
 921   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 922   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 923   # plugins. We may rename it.
 924   if(LLVM_ENABLE_PLUGINS)
 925     set(ENABLE_SHARED "1")
 926   else()
 927     set(ENABLE_SHARED "0")
 928   endif()
 929
 930   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 931     set(ENABLE_ASSERTIONS "1")
 932   else()
 933     set(ENABLE_ASSERTIONS "0")
 934   endif()
 935
 936   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 937   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 938
 939   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 940   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 941   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 942
 943   configure_file(${input} ${output} @ONLY)
 944 endfunction()
 945
 946 # A raw function to create a lit target. This is used to implement the testuite
 947 # management functions.
 948 function(add_lit_target target comment)
 949   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 950   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 951   separate_arguments(LIT_ARGS)
 952   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 953     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 954   endif ()
 955   if (LLVM_MAIN_SRC_DIR)
 956     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 957   else()
 958     find_program(LIT_COMMAND llvm-lit)
 959   endif ()
 960   list(APPEND LIT_COMMAND ${LIT_ARGS})
 961   foreach(param ${ARG_PARAMS})
 962     list(APPEND LIT_COMMAND --param ${param})
 963   endforeach()
 964   if (ARG_UNPARSED_ARGUMENTS)
 965     add_custom_target(${target}
 966       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 967       COMMENT "${comment}"
 968       ${cmake_3_2_USES_TERMINAL}
 969       )
 970   else()
 971     add_custom_target(${target}
 972       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 973     message(STATUS "${target} does nothing.")
 974   endif()
 975   if (ARG_DEPENDS)
 976     add_dependencies(${target} ${ARG_DEPENDS})
 977   endif()
 978
 979   # Tests should be excluded from "Build Solution".
 980   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 981 endfunction()
 982
 983 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 984 function(add_lit_testsuite target comment)
 985   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 986
 987   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 988   if(NOT EXCLUDE_FROM_ALL)
 989     # Register the testsuites, params and depends for the global check rule.
 990     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
 991     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 992     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 993     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 994   endif()
 995
 996   # Produce a specific suffixed check rule.
 997   add_lit_target(${target} ${comment}
 998     ${ARG_UNPARSED_ARGUMENTS}
 999     PARAMS ${ARG_PARAMS}
1000     DEPENDS ${ARG_DEPENDS}
1001     ARGS ${ARG_ARGS}
1002     )
1003 endfunction()
1004
1005 function(add_lit_testsuites project directory)
1006   if (NOT CMAKE_CONFIGURATION_TYPES)
1007     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1008     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
1009     set(lit_suites)
1010     foreach(f ${litCfg})
1011       get_filename_component(dir ${f} DIRECTORY)
1012       set(lit_suites ${lit_suites} ${dir})
1013     endforeach()
1014     list(REMOVE_DUPLICATES lit_suites)
1015     foreach(dir ${lit_suites})
1016       string(REPLACE ${directory} "" name_slash ${dir})
1017       if (name_slash)
1018         string(REPLACE "/" "-" name_slash ${name_slash})
1019         string(REPLACE "\\" "-" name_dashes ${name_slash})
1020         string(TOLOWER "${project}${name_dashes}" name_var)
1021         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
1022           ${dir}
1023           PARAMS ${ARG_PARAMS}
1024           DEPENDS ${ARG_DEPENDS}
1025           ARGS ${ARG_ARGS}
1026         )
1027       endif()
1028     endforeach()
1029   endif()
1030 endfunction()
1031
1032 function(llvm_install_symlink name dest)
1033   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1034   foreach(path ${CMAKE_MODULE_PATH})
1035     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1036       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1037       break()
1038     endif()
1039   endforeach()
1040
1041   if(ARG_ALWAYS_GENERATE)
1042     set(component ${dest})
1043   else()
1044     set(component ${name})
1045   endif()
1046
1047   set(full_name ${name}${CMAKE_EXECUTABLE_SUFFIX})
1048   set(full_dest ${dest}${CMAKE_EXECUTABLE_SUFFIX})
1049
1050   install(SCRIPT ${INSTALL_SYMLINK}
1051           CODE "install_symlink(${full_name} ${full_dest} bin)"
1052           COMPONENT ${component})
1053
1054   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1055     add_custom_target(install-${name}
1056                       DEPENDS ${name} ${dest} install-${dest}
1057                       COMMAND "${CMAKE_COMMAND}"
1058                               -DCMAKE_INSTALL_COMPONENT=${name}
1059                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1060   endif()
1061 endfunction()
1062
1063 function(add_llvm_tool_symlink name dest)
1064   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1065   if(UNIX)
1066     set(LLVM_LINK_OR_COPY create_symlink)
1067     set(dest_binary "${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1068   else()
1069     set(LLVM_LINK_OR_COPY copy)
1070     set(dest_binary "${LLVM_RUNTIME_OUTPUT_INTDIR}/${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1071   endif()
1072
1073   set(output_path "${LLVM_RUNTIME_OUTPUT_INTDIR}/${name}${CMAKE_EXECUTABLE_SUFFIX}")
1074
1075   if(ARG_ALWAYS_GENERATE)
1076     set_property(DIRECTORY APPEND PROPERTY
1077       ADDITIONAL_MAKE_CLEAN_FILES ${dest_binary})
1078     add_custom_command(TARGET ${dest} POST_BUILD
1079       COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}")
1080   else()
1081     add_custom_command(OUTPUT ${output_path}
1082                      COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}"
1083                      DEPENDS ${dest})
1084     add_custom_target(${name} ALL DEPENDS ${output_path})
1085     set_target_properties(${name} PROPERTIES FOLDER Tools)
1086
1087     # Make sure the parent tool is a toolchain tool, otherwise exclude this tool
1088     list(FIND LLVM_TOOLCHAIN_TOOLS ${dest} LLVM_IS_${dest}_TOOLCHAIN_TOOL)
1089     if (NOT LLVM_IS_${dest}_TOOLCHAIN_TOOL GREATER -1)
1090       set(LLVM_IS_${name}_TOOLCHAIN_TOOL ${LLVM_IS_${dest}_TOOLCHAIN_TOOL})
1091     else()
1092       list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
1093     endif()
1094
1095     # LLVM_IS_${name}_TOOLCHAIN_TOOL will only be greater than -1 if both this
1096     # tool and its parent tool are in LLVM_TOOLCHAIN_TOOLS
1097     if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1098       if( LLVM_BUILD_TOOLS )
1099         llvm_install_symlink(${name} ${dest})
1100       endif()
1101     endif()
1102   endif()
1103 endfunction()
1104