cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130
 131   # Add dependency to *_exports later -- CMake issue 14747
 132   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 133   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 134 endfunction(add_llvm_symbol_exports)
 135
 136 function(add_dead_strip target_name)
 137   if(NOT LLVM_NO_DEAD_STRIP)
 138     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,-dead_strip")
 141     elseif(NOT WIN32)
 142       # Object files are compiled with -ffunction-data-sections.
 143       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 144                    LINK_FLAGS " -Wl,--gc-sections")
 145     endif()
 146   endif()
 147 endfunction(add_dead_strip)
 148
 149 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 150 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 151 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 152 function(set_output_directory target bindir libdir)
 153   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 154     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 155       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 156       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 157       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 158       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 159       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 160       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 161     endforeach()
 162   else()
 163     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 164     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 165     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${libdir})
 166   endif()
 167 endfunction()
 168
 169 # llvm_add_library(name sources...
 170 #   SHARED;STATIC
 171 #     STATIC by default w/o BUILD_SHARED_LIBS.
 172 #     SHARED by default w/  BUILD_SHARED_LIBS.
 173 #   MODULE
 174 #     Target ${name} might not be created on unsupported platforms.
 175 #     Check with "if(TARGET ${name})".
 176 #   OUTPUT_NAME name
 177 #     Corresponds to OUTPUT_NAME in target properties.
 178 #   DEPENDS targets...
 179 #     Same semantics as add_dependencies().
 180 #   LINK_COMPONENTS components...
 181 #     Same as the variable LLVM_LINK_COMPONENTS.
 182 #   LINK_LIBS lib_targets...
 183 #     Same semantics as target_link_libraries().
 184 #   ADDITIONAL_HEADERS
 185 #     May specify header files for IDE generators.
 186 #   )
 187 function(llvm_add_library name)
 188   cmake_parse_arguments(ARG
 189     "MODULE;SHARED;STATIC"
 190     "OUTPUT_NAME"
 191     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 192     ${ARGN})
 193   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 194   if(ARG_ADDITIONAL_HEADERS)
 195     # Pass through ADDITIONAL_HEADERS.
 196     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 197   endif()
 198   if(ARG_OBJLIBS)
 199     set(ALL_FILES ${ARG_OBJLIBS})
 200   else()
 201     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 202   endif()
 203
 204   if(ARG_MODULE)
 205     if(ARG_SHARED OR ARG_STATIC)
 206       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 207     endif()
 208     if(NOT LLVM_ON_UNIX OR CYGWIN)
 209       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 210       return()
 211     endif()
 212   else()
 213     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 214       set(ARG_SHARED TRUE)
 215     endif()
 216     if(NOT ARG_SHARED)
 217       set(ARG_STATIC TRUE)
 218     endif()
 219   endif()
 220
 221   # Generate objlib
 222   if(ARG_SHARED AND ARG_STATIC)
 223     # Generate an obj library for both targets.
 224     set(obj_name "obj.${name}")
 225     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 226       ${ALL_FILES}
 227       )
 228     llvm_update_compile_flags(${obj_name})
 229     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 230
 231     # Do add_dependencies(obj) later due to CMake issue 14747.
 232     list(APPEND objlibs ${obj_name})
 233
 234     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 235   endif()
 236
 237   if(ARG_SHARED AND ARG_STATIC)
 238     # static
 239     set(name_static "${name}_static")
 240     if(ARG_OUTPUT_NAME)
 241       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}_static")
 242     endif()
 243     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 244     llvm_add_library(${name_static} STATIC
 245       ${output_name}
 246       OBJLIBS ${ALL_FILES} # objlib
 247       LINK_LIBS ${ARG_LINK_LIBS}
 248       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 249       )
 250     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 251     set(ARG_STATIC)
 252   endif()
 253
 254   if(ARG_MODULE)
 255     add_library(${name} MODULE ${ALL_FILES})
 256   elseif(ARG_SHARED)
 257     add_library(${name} SHARED ${ALL_FILES})
 258   else()
 259     add_library(${name} STATIC ${ALL_FILES})
 260   endif()
 261   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 262   llvm_update_compile_flags(${name})
 263   add_dead_strip( ${name} )
 264   if(ARG_OUTPUT_NAME)
 265     set_target_properties(${name}
 266       PROPERTIES
 267       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 268       )
 269   endif()
 270
 271   if(ARG_MODULE)
 272     set_target_properties(${name} PROPERTIES
 273       PREFIX ""
 274       SUFFIX ${LLVM_PLUGIN_EXT}
 275       )
 276   endif()
 277
 278   if(ARG_SHARED)
 279     if (MSVC)
 280       set_target_properties(${name}
 281         PROPERTIES
 282         IMPORT_SUFFIX ".imp")
 283     endif ()
 284   endif()
 285
 286   if(ARG_MODULE OR ARG_SHARED)
 287     if (LLVM_EXPORTED_SYMBOL_FILE)
 288       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 289     endif()
 290   endif()
 291
 292   if(ARG_STATIC)
 293     target_link_libraries(${name} ${cmake_2_8_12_INTERFACE} ${ARG_LINK_LIBS})
 294   else()
 295     # MODULE|SHARED
 296     target_link_libraries(${name} ${cmake_2_8_12_PRIVATE} ${ARG_LINK_LIBS})
 297   endif()
 298
 299   llvm_config(${name} ${ARG_LINK_COMPONENTS} ${LLVM_LINK_COMPONENTS})
 300
 301   if(LLVM_COMMON_DEPENDS)
 302     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 303     # Add dependencies also to objlibs.
 304     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 305     foreach(objlib ${objlibs})
 306       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 307     endforeach()
 308   endif()
 309 endfunction()
 310
 311 macro(add_llvm_library name)
 312   if( BUILD_SHARED_LIBS )
 313     llvm_add_library(${name} SHARED ${ARGN})
 314   else()
 315     llvm_add_library(${name} ${ARGN})
 316   endif()
 317   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 318
 319   if( EXCLUDE_FROM_ALL )
 320     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 321   else()
 322     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 323       install(TARGETS ${name}
 324         EXPORT LLVMExports
 325         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 326         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 327     endif()
 328     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 329   endif()
 330   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 331
 332   # Add the explicit dependency information for this library.
 333   #
 334   # It would be nice to verify that we have the dependencies for this library
 335   # name, but using get_property(... SET) doesn't suffice to determine if a
 336   # property has been set to an empty value.
 337   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 338   target_link_libraries(${name} ${cmake_2_8_12_INTERFACE} ${lib_deps})
 339 endmacro(add_llvm_library name)
 340
 341 macro(add_llvm_loadable_module name)
 342   llvm_add_library(${name} MODULE ${ARGN})
 343   if(NOT TARGET ${name})
 344     # Add empty "phony" target
 345     add_custom_target(${name})
 346   else()
 347     if( EXCLUDE_FROM_ALL )
 348       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 349     else()
 350       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 351         install(TARGETS ${name}
 352           EXPORT LLVMExports
 353           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 354           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 355       endif()
 356       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 357     endif()
 358   endif()
 359
 360   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 361 endmacro(add_llvm_loadable_module name)
 362
 363
 364 macro(add_llvm_executable name)
 365   llvm_process_sources( ALL_FILES ${ARGN} )
 366   if( EXCLUDE_FROM_ALL )
 367     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 368   else()
 369     add_executable(${name} ${ALL_FILES})
 370   endif()
 371   llvm_update_compile_flags(${name})
 372   add_dead_strip( ${name} )
 373
 374   if (LLVM_EXPORTED_SYMBOL_FILE)
 375     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 376   endif(LLVM_EXPORTED_SYMBOL_FILE)
 377
 378   set(EXCLUDE_FROM_ALL OFF)
 379   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 380   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 381   if( LLVM_COMMON_DEPENDS )
 382     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 383   endif( LLVM_COMMON_DEPENDS )
 384 endmacro(add_llvm_executable name)
 385
 386
 387 set (LLVM_TOOLCHAIN_TOOLS
 388   llvm-ar
 389   llvm-objdump
 390   )
 391
 392 macro(add_llvm_tool name)
 393   if( NOT LLVM_BUILD_TOOLS )
 394     set(EXCLUDE_FROM_ALL ON)
 395   endif()
 396   add_llvm_executable(${name} ${ARGN})
 397
 398   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 399   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 400     if( LLVM_BUILD_TOOLS )
 401       install(TARGETS ${name}
 402               EXPORT LLVMExports
 403               RUNTIME DESTINATION bin)
 404     endif()
 405   endif()
 406   if( LLVM_BUILD_TOOLS )
 407     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 408   endif()
 409   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 410 endmacro(add_llvm_tool name)
 411
 412
 413 macro(add_llvm_example name)
 414   if( NOT LLVM_BUILD_EXAMPLES )
 415     set(EXCLUDE_FROM_ALL ON)
 416   endif()
 417   add_llvm_executable(${name} ${ARGN})
 418   if( LLVM_BUILD_EXAMPLES )
 419     install(TARGETS ${name} RUNTIME DESTINATION examples)
 420   endif()
 421   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 422 endmacro(add_llvm_example name)
 423
 424
 425 macro(add_llvm_utility name)
 426   add_llvm_executable(${name} ${ARGN})
 427   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 428 endmacro(add_llvm_utility name)
 429
 430
 431 macro(add_llvm_target target_name)
 432   include_directories(BEFORE
 433     ${CMAKE_CURRENT_BINARY_DIR}
 434     ${CMAKE_CURRENT_SOURCE_DIR})
 435   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 436   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 437 endmacro(add_llvm_target)
 438
 439 # Add external project that may want to be built as part of llvm such as Clang,
 440 # lld, and Polly. This adds two options. One for the source directory of the
 441 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 442 # enable or disable building it with everything else.
 443 # Additional parameter can be specified as the name of directory.
 444 macro(add_llvm_external_project name)
 445   set(add_llvm_external_dir "${ARGN}")
 446   if("${add_llvm_external_dir}" STREQUAL "")
 447     set(add_llvm_external_dir ${name})
 448   endif()
 449   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 450   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 451   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 452   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 453       CACHE PATH "Path to ${name} source directory")
 454   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 455       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 456     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 457            "Whether to build ${name} as part of LLVM" ON)
 458     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 459       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 460     endif()
 461   endif()
 462 endmacro(add_llvm_external_project)
 463
 464 macro(add_llvm_tool_subdirectory name)
 465   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 466   add_subdirectory(${name})
 467 endmacro(add_llvm_tool_subdirectory)
 468
 469 macro(ignore_llvm_tool_subdirectory name)
 470   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 471 endmacro(ignore_llvm_tool_subdirectory)
 472
 473 function(add_llvm_implicit_external_projects)
 474   set(list_of_implicit_subdirs "")
 475   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 476   foreach(dir ${sub-dirs})
 477     if(IS_DIRECTORY "${dir}")
 478       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 479       if( tool_subdir_ignore EQUAL -1
 480           AND EXISTS "${dir}/CMakeLists.txt")
 481         get_filename_component(fn "${dir}" NAME)
 482         list(APPEND list_of_implicit_subdirs "${fn}")
 483       endif()
 484     endif()
 485   endforeach()
 486
 487   foreach(external_proj ${list_of_implicit_subdirs})
 488     add_llvm_external_project("${external_proj}")
 489   endforeach()
 490 endfunction(add_llvm_implicit_external_projects)
 491
 492 # Generic support for adding a unittest.
 493 function(add_unittest test_suite test_name)
 494   if( NOT LLVM_BUILD_TESTS )
 495     set(EXCLUDE_FROM_ALL ON)
 496   endif()
 497
 498   # Visual Studio 2012 only supports up to 8 template parameters in
 499   # std::tr1::tuple by default, but gtest requires 10
 500   if (MSVC AND MSVC_VERSION EQUAL 1700)
 501     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 502   endif ()
 503
 504   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 505   if (NOT LLVM_ENABLE_THREADS)
 506     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 507   endif ()
 508
 509   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 510     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 511   endif ()
 512
 513   set(LLVM_REQUIRES_RTTI OFF)
 514
 515   add_llvm_executable(${test_name} ${ARGN})
 516   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 517   set_output_directory(${test_name} ${outdir} ${outdir})
 518   target_link_libraries(${test_name}
 519     gtest
 520     gtest_main
 521     LLVMSupport # gtest needs it for raw_ostream.
 522     )
 523
 524   add_dependencies(${test_suite} ${test_name})
 525   get_target_property(test_suite_folder ${test_suite} FOLDER)
 526   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 527     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 528   endif ()
 529 endfunction()
 530
 531 # This function provides an automatic way to 'configure'-like generate a file
 532 # based on a set of common and custom variables, specifically targeting the
 533 # variables needed for the 'lit.site.cfg' files. This function bundles the
 534 # common variables that any Lit instance is likely to need, and custom
 535 # variables can be passed in.
 536 function(configure_lit_site_cfg input output)
 537   foreach(c ${LLVM_TARGETS_TO_BUILD})
 538     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 539   endforeach(c)
 540   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 541
 542   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 543
 544   if(BUILD_SHARED_LIBS)
 545     set(LLVM_SHARED_LIBS_ENABLED "1")
 546   else()
 547     set(LLVM_SHARED_LIBS_ENABLED "0")
 548   endif(BUILD_SHARED_LIBS)
 549
 550   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 551     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 552   else() # Default for all other unix like systems.
 553     # CMake hardcodes the library locaction using rpath.
 554     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 555     # build dir. We pass it anyways.
 556     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 557   endif()
 558
 559   # Configuration-time: See Unit/lit.site.cfg.in
 560   if (CMAKE_CFG_INTDIR STREQUAL ".")
 561     set(LLVM_BUILD_MODE ".")
 562   else ()
 563     set(LLVM_BUILD_MODE "%(build_mode)s")
 564   endif ()
 565
 566   # They below might not be the build tree but provided binary tree.
 567   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 568   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 569   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 570   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 571
 572   # SHLIBDIR points the build tree.
 573   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 574
 575   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 576   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 577   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 578
 579   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 580     set(ENABLE_ASSERTIONS "1")
 581   else()
 582     set(ENABLE_ASSERTIONS "0")
 583   endif()
 584
 585   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 586   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 587
 588   if (CLANG_ENABLE_ARCMT)
 589     set(ENABLE_CLANG_ARCMT "1")
 590   else()
 591     set(ENABLE_CLANG_ARCMT "0")
 592   endif()
 593   if (CLANG_ENABLE_REWRITER)
 594     set(ENABLE_CLANG_REWRITER "1")
 595   else()
 596     set(ENABLE_CLANG_REWRITER "0")
 597   endif()
 598   if (CLANG_ENABLE_STATIC_ANALYZER)
 599     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 600   else()
 601     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 602   endif()
 603
 604   configure_file(${input} ${output} @ONLY)
 605 endfunction()
 606
 607 # A raw function to create a lit target. This is used to implement the testuite
 608 # management functions.
 609 function(add_lit_target target comment)
 610   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 611   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 612   separate_arguments(LIT_ARGS)
 613   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 614     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 615   endif ()
 616   set(LIT_COMMAND
 617     ${PYTHON_EXECUTABLE}
 618     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 619     ${LIT_ARGS}
 620     )
 621   foreach(param ${ARG_PARAMS})
 622     list(APPEND LIT_COMMAND --param ${param})
 623   endforeach()
 624   if( ARG_DEPENDS )
 625     add_custom_target(${target}
 626       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 627       COMMENT "${comment}"
 628       )
 629     add_dependencies(${target} ${ARG_DEPENDS})
 630   else()
 631     add_custom_target(${target}
 632       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 633     message(STATUS "${target} does nothing.")
 634   endif()
 635
 636   # Tests should be excluded from "Build Solution".
 637   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 638 endfunction()
 639
 640 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 641 function(add_lit_testsuite target comment)
 642   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 643
 644   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 645   if(NOT EXCLUDE_FROM_ALL)
 646     # Register the testsuites, params and depends for the global check rule.
 647     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 648     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 649     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 650     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 651   endif()
 652
 653   # Produce a specific suffixed check rule.
 654   add_lit_target(${target} ${comment}
 655     ${ARG_DEFAULT_ARGS}
 656     PARAMS ${ARG_PARAMS}
 657     DEPENDS ${ARG_DEPENDS}
 658     ARGS ${ARG_ARGS}
 659     )
 660 endfunction()