cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVMConfig)
   3
   4 macro(add_llvm_library name)
   5   llvm_process_sources( ALL_FILES ${ARGN} )
   6   add_library( ${name} ${ALL_FILES} )
   7   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
   8   set_property( GLOBAL APPEND PROPERTY LLVM_LIB_TARGETS ${name} )
   9   if( LLVM_COMMON_DEPENDS )
  10     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  11   endif( LLVM_COMMON_DEPENDS )
  12
  13   if( BUILD_SHARED_LIBS )
  14     get_system_libs(sl)
  15     target_link_libraries( ${name} ${sl} )
  16   endif()
  17
  18   install(TARGETS ${name}
  19     LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  20     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  21   # The LLVM Target library shall be built before its sublibraries
  22   # (asmprinter, etc) because those may use tablegenned files which
  23   # generation is triggered by the main LLVM target library. Necessary
  24   # for parallel builds:
  25   if( CURRENT_LLVM_TARGET )
  26     add_dependencies(${name} ${CURRENT_LLVM_TARGET})
  27   endif()
  28   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
  29 endmacro(add_llvm_library name)
  30
  31
  32 macro(add_llvm_loadable_module name)
  33   if( NOT LLVM_ON_UNIX OR CYGWIN )
  34     message(STATUS "Loadable modules not supported on this platform.
  35 ${name} ignored.")
  36     # Add empty "phony" target
  37     add_custom_target(${name})
  38   else()
  39     llvm_process_sources( ALL_FILES ${ARGN} )
  40     if (MODULE)
  41       set(libkind MODULE)
  42     else()
  43       set(libkind SHARED)
  44     endif()
  45
  46     add_library( ${name} ${libkind} ${ALL_FILES} )
  47     set_target_properties( ${name} PROPERTIES PREFIX "" )
  48
  49     if (APPLE)
  50       # Darwin-specific linker flags for loadable modules.
  51       set_target_properties(${name} PROPERTIES
  52         LINK_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
  53     endif()
  54
  55     install(TARGETS ${name}
  56       LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
  57       ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
  58   endif()
  59
  60   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
  61 endmacro(add_llvm_loadable_module name)
  62
  63
  64 macro(add_llvm_executable name)
  65   llvm_process_sources( ALL_FILES ${ARGN} )
  66   if( EXCLUDE_FROM_ALL )
  67     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
  68   else()
  69     add_executable(${name} ${ALL_FILES})
  70   endif()
  71   set(EXCLUDE_FROM_ALL OFF)
  72   if( LLVM_USED_LIBS )
  73     foreach(lib ${LLVM_USED_LIBS})
  74       target_link_libraries( ${name} ${lib} )
  75     endforeach(lib)
  76   endif( LLVM_USED_LIBS )
  77   if( LLVM_LINK_COMPONENTS )
  78     llvm_config(${name} ${LLVM_LINK_COMPONENTS})
  79   endif( LLVM_LINK_COMPONENTS )
  80   if( LLVM_COMMON_DEPENDS )
  81     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
  82   endif( LLVM_COMMON_DEPENDS )
  83   if( NOT MINGW )
  84     get_system_libs(llvm_system_libs)
  85     if( llvm_system_libs )
  86       target_link_libraries(${name} ${llvm_system_libs})
  87     endif()
  88   endif()
  89 endmacro(add_llvm_executable name)
  90
  91
  92 macro(add_llvm_tool name)
  93   set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR})
  94   if( NOT LLVM_BUILD_TOOLS )
  95     set(EXCLUDE_FROM_ALL ON)
  96   endif()
  97   add_llvm_executable(${name} ${ARGN})
  98   if( LLVM_BUILD_TOOLS )
  99     install(TARGETS ${name} RUNTIME DESTINATION bin)
 100   endif()
 101   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 102 endmacro(add_llvm_tool name)
 103
 104
 105 macro(add_llvm_example name)
 106 #  set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_EXAMPLES_BINARY_DIR})
 107   if( NOT LLVM_BUILD_EXAMPLES )
 108     set(EXCLUDE_FROM_ALL ON)
 109   endif()
 110   add_llvm_executable(${name} ${ARGN})
 111   if( LLVM_BUILD_EXAMPLES )
 112     install(TARGETS ${name} RUNTIME DESTINATION examples)
 113   endif()
 114   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 115 endmacro(add_llvm_example name)
 116
 117
 118 macro(add_llvm_utility name)
 119   add_llvm_executable(${name} ${ARGN})
 120   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 121 endmacro(add_llvm_utility name)
 122
 123
 124 macro(add_llvm_target target_name)
 125   if( TABLEGEN_OUTPUT )
 126     add_custom_target(${target_name}Table_gen
 127       DEPENDS ${TABLEGEN_OUTPUT})
 128     add_dependencies(${target_name}Table_gen ${LLVM_COMMON_DEPENDS})
 129   endif( TABLEGEN_OUTPUT )
 130   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
 131   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 132   if ( TABLEGEN_OUTPUT )
 133     add_dependencies(LLVM${target_name} ${target_name}Table_gen)
 134     set_target_properties(${target_name}Table_gen PROPERTIES FOLDER "Tablegenning")
 135   endif (TABLEGEN_OUTPUT)
 136   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 137 endmacro(add_llvm_target)